RFLU_ModThrustSpecImpulse.F90

Go to the documentation of this file.

! *********************************************************************
! * Rocstar Simulation Suite                                          *
! * Copyright@2015, Illinois Rocstar LLC. All rights reserved.        *
! *                                                                   *
! * Illinois Rocstar LLC                                              *
! * Champaign, IL                                                     *
! * www.illinoisrocstar.com                                           *
! * sales@illinoisrocstar.com                                         *
! *                                                                   *
! * License: See LICENSE file in top level of distribution package or *
! * http://opensource.org/licenses/NCSA                               *
! *********************************************************************
! *********************************************************************
! * THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND,   *
! * EXPRESS OR IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES   *
! * OF MERCHANTABILITY, FITNESS FOR A PARTICULAR PURPOSE AND          *
! * NONINFRINGEMENT.  IN NO EVENT SHALL THE CONTRIBUTORS OR           *
! * COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER       *
! * LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE,   *
! * Arising FROM, OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE    *
! * USE OR OTHER DEALINGS WITH THE SOFTWARE.                          *
! *********************************************************************
! ******************************************************************************
!
! Purpose: Collection of routines to compute thrust and specific impulse.
!
! Description: None.
!
! Notes: None. 
!
! ******************************************************************************
!
! $Id: RFLU_ModThrustSpecImpulse.F90,v 1.4 2008/12/06 08:44:24 mtcampbe Exp $
!
! Copyright: (c) 2004-2005 by the University of Illinois
!
! ******************************************************************************

MODULE rflu_modthrustspecimpulse

  USE modparameters
  USE moddatatypes  
  USE modglobal, ONLY: t_global
  USE modgrid, ONLY: t_grid
  USE modbndpatch, ONLY: t_patch  
  USE moddatastruct, ONLY: t_region
  USE moderror
  USE modmpi

  IMPLICIT NONE

! ******************************************************************************
! Declarations and definitions
! ******************************************************************************

! ==============================================================================
! Private data
! ==============================================================================

  CHARACTER(CHRLEN), PRIVATE :: & 
    RCSIdentString = '$$'

! ==============================================================================
! Public functions
! ==============================================================================

  PUBLIC :: rflu_tsi_computeglobalthrustsi, &  
            rflu_tsi_printglobalvals, & 
            rflu_tsi_writeglobalvals
            
! ==============================================================================
! Private functions
! ==============================================================================
  
  PRIVATE :: rflu_tsi_closeglobalvals, &
             rflu_tsi_openglobalvals

! ******************************************************************************
! Routines
! ******************************************************************************

  CONTAINS
  
  





! ******************************************************************************
!
!   Purpose: Close thrust and specific impulse files.
!
!   Description: None.
!
!   Input:
!     global            Pointer to global data
!
!   Notes:
!
! ******************************************************************************

  SUBROUTINE rflu_tsi_closeglobalvals(global,iPatch,iFile1,iFile2)

    USE moddatatypes
    USE modglobal, ONLY: t_global
    USE modparameters
    USE moderror
    USE modmpi

! *****************************************************************************
!   Declarations and definitions
! *****************************************************************************

! =============================================================================
!   Arguments
! =============================================================================

    INTEGER, INTENT(IN) :: ipatch,ifile1,ifile2
    TYPE(t_global), POINTER :: global
    
! ==============================================================================
!   Locals
! ==============================================================================
    
    CHARACTER(CHRLEN) :: ifilename1,ifilename2
    INTEGER :: errorflag 
   
! *****************************************************************************
!   Start
! *****************************************************************************
 
    CALL registerfunction(global,'RFLU_TSI_CloseGlobalVals',&
  'RFLU_ModThrustSpecImpulse.F90')

! ==============================================================================
!   Opening thrust and specific impulse file
! ==============================================================================

    IF ( global%verbLevel > verbose_low ) THEN       
      WRITE(stdout,'(A,1X,A,I4.4)') solver_name,'Closing thrust and '// &
                               'specific impulse files for iPatch =',ipatch 
    END IF ! global%verbLevel
      
