RFLU_ModTimeZoom.F90

Go to the documentation of this file.

! *********************************************************************
! * Rocstar Simulation Suite                                          *
! * Copyright@2015, Illinois Rocstar LLC. All rights reserved.        *
! *                                                                   *
! * Illinois Rocstar LLC                                              *
! * Champaign, IL                                                     *
! * www.illinoisrocstar.com                                           *
! * sales@illinoisrocstar.com                                         *
! *                                                                   *
! * License: See LICENSE file in top level of distribution package or *
! * http://opensource.org/licenses/NCSA                               *
! *********************************************************************
! *********************************************************************
! * THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND,   *
! * EXPRESS OR IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES   *
! * OF MERCHANTABILITY, FITNESS FOR A PARTICULAR PURPOSE AND          *
! * NONINFRINGEMENT.  IN NO EVENT SHALL THE CONTRIBUTORS OR           *
! * COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER       *
! * LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE,   *
! * Arising FROM, OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE    *
! * USE OR OTHER DEALINGS WITH THE SOFTWARE.                          *
! *********************************************************************
! ******************************************************************************
!
! Purpose: Collection of routines related to solution zooming..
!
! Description: None.
!
! Notes: None. 
!**********************************************************************

MODULE rflu_modtimezoom

  USE moddatatypes   !add use list
  USE modparameters
  USE moderror
  USE moddatastruct, ONLY: t_region
  USE modglobal, ONLY: t_global
  USE modgrid, ONLY: t_grid
  USE modbndpatch, ONLY: t_patch
  USE modmpi

  IMPLICIT NONE

  TYPE t_timezoom
     REAL(RFREAL),Dimension(CV_MIXT_DENS:CV_MIXT_ENER) :: CvBulk,resbar_Qbulk,&
          CvdVdtBulk
  END TYPE t_timezoom
  
  PRIVATE
  PUBLIC :: rflu_timezoomdriver,t_timezoom,timezoom, &
       rflu_unzoomgridspeeds,rflu_zoomgridspeeds


!Module Local varaibles
  TYPE (t_timezoom) :: TimeZoom

! ******************************************************************************
! Declarations and definitions
! ******************************************************************************  

  CHARACTER(CHRLEN) :: & 
       RCSIdentString = '$RCSfile: RFLU_ModTimeZoom.F90,v $' 

! ******************************************************************************
! Routines
! ******************************************************************************

CONTAINS


  SUBROUTINE rflu_timezoomdriver(regions)
    IMPLICIT NONE

!---Dummy
    TYPE(t_region), POINTER :: regions(:)

    CALL rflu_timezoomcomputebulkvars(regions)
    CALL rflu_timezoomsumaddsource(regions)

    RETURN
  END SUBROUTINE rflu_timezoomdriver


  SUBROUTINE rflu_timezoomcomputebulkvars(regions)
    IMPLICIT NONE

!---Dummy
    TYPE(t_region), POINTER :: regions(:)
!---Local
    TYPE(t_region), POINTER :: pregion
    TYPE(t_global), POINTER :: global
    REAL(RFREAL), DIMENSION(:), POINTER :: vol,volold
    REAL(RFREAL), DIMENSION(:,:), POINTER :: cv
    INTEGER :: ireg,icell,i,nvars,ncvvars
    REAL(RFREAL) ::x, localintegvol,globalintegvol,dvdt_i, volbulkold
    REAL(RFREAL),DIMENSION(2*(CV_MIXT_ENER-CV_MIXT_DENS+1)+2) :: bulkvarslocal,bulkvarsglobal
!---For submerged nozzles
    REAL(RFREAL) :: y, z
    REAL(RFREAL) :: rnozzleinlet2

    global => regions(1)%global

    rnozzleinlet2 = global%tzNozRad**2

    nvars = ubound(bulkvarslocal,1)-lbound(bulkvarslocal,1)+1
    ncvvars = cv_mixt_ener-cv_mixt_dens+1
    bulkvarslocal = 0_rfreal

    DO ireg = 1,global%nRegionsLocal

