RFLU_TimeStepping.F90

Go to the documentation of this file.

! *********************************************************************
! * Rocstar Simulation Suite                                          *
! * Copyright@2015, Illinois Rocstar LLC. All rights reserved.        *
! *                                                                   *
! * Illinois Rocstar LLC                                              *
! * Champaign, IL                                                     *
! * www.illinoisrocstar.com                                           *
! * sales@illinoisrocstar.com                                         *
! *                                                                   *
! * License: See LICENSE file in top level of distribution package or *
! * http://opensource.org/licenses/NCSA                               *
! *********************************************************************
! *********************************************************************
! * THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND,   *
! * EXPRESS OR IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES   *
! * OF MERCHANTABILITY, FITNESS FOR A PARTICULAR PURPOSE AND          *
! * NONINFRINGEMENT.  IN NO EVENT SHALL THE CONTRIBUTORS OR           *
! * COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER       *
! * LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE,   *
! * Arising FROM, OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE    *
! * USE OR OTHER DEALINGS WITH THE SOFTWARE.                          *
! *********************************************************************
! ******************************************************************************
!
! Purpose: Integrate the governing equations in time; move/regenerate the grid.
!
! Description: None.
!
! Input: 
!   dTimeSystem         Total solution time (unsteady flow)
!   dIterSystem         Total number of iterations (steady flow)
!   regions             Data for all grid regions
!
! Output: 
!   regions             Data for all grid regions
!
! Notes: None.
!
! ******************************************************************************
!
! $Id: RFLU_TimeStepping.F90,v 1.73 2008/12/06 08:44:30 mtcampbe Exp $
!
! Copyright: (c) 2002-2006 by the University of Illinois
!
! ******************************************************************************

SUBROUTINE rflu_timestepping(dTimeSystem,dIterSystem,regions)

  USE moddatatypes
  USE moderror  
  USE modparameters
  USE modglobal, ONLY: t_global  
  USE modbndpatch, ONLY: t_patch
  USE moddatastruct, ONLY: t_region
  USE modmixture, ONLY: t_mixt_input    
  USE modmpi
  
  USE rflu_moddimensions
  USE rflu_modforcesmoments
  USE rflu_modthrustspecimpulse
  USE rflu_modgeometry
  USE rflu_modpatchcoeffs
  USE rflu_modprobes
  USE rflu_modreadwriteflow
  USE rflu_modreadwritegrid
  USE rflu_modreadwritegridspeeds
  USE rflu_modweights

  USE rflu_modtimezoom, ONLY: rflu_unzoomgridspeeds,&
                              rflu_zoomgridspeeds
  USE rflu_modboundxvutils, ONLY: rflu_bxv_writevarswrapper
  
#ifdef PLAG
  USE plag_moddimensions, ONLY: plag_calcnpclsglobal, &
                                plag_printnpclsglobal, &
                                plag_rflu_writedimensions
  USE plag_modsurfstats
#endif  
  
  USE modinterfaces, ONLY: integratesourcetermsmp, &
                           rflu_computegridspeeds, &
                           rflu_computeintegralvalues, & 
                           rflu_checkgridspeeds, &
                           rflu_decideprint, &
                           rflu_decideneedbgradface, & 
                           rflu_decidewrite, & 
                           rflu_explicitmultistage, &
                           rflu_getdeformationwrapper, & 
                           rflu_minimumtimestep, &
                           rflu_movegridwrapper, &
                           rflu_printchangeinfo, &  
                           rflu_printgridinfo, &
                           rflu_printflowinfowrapper, &
                           rflu_printwriteconvergence, &
                           rflu_residualnorm, &
                           rflu_timestepinviscid, &
                           rflu_timestepviscous, &
                           rflu_writerestartinfo, &
                           rflu_writestatsfileoles, &
                           rungekuttamp, &
                           writeprobe, &
                           writetotalmass

#ifdef GENX
  USE modinterfaces, ONLY: rflu_putboundaryvalues
