RFLU_ModBoundXvUtils.F90

Go to the documentation of this file.

! *********************************************************************
! * Rocstar Simulation Suite                                          *
! * Copyright@2015, Illinois Rocstar LLC. All rights reserved.        *
! *                                                                   *
! * Illinois Rocstar LLC                                              *
! * Champaign, IL                                                     *
! * www.illinoisrocstar.com                                           *
! * sales@illinoisrocstar.com                                         *
! *                                                                   *
! * License: See LICENSE file in top level of distribution package or *
! * http://opensource.org/licenses/NCSA                               *
! *********************************************************************
! *********************************************************************
! * THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND,   *
! * EXPRESS OR IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES   *
! * OF MERCHANTABILITY, FITNESS FOR A PARTICULAR PURPOSE AND          *
! * NONINFRINGEMENT.  IN NO EVENT SHALL THE CONTRIBUTORS OR           *
! * COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER       *
! * LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE,   *
! * Arising FROM, OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE    *
! * USE OR OTHER DEALINGS WITH THE SOFTWARE.                          *
! *********************************************************************
! ******************************************************************************
!
! Purpose: Collection of routines for boundary data.
!
! Description: None.
!
! Notes: None. 
!
! ******************************************************************************
!
! $Id: RFLU_ModBoundXvUtils.F90,v 1.6 2008/12/06 08:44:20 mtcampbe Exp $
!
! Copyright: (c) 2006 by the University of Illinois
!
! ******************************************************************************

MODULE rflu_modboundxvutils

  USE modparameters
  USE moddatatypes  
  USE modglobal, ONLY: t_global
  USE modgrid, ONLY: t_grid
  USE modbndpatch, ONLY: t_patch  
  USE moddatastruct, ONLY: t_region
  USE modmixture, ONLY: t_mixt_input
  USE moderror
  USE modmpi

  USE rflu_modnscbc, ONLY: rflu_nscbc_initsw, &
                           rflu_nscbc_initnswheat, &
                           rflu_nscbc_initnswtemp, &
                           rflu_nscbc_initiftotang, &
                           rflu_nscbc_initifveltemp, &
                           rflu_nscbc_initof, &
                           rflu_nscbc_initff, &
                           rflu_nscbc_initij, &
                           rflu_nscbc_decidehavenscbc
                           
  USE modinterfaces, ONLY: mixtperf_c_grt, &
                           mixtperf_eo_dgpuvw, &
                           mixtperf_eo_grtuvw, &
                           mixtperf_g_cpr, &
                           mixtperf_p_deogvm2, &
                           mixtperf_r_m, &
                           mixtperf_t_dpr

  IMPLICIT NONE

! ******************************************************************************
! Declarations and definitions
! ******************************************************************************

! ==============================================================================
! Private data
! ==============================================================================

  CHARACTER(CHRLEN), PRIVATE :: & 
    RCSIdentString = '$RCSfile: RFLU_ModBoundXvUtils.F90,v $ $Revision: 1.6 $'

! ==============================================================================
! Public functions
! ==============================================================================

  PUBLIC :: rflu_bxv_computevarscv, &
            rflu_bxv_createvarscv, &
            rflu_bxv_createvarsdv, &
            rflu_bxv_createvarststep, &            
            rflu_bxv_destroyvarscv, &
            rflu_bxv_destroyvarsdv, &
            rflu_bxv_destroyvarststep, &
            rflu_bxv_initvars, &
            rflu_bxv_nullifyvarscv, &
            rflu_bxv_nullifyvarsdv, &
            rflu_bxv_nullifyvarststep, &
            rflu_bxv_readvarsascii, &
            rflu_bxv_readvarsbinary, &            
            rflu_bxv_readvarswrapper, &
            rflu_bxv_setdependentvars, &
            rflu_bxv_writevarsascii, &
            rflu_bxv_writevarsbinary, &            
            rflu_bxv_writevarswrapper

! ==============================================================================
! Private functions
! ==============================================================================

  PRIVATE :: rflu_bxv_compenergypatch, &             
             rflu_bxv_compmomenergypatch, & 
             rflu_bxv_setdependentvarspatch

! ******************************************************************************
! Routines
! ******************************************************************************

  CONTAINS







! ******************************************************************************
!
! Purpose: Compute conserved variables on patches.
!
! Description: None.
!
! Input:
!   pRegion     Pointer to region
!
! Output: None.
!
! Notes: None.
!
! ******************************************************************************

SUBROUTINE rflu_bxv_computevarscv(pRegion)

  IMPLICIT NONE

! ******************************************************************************
! Definitions and declarations
! ******************************************************************************

! ==============================================================================
! Arguments
! ==============================================================================

  TYPE(t_region), POINTER :: pregion

! ==============================================================================
! Locals
! ==============================================================================

  INTEGER :: ipatch
  TYPE(t_patch), POINTER :: ppatch
  TYPE(t_global), POINTER :: global

! ******************************************************************************
! Start
! ******************************************************************************

  global => pregion%global

  CALL registerfunction(global,'RFLU_BXV_ComputeVarsCv',&
  'RFLU_ModBoundXvUtils.F90')

! ******************************************************************************
! Loop over patches and set dependent variables
! ******************************************************************************

  DO ipatch = 1,pregion%grid%nPatches
    ppatch => pregion%patches(ipatch)

    IF ( ppatch%bcKind == bc_kind_nscbc ) THEN
      SELECT CASE( ppatch%bcType )
        CASE (bc_slipwall)
        CASE (bc_noslipwall_hflux)
        CASE (bc_noslipwall_temp)
        CASE (bc_inflow_totang)
        CASE (bc_inflow_veltemp)
          IF ( ppatch%mixt%switches(bcswi_inflow_type) == bcopt_subsonic ) THEN
            IF ( ppatch%reflect == bc_reflecting ) THEN
              CALL rflu_bxv_compmomenergypatch(pregion,ppatch)
            END IF ! pPatch%reflect
          END IF ! pPatch%mixt%switches
        CASE (bc_outflow)
          IF ( ppatch%mixt%switches(bcswi_outflow_type) == bcopt_subsonic ) THEN
            IF ( ppatch%reflect == bc_reflecting ) THEN
              CALL rflu_bxv_compenergypatch(pregion,ppatch)
            END IF ! pPatch%reflect
          END IF ! pPatch%mixt%switches
        CASE (bc_farfield)
        CASE (bc_injection)
        CASE default
          CALL errorstop(global,err_reached_default,__line__)
      END SELECT ! pPatch%bcType
    END IF ! pPatch%bcKind
  END DO ! iPatch

! ******************************************************************************
! End
! ******************************************************************************

  CALL deregisterfunction(global)

END SUBROUTINE rflu_bxv_computevarscv








! ******************************************************************************
!
! Purpose: Compute energy on patches.
!
! Description: None.
!
! Input:
!   pRegion     Pointer to region
!   pPatch      Pointer to patch
!
! Output: None.
!
! Notes: None.
!
! ******************************************************************************

SUBROUTINE rflu_bxv_compenergypatch(pRegion,pPatch)

  IMPLICIT NONE

! ******************************************************************************
! Definitions and declarations
! ******************************************************************************

! ==============================================================================
! Arguments
! ==============================================================================

  TYPE(t_patch), POINTER :: ppatch
  TYPE(t_region), POINTER :: pregion

! ==============================================================================
! Locals
! ==============================================================================

  INTEGER :: ifl,icg,indcp,indmol
  REAL(RFREAL) :: eo,r,u,v,w,p,ru,rv,rw,mw,cp,gc,g
  REAL(RFREAL), DIMENSION(:,:), POINTER :: pcv,pdv,pgv
  TYPE(t_global), POINTER :: global

! ******************************************************************************
! Start
! ******************************************************************************

  global => pregion%global

  CALL registerfunction(global,'RFLU_BXV_CompEnergyPatch',&
  'RFLU_ModBoundXvUtils.F90')

