PLAG_ModDimensions.F90

Go to the documentation of this file.

! *********************************************************************
! * Rocstar Simulation Suite                                          *
! * Copyright@2015, Illinois Rocstar LLC. All rights reserved.        *
! *                                                                   *
! * Illinois Rocstar LLC                                              *
! * Champaign, IL                                                     *
! * www.illinoisrocstar.com                                           *
! * sales@illinoisrocstar.com                                         *
! *                                                                   *
! * License: See LICENSE file in top level of distribution package or *
! * http://opensource.org/licenses/NCSA                               *
! *********************************************************************
! *********************************************************************
! * THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND,   *
! * EXPRESS OR IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES   *
! * OF MERCHANTABILITY, FITNESS FOR A PARTICULAR PURPOSE AND          *
! * NONINFRINGEMENT.  IN NO EVENT SHALL THE CONTRIBUTORS OR           *
! * COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER       *
! * LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE,   *
! * Arising FROM, OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE    *
! * USE OR OTHER DEALINGS WITH THE SOFTWARE.                          *
! *********************************************************************
! ******************************************************************************
!
! Purpose: Suite of routines to compute, read, and write dimension files.
!
! Description: None.
!
! Notes: None.
!
! ******************************************************************************
!
! $Id: PLAG_ModDimensions.F90,v 1.7 2008/12/06 08:44:34 mtcampbe Exp $
!
! Copyright: (c) 2007 by the University of Illinois
!
! ******************************************************************************

MODULE plag_moddimensions

  USE modparameters
  USE moddatatypes
  USE moderror
  USE modglobal, ONLY: t_global 
  USE modbndpatch, ONLY: t_patch
  USE modborder, ONLY: t_border
  USE moddatastruct, ONLY: t_region  
  USE modgrid, ONLY: t_grid
  USE modpartlag, ONLY: t_plag,t_plag_input
  USE modmpi
  
  USE plag_modparameters
    
  IMPLICIT NONE
     
  PRIVATE
  PUBLIC :: plag_calcnpclsglobal, &
            plag_printdimensions, &
            plag_printnpclsglobal, & 
            plag_rflu_readdimensions, & 
            plag_setdimensions, & 
            plag_setmaxdimensions, & 
            plag_rflu_writedimensions

! ******************************************************************************
! Declarations and definitions
! ******************************************************************************  

! ==============================================================================
! Private
! ==============================================================================
   
  CHARACTER(CHRLEN), PRIVATE :: RCSIdentString = &
    '$RCSfile: PLAG_ModDimensions.F90,v $ $Revision: 1.7 $' 
    
! ******************************************************************************
! Routines
! ******************************************************************************

  CONTAINS





! ******************************************************************************
!
! Purpose: Calculate the total number of particles for all regions.
!
! Description: None.
!
! Input:
!   regions     Pointer to all regions
!
! Output: None.
!
! Notes: None.
!
! ******************************************************************************

  SUBROUTINE plag_calcnpclsglobal(regions)

    IMPLICIT NONE
  
! ******************************************************************************
!   Declarations and definitions
! ******************************************************************************  
  
! ==============================================================================
!   Arguments
! ==============================================================================

    TYPE(t_region), POINTER :: regions(:)
       
! ==============================================================================
!   Local variables
! ==============================================================================

    INTEGER :: errorflag,ireg,iregglobal,npclsglobal,npclslocal

    TYPE(t_global), POINTER :: global    
    TYPE(t_region), POINTER :: pregion
    TYPE(t_plag),   POINTER :: pplag 

! ******************************************************************************
!   Start
! ******************************************************************************

    global => regions(0)%global

    CALL registerfunction(global,'PLAG_CalcNPclsGlobal',&
  'PLAG_ModDimensions.F90')

! ******************************************************************************
!   Initialize variables
! ******************************************************************************

    npclslocal = 0

    DO ireg = 0,global%nRegionsLocal
      pregion => regions(ireg)

      pregion%plag%nPclsGlobal = 0
    END DO ! iReg