#endif
#ifdef STATS
  USE modinterfaces, ONLY: rflu_writestat
  USE modstatsroutines, ONLY: getstatistics
#endif

  IMPLICIT NONE

#ifdef GENX
#include "roccomf90.h"
#endif

! ******************************************************************************
! Declarations and definitions
! ******************************************************************************  

! ==============================================================================
! Arguments
! ==============================================================================

  INTEGER :: ditersystem
  REAL(RFREAL) :: dtimesystem
  TYPE(t_region), POINTER :: regions(:)

! ==============================================================================
! Locals
! ==============================================================================

  CHARACTER(CHRLEN) :: rcsidentstring
  INTEGER :: ipatch,ireg,stophandle,dtlimcount
  LOGICAL :: doprint,doprobe,dowrite,finished,ftermnew,movegrid,residfterm, &
             stopfileexists
  TYPE(t_global), POINTER :: global
  TYPE(t_mixt_input), POINTER :: pmixtinput   
  TYPE(t_patch), POINTER :: ppatch
  TYPE(t_region), POINTER :: pregion,pregionserial

! ******************************************************************************
! Start
! ******************************************************************************

  rcsidentstring = '$RCSfile: RFLU_TimeStepping.F90,v $ $Revision: 1.73 $'

! ******************************************************************************
! Set pointers and variables
! ****************************************************************************** 

  global => regions(1)%global

  CALL registerfunction(global,'RFLU_TimeStepping',&
  'RFLU_TimeStepping.F90')

  finished = .false. ! run not finished yet

#ifdef GENX
  global%timeSinceRestart = 0.0_rfreal
#endif

! ==============================================================================
! No multigrid here
! ==============================================================================

  ftermnew   = .false. ! no new forcing term
  residfterm = .false. ! do not add forcing term to residual

! ==============================================================================
! Determine whether have moving grids
! ==============================================================================
  dtlimcount = 0
  movegrid = .false.

  DO ireg = 1,global%nRegionsLocal
    IF ( regions(ireg)%mixtInput%moveGrid .EQV. .true. ) THEN 
      movegrid = .true.
    END IF ! regions
  END DO ! iReg

! ******************************************************************************
! Loop over iterations/time steps
! ****************************************************************************** 

  DO

! ==============================================================================
!   Check for non-zero system time or iteration step. This is needed because 
!   of changed restart mechanism. If restarting code when final time was 
!   reached, can get zero time step which gives indeterminate or infinite 
!   grid speeds for moving grid computations. 
! ==============================================================================

    IF ( global%flowType == flow_unsteady ) THEN 
      IF ( dtimesystem == 0.0_rfreal ) THEN
        global%warnCounter = global%warnCounter + 1       
      
        IF ( global%myProcid == masterproc .AND. & 
             global%verbLevel > verbose_none ) THEN 
          WRITE(stdout,'(A,2(1X,A))') solver_name,'*** WARNING *** ', & 
                'Nothing to be done. Returning to calling procedure.'
        END IF ! global
        
        EXIT
      END IF ! dTimeSystem
    ELSE
      IF ( ditersystem == 0 ) THEN
        global%warnCounter = global%warnCounter + 1       
      
        IF ( global%myProcid == masterproc .AND. & 
             global%verbLevel > verbose_none ) THEN 
          WRITE(stdout,'(A,2(1X,A))') solver_name,'*** WARNING *** ', & 
                'Nothing to be done. Returning to calling procedure.'
        END IF ! global
        
        EXIT
      END IF ! dIterSystem
    END IF ! global%flowType

! ==============================================================================
!   Update iteration counter for steady flow. NOTE does not have to be done
!   here, but is more consistent, otherwise can get output for iteration 0 
!   from RFLU_DecidePrint, and again from iteration 1 because of how MOD 
!   function works. If update iteration counters here, only get output once.
! ==============================================================================

    IF ( global%flowType == flow_steady ) THEN
      global%currentIter      = global%currentIter      + 1
      global%iterSinceRestart = global%iterSinceRestart + 1
    END IF ! global%flowType