! ******************************************************************************
! Set variables and pointers
! ******************************************************************************

  pcv => ppatch%mixt%cv
  pdv => ppatch%mixt%dv
  pgv => pregion%mixt%gv ! NOTE gv taken from cells for now

  indcp  = pregion%mixtInput%indCp
  indmol = pregion%mixtInput%indMol

! ******************************************************************************
! Compute total energy for patch data
! ******************************************************************************

  DO ifl = 1,ppatch%nBFaces
    icg  = ppatch%bf2c(ifl) 

    r  = pcv(cv_mixt_dens,ifl)
    ru = pcv(cv_mixt_xmom,ifl)
    rv = pcv(cv_mixt_ymom,ifl)
    rw = pcv(cv_mixt_zmom,ifl)
    p  = pdv(dv_mixt_pres,ifl)

    u = ru/r
    v = rv/r
    w = rw/r

    mw = pgv(gv_mixt_mol,indmol*icg)
    cp = pgv(gv_mixt_cp ,indcp *icg)
    gc = mixtperf_r_m(mw)
    g  = mixtperf_g_cpr(cp,gc)

    eo = mixtperf_eo_dgpuvw(r,g,p,u,v,w)

    pcv(cv_mixt_ener,ifl) = r*eo
  END DO ! ifl

! ******************************************************************************
! End
! ******************************************************************************

  CALL deregisterfunction(global)

END SUBROUTINE rflu_bxv_compenergypatch









! ******************************************************************************
!
! Purpose: Compute momentum and energy on patches.
!
! Description: None.
!
! Input:
!   pRegion     Pointer to region
!   pPatch      Pointer to patch
!
! Output: None.
!
! Notes: None.
!
! ******************************************************************************

SUBROUTINE rflu_bxv_compmomenergypatch(pRegion,pPatch)

  IMPLICIT NONE

! ******************************************************************************
! Definitions and declarations
! ******************************************************************************

! ==============================================================================
! Arguments
! ==============================================================================

  TYPE(t_patch), POINTER :: ppatch
  TYPE(t_region), POINTER :: pregion

! ==============================================================================
! Locals
! ==============================================================================

  INTEGER :: ifl,icg,indcp,indmol,distrib
  REAL(RFREAL) :: eo,r,u,v,w,ru,rv,rw,mw,cp,gc,g,t
  REAL(RFREAL), DIMENSION(:,:), POINTER :: pcv,pdv,pgv,vals
  TYPE(t_global), POINTER :: global

! ******************************************************************************
! Start
! ******************************************************************************

  global => pregion%global

  CALL registerfunction(global,'RFLU_BXV_CompMomEnergyPatch',&
  'RFLU_ModBoundXvUtils.F90')

! ******************************************************************************
! Set variables and pointers
! ******************************************************************************

  distrib = ppatch%mixt%distrib

  pcv  => ppatch%mixt%cv
  vals => ppatch%mixt%vals
  pgv => pregion%mixt%gv ! NOTE gv taken from cells for now

  indcp  = pregion%mixtInput%indCp
  indmol = pregion%mixtInput%indMol

! ******************************************************************************
! Compute Momentum variables for patch data
! ******************************************************************************

  DO ifl = 1,ppatch%nBFaces
    icg  = ppatch%bf2c(ifl) 

    r  = pcv(cv_mixt_dens,ifl)

    u = vals(bcdat_inflow_u,distrib*ifl) 
    v = vals(bcdat_inflow_v,distrib*ifl)
    w = vals(bcdat_inflow_w,distrib*ifl)

    t = vals(bcdat_inflow_t,distrib*ifl)

    mw = pgv(gv_mixt_mol,indmol*icg)
    cp = pgv(gv_mixt_cp ,indcp *icg)
    gc = mixtperf_r_m(mw)
    g  = mixtperf_g_cpr(cp,gc)

    eo = mixtperf_eo_grtuvw(g,gc,t,u,v,w)

    pcv(cv_mixt_xmom,ifl) = r*u
    pcv(cv_mixt_ymom,ifl) = r*v
    pcv(cv_mixt_zmom,ifl) = r*w
    pcv(cv_mixt_ener,ifl) = r*eo
  END DO ! ifl

! ******************************************************************************
! End
! ******************************************************************************

  CALL deregisterfunction(global)

END SUBROUTINE rflu_bxv_compmomenergypatch








! ******************************************************************************
!
! Purpose: Allocate memory for conserved variables on boundary. 
!
! Description: None.
!
! Input:
!   pRegion        Region pointer
!
! Output: None.
!
! Notes: None.
!
! ******************************************************************************

SUBROUTINE rflu_bxv_createvarscv(pRegion)

  IMPLICIT NONE

! ******************************************************************************
! Definitions and declarations
! ******************************************************************************

! ==============================================================================
! Arguments
! ==============================================================================

  TYPE(t_region), POINTER :: pregion

! ==============================================================================
! Locals
! ==============================================================================

  INTEGER :: errorflag,ipatch
  TYPE(t_patch), POINTER :: ppatch
  TYPE(t_global), POINTER :: global

! ******************************************************************************
! Start
! ******************************************************************************

  global => pregion%global

  CALL registerfunction(global,'RFLU_BXV_CreateVarsCv',&
  'RFLU_ModBoundXvUtils.F90')

! ******************************************************************************
! Loop over patches and allocate memory
! ******************************************************************************

  DO ipatch = 1,pregion%grid%nPatches
    ppatch => pregion%patches(ipatch)

    IF (ppatch%bcKind == bc_kind_nscbc ) THEN
      ALLOCATE(ppatch%mixt%cv(pregion%mixtInput%nCv,ppatch%nBFaces), &
               stat=errorflag)
      global%error = errorflag
      IF (global%error /= err_none) THEN
        CALL errorstop(global,err_allocate,__line__,'pPatch%mixt%cv')
      END IF ! global%error
    END IF ! pPatch%bcKind
  END DO ! iPatch

! ******************************************************************************
! End
! ******************************************************************************

  CALL deregisterfunction(global)

END SUBROUTINE rflu_bxv_createvarscv







! ******************************************************************************
!
! Purpose: Allocate memory for dependent variables on boundary.
!
! Description: None.
!
! Input:
!   pRegion        Region pointer
!
! Output: None.
!
! Notes: None.
!
! ******************************************************************************

SUBROUTINE rflu_bxv_createvarsdv(pRegion)

  IMPLICIT NONE

! ******************************************************************************
! Definitions and declarations
! ******************************************************************************

! ==============================================================================
! Arguments
! ==============================================================================

  TYPE(t_region), POINTER :: pregion

! ==============================================================================
! Locals
! ==============================================================================

  INTEGER :: errorflag, ipatch
  TYPE(t_patch), POINTER :: ppatch
  TYPE(t_global), POINTER :: global

! ******************************************************************************
! Start
! ******************************************************************************

  global => pregion%global

  CALL registerfunction(global,'RFLU_BXV_CreateVarsDv',&
  'RFLU_ModBoundXvUtils.F90')

! ******************************************************************************
! Loop over patches and allocate memory
! ******************************************************************************

  DO ipatch = 1,pregion%grid%nPatches
    ppatch => pregion%patches(ipatch)

    IF ( ppatch%bcKind == bc_kind_nscbc ) THEN
      ALLOCATE(ppatch%mixt%dv(pregion%mixtInput%nDv,ppatch%nBFaces), &
               stat=errorflag)
      global%error = errorflag
      IF (global%error /= err_none) THEN
        CALL errorstop(global,err_allocate,__line__,'pPatch%mixt%dv')
      END IF ! global%error
    END IF ! pPatch%bcKind
  END DO ! iPatch

! ******************************************************************************
! End
! ******************************************************************************

  CALL deregisterfunction(global)

END SUBROUTINE rflu_bxv_createvarsdv






! ******************************************************************************
!
! Purpose: Allocate memory for time-stepping variables on boundary. 
!
! Description: None.
!
! Input:
!   pRegion        Region pointer
!
! Output: None.
!
! Notes: None.
!
! ******************************************************************************

SUBROUTINE rflu_bxv_createvarststep(pRegion)

  IMPLICIT NONE