! ******************************************************************************
!   Compute sum of particles for all regions on the same processor. NOTE cannot
!   include region 0 in this sum because it would pick up the CRAZY_VALUE_INT
!   value assigned below.
! ******************************************************************************

    DO ireg = 1,global%nRegionsLocal
      pregion => regions(ireg)

      npclslocal = npclslocal + pregion%plag%nPcls
    END DO ! iReg
    
! ******************************************************************************
!   Determine global sum of particles over all processors
! ******************************************************************************

! ==============================================================================
!   Perform reduction operation. NOTE need to include region index 0 
!    to make sure that this works properly for serial runs.
! ==============================================================================

    CALL mpi_allreduce(npclslocal,npclsglobal,1,mpi_integer,mpi_sum, &
                       global%mpiComm,errorflag )
    global%error = errorflag
    IF ( global%error /= err_none ) THEN 
      CALL errorstop(global,err_mpi_trouble,__line__)
    END IF ! global%errorFlag
    
! ******************************************************************************
!   Store the global sum of particles. NOTE copy into serial nPcls for master
!   process, but for others set to CRAZY_VALUE_INT.
! ******************************************************************************

    DO ireg = 0,global%nRegionsLocal
      pregion => regions(ireg)

      pregion%plag%nPclsGlobal = npclsglobal 
    END DO ! iReg

    IF ( global%myProcid == masterproc ) THEN 
      regions(0)%plag%nPcls = regions(0)%plag%nPclsGlobal
    ELSE 
      regions(0)%plag%nPcls = crazy_value_int
    END IF ! global%myProcid

! ******************************************************************************
!   End
! ******************************************************************************

    CALL deregisterfunction(global)

  END SUBROUTINE plag_calcnpclsglobal








! ******************************************************************************
!
! Purpose: Print the number of particles.
!
! Description: None.
!
! Input:
!   pRegion     Pointer to region
!
! Output: None.
!
! Notes: None.
!
! ******************************************************************************

  SUBROUTINE plag_printdimensions(pRegion)

    IMPLICIT NONE
  
! ******************************************************************************
!   Declarations and definitions
! ******************************************************************************  
  
! ==============================================================================
!   Arguments
! ==============================================================================

    TYPE(t_region), POINTER :: pregion
       
! ==============================================================================
!   Local variables
! ==============================================================================

    TYPE(t_global), POINTER :: global    

! ******************************************************************************
!   Start
! ******************************************************************************

    global => pregion%global

    CALL registerfunction(global,'PLAG_PrintDimensions',&
  'PLAG_ModDimensions.F90')

! ******************************************************************************
!   Print information
! ******************************************************************************

    IF ( global%verbLevel > verbose_none ) THEN 
      WRITE(stdout,'(A,1X,A)') solver_name,'Printing number of particles...'
      WRITE(stdout,'(A,3X,A,1X,I5.5)') solver_name,'Global region:', &
                                       pregion%iRegionGlobal
      IF ( global%flowType == flow_unsteady ) THEN
        WRITE(stdout,'(A,3X,A,1X,1PE11.5)') solver_name,'Current time:', &
                                            global%currentTime
      END IF ! global%flowType

      WRITE(stdout,'(A,3X,A,9X,I8)') solver_name,'Number of particles:', &
                                     pregion%plag%nPcls
      WRITE(stdout,'(A,3X,A,1X,I8)') solver_name,'Maximum number of '// &
                                     'particles:',pregion%plag%nPclsMax

      WRITE(stdout,'(A,1X,A)') solver_name,'Printing number of particles done.'
    END IF ! global%verbLevel

! ******************************************************************************
!   End
! ******************************************************************************

    CALL deregisterfunction(global)

  END SUBROUTINE plag_printdimensions








! ******************************************************************************
!
! Purpose: Print the total number of particles in all regions.
!
! Description: None.
!
! Input:
!   pRegion     Pointer to region
!
! Output: None.
!
! Notes: None.
!
! ******************************************************************************

  SUBROUTINE plag_printnpclsglobal(pRegion)

    IMPLICIT NONE
  
! ******************************************************************************
!   Declarations and definitions
! ******************************************************************************  
  