! Region Pointers
       pregion => regions(ireg)
       vol    => pregion%grid%vol
       volold => pregion%gridOld%vol
       cv     => pregion%mixt%cv

! Sum over Cells
       IF (.NOT. global%tzSubNoz) THEN
          DO icell = 1,pregion%grid%nCells
             x = pregion%grid%cofg(global%tzCoordLong,icell)
             IF(x > global%tzMinPlane .AND. x < global%tzMaxPlane) THEN
                dvdt_i = (vol(icell)-volold(icell))/max(global%dtMin,  &
                         tiny(1.0_rfreal))
                bulkvarslocal  = bulkvarslocal + (/ (cv(i,icell)*vol(icell), &
                     i=cv_mixt_dens,cv_mixt_ener),vol(icell),volold(icell), &
                     (cv(i,icell)*dvdt_i,i=cv_mixt_dens,cv_mixt_ener)/)
             ENDIF
          END DO !iCell
       ELSE
!         Exclude submerged nozzle
          DO icell = 1,pregion%grid%nCells
             x = pregion%grid%cofg(global%tzCoordLong,icell)
             y = pregion%grid%cofg(global%tzCoordTrans1,icell)
             z = pregion%grid%cofg(global%tzCoordTrans2,icell)
             IF((x > global%tzMinPlane .AND. x < global%tzNozInlet) .OR.  &
                ((x >= global%tzNozInlet .AND. x < global%tzMaxPlane) .AND.  &
                 (y**2 + z**2 > rnozzleinlet2) ) ) THEN
                dvdt_i = (vol(icell)-volold(icell))/max(global%dtMin,  &
                         tiny(1.0_rfreal))
                bulkvarslocal  = bulkvarslocal + (/ (cv(i,icell)*vol(icell), &
                     i=cv_mixt_dens,cv_mixt_ener),vol(icell),volold(icell), &
                     (cv(i,icell)*dvdt_i,i=cv_mixt_dens,cv_mixt_ener)/)
             ENDIF ! In zoomed volume
          END DO !iCell
       ENDIF ! submerged
    END DO  !iReg

    CALL mpi_allreduce(bulkvarslocal, bulkvarsglobal,nvars, &
                 mpi_rfreal,mpi_sum,global%mpiComm,global%error)
    IF ( global%error /= err_none ) THEN
      CALL errorstop(global,err_mpi_trouble,__line__)
    END IF ! global%errorFlag
    
    global%tzVolBulk = bulkvarsglobal(ncvvars+1)
    volbulkold = bulkvarsglobal(ncvvars+2)
    timezoom%CvBulk(cv_mixt_dens:cv_mixt_ener) = bulkvarsglobal(1:ncvvars)/global%tzVolBulk
    timezoom%CvdVdtBulk(cv_mixt_dens:cv_mixt_ener) = bulkvarsglobal(ncvvars+3:nvars)

    global%tzRadChamber = sqrt(global%tzVolBulk/global%tzLenChamb/global%pi)
    global%tzEpsNozz     = (global%tzThroatRad/global%tzRadChamber)**2.0d0
   
!   is the time difference between pRegion%gridOld and pRegion%grid = global%dtMin !???ZOOM???
    global%tzDvolBulkDt = (global%tzVolBulk-volbulkold)/max(global%dtMin,tiny(1.0_rfreal))


    return
  End Subroutine rflu_timezoomcomputebulkvars



  Subroutine rflu_timezoomsumaddsource(regions)
    USE rflu_modgridspeedutils, ONLY: rflu_descalegridspeed,&
         &                            rflu_scalegridspeed

    IMPLICIT NONE

!---Dummy
    TYPE(t_region), POINTER :: regions(:)
!---Local
    TYPE(t_global), POINTER :: global
    TYPE(t_region), POINTER :: pregion
    REAL(RFREAL), DIMENSION(:,:), POINTER :: res   !use res to conform to Q1D code
    REAL(RFREAL), DIMENSION(:), POINTER :: vol,volold
    INTEGER :: ireg,icell,nvars,ivar
    REAL(RFREAL) :: x,betafill,volbulk,ddt_volbulk,termr1,termr2,termr3,terml1