! ------------------------------------------------------------------------------
!   Build file name
! ------------------------------------------------------------------------------

    WRITE(ifilename1,'(A,I4.4)') trim(global%outDir)// & 
                                 trim(global%casename)//'.thr_',ipatch

    WRITE(ifilename2,'(A,I4.4)') trim(global%outDir)// & 
                                 trim(global%casename)//'.isp_',ipatch

! ------------------------------------------------------------------------------
!   Open file
! ------------------------------------------------------------------------------

    CLOSE(ifile1,iostat=errorflag)
    IF (global%error /= err_none ) THEN
      CALL errorstop(global,err_file_close,__line__,'File: '// & 
                     trim(ifilename1))
    END IF ! global%error
    CLOSE(ifile2,iostat=errorflag)
    IF (global%error /= err_none ) THEN
      CALL errorstop(global,err_file_close,__line__,'File: '// & 
                     trim(ifilename2))
    END IF ! global%error

! ******************************************************************************
!   End  
! ******************************************************************************

    IF ( global%verbLevel > verbose_low ) THEN       
      WRITE(stdout,'(A,1X,A)') solver_name,'Closing thrust and '// & 
                               'specific impulse files done.'             
    END IF ! global%verbLevel

    CALL deregisterfunction(global)

  END SUBROUTINE rflu_tsi_closeglobalvals










! *******************************************************************************
!
! Purpose: Compute thrust and specific impulse coefficients.
!
! Description: None.
!
! Input:
!   regions             Region data
!
! Output: None.
!
! Notes: None.
!
! ******************************************************************************

  SUBROUTINE rflu_tsi_computeglobalthrustsi(pRegion)

    IMPLICIT NONE
        
! ******************************************************************************
!   Declarations and definitions
! ******************************************************************************
    
! ==============================================================================
!   Arguments
! ==============================================================================
    
    TYPE(t_region), POINTER :: pregion
    
! ==============================================================================
!   Locals
! ==============================================================================
    
    INTEGER :: errorflag,ipatch,ipatchglobal
    REAL(RFREAL) :: forcecoeff2thrust,thrust2isp,masscoeffin,masscoeffout, &
                    massin,massout
    REAL(RFREAL), DIMENSION(:,:,:), POINTER :: pforcecoeff,pforcecoeffvac
    REAL(RFREAL), DIMENSION(:,:), POINTER :: pspecimpulse,pspecimpulsevac, &
                                             pthrust,pthrustvac
    TYPE(t_global), POINTER :: global
    
! ******************************************************************************
!   Start, set pointers and variables
! ******************************************************************************
    
    global => pregion%global
    
    CALL registerfunction(global,'RFLU_TSI_ComputeGlobalThrustSI',&
  'RFLU_ModThrustSpecImpulse.F90')

    pforcecoeff     => pregion%forceCoeffsGlobal
    pforcecoeffvac  => pregion%forceVacCoeffsGlobal
    pspecimpulse    => pregion%specImpulseGlobal
    pspecimpulsevac => pregion%specImpulseVacGlobal
    pthrust         => pregion%thrustGlobal
    pthrustvac      => pregion%thrustVacGlobal
        
! ******************************************************************************
!   Compute thrust
! ******************************************************************************
        
! ==============================================================================
!   De-normalize mass coefficients
! ==============================================================================

    masscoeffin  = 0.0_rfreal
    masscoeffout = 0.0_rfreal
    massin       = 0.0_rfreal
    massout      = 0.0_rfreal

    DO ipatch = 1,pregion%global%nPatches
      masscoeffin  = masscoeffin  + pregion%massCoeffsGlobal(mass_in ,ipatch)
      masscoeffout = masscoeffout + pregion%massCoeffsGlobal(mass_out,ipatch)
    END DO ! iPatch

    massin  = masscoeffin*global%refDensity*global%refVelocity*global%forceRefArea
    massout = masscoeffout*global%refDensity*global%refVelocity*global%forceRefArea