! ******************************************************************************
! Definitions and declarations
! ******************************************************************************

! ==============================================================================
! Arguments
! ==============================================================================

  TYPE(t_region), POINTER :: pregion

! ==============================================================================
! Locals
! ==============================================================================

  INTEGER :: errorflag,ipatch
  TYPE(t_patch), POINTER :: ppatch
  TYPE(t_global), POINTER :: global

! ******************************************************************************
! Start
! ******************************************************************************

  global => pregion%global

  CALL registerfunction(global,'RFLU_BXV_CreateVarsTStep',&
  'RFLU_ModBoundXvUtils.F90')

! ******************************************************************************
! Loop over patches and Allocate memory
! ******************************************************************************

  DO ipatch = 1,pregion%grid%nPatches
    ppatch => pregion%patches(ipatch)

    IF (ppatch%bcKind == bc_kind_nscbc ) THEN
      ALLOCATE(ppatch%mixt%cvOld(pregion%mixtInput%nCv,ppatch%nBFaces), &
               stat=errorflag)
      global%error = errorflag
      IF (global%error /= err_none) THEN
        CALL errorstop(global,err_allocate,__line__,'pPatch%mixt%cvOld')
      END IF ! global%error

      ALLOCATE(ppatch%mixt%rhs(pregion%mixtInput%nCv,ppatch%nBFaces), &
               stat=errorflag)
      global%error = errorflag
      IF (global%error /= err_none) THEN
        CALL errorstop(global,err_allocate,__line__,'pPatch%mixt%rhs')
      END IF ! global%error

      ALLOCATE(ppatch%mixt%rhsSum(pregion%mixtInput%nCv,ppatch%nBFaces), &
               stat=errorflag)
      global%error = errorflag
      IF (global%error /= err_none) THEN
        CALL errorstop(global,err_allocate,__line__,'pPatch%mixt%rhsSum')
      END IF ! global%error
    END IF ! pPatch%bcKind
  END DO ! iPatch

! ******************************************************************************
! End
! ******************************************************************************

  CALL deregisterfunction(global)

END SUBROUTINE rflu_bxv_createvarststep






! ******************************************************************************
!
! Purpose: Destroy conserved variables on patches.
!
! Description: None.
!
! Input:
!   pRegion     Pointer to region
!
! Output: None.
!
! Notes: None.
!
! ******************************************************************************

SUBROUTINE rflu_bxv_destroyvarscv(pRegion)

  IMPLICIT NONE

! ******************************************************************************
! Definitions and declarations
! ******************************************************************************

! ==============================================================================
! Arguments
! ==============================================================================

  TYPE(t_region), POINTER :: pregion

! ==============================================================================
! Locals
! ==============================================================================

  INTEGER :: errorflag, ipatch
  TYPE(t_patch), POINTER :: ppatch
  TYPE(t_global), POINTER :: global

! ******************************************************************************
! Start
! ******************************************************************************

  global => pregion%global

  CALL registerfunction(global,'RFLU_BXV_DestroyVarsCv',&
  'RFLU_ModBoundXvUtils.F90')

! ******************************************************************************
! Loop over patches and deallocate memory
! ******************************************************************************

  DO ipatch = 1,pregion%grid%nPatches
    ppatch => pregion%patches(ipatch)

    IF ( ppatch%bcKind == bc_kind_nscbc ) THEN
      DEALLOCATE(ppatch%mixt%cv,stat=errorflag)
      global%error = errorflag
      IF (global%error /= err_none) THEN
        CALL errorstop(global,err_deallocate,__line__,'pPatch%mixt%cv')
      END IF ! global%error
    END IF ! pPatch%bcKind
  END DO ! iPatch

  CALL rflu_bxv_nullifyvarscv(pregion)

! ******************************************************************************
! End
! ******************************************************************************

  CALL deregisterfunction(global)

END SUBROUTINE rflu_bxv_destroyvarscv






! ******************************************************************************
!
! Purpose: Destroy dependent variables on patches.
!
! Description: None.
!
! Input:
!   pRegion     Pointer to region
!
! Output: None.
!
! Notes: None.
!
! ******************************************************************************

SUBROUTINE rflu_bxv_destroyvarsdv(pRegion)

  IMPLICIT NONE

! ******************************************************************************
! Definitions and declarations
! ******************************************************************************

! ==============================================================================
! Arguments
! ==============================================================================

  TYPE(t_region), POINTER :: pregion

! ==============================================================================
! Locals
! ==============================================================================

  INTEGER :: errorflag,ipatch
  TYPE(t_patch), POINTER :: ppatch
  TYPE(t_global), POINTER :: global

! ******************************************************************************
! Start
! ******************************************************************************

  global => pregion%global

  CALL registerfunction(global,'RFLU_BXV_DestroyVarsDv',&
  'RFLU_ModBoundXvUtils.F90')

! ******************************************************************************
! Loop over patches and deallocate memory
! ******************************************************************************

  DO ipatch = 1,pregion%grid%nPatches
    ppatch => pregion%patches(ipatch)

    IF ( ppatch%bcKind == bc_kind_nscbc ) THEN
      DEALLOCATE(ppatch%mixt%dv,stat=errorflag)
      global%error = errorflag
      IF (global%error /= err_none) THEN
        CALL errorstop(global,err_deallocate,__line__,'pPatch%mixt%dv')
      END IF ! global%error
    END IF ! pPatch%bcKind
  END DO ! iPatch

  CALL rflu_bxv_nullifyvarsdv(pregion)

! ******************************************************************************
! End
! ******************************************************************************

  CALL deregisterfunction(global)

END SUBROUTINE rflu_bxv_destroyvarsdv





! ******************************************************************************
!
! Purpose: Destroy variables on patches related to time-stepping.
!
! Description: None.
!
! Input:
!   pRegion     Pointer to region
!
! Output: None.
!
! Notes: None.
!
! ******************************************************************************

SUBROUTINE rflu_bxv_destroyvarststep(pRegion)

  IMPLICIT NONE

! ******************************************************************************
! Definitions and declarations
! ******************************************************************************

! ==============================================================================
! Arguments
! ==============================================================================

  TYPE(t_region), POINTER :: pregion

! ==============================================================================
! Locals
! ==============================================================================

  INTEGER :: errorflag, ipatch
  TYPE(t_patch), POINTER :: ppatch
  TYPE(t_global), POINTER :: global

! ******************************************************************************
! Start
! ******************************************************************************

  global => pregion%global

  CALL registerfunction(global,'RFLU_BXV_DestroyVarsTStep',&
  'RFLU_ModBoundXvUtils.F90')

! ******************************************************************************
! Loop over patches and deallocate memory
! ******************************************************************************

  DO ipatch = 1,pregion%grid%nPatches
    ppatch => pregion%patches(ipatch)

    IF ( ppatch%bcKind == bc_kind_nscbc ) THEN
      DEALLOCATE(ppatch%mixt%rhs,stat=errorflag)
      global%error = errorflag
      IF (global%error /= err_none) THEN
        CALL errorstop(global,err_deallocate,__line__,'pPatch%mixt%rhs')
      END IF ! global%error

      DEALLOCATE(ppatch%mixt%rhsSum,stat=errorflag)
      global%error = errorflag
      IF (global%error /= err_none) THEN
        CALL errorstop(global,err_deallocate,__line__,'pPatch%mixt%rhs')
      END IF ! global%error
    END IF ! pPatch%bcKind
  END DO ! iPatch

  CALL rflu_bxv_nullifyvarststep(pregion)

! ******************************************************************************
! End
! ******************************************************************************

  CALL deregisterfunction(global)

END SUBROUTINE rflu_bxv_destroyvarststep








! ******************************************************************************
!
! Purpose: Initialize patch variables.
!
! Description: None.
!
! Input:
!   pRegion     Pointer to region
!
! Output: None.
!
! Notes: None.
!
! ******************************************************************************

SUBROUTINE rflu_bxv_initvars(pRegion)

  IMPLICIT NONE

! ******************************************************************************
! Definitions and declarations
! ******************************************************************************