! ==============================================================================
!   Compute time step. For unsteady flow, compute minimum time step and make 
!   sure do not run over maximum time.
! ==============================================================================

    DO ireg = 1,global%nRegionsLocal  
       pregion => regions(ireg)
       
       IF ( pregion%mixtInput%flowModel == flow_euler ) THEN      
          CALL rflu_timestepinviscid(pregion)
       ELSE 
          CALL rflu_timestepviscous(pregion)
       END IF ! pRegion
    END DO ! iReg
    
    IF ( global%flowType == flow_unsteady ) THEN         
       CALL rflu_minimumtimestep(regions)
#ifdef GENX
       IF ( global%dtMin < global%dtImposed .AND. &
            global%dtMin < global%dtMinLimit ) THEN
          dtlimcount = dtlimcount + 1
          IF ( dtlimcount > 2) THEN
             dtlimcount = 0
             stophandle   = com_get_function_handle('Rocman.interrupt')
             IF(stophandle <= 0) THEN
                WRITE(*,*) 'Could not get Rocman.stop function handle.'
               ELSE
                  CALL com_call_function(stophandle,2,3,'Rocflu dt < limit, requesting remesh')
               ENDIF
            ENDIF
         ENDIF
#endif
         
         IF ( global%timeSinceRestart + global%dtMin > dtimesystem ) THEN 
            global%dtMin = dtimesystem - global%timeSinceRestart
            finished     = .true.                     
         END IF ! global%timeSinceRestart            
      END IF ! global
      
! ==============================================================================
!   Move or generate new grid
! ==============================================================================

    IF ( global%flowType == flow_unsteady ) THEN    
      IF ( movegrid .EQV. .true. ) THEN     
        CALL rflu_getdeformationwrapper(regions)        
        CALL rflu_movegridwrapper(regions)
            
        DO ireg=1,global%nRegionsLocal
          pregion => regions(ireg)
                   
          CALL rflu_buildgeometry(pregion)          
          CALL rflu_computegridspeeds(pregion)

          IF(global%zoomFactor > 1) THEN
             CALL rflu_unzoomgridspeeds(pregion)
          ENDIF
          
          IF ( global%checkLevel == check_high ) THEN           
            CALL rflu_checkgridspeeds(pregion)               
          END IF ! global%checkLevel
        END DO ! iReg
      END IF ! moveGrid     
    END IF ! global%flowType  

! ==============================================================================
!   Recompute weights
! ==============================================================================
#ifndef PROPONLY

    IF ( global%flowType == flow_unsteady ) THEN    
      IF ( movegrid .EQV. .true. ) THEN     
        DO ireg=1,global%nRegionsLocal
          pregion => regions(ireg)
          pmixtinput => pregion%mixtInput

          IF ( pmixtinput%spaceOrder > 1 ) THEN 
            CALL rflu_computewtsc2cwrapper(pregion,pmixtinput%spaceOrder-1)
          END IF ! pMixtInput%spaceOrder      

          IF ( pmixtinput%flowModel == flow_navst ) THEN
            CALL rflu_computewtsf2cwrapper(pregion,pmixtinput%spaceOrder-1)
          END IF ! pMixtInput%flowModel           
           
          DO ipatch = 1,pregion%grid%nPatches
            ppatch => pregion%patches(ipatch)

            IF ( rflu_decideneedbgradface(pregion,ppatch) .EQV. .true. ) THEN
              CALL rflu_computewtsbf2cwrapper(pregion,ppatch,ppatch%spaceOrder)
            END IF ! RFLU_DecideNeedBGradFace
          END DO ! iPatch
        END DO ! iReg
      END IF ! moveGrid     
    END IF ! global%flowType 

! ==============================================================================
!   Relocate probes
! ==============================================================================
       
    IF ( global%flowType == flow_unsteady ) THEN    
      IF ( movegrid .EQV. .true. ) THEN     
        IF ( global%nProbes > 0 ) THEN 
          DO ireg = 1,global%nRegionsLocal
            pregion => regions(ireg)
            CALL rflu_findprobecells(pregion)
          END DO ! iReg

          CALL rflu_printprobeinfo(global)
        END IF ! global         
      END IF ! moveGrid     
    END IF ! global%flowType             
            