! ==============================================================================
!   De-normalize force coefficients to compute thrusts
! ==============================================================================

    forcecoeff2thrust  = 0.5_rfreal*global%refDensity*global%refVelocity &
                                   *global%refVelocity*global%forceRefArea

    DO ipatch = 1,pregion%global%nPatches
      pthrust(xcoord,ipatch) = forcecoeff2thrust &
                             *(pforcecoeff(xcoord,comp_mom ,ipatch) &
                             + pforcecoeff(xcoord,comp_pres,ipatch) &
                             + pforcecoeff(xcoord,comp_visc,ipatch))
      pthrust(ycoord,ipatch) = forcecoeff2thrust &
                             *(pforcecoeff(ycoord,comp_mom ,ipatch) &
                             + pforcecoeff(ycoord,comp_pres,ipatch) &
                             + pforcecoeff(ycoord,comp_visc,ipatch))
      pthrust(zcoord,ipatch) = forcecoeff2thrust &
                             *(pforcecoeff(zcoord,comp_mom ,ipatch) &
                             + pforcecoeff(zcoord,comp_pres,ipatch) &
                             + pforcecoeff(zcoord,comp_visc,ipatch))
      
      pthrustvac(xcoord,ipatch) = forcecoeff2thrust &
                                *(pforcecoeffvac(xcoord,comp_mom ,ipatch) &
                                + pforcecoeffvac(xcoord,comp_pres,ipatch) &
                                + pforcecoeffvac(xcoord,comp_visc,ipatch))
      pthrustvac(ycoord,ipatch) = forcecoeff2thrust &
                                *(pforcecoeffvac(ycoord,comp_mom ,ipatch) &
                                + pforcecoeffvac(ycoord,comp_pres,ipatch) &
                                + pforcecoeffvac(ycoord,comp_visc,ipatch))
      pthrustvac(zcoord,ipatch) = forcecoeff2thrust &
                                *(pforcecoeffvac(zcoord,comp_mom ,ipatch) &
                                + pforcecoeffvac(zcoord,comp_pres,ipatch) &
                                + pforcecoeffvac(zcoord,comp_visc,ipatch))
    END DO ! iPatch

! ==============================================================================
!   Normalize thrusts to compute specific impulse
! ==============================================================================

    thrust2isp  = 1.0_rfreal/(massin*global%gravity)

    DO ipatch = 1,pregion%global%nPatches
      pspecimpulse(xcoord,ipatch) = thrust2isp*pthrust(xcoord,ipatch)
      pspecimpulse(ycoord,ipatch) = thrust2isp*pthrust(ycoord,ipatch)
      pspecimpulse(zcoord,ipatch) = thrust2isp*pthrust(zcoord,ipatch)
      
      pspecimpulsevac(xcoord,ipatch) = thrust2isp*pthrustvac(xcoord,ipatch)
      pspecimpulsevac(ycoord,ipatch) = thrust2isp*pthrustvac(ycoord,ipatch)
      pspecimpulsevac(zcoord,ipatch) = thrust2isp*pthrustvac(zcoord,ipatch)
    END DO ! iPatch

! ******************************************************************************
!   End  
! ******************************************************************************

    CALL deregisterfunction(global)

  END SUBROUTINE rflu_tsi_computeglobalthrustsi






  


! ******************************************************************************
!
!   Purpose: Open thrust and specific impulse files.
!
!   Description: None.
!
!   Input:
!     global            Pointer to global data
!
!   Notes:
!
! ******************************************************************************

  SUBROUTINE rflu_tsi_openglobalvals(global,iPatch,iFile1,iFile2)

    USE moddatatypes
    USE modglobal, ONLY: t_global
    USE modparameters
    USE moderror
    USE modmpi

! *****************************************************************************
!   Declarations and definitions
! *****************************************************************************

! =============================================================================
!   Arguments
! =============================================================================

    INTEGER, INTENT(IN) :: ipatch
    TYPE(t_global), POINTER :: global
    
    INTEGER, INTENT(OUT) :: ifile1,ifile2

! ==============================================================================
!   Locals
! ==============================================================================
    
    LOGICAL :: fileexists1,fileexists2
    CHARACTER(CHRLEN) :: ifilename1,ifilename2
    INTEGER :: errorflag 
   
! *****************************************************************************
!   Start
! *****************************************************************************
 
    CALL registerfunction(global,'RFLU_TSI_OpenGlobalVals',&
  'RFLU_ModThrustSpecImpulse.F90')

! ==============================================================================
!   Opening thrust and specific impulse file
! ==============================================================================

    IF ( global%verbLevel > verbose_low ) THEN       
      WRITE(stdout,'(A,1X,A,I4.4)') solver_name,'Opening thrust and '// &
                               'specific impulse files for iPatch =',ipatch 
    END IF ! global%verbLevel
      