!---For submerged nozzles
    REAL(RFREAL) :: y, z
    REAL(RFREAL) :: rnozzleinlet2
    
    global => regions(1)%global

    rnozzleinlet2 = global%tzNozRad**2

    nvars  = cv_mixt_ener-cv_mixt_dens+1

    betafill    = global%zoomFactor
    volbulk     = global%tzVolBulk
    ddt_volbulk = global%tzDvolBulkDt


!sum Residuals
    call rflu_timezoomsumresiduals(regions)

!Add R1 
    DO ireg = 1,global%nRegionsLocal
       pregion => regions(ireg)
       res     => pregion%mixt%rhs
       vol     => pregion%grid%vol
       volold  => pregion%gridOld%vol

       IF (.NOT. global%tzSubNoz) THEN
          DO icell = 1,pregion%grid%nCells
             x = pregion%grid%cofg(global%tzCoordLong,icell)

             if(x > global%tzMinPlane .and. x < global%tzMaxPlane) then
                termr1 = (1_rfreal-betafill)/betafill/max(global%dtMin,tiny(1.0_rfreal))
                termr1 = rflu_scalegridspeed(pregion,termr1)
                do ivar = cv_mixt_dens,cv_mixt_ener
                   res(ivar,icell) = res(ivar,icell) + termr1*pregion%mixt%Cv(ivar,icell)*&
                        &(vol(icell)-volold(icell))
                end do
             end if ! if x > Xmin & x < Xmax

          End DO !ic
       ELSE
!         Exclude submerged nozzle
          DO icell = 1,pregion%grid%nCells
             x = pregion%grid%cofg(global%tzCoordLong,icell)
             y = pregion%grid%cofg(global%tzCoordTrans1,icell)
             z = pregion%grid%cofg(global%tzCoordTrans2,icell)
             IF((x > global%tzMinPlane .AND. x < global%tzNozInlet) .OR.  &
                ((x >= global%tzNozInlet .AND. x < global%tzMaxPlane) .AND.  &
                 (y**2 + z**2 > rnozzleinlet2) ) ) THEN

                termr1 = (1_rfreal-betafill)/betafill/max(global%dtMin,tiny(1.0_rfreal))
                termr1 = rflu_scalegridspeed(pregion,termr1)
                do ivar = cv_mixt_dens,cv_mixt_ener
                   res(ivar,icell) = res(ivar,icell) + termr1*pregion%mixt%Cv(ivar,icell)*&
                        &(vol(icell)-volold(icell))
                end do
             ENDIF ! In zoomed volume

          End DO !ic
       ENDIF ! submerged
    End Do !iReg

! Add R2 and R3
    DO ireg = 1,global%nRegionsLocal
       pregion => regions(ireg)
       res    => pregion%mixt%rhs
       vol    => pregion%grid%vol

       IF (.NOT. global%tzSubNoz) THEN
          DO icell = 1,pregion%grid%nCells
             x = pregion%grid%cofg(global%tzCoordLong,icell)

             if(x > global%tzMinPlane .and. x < global%tzMaxPlane) then
   !---R2
                termr2 = (betafill-1_rfreal)*vol(icell)/volbulk
                do ivar = cv_mixt_dens,cv_mixt_ener
                   res(ivar,icell) = res(ivar,icell) + termr2*timezoom%resbar_Qbulk(ivar)
                end do
   !---R3
                termr3 = (betafill-1_rfreal)/betafill*vol(icell)/volbulk*ddt_volbulk 
                termr3 = rflu_scalegridspeed(pregion,termr3)
                do ivar = cv_mixt_dens,cv_mixt_ener
                   res(ivar,icell) = res(ivar,icell) + termr3*timezoom%CvBulk(ivar)
                end do

             end if ! if x > Xmin & x < Xmax

          End DO !ic
       ELSE