! ==============================================================================
!   Arguments
! ==============================================================================

    TYPE(t_region), POINTER :: pregion
       
! ==============================================================================
!   Local variables
! ==============================================================================

    TYPE(t_global), POINTER :: global    

! ******************************************************************************
!   Start
! ******************************************************************************

    global => pregion%global

    CALL registerfunction(global,'PLAG_PrintNPclsGlobal',&
  'PLAG_ModDimensions.F90')

! ******************************************************************************
!   Print information
! ******************************************************************************

    IF ( global%verbLevel > verbose_none ) THEN 
      WRITE(stdout,'(A,1X,A)') solver_name,'Printing total number of '// & 
                               'particles...'
      WRITE(stdout,'(A,3X,A,1X,I5.5)') solver_name,'Global region:', &
                                       pregion%iRegionGlobal
      IF ( global%flowType == flow_unsteady ) THEN
        WRITE(stdout,'(A,3X,A,1X,1PE11.5)') solver_name,'Current time:', &
                                            global%currentTime
      END IF ! global%flowType

      WRITE(stdout,'(A,3X,A,1X,I8)') solver_name,'Number of particles:', &
                                     pregion%plag%nPclsGlobal

      WRITE(stdout,'(A,1X,A)') solver_name,'Printing total number of '// &
                               'particles done.'
    END IF ! global%verbLevel

! ******************************************************************************
!   End
! ******************************************************************************

    CALL deregisterfunction(global)

  END SUBROUTINE plag_printnpclsglobal







! ******************************************************************************
!
! Purpose: Read dimensions for Lagrangian particles.
!
! Description: None.
!
! Input:
!   pRegion     Pointer to region
!
! Output: None.
!
! Notes: None.
!
! ******************************************************************************

  SUBROUTINE plag_rflu_readdimensions(pRegion)

    USE rflu_modgrid

    USE modbuildfilenames, ONLY: buildfilenamebasic, &
                                 buildfilenameunsteady  

    IMPLICIT NONE
  
! ******************************************************************************
!   Declarations and definitions
! ******************************************************************************  

! ==============================================================================
!   Arguments
! ==============================================================================

    TYPE(t_region), POINTER :: pregion  
   
! ==============================================================================
!   Local variables
! ==============================================================================

    CHARACTER(CHRLEN) :: errorstring,ifilename,rcsidentstring,sectionstring, & 
                         timestring1,timestring2
    INTEGER :: errorflag,dummy,ipatch,ifile,loopcounter,ncont,npclsmax
    REAL(RFREAL) :: currenttime
    TYPE(t_grid), POINTER :: pgrid  
    TYPE(t_global), POINTER :: global
    
! ******************************************************************************
!   Start
! ******************************************************************************

    global => pregion%global

    CALL registerfunction(global,'PLAG_RFLU_ReadDimensions',&
  'PLAG_ModDimensions.F90')

    IF ( global%myProcid == masterproc .AND. &
         global%verbLevel > verbose_none ) THEN  
      WRITE(stdout,'(A,1X,A)') solver_name,'Reading particle dimensions...'
    END IF ! global%verbLevel

! ==============================================================================
!   Build file name
! ==============================================================================

    ifile = if_dims

    IF ( global%flowType == flow_unsteady ) THEN 
#ifndef GENX
      currenttime = global%currentTime
#else
      IF ( global%timeStamp > 0.0_rfreal ) THEN
        global%warnCounter = global%warnCounter + 1    

        IF ( global%myProcid == masterproc .AND. &
             global%verbLevel > verbose_none ) THEN        
          WRITE(stdout,'(A,3X,A,1X,A)') solver_name,'*** WARNING ***', & 
                                        'Hard-code - read file from time zero.'
        END IF ! global%myProcid
      END IF ! global%timeStamp

      currenttime = 0.0_rfreal ! Hard-code for GENX restart
#endif        

! TEMPORARY
      IF ( pregion%iRegionGlobal == 0 ) THEN 
        currenttime = 0.0_rfreal
      END IF ! pRegion%iRegionGlobal