! ------------------------------------------------------------------------------
!   Build file name
! ------------------------------------------------------------------------------

    ifile1 = if_thrust
    ifile2 = if_isp

    WRITE(ifilename1,'(A,I4.4)') trim(global%outDir)// & 
                                 trim(global%casename)//'.thr_',ipatch

    WRITE(ifilename2,'(A,I4.4)') trim(global%outDir)// & 
                                 trim(global%casename)//'.isp_',ipatch

! ------------------------------------------------------------------------------
!   Open file
! ------------------------------------------------------------------------------

    IF ( global%restartFromScratch .EQV. .false. ) THEN
      INQUIRE(file=ifilename1,exist=fileexists1)

      IF ( fileexists1 .EQV. .true. ) THEN 
        OPEN(ifile1,file=ifilename1,form='FORMATTED',status='OLD', &
             position='APPEND',iostat=errorflag)
      ELSE 
        OPEN(ifile1,file=ifilename1,form='FORMATTED',status='NEW', &
             iostat=errorflag)
      END IF ! fileExists1

      INQUIRE(file=ifilename2,exist=fileexists2)

      IF ( fileexists2 .EQV. .true. ) THEN 
        OPEN(ifile2,file=ifilename2,form='FORMATTED',status='OLD', &
             position='APPEND',iostat=errorflag)
      ELSE 
        OPEN(ifile1,file=ifilename2,form='FORMATTED',status='NEW', &
             iostat=errorflag)
      END IF ! fileExists2
    ELSE
      IF ( global%thrustWriteCntr == 1 ) THEN 
        OPEN(ifile1,file=ifilename1,form='FORMATTED',status='UNKNOWN', &
             iostat=errorflag)
        OPEN(ifile2,file=ifilename2,form='FORMATTED',status='UNKNOWN', &
             iostat=errorflag)
      ELSE 
        OPEN(ifile1,file=ifilename1,form='FORMATTED',status='OLD', &
             position='APPEND',iostat=errorflag)          
        OPEN(ifile2,file=ifilename2,form='FORMATTED',status='OLD', &
             position='APPEND',iostat=errorflag)          
      END IF ! global%thrustWriteCntr
    END IF ! global      

    global%error = errorflag

    IF ( global%error /= err_none ) THEN
      CALL errorstop(global,err_file_open,__line__,'File: '// & 
                     trim(ifilename1)//' and '//trim(ifilename2))
    END IF ! global%error

! ******************************************************************************
!   End  
! ******************************************************************************

    IF ( global%verbLevel > verbose_low ) THEN       
      WRITE(stdout,'(A,1X,A)') solver_name,'Opening thrust and '// & 
                               'specific impulse files done.'             
    END IF ! global%verbLevel

    CALL deregisterfunction(global)

  END SUBROUTINE rflu_tsi_openglobalvals











! *******************************************************************************
!
! Purpose: Print thrust and specific impulse.
!
! Description: None.
!
! Input:
!   pRegion             Pointer to region
!
! Output: None.
!
! Notes: 
!   1. This routine should only be called for the master process. It will not 
!      do anything if called by any other process (safeguard).
!
! ******************************************************************************

  SUBROUTINE rflu_tsi_printglobalvals(pRegion)

    IMPLICIT NONE
        
! ******************************************************************************
!   Declarations and definitions
! ******************************************************************************
    
! ==============================================================================
!   Arguments
! ==============================================================================
    
    TYPE(t_region), POINTER :: pregion
    
! ==============================================================================
!   Locals
! ==============================================================================
    
    INTEGER :: ipatch 
    TYPE(t_global), POINTER :: global
    
! ******************************************************************************
!   Start, set pointers and variables
! ******************************************************************************
    
    global => pregion%global
    
    CALL registerfunction(global,'RFLU_TSI_PrintGlobalVals',&
  'RFLU_ModThrustSpecImpulse.F90')
                
! ******************************************************************************
!   Print global force coefficients
! ******************************************************************************

    IF ( global%myProcid == masterproc .AND. &
         global%verbLevel > verbose_low ) THEN   
      WRITE(stdout,'(A,1X,A)') solver_name,'Printing thrust and '// &
                               'specific impulse...' 
      
      DO ipatch = 1,pregion%global%nPatches
        IF ( pregion%thrustFlagsGlobal(ipatch) .EQV. .true. ) THEN
          WRITE(stdout,'(A,5X,A,1X,I2)') solver_name,'Patch:',ipatch
          WRITE(stdout,'(A,7X,A,7X,A,6X,A,8X,A,8X,A)') solver_name, & 
                'Component','Thrust','Thrust vacuum','Isp','Isp vacuum'
          WRITE(stdout,'(A,7X,A,4(1X,E13.6))') solver_name,'x-direction:', & 
                pregion%thrustGlobal(xcoord,ipatch), & 
                pregion%thrustVacGlobal(xcoord,ipatch), &
                pregion%specImpulseGlobal(xcoord,ipatch), & 
                pregion%specImpulseVacGlobal(xcoord,ipatch)
          WRITE(stdout,'(A,7X,A,4(1X,E13.6))') solver_name,'y-direction:', & 
                pregion%thrustGlobal(ycoord,ipatch), & 
                pregion%thrustVacGlobal(ycoord,ipatch), &
                pregion%specImpulseGlobal(ycoord,ipatch), & 
                pregion%specImpulseVacGlobal(ycoord,ipatch)
          WRITE(stdout,'(A,7X,A,4(1X,E13.6))') solver_name,'z-direction:', & 
                pregion%thrustGlobal(zcoord,ipatch), & 
                pregion%thrustVacGlobal(zcoord,ipatch), &
                pregion%specImpulseGlobal(zcoord,ipatch), & 
                pregion%specImpulseVacGlobal(zcoord,ipatch)
        END IF ! pRegion%thrustFlagsGlobal
      END DO ! iPatch     
 
      WRITE(stdout,'(A,1X,A)') solver_name,'Printing thrust and '// & 
                               'specific impulse done.'             
    END IF ! global%myProcid

! ******************************************************************************
!   End  
! ******************************************************************************

    CALL deregisterfunction(global)

  END SUBROUTINE rflu_tsi_printglobalvals








! *******************************************************************************
!
! Purpose: Write thrust and specific impulse to file.
!
! Description: None.
!
! Input:
!   pRegion             Pointer to region
!
! Output: None.
!
! Notes: 
!   1. This routine should only be called for the master process. It will not 
!      do anything if called by any other process (safeguard).
!   2. At present, each patch is written to separate file. This may change in
!      future with definition of superpatches which are treated together. 
!
! ******************************************************************************

  SUBROUTINE rflu_tsi_writeglobalvals(pRegion)

    IMPLICIT NONE
        
! ******************************************************************************
!   Declarations and definitions
! ******************************************************************************
    
! ==============================================================================
!   Arguments
! ==============================================================================
    
    TYPE(t_region), POINTER :: pregion
    
! ==============================================================================
!   Locals
! ==============================================================================
    
    LOGICAL :: fileexists1,fileexists2
    CHARACTER(CHRLEN) :: ifilename1,ifilename2
    INTEGER :: errorflag,ifile1,ifile2,ipatch 
    TYPE(t_global), POINTER :: global
    
! ******************************************************************************
!   Start, set pointers and variables
! ******************************************************************************
    
    global => pregion%global
    
    CALL registerfunction(global,'RFLU_TSI_WriteGlobalVals',&
  'RFLU_ModThrustSpecImpulse.F90')

! ******************************************************************************
!   Increment counter
! ******************************************************************************

    global%thrustWriteCntr = global%thrustWriteCntr + 1
                
! ******************************************************************************
!   Write global force coefficients
! ******************************************************************************

    IF ( global%myProcid == masterproc ) THEN
      IF ( global%verbLevel > verbose_low ) THEN   
        WRITE(stdout,'(A,1X,A)') solver_name,'Writing thrust and '// &
                                 'specific impulse...' 
      END IF ! global%verbLevel

! ==============================================================================
!   Loop over patches - DONT LOOP OVER PATCH, just write for a given patch
! ==============================================================================

      DO ipatch = 1,global%nPatches
        IF ( pregion%thrustFlagsGlobal(ipatch) .EQV. .true. ) THEN
          IF ( global%verbLevel > verbose_low ) THEN   
            WRITE(stdout,'(A,3X,A,1X,I2)') solver_name,'Patch:',ipatch 
          END IF ! global%verbLevel

! ------------------------------------------------------------------------------
!   Open file
! ------------------------------------------------------------------------------

          CALL rflu_tsi_openglobalvals(global,ipatch,ifile1,ifile2)

! ------------------------------------------------------------------------------
!   Write to file
! ------------------------------------------------------------------------------

          IF ( global%flowType == flow_steady ) THEN                               
            WRITE(ifile1,'(I6,6(1X,E13.6))') global%currentIter, & 
                  pregion%thrustGlobal(xcoord,ipatch), & 
                  pregion%thrustVacGlobal(xcoord,ipatch), &
              
                  pregion%thrustGlobal(ycoord,ipatch), & 
                  pregion%thrustVacGlobal(ycoord,ipatch), &
  
                  pregion%thrustGlobal(zcoord,ipatch), & 
                  pregion%thrustVacGlobal(zcoord,ipatch)
          ELSE 
            WRITE(ifile1,'(1PE12.5,6(1X,E13.6))') global%currentTime, & 
                  pregion%thrustGlobal(xcoord,ipatch), & 
                  pregion%thrustVacGlobal(xcoord,ipatch), &
                
                  pregion%thrustGlobal(ycoord,ipatch), & 
                  pregion%thrustVacGlobal(ycoord,ipatch), &
  
                  pregion%thrustGlobal(zcoord,ipatch), & 
                  pregion%thrustVacGlobal(zcoord,ipatch)
          END IF ! global%flowType                                     
  
          IF ( global%flowType == flow_steady ) THEN                               
            WRITE(ifile2,'(I6,6(1X,E13.6))') global%currentIter, & 
                  pregion%specImpulseGlobal(xcoord,ipatch), & 
                  pregion%specImpulseVacGlobal(xcoord,ipatch), &
                
                  pregion%specImpulseGlobal(ycoord,ipatch), & 
                  pregion%specImpulseVacGlobal(ycoord,ipatch), &
  
                  pregion%specImpulseGlobal(zcoord,ipatch), & 
                  pregion%specImpulseVacGlobal(zcoord,ipatch)
          ELSE 
            WRITE(ifile2,'(1PE12.5,6(1X,E13.6))') global%currentTime, & 
                  pregion%specImpulseGlobal(xcoord,ipatch), & 
                  pregion%specImpulseVacGlobal(xcoord,ipatch), &
                
                  pregion%specImpulseGlobal(ycoord,ipatch), & 
                  pregion%specImpulseVacGlobal(ycoord,ipatch), &
  
                  pregion%specImpulseGlobal(zcoord,ipatch), & 
                  pregion%specImpulseVacGlobal(zcoord,ipatch)
          END IF ! global%flowType                                     

! ------------------------------------------------------------------------------
!   Close file
! ------------------------------------------------------------------------------

          CALL rflu_tsi_closeglobalvals(global,ipatch,ifile1,ifile2)
        END IF ! pRegion%thrustFlagsGlobal
      END do! iPatch        
            
! ******************************************************************************
!   End  
! ******************************************************************************

      IF ( global%verbLevel > verbose_low ) THEN       
        WRITE(stdout,'(A,1X,A)') solver_name,'Writing thrust and '// & 
                                 'specific impulse done.'             
      END IF ! global%verbLevel
    END IF ! global%myProcid

    CALL deregisterfunction(global)

  END SUBROUTINE rflu_tsi_writeglobalvals






END MODULE rflu_modthrustspecimpulse

! ******************************************************************************
!
! RCS Revision history:
!
! $Log: RFLU_ModThrustSpecImpulse.F90,v $
! Revision 1.4  2008/12/06 08:44:24  mtcampbe
! Updated license.
!
! Revision 1.3  2008/11/19 22:17:35  mtcampbe
! Added Illinois Open Source License/Copyright
!
! Revision 1.2  2007/12/19 19:13:42  rfiedler
! Increased verbosity level required for writing to screen dump to > VERBOSE_LOW.
!
! Revision 1.1  2006/10/20 21:16:32  mparmar
! Initial import
!
!
! ******************************************************************************