! ==============================================================================
! Arguments
! ==============================================================================

  TYPE(t_region), POINTER :: pregion

! ==============================================================================
! Locals
! ==============================================================================

  INTEGER :: errorflag, ipatch
  TYPE(t_patch), POINTER :: ppatch
  TYPE(t_global), POINTER :: global

! ******************************************************************************
! Start
! ******************************************************************************

  global => pregion%global

  CALL registerfunction(global,'RFLU_BXV_InitVars',&
  'RFLU_ModBoundXvUtils.F90')

! ******************************************************************************
! Loop over patches and initialize patch variable arrays 
! ******************************************************************************

  DO ipatch = 1,pregion%grid%nPatches
    ppatch => pregion%patches(ipatch)

    IF ( ppatch%bcKind == bc_kind_nscbc ) THEN
      SELECT CASE( ppatch%bcType )
        CASE (bc_slipwall)
          CALL rflu_nscbc_initsw(pregion,ppatch)
        CASE (bc_noslipwall_hflux)
          CALL rflu_nscbc_initnswheat(pregion,ppatch)
        CASE (bc_noslipwall_temp)
          CALL rflu_nscbc_initnswtemp(pregion,ppatch)
        CASE (bc_inflow_totang)
          CALL rflu_nscbc_initiftotang(pregion,ppatch)
        CASE (bc_inflow_veltemp)
          CALL rflu_nscbc_initifveltemp(pregion,ppatch)
        CASE (bc_outflow)
          CALL rflu_nscbc_initof(pregion,ppatch)
        CASE (bc_farfield)
          CALL rflu_nscbc_initff(pregion,ppatch)
        CASE (bc_injection)
          CALL rflu_nscbc_initij(pregion,ppatch)
        CASE default
          CALL errorstop(global,err_reached_default,__line__)
      END SELECT ! pPatch%bcType
    END IF ! pPatch%bcKind
  END DO ! iPatch

! ******************************************************************************
! Set dependent variables for each patch 
! ******************************************************************************

  CALL rflu_bxv_setdependentvars(pregion)

! ******************************************************************************
! End
! ******************************************************************************

  CALL deregisterfunction(global)

END SUBROUTINE rflu_bxv_initvars






! ******************************************************************************
!
! Purpose: Nullify conserved variables on patches.
!
! Description: None.
!
! Input:
!   pRegion     Pointer to region
!
! Output: None.
!
! Notes: None.
!
! ******************************************************************************

SUBROUTINE rflu_bxv_nullifyvarscv(pRegion)

  IMPLICIT NONE

! ******************************************************************************
! Definitions and declarations
! ******************************************************************************

! ==============================================================================
! Arguments
! ==============================================================================

  TYPE(t_region), POINTER :: pregion

! ==============================================================================
! Locals
! ==============================================================================

  INTEGER :: errorflag, ipatch
  TYPE(t_patch), POINTER :: ppatch
  TYPE(t_global), POINTER :: global

! ******************************************************************************
! Start
! ******************************************************************************

  global => pregion%global

  CALL registerfunction(global,'RFLU_BXV_NullifyVarsCv',&
  'RFLU_ModBoundXvUtils.F90')

! ******************************************************************************
! Loop over patches and nullify memory
! ******************************************************************************

  DO ipatch = 1,pregion%grid%nPatches
    ppatch => pregion%patches(ipatch)

    IF ( ppatch%bcKind == bc_kind_nscbc ) THEN
      nullify(ppatch%mixt%cv)
    END IF ! pPatch%bcKind
  END DO ! iPatch

! ******************************************************************************
! End
! ******************************************************************************

  CALL deregisterfunction(global)

END SUBROUTINE rflu_bxv_nullifyvarscv







! ******************************************************************************
!
! Purpose: Nullify dependent variables on patches.
!
! Description: None.
!
! Input:
!   pRegion     Pointer to region
!
! Output: None.
!
! Notes: None.
!
! ******************************************************************************

SUBROUTINE rflu_bxv_nullifyvarsdv(pRegion)

  IMPLICIT NONE

! ******************************************************************************
! Definitions and declarations
! ******************************************************************************

! ==============================================================================
! Arguments
! ==============================================================================

  TYPE(t_region), POINTER :: pregion

! ==============================================================================
! Locals
! ==============================================================================

  INTEGER :: errorflag, ipatch
  TYPE(t_patch), POINTER :: ppatch
  TYPE(t_global), POINTER :: global

! ******************************************************************************
! Start
! ******************************************************************************

  global => pregion%global

  CALL registerfunction(global,'RFLU_BXV_NullifyVarsDv',&
  'RFLU_ModBoundXvUtils.F90')

! ******************************************************************************
! Loop over patches and nullify memory
! ******************************************************************************

  DO ipatch = 1,pregion%grid%nPatches
    ppatch => pregion%patches(ipatch)

    IF ( ppatch%bcKind == bc_kind_nscbc ) THEN
      nullify(ppatch%mixt%dv)
    END IF ! pPatch%bcKind
  END DO ! iPatch

! ******************************************************************************
! End
! ******************************************************************************

  CALL deregisterfunction(global)

END SUBROUTINE rflu_bxv_nullifyvarsdv







! ******************************************************************************
!
! Purpose: Nullify time-stepping variables on patches.
!
! Description: None.
!
! Input:
!   pRegion     Pointer to region
!
! Output: None.
!
! Notes: None.
!
! ******************************************************************************

SUBROUTINE rflu_bxv_nullifyvarststep(pRegion)

  IMPLICIT NONE

! ******************************************************************************
! Definitions and declarations
! ******************************************************************************

! ==============================================================================
! Arguments
! ==============================================================================

  TYPE(t_region), POINTER :: pregion

! ==============================================================================
! Locals
! ==============================================================================

  INTEGER :: errorflag, ipatch
  TYPE(t_patch), POINTER :: ppatch
  TYPE(t_global), POINTER :: global

! ******************************************************************************
! Start
! ******************************************************************************

  global => pregion%global

  CALL registerfunction(global,'RFLU_BXV_NullifyVarsTStep',&
  'RFLU_ModBoundXvUtils.F90')

! ******************************************************************************
! Loop over patches and nullify memory
! ******************************************************************************

  DO ipatch = 1,pregion%grid%nPatches
    ppatch => pregion%patches(ipatch)

    IF ( ppatch%bcKind == bc_kind_nscbc ) THEN
      nullify(ppatch%mixt%cvOld)
      nullify(ppatch%mixt%rhs)
      nullify(ppatch%mixt%rhsSum)
    END IF ! pPatch%bcKind
  END DO ! iPatch

! ******************************************************************************
! End
! ******************************************************************************

  CALL deregisterfunction(global)

END SUBROUTINE rflu_bxv_nullifyvarststep








! ******************************************************************************
!
! Purpose: Read patch variables in ASCII format.
!
! Description: None.
!
! Input:
!   pRegion     Pointer to region
!
! Output: None.
!
! Notes: None.
!
! ******************************************************************************

SUBROUTINE rflu_bxv_readvarsascii(pRegion)

  USE modbuildfilenames, ONLY: buildfilenameunsteady, &
                               buildfilenamesteady

  IMPLICIT NONE

! ******************************************************************************
! Declarations and definitions
! ******************************************************************************

! ==============================================================================
! Arguments
! ==============================================================================

  TYPE(t_region), POINTER :: pregion

! ==============================================================================
! Local variables
! ==============================================================================

  CHARACTER(CHRLEN) :: errorstring,ifilename,sectionstring
  INTEGER :: dummyinteger,errorflag,idata,ifile,ifl,ipatch,ipatchglobal, &
             loopcounter,nbfaces,ndata
  TYPE(t_global), POINTER :: global
  TYPE(t_grid), POINTER :: pgrid
  TYPE(t_patch), POINTER :: ppatch

! ******************************************************************************
! Start
! ******************************************************************************

  global => pregion%global

  CALL registerfunction(global,'RFLU_BXV_ReadVarsASCII',&
  'RFLU_ModBoundXvUtils.F90')

  IF ( global%myProcid == masterproc .AND. &
       global%verbLevel > verbose_none ) THEN
    WRITE(stdout,'(A,1X,A)') solver_name,'Reading ASCII boundary-condition' // &
                                         ' variable file...'
  END IF ! global%verbLevel