! END TEMPORARY

      CALL buildfilenameunsteady(global,filedest_indir,'.pdim', & 
                                 pregion%iRegionGlobal,currenttime, & 
                                 ifilename)

      IF ( global%myProcid == masterproc .AND. &
           global%verbLevel > verbose_none ) THEN        
        WRITE(stdout,'(A,3X,A,1X,I5.5)') solver_name,'Global region:', & 
                                         pregion%iRegionGlobal          
        WRITE(stdout,'(A,3X,A,1X,1PE11.5)') solver_name,'Current time:', & 
                                            global%currentTime   
      END IF ! global%verbLevel
    ELSE 
      CALL buildfilenamebasic(global,filedest_indir,'.pdim', & 
                              pregion%iRegionGlobal,ifilename) 

      IF ( global%myProcid == masterproc .AND. &
           global%verbLevel > verbose_none ) THEN 
        WRITE(stdout,'(A,3X,A,1X,I5.5)') solver_name,'Global region:', & 
                                         pregion%iRegionGlobal
      END IF ! global%verbLevel
    END IF ! global

! ==============================================================================
!   Open file
! ==============================================================================

    OPEN(ifile,file=ifilename,form="FORMATTED",status="OLD", & 
         iostat=errorflag)   
    global%error = errorflag        
    IF ( global%error /= err_none ) THEN 
      CALL errorstop(global,err_file_open,__line__,ifilename)
    END IF ! global%error
    
! ==============================================================================
!   Header and general information
! ==============================================================================

    IF ( global%myProcid == masterproc .AND. &
         global%verbLevel > verbose_low ) THEN  
      WRITE(stdout,'(A,3X,A)') solver_name,'Header information...'
    END IF ! global%verbLevel 

    READ(ifile,'(A)') sectionstring  
    IF ( trim(sectionstring) /= '# ROCPART dimensions file' ) THEN 
      CALL errorstop(global,err_invalid_marker,__line__,sectionstring) 
    END IF ! TRIM  
    
! ==============================================================================
!   Rest of file
! ==============================================================================

    pgrid => pregion%grid  

    loopcounter = 0

    DO ! set up infinite loop
      loopcounter = loopcounter + 1

      READ(ifile,'(A)') sectionstring

      SELECT CASE ( trim(sectionstring) ) 

! ------------------------------------------------------------------------------
!       Actual number of particles
! ------------------------------------------------------------------------------ 
    
        CASE ( '# Actual number of particles' )     
          IF ( global%myProcid == masterproc .AND. &
               global%verbLevel > verbose_low ) THEN  
            WRITE(stdout,'(A,3X,A)') solver_name,'Actual number of particles...'
          END IF ! global%verbLevel          

          READ(ifile,'(I8)') pregion%plag%nPcls   

! ------------------------------------------------------------------------------
!       Maximum number of particles
! ------------------------------------------------------------------------------ 
        
        CASE ( '# Maximum number of particles' )     
          IF ( global%myProcid == masterproc .AND. &
               global%verbLevel > verbose_low ) THEN  
            WRITE(stdout,'(A,3X,A)') solver_name,'Maximum number of particles...'
          END IF ! global%verbLevel          

          READ(ifile,'(I8)') pregion%plag%nPclsMax     

! ------------------------------------------------------------------------------
!       Number of constituents
! ------------------------------------------------------------------------------ 
        
        CASE ( '# Number of constituents' )     
          IF ( global%myProcid == masterproc .AND. &
               global%verbLevel > verbose_low ) THEN  
            WRITE(stdout,'(A,3X,A)') solver_name,'Number of constituents...'
          END IF ! global%verbLevel          

          READ(ifile,'(I8)') ncont

          IF ( ncont /= pregion%plagInput%nCont ) THEN 
            WRITE(errorstring,'(A,1X,I2,1X,A,1X,I2)') 'Specified:',ncont, & 
                  'but expected:',pregion%plagInput%nCont        
            CALL errorstop(global,err_plag_ncont_invalid,__line__)          
          END IF ! nCont              
        