! ==============================================================================
!   Compute new solution
! ==============================================================================

    global%forceX  = 0.0_rfreal
    global%forceY  = 0.0_rfreal
    global%forceZ  = 0.0_rfreal
    global%massIn  = 0.0_rfreal
    global%massOut = 0.0_rfreal  

    IF ( global%flowType == flow_unsteady ) THEN    
      CALL rungekuttamp(regions)      
! TEMPORARY - At present, do not use operator-split integration of chemistry
!             source terms based on modifications by Luca. This means that 
!             call source term residual function directly in SourceTermsMP.F90
!      CALL IntegrateSourceTermsMP(regions)  
! END TEMPORARY
    ELSE
      CALL rflu_explicitmultistage(regions)
    END IF ! global%flowType
 
#ifdef STATS
! ==============================================================================
!   Get statistics
! ==============================================================================

    CALL getstatistics(regions)
#endif

! ==============================================================================
!   Reset global%timeSince* variables. NOTE this must be done right before
!   the update of the various time variables, otherwise calling the routines
!   RFLU_Decide* from within rungeKuttaMP or explicitMultiStage will not work
!   correctly.
! ==============================================================================

    IF ( rflu_decideprint(global) .EQV. .true. ) THEN 
      IF ( global%flowType == flow_unsteady ) THEN    
        IF ( global%iterSinceRestart > 1 ) THEN 
          global%timeSincePrint = 0.0_rfreal
        END IF ! global%iterSinceRestart
      END IF ! global%flowType      
    END IF ! RFLU_DecidePrint

    IF ( rflu_decidewrite(global) .EQV. .true. ) THEN 
      IF ( global%flowType == flow_unsteady ) THEN    
        global%timeSinceWrite = 0.0_rfreal
      END IF ! global%flowType      
    END IF ! RFLU_DecideWrite

    IF ( rflu_decidewriteprobes(global) .EQV. .true. ) THEN 
      IF ( global%flowType == flow_unsteady ) THEN    
        IF ( global%iterSinceRestart > 1 ) THEN 
          global%timeSinceProbe = 0.0_rfreal
        END IF ! global%iterSinceRestart 
      END IF ! global%flowType      
    END IF ! RFLU_DecideWriteProbes   

! ==============================================================================
!   Update times for unsteady flow
! ==============================================================================

! ENDIF PROPONLY
#endif

    IF ( global%flowType == flow_unsteady ) THEN
      global%currentTime      = global%currentTime      + global%dtMin      
      global%timeSinceRestart = global%timeSinceRestart + global%dtMin
      
      global%timeSincePrint = global%timeSincePrint + global%dtMin
      global%timeSinceWrite = global%timeSinceWrite + global%dtMin
      global%timeSinceProbe = global%timeSinceProbe + global%dtMin      
      
      global%iterSinceRestart = global%iterSinceRestart + 1
    END IF ! global%flowType

! ==============================================================================
!   Decide whether to print/write convergence, data, and probes
! ==============================================================================

    doprint = rflu_decideprint(global)
    dowrite = rflu_decidewrite(global)
    doprobe = rflu_decidewriteprobes(global)

! ==============================================================================
!   Check for stop file
! ==============================================================================

    INQUIRE(file="STOP",exist=stopfileexists)
    IF ( stopfileexists .EQV. .true. ) THEN 
      IF ( global%myProcid  == masterproc .AND. &
           global%verbLevel /= verbose_none ) THEN
        WRITE(stdout,'(A)')      solver_name
        WRITE(stdout,'(A,1X,A)') solver_name,'Stop file detected!'
        WRITE(stdout,'(A)')      solver_name        
      END IF ! global

      finished = .true.
    END IF ! stopFileExists
  