!         Exclude submerged nozzle
          DO icell = 1,pregion%grid%nCells
             x = pregion%grid%cofg(global%tzCoordLong,icell)
             y = pregion%grid%cofg(global%tzCoordTrans1,icell)
             z = pregion%grid%cofg(global%tzCoordTrans2,icell)
             IF((x > global%tzMinPlane .AND. x < global%tzNozInlet) .OR.  &
                ((x >= global%tzNozInlet .AND. x < global%tzMaxPlane) .AND.  &
                 (y**2 + z**2 > rnozzleinlet2) ) ) THEN

!---R2
                termr2 = (betafill-1_rfreal)*vol(icell)/volbulk
                do ivar = cv_mixt_dens,cv_mixt_ener
                   res(ivar,icell) = res(ivar,icell) + termr2*timezoom%resbar_Qbulk(ivar)
                end do
!---R3
                termr3 = (betafill-1_rfreal)/betafill*vol(icell)/volbulk*ddt_volbulk 
                termr3 = rflu_scalegridspeed(pregion,termr3)
                do ivar = cv_mixt_dens,cv_mixt_ener
                   res(ivar,icell) = res(ivar,icell) + termr3*timezoom%CvBulk(ivar)
                end do
             ENDIF ! In zoomed volume

          End DO !ic

       ENDIF ! submerged

    End Do !iReg

    return
  End Subroutine rflu_timezoomsumaddsource
    



  Subroutine rflu_timezoomsumresiduals(Regions)
    IMPLICIT NONE

!---Dummy
    TYPE(t_global), POINTER :: global
!---Local
    TYPE(t_region), POINTER :: pregion, regions(:) 
    REAL(RFREAL), DIMENSION(:,:), POINTER :: res   !use res to conform to Q1D code
    INTEGER :: ireg,icell,nvars
    REAL(RFREAL) ::x, localintegvol,globalintegvol
    REAL(RFREAL),DIMENSION(CV_MIXT_ENER-CV_MIXT_DENS+1) :: resbarveclocal,resbarvecglobal
!---For submerged nozzles
    REAL(RFREAL) :: y, z
    REAL(RFREAL) :: rnozzleinlet2

    global => regions(1)%global

    rnozzleinlet2 = global%tzNozRad**2

    nvars = cv_mixt_ener-cv_mixt_dens+1

    resbarveclocal = 0_rfreal
    DO ireg = 1,global%nRegionsLocal

       pregion => regions(ireg)
       res    => pregion%mixt%rhs

       IF (.NOT. global%tzSubNoz) THEN
          DO icell = 1,pregion%grid%nCells
             x = pregion%grid%cofg(global%tzCoordLong,icell)
             if(x > global%tzMinPlane .and. x < global%tzMaxPlane) then
                resbarveclocal = resbarveclocal + res(cv_mixt_dens:cv_mixt_ener,icell)
             end if
          End DO !iCell
       ELSE 
!         Exclude submerged nozzle
          DO icell = 1,pregion%grid%nCells
             x = pregion%grid%cofg(global%tzCoordLong,icell)
             y = pregion%grid%cofg(global%tzCoordTrans1,icell)
             z = pregion%grid%cofg(global%tzCoordTrans2,icell)
             IF((x > global%tzMinPlane .AND. x < global%tzNozInlet) .OR.  &
                ((x >= global%tzNozInlet .AND. x < global%tzMaxPlane) .AND.  &
                 (y**2 + z**2 > rnozzleinlet2) ) ) THEN
                resbarveclocal = resbarveclocal + res(cv_mixt_dens:cv_mixt_ener,icell)
             ENDIF ! In zoomed volume
          End DO !iCell
       ENDIF ! submerged
    End DO

    CALL mpi_allreduce(resbarveclocal, resbarvecglobal,nvars, &
         mpi_rfreal,mpi_sum,global%mpiComm,global%error)
    IF ( global%error /= err_none ) THEN
       CALL errorstop(global,err_mpi_trouble,__line__)
    END IF ! global%errorFlag
    
    timezoom%resbar_Qbulk(cv_mixt_dens:cv_mixt_ener) = resbarvecglobal(1:nvars)



    return
  END SUBROUTINE rflu_timezoomsumresiduals