! ------------------------------------------------------------------------------
!       Next particle identifier
! ------------------------------------------------------------------------------ 
        
        CASE ( '# Next particle identifier' )     
          IF ( global%myProcid == masterproc .AND. &
               global%verbLevel > verbose_low ) THEN  
            WRITE(stdout,'(A,3X,A)') solver_name,'Next particle identifier...'
          END IF ! global%verbLevel          

          READ(ifile,'(I8)') pregion%plag%nextIdNumber         
        
! ------------------------------------------------------------------------------
!       End marker
! ------------------------------------------------------------------------------ 
      
        CASE ( '# End' ) 
          IF ( global%myProcid == masterproc .AND. & 
               global%verbLevel > verbose_low ) THEN  
            WRITE(stdout,'(A,3X,A)') solver_name,'End marker...'
          END IF ! global%verbLevel           
      
          EXIT
      
! ------------------------------------------------------------------------------
!       Invalid section string
! ------------------------------------------------------------------------------ 
      
        CASE default
          IF ( global%verbLevel > verbose_low ) THEN  
            WRITE(stdout,'(A,3X,A)') solver_name,sectionstring
          END IF ! verbosityLevel           

          CALL errorstop(global,err_invalid_marker,__line__,sectionstring)      

      END SELECT ! TRIM

! ------------------------------------------------------------------------------
!     Guard against infinite loop - might be unnecessary because of read errors?
! ------------------------------------------------------------------------------  
  
      IF ( loopcounter >= limit_infinite_loop ) THEN 
        CALL errorstop(global,err_infinite_loop,__line__)
      END IF ! loopCounter

    END DO ! <empty> 

! ==============================================================================
!   Close file
! ==============================================================================

    CLOSE(ifile,iostat=errorflag)
    global%error = errorflag      
    IF ( global%myProcid == masterproc .AND. &
         global%error /= err_none ) THEN 
      CALL errorstop(global,err_file_close,__line__,ifilename)
    END IF ! global%error 
   
! ******************************************************************************
!   End
! ******************************************************************************
    
    IF ( global%myProcid == masterproc .AND. &
         global%verbLevel > verbose_none ) THEN   
      WRITE(stdout,'(A,1X,A)') solver_name,'Reading particle dimensions done.'
    END IF ! global%verbLevel  

    CALL deregisterfunction(global)  
  
  END SUBROUTINE plag_rflu_readdimensions








! ******************************************************************************
!
! Purpose: Set dimensions for Lagrangian particle datastructure 
!          at initialization stage.
!
! Description: None.
!
! Input:
!   pRegion        Pointer to region
!   nPcls          Number of particles 
!
! Output: None.
!
! Notes: None.
!
! ******************************************************************************

  SUBROUTINE plag_setdimensions(pRegion,nPcls)

! ******************************************************************************
!   Definitions and declarations
! ******************************************************************************

! ==============================================================================
!   Arguments
! ==============================================================================

    INTEGER, INTENT(IN) :: npcls
    TYPE(t_region), POINTER :: pregion

! ==============================================================================
!   Locals
! ==============================================================================

    TYPE(t_global), POINTER :: global

! ******************************************************************************
!   Start
! ******************************************************************************

    global => pregion%global

    CALL registerfunction(global,'PLAG_SetDimensions',&
  'PLAG_ModDimensions.F90')

! ******************************************************************************
!   Set number of particles
! ******************************************************************************

    pregion%plag%nPcls = npcls

! ******************************************************************************
!   End
! ******************************************************************************
    
    CALL deregisterfunction(global)

  END SUBROUTINE plag_setdimensions








! ******************************************************************************
!
! Purpose: Set maximum dimensions for Lagrangian particle datastructure.
!
! Description: None.
!
! Input:
!   pRegion        Region pointer
!
! Output: None.
!
! Notes: None.
!
! ******************************************************************************

  SUBROUTINE plag_setmaxdimensions(pRegion)
  
    IMPLICIT NONE

! ******************************************************************************
!   Declarations and definitions
! ******************************************************************************

! ==============================================================================
!   Arguments
! ==============================================================================

    TYPE(t_region), POINTER :: pregion

! ==============================================================================
!   Locals
! ==============================================================================

    INTEGER :: npcls,npclsmax
    REAL(RFREAL), PARAMETER :: plag_realloc_fact = 1.20_rfreal   
    TYPE(t_global), POINTER :: global 