! ==============================================================================
!   Check for end of time stepping
! ==============================================================================

    IF ( global%flowType == flow_unsteady ) THEN    
      IF ( global%timeSinceRestart >= dtimesystem ) THEN 
        finished = .true.
      END IF ! global%timeSinceRestart
    ELSE
      IF ( (doprint .EQV. .true.) .OR. (global%iterSinceRestart >= ditersystem) ) THEN 
        CALL rflu_residualnorm(regions)    
        IF ( (global%iterSinceRestart >= ditersystem) .OR. &
             (global%residual/global%resInit <= global%resTol) ) THEN 
           finished = .true.
        END IF ! global%iterSinceRestart      
      END IF ! doPrint
    END IF ! global%flowType

! ==============================================================================
!   Write convergence (file & screen) and total mass (file) history
! ==============================================================================

    IF ( (doprint .EQV. .true.) .OR. (finished .EQV. .true.) ) THEN
      CALL rflu_printwriteconvergence(global)
      
#ifndef GENX      
      IF ( movegrid .EQV. .true. ) THEN
        CALL rflu_computeintegralvalues(regions) 
        CALL writetotalmass(regions)
      END IF ! moveGrid
#endif    
      
#ifndef PROPONLY
      DO ireg = 1,global%nRegionsLocal
        IF ( regions(ireg)%mixtInput%spaceDiscr == discr_opt_les ) THEN 
          CALL rflu_writestatsfileoles(global)
        END IF ! mixtInput
      END DO ! iReg
#endif
    END IF ! doPrint

#ifndef PROPONLY
! ==============================================================================
!   Compute forces and mass flow
! ==============================================================================

    IF ( global%forceFlag .EQV. .true. ) THEN 
      IF ( (dowrite .EQV. .true.) .OR. (finished .EQV. .true.) ) THEN 
        DO ireg = 1,global%nRegionsLocal
          pregion => regions(ireg)

          CALL rflu_computelocalforcesmoments(pregion)     
        END DO ! iReg

        CALL rflu_computeglobalforcesmoments(regions)

        DO ireg = 1,global%nRegionsLocal
          pregion => regions(ireg)

          CALL rflu_tsi_computeglobalthrustsi(pregion)     
        END DO ! iReg

        pregion => regions(1)

        IF ( pregion%global%myProcid == masterproc ) THEN 
          CALL rflu_printglobalforcesmoments(pregion)
          CALL rflu_writeglobalforcesmoments(pregion)
          CALL rflu_tsi_printglobalvals(pregion)
          CALL rflu_tsi_writeglobalvals(pregion)
        END IF ! pRegion
      END IF ! doWrite
    END IF ! global%forceFlag

! ==============================================================================
!   Store probe data
! ==============================================================================

    IF ( global%nProbes > 0 ) THEN
      IF ( doprobe .EQV. .true. ) THEN 
        DO ireg = 1,global%nRegionsLocal
          CALL writeprobe(regions,ireg)
        END DO ! iReg
      END IF ! doProbe
    END IF ! global

#ifndef GENX
! ==============================================================================
!   Store flow field (and grid if moving). Write restart info file after 
!   flow (and grid) files so that should those not be written due to reaching
!   the time limit, the restart file will not contain the time level of the 
!   incomplete flow (and grid) files.
! ==============================================================================

    IF ( (dowrite .EQV. .true.) .AND. (finished .EQV. .false.) ) THEN            
#ifdef PLAG
      IF ( global%plagUsed .EQV. .true. ) THEN
        CALL plag_calcnpclsglobal(regions)

        IF ( global%myProcid == masterproc ) THEN 
          pregionserial => regions(0)

          CALL plag_rflu_writedimensions(pregionserial)
        END IF ! global%myProcid
      END IF ! global%plagUsed
