RFLU_ExplicitMultiStage.F90

Go to the documentation of this file.

! *********************************************************************
! * Rocstar Simulation Suite                                          *
! * Copyright@2015, Illinois Rocstar LLC. All rights reserved.        *
! *                                                                   *
! * Illinois Rocstar LLC                                              *
! * Champaign, IL                                                     *
! * www.illinoisrocstar.com                                           *
! * sales@illinoisrocstar.com                                         *
! *                                                                   *
! * License: See LICENSE file in top level of distribution package or *
! * http://opensource.org/licenses/NCSA                               *
! *********************************************************************
! *********************************************************************
! * THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND,   *
! * EXPRESS OR IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES   *
! * OF MERCHANTABILITY, FITNESS FOR A PARTICULAR PURPOSE AND          *
! * NONINFRINGEMENT.  IN NO EVENT SHALL THE CONTRIBUTORS OR           *
! * COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER       *
! * LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE,   *
! * Arising FROM, OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE    *
! * USE OR OTHER DEALINGS WITH THE SOFTWARE.                          *
! *********************************************************************
! ******************************************************************************
!
! Purpose: Calculate solution at a new time level/iteration.
!
! Description: None.
!
! Input: 
!   regions     Region data
!
! Output: None.
!
! Notes: None.
!
! ******************************************************************************
!
! $Id: RFLU_ExplicitMultiStage.F90,v 1.7 2008/12/06 08:44:29 mtcampbe Exp $
!
! Copyright: (c) 2005-2006 by the University of Illinois
!
! ******************************************************************************

SUBROUTINE rflu_explicitmultistage(regions)

  USE moddatatypes
  USE modparameters  
  USE modglobal, ONLY: t_global
  USE moderror
  USE moddatastruct, ONLY: t_region
  USE modgrid, ONLY: t_grid
  USE modmixture, ONLY: t_mixt
  USE modmpi

  USE rflu_modexplicitmultistage
  USE rflu_modmpi
  USE rflu_modrelatedpatches, ONLY: rflu_relp_transformwrapper
  
  USE modinterfaces, ONLY: rflu_checkpositivitywrapper, &
                           rflu_checkvaliditywrapper, &
                           rflu_setvars, & 
                           rflu_zerovirtualcellvars

  IMPLICIT NONE

! ******************************************************************************
! Declarations and definitions
! ******************************************************************************  

! ==============================================================================
! Arguments
! ==============================================================================

  TYPE(t_region), POINTER :: regions(:)

! ==============================================================================
! Locals
! ==============================================================================

  INTEGER :: ireg,istage
  TYPE(t_global), POINTER :: global
  TYPE(t_grid), POINTER :: pgrid
  TYPE(t_mixt), POINTER :: pmixt
  TYPE(t_region), POINTER :: pregion

! ******************************************************************************
! Start
! ******************************************************************************

  global => regions(1)%global

  CALL registerfunction(global,'RFLU_ExplicitMultiStage',&
  'RFLU_ExplicitMultiStage.F90')

! ******************************************************************************
! Loop over stages
! ******************************************************************************

  DO istage = 1,global%nrkSteps
  
! ==============================================================================
!   Loop over regions, update and send variables
! ==============================================================================
 
    DO ireg = 1,global%nRegionsLocal
      pregion => regions(ireg)
      pgrid   => pregion%grid
      pmixt   => pregion%mixt
      
      pregion%irkStep = istage

! ------------------------------------------------------------------------------
!     Store previous solution
! ------------------------------------------------------------------------------

      IF ( istage == 1 ) THEN
        CALL rflu_ems_setcvold(pregion)
      END IF ! iStage

! ------------------------------------------------------------------------------
!     Compute residual and zero residuals in dummy cells 
! ------------------------------------------------------------------------------

      CALL rflu_ems_computeresidual(pregion)
      CALL rflu_zerovirtualcellvars(pregion,pmixt%rhs)

! ------------------------------------------------------------------------------
!     Update conserved variables, check validity and positivity
! ------------------------------------------------------------------------------

      CALL rflu_ems_updateconservedvars(pregion)
      CALL rflu_checkvaliditywrapper(pregion)
      CALL rflu_checkpositivitywrapper(pregion)

! ------------------------------------------------------------------------------
!     Send variables to other regions
! ------------------------------------------------------------------------------

      CALL rflu_mpi_isendwrapper(pregion)

! ------------------------------------------------------------------------------
!     Update other variables
! ------------------------------------------------------------------------------

      CALL rflu_setvars(pregion,1,pgrid%nCells)
    END DO ! iReg

! ==============================================================================
!   Copy variables between regions on same process
! ==============================================================================

    CALL rflu_mpi_copywrapper(regions)

! ==============================================================================
!   Loop over regions, receive variables and update 
! ==============================================================================

    DO ireg = 1,global%nRegionsLocal
      pregion => regions(ireg)
      pgrid   => pregion%grid

! ------------------------------------------------------------------------------
!     Receive variables from other regions
! ------------------------------------------------------------------------------

      CALL rflu_mpi_recvwrapper(pregion)    

! ------------------------------------------------------------------------------
!     Update other variables in virtual cells
! ------------------------------------------------------------------------------

      CALL rflu_setvars(pregion,pgrid%nCells+1,pgrid%nCellsTot) 
      
! ------------------------------------------------------------------------------
!     Transform variables in virtual cells associated with related patches
! ------------------------------------------------------------------------------

      CALL rflu_relp_transformwrapper(pregion)            
    END DO ! iReg

! ==============================================================================
!   Loop over regions, clear requests
! ==============================================================================

    DO ireg = 1,global%nRegionsLocal
      pregion => regions(ireg)
      pgrid   => pregion%grid

      CALL rflu_mpi_clearrequestwrapper(pregion)
    END DO ! iReg
  END DO ! iStage

! ******************************************************************************
! End
! ****************************************************************************** 

  CALL deregisterfunction(global)

END SUBROUTINE rflu_explicitmultistage

! ******************************************************************************
!
! RCS Revision history:
!
! $Log: RFLU_ExplicitMultiStage.F90,v $
! Revision 1.7  2008/12/06 08:44:29  mtcampbe
! Updated license.
!
! Revision 1.6  2008/11/19 22:17:42  mtcampbe
! Added Illinois Open Source License/Copyright
!
! Revision 1.5  2006/04/07 15:19:22  haselbac
! Removed tabs
!
! Revision 1.4  2006/03/26 20:28:43  haselbac
! Changed to wrappers bcos of GL model
!
! Revision 1.3  2006/03/25 22:01:35  haselbac
! Added call to transforming data on related patches
!
! Revision 1.2  2005/12/03 19:45:20  haselbac
! Apparent bug fix: Separated call to RFLU_MPI_ClearRequestWrapper into separate loop
!
! Revision 1.1  2005/05/16 20:36:29  haselbac
! Initial revision
!
! ******************************************************************************