! ******************************************************************************
!   Start
! ******************************************************************************

    global => pregion%global

    CALL registerfunction(global,'PLAG_SetMaxDimensions',&
  'PLAG_ModDimensions.F90')

! ******************************************************************************
!   Set variables 
! ******************************************************************************

    npcls    = pregion%plag%nPcls
    npclsmax = pregion%plag%nPclsMax

! ******************************************************************************
!   Set maximum dimension of particle datastructure. First ensure that 
!   a minimum value is preserved for null particle field.
! ******************************************************************************
  
    npclsmax = nint(plag_realloc_fact*REAL(npcls,kind=rfreal))

! ******************************************************************************
!   Update maximum value of particle datastructure
! ******************************************************************************

    pregion%plag%nPclsMax = max(npclsmax,npcls_tot_min)

! ******************************************************************************
!   End
! ******************************************************************************
    
    CALL deregisterfunction(global)  
  
  END SUBROUTINE plag_setmaxdimensions






! ******************************************************************************
!
! Purpose: Write dimensions for Lagrangian particles.
!
! Description: None.
!
! Input:
!   pRegion     Pointer to region
!
! Output: None.
!
! Notes: None.
!
! ******************************************************************************

  SUBROUTINE plag_rflu_writedimensions(pRegion)

    USE modbuildfilenames, ONLY: buildfilenamebasic, &
                                 buildfilenameunsteady  

    IMPLICIT NONE
  
! ******************************************************************************
!   Declarations and definitions
! ******************************************************************************  

! ==============================================================================
!   Arguments
! ==============================================================================

    TYPE(t_region), POINTER :: pregion  
   
! ==============================================================================
!   Local variables
! ==============================================================================

    CHARACTER(CHRLEN) :: ifilename,rcsidentstring,sectionstring, & 
                         timestring1,timestring2
    INTEGER :: errorflag,dummy,ifile
    REAL(RFREAL) :: currenttime
    TYPE(t_grid), POINTER :: pgrid  
    TYPE(t_global), POINTER :: global
    
! ******************************************************************************
!   Start
! ******************************************************************************

    global => pregion%global
    
    CALL registerfunction(global,'PLAG_RFLU_WriteDimensions',&
  'PLAG_ModDimensions.F90')
    
    IF ( global%myProcid == masterproc .AND. &
         global%verbLevel > verbose_none ) THEN  
      WRITE(stdout,'(A,1X,A)') solver_name,'Writing particle dimensions...'
    END IF ! global%verbLevel

! ==============================================================================
!   Build file name
! ==============================================================================

    ifile = if_dims

    IF ( global%flowType == flow_unsteady ) THEN 
#ifndef GENX
      currenttime = global%currentTime
#else
      IF ( global%timeStamp > 0.0_rfreal ) THEN
        global%warnCounter = global%warnCounter + 1    

        IF ( global%myProcid == masterproc .AND. &
             global%verbLevel > verbose_none ) THEN        
          WRITE(stdout,'(A,3X,A,1X,A)') solver_name,'*** WARNING ***', & 
                                        'Hard-code - read file from time zero.'
        END IF ! global%myProcid
      END IF ! global%timeStamp

      currenttime = 0.0_rfreal ! Hard-code for GENX restart
#endif        
      CALL buildfilenameunsteady(global,filedest_indir,'.pdim', & 
                                 pregion%iRegionGlobal,currenttime, & 
                                 ifilename)

      IF ( global%myProcid == masterproc .AND. &
           global%verbLevel > verbose_none ) THEN        
        WRITE(stdout,'(A,3X,A,1X,I5.5)') solver_name,'Global region:', & 
                                         pregion%iRegionGlobal          
        WRITE(stdout,'(A,3X,A,1X,1PE11.5)') solver_name,'Current time:', & 
                                            global%currentTime   
      END IF ! global%verbLevel
    ELSE 
      CALL buildfilenamebasic(global,filedest_indir,'.pdim', & 
                              pregion%iRegionGlobal,ifilename) 

      IF ( global%myProcid == masterproc .AND. &
           global%verbLevel > verbose_none ) THEN 
        WRITE(stdout,'(A,3X,A,1X,I5.5)') solver_name,'Global region:', & 
                                         pregion%iRegionGlobal
      END IF ! global%verbLevel
    END IF ! global