#endif

      DO ireg=1,global%nRegionsLocal
        pregion => regions(ireg)

        CALL rflu_writedimensionswrapper(pregion,write_dimens_mode_maybe)
                
        IF ( movegrid .EQV. .true. ) THEN        
          CALL rflu_writegridwrapper(pregion)
          CALL rflu_writegridspeedswrapper(pregion)
          
          IF ( global%myProcid == masterproc .AND. &
               global%verbLevel > verbose_none ) THEN           
            CALL rflu_printgridinfo(pregion)
          END IF ! global%myProcid
        END IF ! moveGrid
                       
        CALL rflu_writeflowwrapper(pregion)
        CALL rflu_bxv_writevarswrapper(pregion)

        IF ( global%patchCoeffFlag .EQV. .true. ) THEN 
          CALL rflu_writepatchcoeffswrapper(pregion)
        END IF ! global%patchCoeffFlag
        
#ifdef PLAG
        IF ( global%plagUsed .EQV. .true. ) THEN 
          CALL plag_writesurfstatswrapper(pregion)
        END IF ! global%plagUsed
#endif  
        
        IF ( global%myProcid == masterproc .AND. &
             global%verbLevel > verbose_none ) THEN          
          CALL rflu_printflowinfowrapper(pregion)
          
          IF ( global%verbLevel > verbose_low ) THEN 
            CALL rflu_printchangeinfo(pregion)
          END IF ! global%verbLevel

#ifdef PLAG
          IF ( global%plagUsed .EQV. .true. ) THEN 
            CALL plag_printnpclsglobal(pregion)
          END IF ! global%plagUsed
#endif
        END IF ! global%myProcid        
      END DO ! iReg
      
      CALL rflu_writerestartinfo(global)      
    END IF ! doWrite

#ifdef STATS
! ==============================================================================
!   Output statistics
! ==============================================================================

    IF ( (dowrite .EQV. .true.) .AND. (finished .EQV. .false.) .AND. &
         (global%doStat == active) ) THEN
      IF (global%myProcid==masterproc .AND. &
          global%verbLevel/=verbose_none) THEN
        WRITE(stdout,'(A)') solver_name,'Saving statistics ...'
      ENDIF
      
      DO ireg = 1,global%nRegionsLocal
        pregion => regions(ireg)
        CALL rflu_writestat(pregion)
      END DO ! iReg
    END IF ! iReg
#endif
#endif
#endif

! ==============================================================================
!   If run finished, update GENX buffers and exit
! ==============================================================================

    IF ( finished .EQV. .true. ) THEN 
#ifdef GENX
       DO ireg = 1,global%nRegionsLocal
         CALL rflu_putboundaryvalues(regions(ireg))
       END DO ! iReg
       
       global%timeStamp = global%currentTime       
#endif    
      EXIT
    END IF ! finished

  END DO ! loop over time/iterations

! ******************************************************************************
! End
! ****************************************************************************** 

  CALL deregisterfunction(global)

END SUBROUTINE rflu_timestepping