! ******************************************************************************
! Set pointers
! ******************************************************************************

  pgrid => pregion%grid

! ******************************************************************************
! Open file
! ******************************************************************************

  ifile = if_distr

  IF ( global%flowType == flow_unsteady ) THEN
    CALL buildfilenameunsteady(global,filedest_indir,'.bcva', &
                               pregion%iRegionGlobal,global%currentTime, &
                               ifilename)
  ELSE
    CALL buildfilenamesteady(global,filedest_indir,'.bcva', &
                             pregion%iRegionGlobal,global%currentIter, &
                             ifilename)
  END IF ! global%flowType

  OPEN(ifile,file=ifilename,form='FORMATTED',status='OLD',iostat=errorflag)
  global%error = errorflag
  IF ( global%error /= err_none ) THEN
    CALL errorstop(global,err_file_open,__line__,'File: '//trim(ifilename))
  END IF ! global%error

! ******************************************************************************
! Read header
! ******************************************************************************

  READ(ifile,'(A)') sectionstring
  IF ( trim(sectionstring) /= '# ROCFLU boundary-condition variable file' ) THEN
    CALL errorstop(global,err_invalid_marker,__line__,sectionstring)
  END IF ! TRIM

! ******************************************************************************
! Read data
! ******************************************************************************

  loopcounter = 0

  DO ! set up infinite loop
    loopcounter = loopcounter + 1

    READ(ifile,'(A)') sectionstring

    SELECT CASE ( trim(sectionstring) )

! ==============================================================================
!     Patch data
! ==============================================================================

      CASE ( '# Patch data' )
        IF ( global%myProcid == masterproc .AND. &
             global%verbLevel > verbose_low ) THEN
          WRITE(stdout,'(A,3X,A)') solver_name,'Patch variable...'
        END IF ! global%verbLevel

        READ(ifile,*) ipatch,ipatchglobal,nbfaces,ndata

! ------------------------------------------------------------------------------
!       Check that input correct
! ------------------------------------------------------------------------------

        IF ( ipatch > pgrid%nPatches ) THEN
          WRITE(errorstring,'(A,1X,I3)') 'Patch index invalid:',ipatch
          CALL errorstop(global,err_bcdata_value_invalid,__line__, &
                         trim(errorstring))
        END IF ! iPatch

        ppatch => pregion%patches(ipatch)

! ------------------------------------------------------------------------------
!       Check if this patch kind is NSCBC
! ------------------------------------------------------------------------------

        IF ( ppatch%bcKind /= bc_kind_nscbc ) THEN
          WRITE(errorstring,'(A,1X,I3)') 'Error in writing NSCBC variables for patch :', &
                                         ipatchglobal
          CALL errorstop(global,err_bcdata_value_invalid,__line__, &
                         trim(errorstring))
        END IF ! pPatch%bcKind

        IF ( nbfaces /= ppatch%nBFaces ) THEN
          WRITE(errorstring,'(A,1X,I6)') 'Number of faces invalid:',nbfaces
          CALL errorstop(global,err_bcdata_value_invalid,__line__, &
                           trim(errorstring))
        END IF ! nBFaces

        IF ( ipatchglobal /= ppatch%iPatchGlobal ) THEN
          WRITE(errorstring,'(A,1X,I3)') 'Global patch index invalid:', &
                                         ipatchglobal
          CALL errorstop(global,err_bcdata_value_invalid,__line__, &
                         trim(errorstring))
        END IF ! iPatchGlobal

        IF ( ndata /= pregion%mixtInput%nCv ) THEN
          WRITE(errorstring,'(A,1X,I3)') &
              'Number of pieces of data invalid:',ndata
          CALL errorstop(global,err_bcdata_value_invalid,__line__, &
                         trim(errorstring))
        END IF ! iPatchGlobal

! ------------------------------------------------------------------------------
!       Read data
! ------------------------------------------------------------------------------

        ppatch%mixt%cvState = cv_mixt_state_cons

        DO ifl = 1,ppatch%nBFaces
          DO idata = 1,pregion%mixtInput%nCv
            READ(ifile,'(1X,I6,1X,I2,1X,E23.16)') dummyinteger,dummyinteger, &
                                                  ppatch%mixt%cv(idata,ifl)
          END DO ! iData
        END DO ! ifl

! ==============================================================================
!     End marker
! ==============================================================================

      CASE ( '# End' )
        IF ( global%myProcid == masterproc .AND. &
             global%verbLevel > verbose_low ) THEN
          WRITE(stdout,'(A,3X,A)') solver_name,'End marker...'
        END IF ! global%verbLevel

        EXIT

! ==============================================================================
!     Invalid section string
! ==============================================================================

      CASE default
        IF ( global%verbLevel > verbose_low ) THEN
          WRITE(stdout,'(A,3X,A)') solver_name,sectionstring
        END IF ! verbosityLevel

        CALL errorstop(global,err_invalid_marker,__line__,sectionstring)
    END SELECT ! TRIM

! ==============================================================================
!   Guard against infinite loop - might be unnecessary because of read errors?
! ==============================================================================

    IF ( loopcounter >= limit_infinite_loop ) THEN
      CALL errorstop(global,err_infinite_loop,__line__)
    END IF ! loopCounter
  END DO ! <empty>

! ******************************************************************************
! Close file
! ******************************************************************************

  CLOSE(ifile,iostat=errorflag)
  global%error = errorflag
  IF ( global%error /= err_none ) THEN
    CALL errorstop(global,err_file_close,__line__,'File: '//trim(ifilename))
  END IF ! global%error

! ******************************************************************************
! End
! ******************************************************************************

  IF ( global%myProcid == masterproc .AND. &
       global%verbLevel > verbose_none ) THEN
    WRITE(stdout,'(A,1X,A)') solver_name,'Reading ASCII boundary-condition' // &
                                         ' variable file done.'
  END IF ! global%verbLevel

  CALL deregisterfunction(global)

END SUBROUTINE rflu_bxv_readvarsascii






! ******************************************************************************
!
! Purpose: Read patch variables in binary format.
!
! Description: None.
!
! Input:
!   pRegion     Pointer to region
!
! Output: None.
!
! Notes: None.
!
! ******************************************************************************

SUBROUTINE rflu_bxv_readvarsbinary(pRegion)

  USE modbuildfilenames, ONLY: buildfilenameunsteady, &
                               buildfilenamesteady

  IMPLICIT NONE

! ******************************************************************************
! Declarations and definitions
! ******************************************************************************

! ==============================================================================
! Arguments
! ==============================================================================

  TYPE(t_region), POINTER :: pregion

! ==============================================================================
! Local variables
! ==============================================================================

  CHARACTER(CHRLEN) :: errorstring,ifilename,sectionstring
  INTEGER :: dummyinteger,errorflag,idata,ifile,ifl,ipatch,ipatchglobal, &
             loopcounter,nbfaces,ndata
  TYPE(t_global), POINTER :: global
  TYPE(t_grid), POINTER :: pgrid
  TYPE(t_patch), POINTER :: ppatch

! ******************************************************************************
! Start
! ******************************************************************************

  global => pregion%global

  CALL registerfunction(global,'RFLU_BXV_ReadVarsBinary',&
  'RFLU_ModBoundXvUtils.F90')

  IF ( global%myProcid == masterproc .AND. &
       global%verbLevel > verbose_none ) THEN
    WRITE(stdout,'(A,1X,A)') solver_name,'Reading binary boundary-condition' // &
                                         ' variable file...'
  END IF ! global%verbLevel

! ******************************************************************************
! Set pointers
! ******************************************************************************

  pgrid => pregion%grid

! ******************************************************************************
! Open file
! ******************************************************************************

  ifile = if_distr

  IF ( global%flowType == flow_unsteady ) THEN
    CALL buildfilenameunsteady(global,filedest_indir,'.bcv', &
                               pregion%iRegionGlobal,global%currentTime, &
                               ifilename)
  ELSE
    CALL buildfilenamesteady(global,filedest_indir,'.bcv', &
                             pregion%iRegionGlobal,global%currentIter, &
                             ifilename)
  ENDIF ! global%flowType

  OPEN(ifile,file=ifilename,form='UNFORMATTED',status='OLD',iostat=errorflag)
  global%error = errorflag
  IF ( global%error /= err_none ) THEN
    CALL errorstop(global,err_file_open,__line__,'File: '//trim(ifilename))
  END IF ! global%error

! ******************************************************************************
! Read header
! ******************************************************************************

  READ(ifile) sectionstring
  IF ( trim(sectionstring) /= '# ROCFLU boundary-condition variable file' ) THEN
    CALL errorstop(global,err_invalid_marker,__line__,sectionstring)
  END IF ! TRIM

! ******************************************************************************
! Read data
! ******************************************************************************

  loopcounter = 0

  DO ! set up infinite loop
    loopcounter = loopcounter + 1

    READ(ifile) sectionstring

    SELECT CASE ( trim(sectionstring) )

! ==============================================================================
!     Patch data
! ==============================================================================

      CASE ( '# Patch data' )
        IF ( global%myProcid == masterproc .AND. &
             global%verbLevel > verbose_low ) THEN
          WRITE(stdout,'(A,3X,A)') solver_name,'Patch variable...'
        END IF ! global%verbLevel

        READ(ifile) ipatch,ipatchglobal,nbfaces,ndata

! ------------------------------------------------------------------------------
!       Check that input correct
! ------------------------------------------------------------------------------

        IF ( ipatch > pgrid%nPatches ) THEN
          WRITE(errorstring,'(A,1X,I3)') 'Patch index invalid:',ipatch
          CALL errorstop(global,err_bcdata_value_invalid,__line__, &
                         trim(errorstring))
        END IF ! iPatch

        ppatch => pregion%patches(ipatch)

! ------------------------------------------------------------------------------
!       Check if this patch kind is NSCBC
! ------------------------------------------------------------------------------

        IF ( ppatch%bcKind /= bc_kind_nscbc ) THEN
          WRITE(errorstring,'(A,1X,I3)') 'Error in writing NSCBC variables for patch :', &
                                         ipatchglobal
          CALL errorstop(global,err_bcdata_value_invalid,__line__, &
                         trim(errorstring))
        END IF ! pPatch%bcKind

        IF ( nbfaces /= ppatch%nBFaces ) THEN
          WRITE(errorstring,'(A,1X,I6)') 'Number of faces invalid:',nbfaces
          CALL errorstop(global,err_bcdata_value_invalid,__line__, &
                           trim(errorstring))
        END IF ! nBFaces

        IF ( ipatchglobal /= ppatch%iPatchGlobal ) THEN
          WRITE(errorstring,'(A,1X,I3)') 'Global patch index invalid:', &
                                         ipatchglobal
          CALL errorstop(global,err_bcdata_value_invalid,__line__, &
                         trim(errorstring))
        END IF ! iPatchGlobal

        IF ( ndata /= pregion%mixtInput%nCv ) THEN
          WRITE(errorstring,'(A,1X,I3)') &
              'Number of pieces of data invalid:',ndata
          CALL errorstop(global,err_bcdata_value_invalid,__line__, &
                         trim(errorstring))
        END IF ! iPatchGlobal

! ------------------------------------------------------------------------------
!       Read data
! ------------------------------------------------------------------------------

        ppatch%mixt%cvState = cv_mixt_state_cons

        DO ifl = 1,ppatch%nBFaces
          DO idata = 1,pregion%mixtInput%nCv
            READ(ifile) dummyinteger,dummyinteger,ppatch%mixt%cv(idata,ifl)
          END DO ! iData
        END DO ! ifl

! ==============================================================================
!     End marker
! ==============================================================================

      CASE ( '# End' )
        IF ( global%myProcid == masterproc .AND. &
             global%verbLevel > verbose_low ) THEN
          WRITE(stdout,'(A,3X,A)') solver_name,'End marker...'
        END IF ! global%verbLevel

        EXIT

! ==============================================================================
!     Invalid section string
! ==============================================================================

      CASE default
        IF ( global%verbLevel > verbose_low ) THEN
          WRITE(stdout,'(A,3X,A)') solver_name,sectionstring
        END IF ! verbosityLevel

        CALL errorstop(global,err_invalid_marker,__line__,sectionstring)
    END SELECT ! TRIM

! ==============================================================================
!   Guard against infinite loop - might be unnecessary because of read errors?
! ==============================================================================

    IF ( loopcounter >= limit_infinite_loop ) THEN
      CALL errorstop(global,err_infinite_loop,__line__)
    END IF ! loopCounter
  END DO ! <empty>

! ******************************************************************************
! Close file
! ******************************************************************************

  CLOSE(ifile,iostat=errorflag)
  global%error = errorflag
  IF ( global%error /= err_none ) THEN
    CALL errorstop(global,err_file_close,__line__,'File: '//trim(ifilename))
  END IF ! global%error

! ******************************************************************************
! End
! ******************************************************************************

  IF ( global%myProcid == masterproc .AND. &
       global%verbLevel > verbose_none ) THEN
    WRITE(stdout,'(A,1X,A)') solver_name,'Reading binary boundary-condition' // &
                                         ' variable file done.'
  END IF ! global%verbLevel

  CALL deregisterfunction(global)

END SUBROUTINE rflu_bxv_readvarsbinary








! ******************************************************************************
!
! Purpose: Wrapper for reading of boundary condition variables
!
! Description: None.
!
! Input:
!   pRegion     Pointer to region
!
! Output: None.
!
! Notes: None.
!
! ******************************************************************************

SUBROUTINE rflu_bxv_readvarswrapper(pRegion)

  IMPLICIT NONE

! ******************************************************************************
! Declarations and definitions
! ******************************************************************************

! ==============================================================================
! Arguments
! ==============================================================================

  TYPE(t_region), POINTER :: pregion

! ==============================================================================
! Local variables
! ==============================================================================

  TYPE(t_global), POINTER :: global

! ******************************************************************************
! Start
! ******************************************************************************

  global => pregion%global

  CALL registerfunction(global,'RFLU_BXV_ReadVarsWrapper',&
  'RFLU_ModBoundXvUtils.F90')

! ******************************************************************************
! Read bcv files
! ******************************************************************************

  IF ( rflu_nscbc_decidehavenscbc(pregion) .EQV. .true. ) THEN
    IF ( global%solutFormat == format_ascii ) THEN
      CALL rflu_bxv_readvarsascii(pregion)
    ELSE IF ( global%solutFormat == format_binary ) THEN
      CALL rflu_bxv_readvarsbinary(pregion)
    ELSE
      CALL errorstop(global,err_reached_default,__line__)
    END IF ! global%solutFormat
  END IF ! RFLU_NSCBC_DecideHaveNSCBC(pRegion)

! ******************************************************************************
! End
! ******************************************************************************

  CALL deregisterfunction(global)

END SUBROUTINE rflu_bxv_readvarswrapper







! ******************************************************************************
!
! Purpose: Set dependent variables on patches.
!
! Description: None.
!
! Input:
!   pRegion     Pointer to region
!
! Output: None.
!
! Notes: None.
!
! ******************************************************************************

SUBROUTINE rflu_bxv_setdependentvars(pRegion)

  IMPLICIT NONE

! ******************************************************************************
! Definitions and declarations
! ******************************************************************************

! ==============================================================================
! Arguments
! ==============================================================================

  TYPE(t_region), POINTER :: pregion

! ==============================================================================
! Locals
! ==============================================================================

  INTEGER :: ipatch
  TYPE(t_patch), POINTER :: ppatch
  TYPE(t_global), POINTER :: global

! ******************************************************************************
! Start
! ******************************************************************************

  global => pregion%global

  CALL registerfunction(global,'RFLU_BXV_SetDependentVars',&
  'RFLU_ModBoundXvUtils.F90')

! ******************************************************************************
! Loop over patches and set dependent variables if NSCBC active.
! ******************************************************************************

  DO ipatch = 1,pregion%grid%nPatches
    ppatch => pregion%patches(ipatch)

    IF (ppatch%bcKind == bc_kind_nscbc ) THEN
      CALL rflu_bxv_setdependentvarspatch(pregion,ppatch)
    END IF ! pPatch%bcKind
  END DO ! iPatch

! ******************************************************************************
! End
! ******************************************************************************

  CALL deregisterfunction(global)

END SUBROUTINE rflu_bxv_setdependentvars






! ******************************************************************************
!
! Purpose: Set dependent variables on patch.
!
! Description: None.
!
! Input:
!   pRegion     Pointer to region
!   pPatch      Pointer to patch
!
! Output: None.
!
! Notes: None.
!
! ******************************************************************************

SUBROUTINE rflu_bxv_setdependentvarspatch(pRegion,pPatch)

  IMPLICIT NONE

! ******************************************************************************
! Definitions and declarations
! ******************************************************************************

! ==============================================================================
! Arguments
! ==============================================================================

  TYPE(t_patch), POINTER :: ppatch
  TYPE(t_region), POINTER :: pregion

! ==============================================================================
! Locals
! ==============================================================================

  INTEGER :: ifl,icg,indcp,indmol
  REAL(RFREAL) :: cpgas,eo,ggas,ir,mm,r,u,v,w,p,rgas,vm2
  REAL(RFREAL), DIMENSION(:,:), POINTER :: pcv,pdv,pgv
  TYPE(t_global), POINTER :: global

! ******************************************************************************
! Start
! ******************************************************************************

  global => pregion%global

  CALL registerfunction(global,'RFLU_BXV_SetDependentVarsPatch',&
  'RFLU_ModBoundXvUtils.F90')

! ******************************************************************************
! Set variables and pointers
! ******************************************************************************

  pcv => ppatch%mixt%cv
  pdv => ppatch%mixt%dv
  pgv => pregion%mixt%gv ! NOTE gv taken from cells for now

  indcp  = pregion%mixtInput%indCp
  indmol = pregion%mixtInput%indMol

! ******************************************************************************
! Compute dependent variables
! ******************************************************************************

  SELECT CASE ( pregion%mixtInput%fluidModel )

! ==============================================================================
!   Incompressible fluid model
! ==============================================================================

    CASE ( fluid_model_incomp )

! ==============================================================================
!   Compressible fluid model. NOTE check state of solution vector.
! ==============================================================================

    CASE ( fluid_model_comp )
      SELECT CASE ( pregion%mixtInput%gasModel )

! ------------------------------------------------------------------------------
!       Thermally and calorically perfect gas (single species)
! ------------------------------------------------------------------------------

        CASE ( gas_model_tcperf )
          IF ( ppatch%mixt%cvState /= cv_mixt_state_cons ) THEN
            CALL errorstop(global,err_cv_state_invalid,__line__)
          END IF ! pPatch%mixt%cvState

          DO ifl = 1,ppatch%nBFaces
            icg  = ppatch%bf2c(ifl) 

            mm    = pgv(gv_mixt_mol,icg*indmol)
            cpgas = pgv(gv_mixt_cp,icg*indcp)
            rgas  = mixtperf_r_m(mm)
            ggas  = mixtperf_g_cpr(cpgas,rgas)

            r  = pcv(cv_mixt_dens,ifl)
            ir = 1.0_rfreal/r

            u  = ir*pcv(cv_mixt_xmom,ifl)
            v  = ir*pcv(cv_mixt_ymom,ifl)
            w  = ir*pcv(cv_mixt_zmom,ifl)
            eo = ir*pcv(cv_mixt_ener,ifl)
            
            vm2 = u*u + v*v + w*w

            p = mixtperf_p_deogvm2(r,eo,ggas,vm2)

            pdv(dv_mixt_pres,ifl) = p 
            pdv(dv_mixt_temp,ifl) = mixtperf_t_dpr(r,pdv(dv_mixt_pres,ifl),rgas)
            pdv(dv_mixt_soun,ifl) = mixtperf_c_grt(ggas,rgas, &
                                                   pdv(dv_mixt_temp,ifl))
          END DO ! ifl

! ------------------------------------------------------------------------------
!       Default
! ------------------------------------------------------------------------------

        CASE default
          CALL errorstop(global,err_reached_default,__line__)
      END SELECT ! pRegion%mixtInput%gasModel

! ==============================================================================
!   Default
! ==============================================================================

    CASE default
      CALL errorstop(global,err_reached_default,__line__)
  END SELECT ! pRegion%mixtInput%fluidModel

! ******************************************************************************
! End
! ******************************************************************************

  CALL deregisterfunction(global)

END SUBROUTINE rflu_bxv_setdependentvarspatch







! ******************************************************************************
!
! Purpose: Write solution on patches in ASCII format.
!
! Description: None.
!
! Input:
!   pRegion     Pointer to region
!   pPatch      Pointer to patch
!
! Output: None.
!
! Notes: None.
!
! ******************************************************************************

SUBROUTINE rflu_bxv_writevarsascii(pRegion)

  USE modbuildfilenames, ONLY: buildfilenameunsteady, &
                               buildfilenamesteady

  IMPLICIT NONE

! ******************************************************************************
! Declarations and definitions
! ******************************************************************************

! ==============================================================================
! Arguments
! ==============================================================================

  TYPE(t_region), POINTER :: pregion

! ==============================================================================
! Local variables
! ==============================================================================

  CHARACTER(CHRLEN) :: ifilename,sectionstring
  INTEGER :: dummyinteger,errorflag,idata,ifile,ifl,ipatch
  TYPE(t_grid), POINTER :: pgrid
  TYPE(t_patch), POINTER :: ppatch
  TYPE(t_global), POINTER :: global

! ******************************************************************************
! Start
! ******************************************************************************

  global => pregion%global

  CALL registerfunction(global,'RFLU_BXV_WriteVarsASCII',&
  'RFLU_ModBoundXvUtils.F90')

  IF ( global%myProcid == masterproc .AND. &
       global%verbLevel > verbose_none ) THEN
    WRITE(stdout,'(A,1X,A)') solver_name,'Writing ASCII boundary-condition' // &
                                         ' variable file...'
  END IF ! global%verbLevel

! ******************************************************************************
! Set pointers
! ******************************************************************************

  pgrid => pregion%grid

! ******************************************************************************
! Open file
! ******************************************************************************

  ifile = if_distr

  IF ( global%flowType == flow_unsteady ) THEN
    CALL buildfilenameunsteady(global,filedest_indir,'.bcva', &
                               pregion%iRegionGlobal,global%currentTime, &
                               ifilename)
  ELSE
    CALL buildfilenamesteady(global,filedest_indir,'.bcva', &
                             pregion%iRegionGlobal,global%currentIter, &
                             ifilename)
  ENDIF ! global%flowType

  OPEN(ifile,file=ifilename,form='FORMATTED',status='UNKNOWN', &
       iostat=errorflag)
  global%error = errorflag
  IF ( global%error /= err_none ) THEN
    CALL errorstop(global,err_file_open,__line__,'File: '//trim(ifilename))
  END IF ! global%error

! ******************************************************************************
! Write header
! ******************************************************************************

  sectionstring = '# ROCFLU boundary-condition variable file'
  WRITE(ifile,'(A)') sectionstring

! ******************************************************************************
! Loop over patches
! ******************************************************************************

  DO ipatch = 1,pgrid%nPatches
    ppatch => pregion%patches(ipatch)

! ==============================================================================
!   If bcKind = NSCBC, write data
! ==============================================================================

    IF ( ppatch%bcKind == bc_kind_nscbc ) THEN
      WRITE(ifile,'(A)') '# Patch data'
      WRITE(ifile,'(2(1X,I3),1X,I6,1X,I2)') ipatch,ppatch%iPatchGlobal, &
                                            ppatch%nBFaces, &
                                            pregion%mixtInput%nCv

      DO ifl = 1,ppatch%nBFaces
        DO idata = 1,pregion%mixtInput%nCv
          WRITE(ifile,'(1X,I6,1X,I2,1X,E23.16)') ifl,idata, &
                                                 ppatch%mixt%cv(idata,ifl)
        END DO ! iData
      END DO ! ifl
    END IF ! pPatch%bcKind 
  END DO ! iPatch

! ******************************************************************************
! Write footer
! ******************************************************************************

  sectionstring = '# End'
  WRITE(ifile,'(A)') sectionstring

! ******************************************************************************
! Close file
! ******************************************************************************

  CLOSE(ifile,iostat=errorflag)
  global%error = errorflag
  IF ( global%error /= err_none ) THEN
    CALL errorstop(global,err_file_close,__line__,'File: '//trim(ifilename))
  END IF ! global%error

! ******************************************************************************
! End
! ******************************************************************************

  IF ( global%myProcid == masterproc .AND. &
       global%verbLevel > verbose_none ) THEN
    WRITE(stdout,'(A,1X,A)') solver_name,'Writing ASCII boundary-condition' // &
                                         ' variable file done.'
  END IF ! global%verbLevel

  CALL deregisterfunction(global)

END SUBROUTINE rflu_bxv_writevarsascii







! ******************************************************************************
!
! Purpose: Write solution on patches in binary format.
!
! Description: None.
!
! Input:
!   pRegion     Pointer to region
!
! Output: None.
!
! Notes: None.
!
! ******************************************************************************

SUBROUTINE rflu_bxv_writevarsbinary(pRegion)

  USE modbuildfilenames, ONLY: buildfilenameunsteady, &
                               buildfilenamesteady

  IMPLICIT NONE

! ******************************************************************************
! Declarations and definitions
! ******************************************************************************

! ==============================================================================
! Arguments
! ==============================================================================

  TYPE(t_region), POINTER :: pregion

! ==============================================================================
! Local variables
! ==============================================================================

  CHARACTER(CHRLEN) :: ifilename,sectionstring
  INTEGER :: dummyinteger,errorflag,idata,ifile,ifl,ipatch
  TYPE(t_grid), POINTER :: pgrid
  TYPE(t_patch), POINTER :: ppatch
  TYPE(t_global), POINTER :: global

! ******************************************************************************
! Start
! ******************************************************************************

  global => pregion%global

  CALL registerfunction(global,'RFLU_BXV_WriteVarsBinary',&
  'RFLU_ModBoundXvUtils.F90')

  IF ( global%myProcid == masterproc .AND. &
       global%verbLevel > verbose_none ) THEN
    WRITE(stdout,'(A,1X,A)') solver_name,'Writing binary boundary-condition' // &
                                         ' variable file...'
  END IF ! global%verbLevel

! ******************************************************************************
! Set pointers
! ******************************************************************************

  pgrid => pregion%grid

! ******************************************************************************
! Open file
! ******************************************************************************

  ifile = if_distr

  IF ( global%flowType == flow_unsteady ) THEN
    CALL buildfilenameunsteady(global,filedest_indir,'.bcv', &
                               pregion%iRegionGlobal,global%currentTime, &
                               ifilename)
  ELSE
    CALL buildfilenamesteady(global,filedest_indir,'.bcv', &
                             pregion%iRegionGlobal,global%currentIter, &
                             ifilename)
  ENDIF ! global%flowType

  OPEN(ifile,file=ifilename,form='UNFORMATTED',status='UNKNOWN', &
       iostat=errorflag)
  global%error = errorflag
  IF ( global%error /= err_none ) THEN
    CALL errorstop(global,err_file_open,__line__,'File: '//trim(ifilename))
  END IF ! global%error

! ******************************************************************************
! Write header
! ******************************************************************************

  sectionstring = '# ROCFLU boundary-condition variable file'
  WRITE(ifile) sectionstring

! ******************************************************************************
! Loop over patches
! ******************************************************************************

  DO ipatch = 1,pgrid%nPatches
    ppatch => pregion%patches(ipatch)

! ==============================================================================
!   If bcKind = NSCBC, write data
! ==============================================================================

    IF ( ppatch%bcKind == bc_kind_nscbc ) THEN
      sectionstring = '# Patch data'
      WRITE(ifile) sectionstring
      WRITE(ifile) ipatch,ppatch%iPatchGlobal,ppatch%nBFaces, &
                   pregion%mixtInput%nCv

      DO ifl = 1,ppatch%nBFaces
        DO idata = 1,pregion%mixtInput%nCv
          WRITE(ifile) ifl,idata,ppatch%mixt%cv(idata,ifl)
        END DO ! iData
      END DO ! ifl
    END IF ! pPatch%bcKind 
  END DO ! iPatch

! ******************************************************************************
! Write footer
! ******************************************************************************

  sectionstring = '# End'
  WRITE(ifile) sectionstring

! ******************************************************************************
! Close file
! ******************************************************************************

  CLOSE(ifile,iostat=errorflag)
  global%error = errorflag
  IF ( global%error /= err_none ) THEN
    CALL errorstop(global,err_file_close,__line__,'File: '//trim(ifilename))
  END IF ! global%error

! ******************************************************************************
! End
! ******************************************************************************

  IF ( global%myProcid == masterproc .AND. &
       global%verbLevel > verbose_none ) THEN
    WRITE(stdout,'(A,1X,A)') solver_name,'Writing binary boundary-condition' // &
                                         ' variable file done.'
  END IF ! global%verbLevel

  CALL deregisterfunction(global)

END SUBROUTINE rflu_bxv_writevarsbinary







! ******************************************************************************
!
! Purpose: Wrapper for writing of boundary condition variables
!
! Description: None.
!
! Input:
!   pRegion     Pointer to region
!
! Output: None.
!
! Notes: None.
!
! ******************************************************************************

SUBROUTINE rflu_bxv_writevarswrapper(pRegion)

  IMPLICIT NONE

! ******************************************************************************
! Declarations and definitions
! ******************************************************************************

! ==============================================================================
! Arguments
! ==============================================================================

  TYPE(t_region), POINTER :: pregion

! ==============================================================================
! Local variables
! ==============================================================================

  TYPE(t_global), POINTER :: global

! ******************************************************************************
! Start
! ******************************************************************************

  global => pregion%global

  CALL registerfunction(global,'RFLU_BXV_WriteVarsWrapper',&
  'RFLU_ModBoundXvUtils.F90')

! ******************************************************************************
! Read bcv files
! ******************************************************************************

  IF ( rflu_nscbc_decidehavenscbc(pregion) .EQV. .true. ) THEN
    IF ( global%solutFormat == format_ascii ) THEN
      CALL rflu_bxv_writevarsascii(pregion)
    ELSE IF ( global%solutFormat == format_binary ) THEN
      CALL rflu_bxv_writevarsbinary(pregion)
    ELSE
      CALL errorstop(global,err_reached_default,__line__)
    END IF ! global%solutFormat
  END IF ! RFLU_NSCBC_DecideHaveNSCBC(pRegion)

! ******************************************************************************
! End
! ******************************************************************************

  CALL deregisterfunction(global)

END SUBROUTINE rflu_bxv_writevarswrapper






END MODULE rflu_modboundxvutils

! ******************************************************************************
!
! RCS Revision history:
!
! $Log: RFLU_ModBoundXvUtils.F90,v $
! Revision 1.6  2008/12/06 08:44:20  mtcampbe
! Updated license.
!
! Revision 1.5  2008/11/19 22:17:31  mtcampbe
! Added Illinois Open Source License/Copyright
!
! Revision 1.4  2006/10/20 21:17:43  mparmar
! Modified read/write of binary boundary variable files
!
! Revision 1.3  2006/08/21 16:11:19  haselbac
! Clean-up: comments, order of routines, missing headers, indentation, etc
!
! Revision 1.2  2006/08/19 19:44:08  haselbac
! Significant clean-up and cosmetic changes
!
! Revision 1.1  2006/08/19 15:37:40  mparmar
! Initial revision
!
! ******************************************************************************