! ==============================================================================
!   Open file
! ==============================================================================

    OPEN(ifile,file=ifilename,form="FORMATTED",status="UNKNOWN", & 
         iostat=errorflag)   
    global%error = errorflag        
    IF ( global%error /= err_none ) THEN 
      CALL errorstop(global,err_file_open,__line__,ifilename)
    END IF ! global%error

! ==============================================================================
!   Header and general information
! ==============================================================================

    IF ( global%myProcid == masterproc .AND. &
         global%verbLevel > verbose_low ) THEN  
      WRITE(stdout,'(A,3X,A)') solver_name,'Header information...'
    END IF ! global%verbLevel 

    sectionstring = '# ROCPART dimensions file'  
    WRITE(ifile,'(A)') trim(sectionstring) 

! ==============================================================================
!   Write dimensions
! ==============================================================================

    sectionstring = '# Actual number of particles'
    WRITE(ifile,'(A)') trim(sectionstring) 
    WRITE(ifile,'(I8)') pregion%plag%nPcls   

    sectionstring = '# Maximum number of particles'
    WRITE(ifile,'(A)') trim(sectionstring) 
    WRITE(ifile,'(I8)') pregion%plag%nPclsMax  

    sectionstring = '# Number of constituents'
    WRITE(ifile,'(A)') trim(sectionstring) 
    WRITE(ifile,'(I8)') pregion%plagInput%nCont  

    sectionstring = '# Next particle identifier'
    WRITE(ifile,'(A)') trim(sectionstring) 
    WRITE(ifile,'(I8)') pregion%plag%nextIdNumber      
    
! ==============================================================================
!   End marker
! ==============================================================================

    IF ( global%myProcid == masterproc .AND. &
         global%verbLevel > verbose_low ) THEN  
      WRITE(stdout,'(A,3X,A)') solver_name,'End marker...'
    END IF ! global%verbLevel

    sectionstring = '# End'
    WRITE(ifile,'(A)') trim(sectionstring) 
 
! ==============================================================================
!   Close file
! ==============================================================================

    CLOSE(ifile,iostat=errorflag)
    global%error = errorflag      
    IF ( global%myProcid == masterproc .AND. &
         global%error /= err_none ) THEN 
      CALL errorstop(global,err_file_close,__line__,ifilename)
    END IF ! global%error
   
! ******************************************************************************
!   End
! ******************************************************************************
  
    IF ( global%myProcid == masterproc .AND. &
         global%verbLevel > verbose_none ) THEN   
      WRITE(stdout,'(A,1X,A)') solver_name,'Writing dimensions done.'
    END IF ! global%verbLevel

    CALL deregisterfunction(global)
  
  END SUBROUTINE plag_rflu_writedimensions








! ******************************************************************************
! End
! ******************************************************************************
  
END MODULE plag_moddimensions


! ******************************************************************************
!
! RCS Revision history:
!
! $Log: PLAG_ModDimensions.F90,v $
! Revision 1.7  2008/12/06 08:44:34  mtcampbe
! Updated license.
!
! Revision 1.6  2008/11/19 22:17:46  mtcampbe
! Added Illinois Open Source License/Copyright
!
! Revision 1.5  2007/03/31 23:55:43  haselbac
! Removed Tot from names, bug fix in CalcNPclsGlobal, removed tabs
!
! Revision 1.4  2007/03/27 00:55:33  haselbac
! Substantial changes and additions
!
! Revision 1.3  2007/03/21 21:33:10  fnajjar
! Activated IO of nPclsTotGlobal when doPrint is on
!
! Revision 1.2  2007/03/20 22:03:27  fnajjar
! Included PLAG_CalcnPclsTotGlobal routine
!
! Revision 1.1  2007/03/20 17:39:12  fnajjar
! Initial import
!
! ******************************************************************************