! ******************************************************************************
!
! Purpose: Time UnZoom grid speeds for faces and boundary patches.
!
! Description: None.
!
! Input:
!   pRegion             Pointer to region data
!
! Output: None.
!
! Notes: None.
!
! ******************************************************************************

  SUBROUTINE rflu_unzoomgridspeeds(pRegion)
 
    IMPLICIT NONE

! ******************************************************************************
!   Declarations and definitions
! ******************************************************************************

! ==============================================================================  
!   Arguments 
! ==============================================================================  

    TYPE(t_region), POINTER :: pregion

! ==============================================================================  
!   Locals 
! ==============================================================================  

    INTEGER :: ifg,ifl,ipatch
    REAL(RFREAL) :: scalefactor
    TYPE(t_grid), POINTER :: pgrid
    TYPE(t_patch), POINTER :: ppatch
    TYPE(t_global), POINTER :: global
    
! *****************************************************************************
!   Set pointers and variables
! *****************************************************************************

    global => pregion%global
    pgrid => pregion%grid

    scalefactor = 1_rfreal/global%Zoomfactor
  
! ******************************************************************************
!   Scale grid speeds
! ******************************************************************************

    DO ifg = lbound(pgrid%gs,1),ubound(pgrid%gs,1) 
      pgrid%gs(ifg) = scalefactor*pgrid%gs(ifg)
    END DO ! ifg
 
    DO ipatch = 1,pgrid%nPatches
      ppatch => pregion%patches(ipatch)

      DO ifl = lbound(ppatch%gs,1),ubound(ppatch%gs,1) 
        ppatch%gs(ifl) = scalefactor*ppatch%gs(ifl)
      END DO ! ifl
    END DO ! iPatch
 
! ******************************************************************************
!   End
! ******************************************************************************

  END SUBROUTINE rflu_unzoomgridspeeds




! ******************************************************************************
!
! Purpose: Time Zoom grid speeds for faces and boundary patches.
!
! Description: None.
!
! Input:
!   pRegion             Pointer to region data
!
! Output: None.
!
! Notes: None.
!
! ******************************************************************************

  SUBROUTINE rflu_zoomgridspeeds(pRegion)
 
    IMPLICIT NONE

! ******************************************************************************
!   Declarations and definitions
! ******************************************************************************

! ==============================================================================  
!   Arguments 
! ==============================================================================  

    TYPE(t_region), POINTER :: pregion

! ==============================================================================  
!   Locals 
! ==============================================================================  

    INTEGER :: ifg,ifl,ipatch
    REAL(RFREAL) :: scalefactor
    TYPE(t_grid), POINTER :: pgrid
    TYPE(t_patch), POINTER :: ppatch
    TYPE(t_global), POINTER :: global
    
! *****************************************************************************
!   Set pointers and variables
! *****************************************************************************

    global => pregion%global
    pgrid => pregion%grid

    scalefactor = global%Zoomfactor
  
! ******************************************************************************
!   Scale grid speeds
! ******************************************************************************

    DO ifg = lbound(pgrid%gs,1),ubound(pgrid%gs,1) 
      pgrid%gs(ifg) = scalefactor*pgrid%gs(ifg)
    END DO ! ifg
 
    DO ipatch = 1,pgrid%nPatches
      ppatch => pregion%patches(ipatch)

      DO ifl = lbound(ppatch%gs,1),ubound(ppatch%gs,1) 
        ppatch%gs(ifl) = scalefactor*ppatch%gs(ifl)
      END DO ! ifl
    END DO ! iPatch
 
! ******************************************************************************
!   End
! ******************************************************************************

  END SUBROUTINE rflu_zoomgridspeeds



! ******************************************************************************
! End
! ******************************************************************************

END MODULE rflu_modtimezoom


! ******************************************************************************
!
! RCS Revision history:
!
!
! ******************************************************************************