! ******************************************************************************
!
! RCS Revision history:
!
! $Log: RFLU_TimeStepping.F90,v $
! Revision 1.73  2008/12/06 08:44:30  mtcampbe
! Updated license.
!
! Revision 1.72  2008/11/19 22:17:43  mtcampbe
! Added Illinois Open Source License/Copyright
!
! Revision 1.71  2007/04/14 14:25:56  mtcampbe
! Updated for TZ
!
! Revision 1.70  2007/03/31 23:54:34  haselbac
! Bug fix: Writing of PLAG dims should only be called by serial region on master proc
!
! Revision 1.69  2007/03/27 00:41:17  haselbac
! Added calls to calculate, write, and print particle dimensions
!
! Revision 1.68  2007/02/18 03:17:56  mtcampbe
! Added proponly for Rocstar proponly runs
!
! Revision 1.67  2006/10/20 21:33:07  mparmar
! Added calls to write thrust/specific impulse and again added code for NSCBC implementation
!
! Revision 1.66  2006/09/12 14:58:44  mtcampbe
! Moved include of Roccom after IMPLICIT NONE
!
! Revision 1.65  2006/09/11 15:43:11  mtcampbe
! Added Rocman interrupt call to support automatic remeshing.
!
! Revision 1.64  2006/08/19 15:40:04  mparmar
! Changed because of NSCBC implementation
!
! Revision 1.63  2006/04/07 16:04:03  haselbac
! Adapted to changes in bf2c wts computation
!
! Revision 1.62  2006/04/07 15:19:22  haselbac
! Removed tabs
!
! Revision 1.61  2006/04/07 14:55:06  haselbac
! Adapted to changes in bface stencil routine
!
! Revision 1.60  2006/03/09 14:10:31  haselbac
! Now call wrapper routine for F2C weights
!
! Revision 1.59  2006/01/06 22:16:13  haselbac
! Adapted to name changes, removed commented-out call to ExplMS routine
!
! Revision 1.58  2005/11/10 16:51:29  fnajjar
! Added plagUsed IF statement around PLAG routines
!
! Revision 1.57  2005/10/25 19:39:23  haselbac
! Added IF on forceFlag
!
! Revision 1.56  2005/10/05 14:20:35  haselbac
! Added call to recompute bface wts for moving grids
!
! Revision 1.55  2005/08/09 00:59:56  haselbac
! Enclosed writing of patch coeffs within IF (patchCoeffFlag)
!
! Revision 1.54  2005/06/06 14:23:35  haselbac
! Adapted to Lucas changes
!
! Revision 1.53  2005/05/16 20:44:55  haselbac
! Now compute time step also for steady flow, call RFLU_ExplicitMultiStage
!
! Revision 1.52  2005/04/29 12:50:00  haselbac
! Added USE RFLU_ModProbes, removed interfaces for probe routines
!
! Revision 1.51  2005/04/20 14:44:04  haselbac
! Removed CHECK_UNIFLOW code section
!
! Revision 1.50  2005/04/15 15:07:26  haselbac
! Now use RFLU_PrintWriteConvergence, fixed bug in writing forces
!
! Revision 1.49  2004/12/28 20:28:20  wasistho
! moved statistics routines into module ModStatsRoutines
!
! Revision 1.48  2004/12/21 15:05:11  fnajjar
! Included calls for PLAG surface statistics
!
! Revision 1.47  2004/11/29 17:17:29  wasistho
! use ModInterfacesStatistics
!
! Revision 1.46  2004/11/03 17:05:53  haselbac
! Removed HACK_PERIODIC ifdef
!
! Revision 1.45  2004/10/19 19:29:36  haselbac
! Added writing of grid speeds, changed time step interfaces, cosmetics
!
! Revision 1.44  2004/07/06 15:14:53  haselbac
! Adapted to changes in libflu and modflu, cosmetics
!
! Revision 1.43  2004/06/16 20:01:15  haselbac
! Added forces and moments stuff, cosmetics
!
! Revision 1.42  2004/04/14 02:10:07  haselbac
! Removed call to DescaleGridSpeeds
!
! Revision 1.41  2004/04/01 21:30:35  haselbac
! Added IntegrateSourceTermsMP, cosmetic changes
!
! Revision 1.40  2004/03/17 04:28:25  haselbac
! Adapted call to RFLU_WriteDimensionsWrapper
!
! Revision 1.39  2004/03/11 16:34:32  fnajjar
! ACH: Changed call to RFLU_WriteDimWrapper bcos of Rocpart
!
! Revision 1.38  2004/01/31 03:59:03  haselbac
! Improved updating of iteration counters
!
! Revision 1.37  2004/01/29 22:59:24  haselbac
! Added setting of timeSince* vars for improved useability of RFLU_Decide* 
! funcs
!
! Revision 1.36  2003/12/04 03:30:09  haselbac
! Adapted recomputation of weights
!
! Revision 1.35  2003/11/25 21:04:46  haselbac
! Added call to RFLU_PrintFlowInfoWrapper, cosmetic changes
!
! Revision 1.34  2003/11/04 01:35:27  haselbac
! Bug fix: added init for timeSinceRestart for GENX
!
! Revision 1.33  2003/10/29 21:39:57  haselbac
! Bug fix and clean-up: Writing of data to screen and files
!
! Revision 1.32  2003/10/15 02:44:21  haselbac
! Removed unnecessary initialization of dtMin
!
! Revision 1.31  2003/10/03 20:47:21  haselbac
! Changed from RungeKutta to RungeKuttaMP
!
! Revision 1.30  2003/08/13 20:28:49  haselbac
! Fixed bug with writing probe data within GENx
!
! Revision 1.29  2003/07/22 02:11:40  haselbac
! Added global%warnCounter
!
! Revision 1.28  2003/07/09 22:37:48  haselbac
! Added check to avoid wrong restart, find probes on moving grids
!
! Revision 1.27  2003/06/20 22:36:23  haselbac
! Added call to RFLU_WriteRestartInfo, fixed bug in steady conv check
!
! Revision 1.26  2003/04/24 15:43:35  haselbac
! Adapted interface to RFLU_PutBoundaryValues
!
! Revision 1.25  2003/04/07 14:27:44  haselbac
! Added interval writing of probe info
!
! Revision 1.24  2003/03/31 16:18:17  haselbac
! Replaced MoveGrid call by call to wrapper
!
! Revision 1.23  2003/03/15 18:59:56  haselbac
! Added calls to DescaleGridSpeeds and GetDeformationWrapper
!
! Revision 1.22  2003/02/25 21:47:39  haselbac
! Added call to DescaleGridSpeeds
!
! Revision 1.21  2003/01/28 14:52:08  haselbac
! Changes to be consistent with rewrite of RFLU_InitFlowSolver
!
! Revision 1.20  2002/12/20 23:21:33  haselbac
! Fixed output bug: no output for verbosity=0
!
! Revision 1.19  2002/11/15 21:26:49  haselbac
! Added RFLU_ComputeIntegralValues
!
! Revision 1.18  2002/11/08 21:36:25  haselbac
! Fixed bug in grid-speed comp, added RFLU_CheckGridSpeeds and WriteTotalMass
!
! Revision 1.17  2002/11/02 02:04:49  wasistho
! Added TURB statistics
!
! Revision 1.16  2002/10/27 19:19:31  haselbac
! Logical modifications of last part, cosmetic redesign
!
! Revision 1.15  2002/10/16 21:18:50  haselbac
! Added call to RFLU_NewGrid, some rearrangement of calls
!
! Revision 1.14  2002/10/12 15:00:44  haselbac
! Added statements for time check for GENX runs
!
! Revision 1.13  2002/10/05 19:35:19  haselbac
! Call wrapper routines for output, write probe data
!
! Revision 1.12  2002/09/09 15:51:56  haselbac
! global and mixtInput under regions, adapated calls to RFLU_CheckCalcGrad, 
! OLES routines removed, added viscous calls
!
! Revision 1.11  2002/07/25 14:23:40  haselbac
! Added OLES calls, gradient check, and HACK_PERIODIC segment
!
! Revision 1.10  2002/06/18 00:26:20  wasistho
! Added prefix SOLVER NAME to satistics STDOutput
!
! Revision 1.9  2002/06/17 13:34:12  haselbac
! Prefixed SOLVER_NAME to all screen output
!
! Revision 1.8  2002/06/14 22:26:08  wasistho
! update statistics
!
! Revision 1.7  2002/06/14 21:54:35  wasistho
! Added time avg statistics
!
! Revision 1.6  2002/06/14 20:19:46  haselbac
! Deleted ModLocal, changed local%nRegions to global%nRegionsLocal
!
! Revision 1.5  2002/06/10 21:35:50  haselbac
! Changed order of convergence and file writing, changed flag to CHECK_UNIFLOW
!
! Revision 1.4  2002/06/05 18:59:12  haselbac
! Miscellaneous small functionality changes
!
! Revision 1.3  2002/05/28 14:02:04  haselbac
! Activated unsteady routines
!
! Revision 1.2  2002/05/04 17:13:15  haselbac
! Many changes to enable flow solution
!
! Revision 1.1  2002/04/11 18:57:06  haselbac
! Initial revision, commented out RFLO stuff
!
! ******************************************************************************