RFLU_PrintGridInfo.F90

Go to the documentation of this file.

! *********************************************************************
! * Rocstar Simulation Suite                                          *
! * Copyright@2015, Illinois Rocstar LLC. All rights reserved.        *
! *                                                                   *
! * Illinois Rocstar LLC                                              *
! * Champaign, IL                                                     *
! * www.illinoisrocstar.com                                           *
! * sales@illinoisrocstar.com                                         *
! *                                                                   *
! * License: See LICENSE file in top level of distribution package or *
! * http://opensource.org/licenses/NCSA                               *
! *********************************************************************
! *********************************************************************
! * THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND,   *
! * EXPRESS OR IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES   *
! * OF MERCHANTABILITY, FITNESS FOR A PARTICULAR PURPOSE AND          *
! * NONINFRINGEMENT.  IN NO EVENT SHALL THE CONTRIBUTORS OR           *
! * COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER       *
! * LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE,   *
! * Arising FROM, OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE    *
! * USE OR OTHER DEALINGS WITH THE SOFTWARE.                          *
! *********************************************************************
! ******************************************************************************
!
! Purpose: Display information on grid.
!
! Description: None.
!
! Input: 
!   pRegion     Pointer to region
! 
! Output: N/A.
!
! Notes: None.
!
! ******************************************************************************
!
! $Id: RFLU_PrintGridInfo.F90,v 1.15 2008/12/06 08:44:12 mtcampbe Exp $
!
! Copyright: (c) 2000-2004 by the University of Illinois
!
! ******************************************************************************

SUBROUTINE rflu_printgridinfo(pRegion)

  USE modglobal, ONLY: t_global
  USE moddatatypes
  USE modparameters
  USE moderror

  USE modgrid, ONLY: t_grid
  USE modbndpatch, ONLY: t_patch
  USE moddatastruct, ONLY: t_region   

  IMPLICIT NONE
  
! ******************************************************************************
! Declarations and definitions
! ******************************************************************************  

! ==============================================================================
! Parameters
! ==============================================================================   

  TYPE(t_region), POINTER :: pregion 

! ==============================================================================
! Local variables
! ==============================================================================
 
  CHARACTER(CHRLEN) :: rcsidentstring
  INTEGER :: ipatch,nbquads,nbquadstot,nbtris,nbtristot
  INTEGER :: dummy(1)  
  INTEGER :: loc(xcoord:zcoord,min_val:max_val)
  TYPE(t_grid), POINTER :: pgrid  
  TYPE(t_patch), POINTER :: ppatch
  TYPE(t_global), POINTER :: global
  
  rcsidentstring = '$RCSfile: RFLU_PrintGridInfo.F90,v $ $Revision: 1.15 $'

! ******************************************************************************
! Start
! ******************************************************************************

  global => pregion%global

  CALL registerfunction(global,'RFLU_PrintGridInfo',&
  'RFLU_PrintGridInfo.F90')

  IF ( global%verbLevel >= verbose_med ) THEN 
    WRITE(stdout,'(A,1X,A)') solver_name
    WRITE(stdout,'(A,1X,A)') solver_name,'Printing grid information...'
    WRITE(stdout,'(A,3X,A,1X,I5.5)') solver_name,'Global region:', & 
                                     pregion%iRegionGlobal 
    IF ( global%flowType == flow_unsteady ) THEN 
      WRITE(stdout,'(A,3X,A,1X,1PE11.5)') solver_name,'Current time:', & 
                                          global%currentTime
    END IF ! global%flowType    
  END IF ! global%verbLevel

! ==============================================================================
! Set pointers
! ==============================================================================

  pgrid => pregion%grid

! ==============================================================================
! Compute patch dimensions here to be independent
! ==============================================================================

  nbtris     = 0
  nbtristot  = 0
  nbquads    = 0
  nbquadstot = 0
  
  DO ipatch = 1,pgrid%nPatches
    ppatch => pregion%patches(ipatch)
    
    nbtris     = nbtris     + ppatch%nBTris 
    nbtristot  = nbtristot  + ppatch%nBTrisTot     
    nbquads    = nbquads    + ppatch%nBQuads 
    nbquadstot = nbquadstot + ppatch%nBQuadsTot            
  END DO ! iPatch  

! ==============================================================================
! Grid dimensions
! ==============================================================================

  IF ( global%verbLevel >= verbose_med ) THEN 
    WRITE(stdout,'(A,3X,A)')                solver_name,'Grid statistics:'
    WRITE(stdout,'(A,5X,A,3X,2(1X,I9))')    solver_name,'Vertices:      ', &
          pgrid%nVert,pgrid%nVertTot-pgrid%nVert
    WRITE(stdout,'(A,5X,A,3X,2(1X,I9))')    solver_name,'Cells:         ', &
          pgrid%nCells,pgrid%nCellsTot-pgrid%nCells
    WRITE(stdout,'(A,7X,A,1X,2(1X,I9))')    solver_name,'Tetrahedra:    ', &
          pgrid%nTets,pgrid%nTetsTot-pgrid%nTets
    WRITE(stdout,'(A,7X,A,1X,2(1X,I9))')    solver_name,'Hexahedra:     ', &
          pgrid%nHexs,pgrid%nHexsTot-pgrid%nHexs
    WRITE(stdout,'(A,7X,A,1X,2(1X,I9))')    solver_name,'Prisms:        ', & 
          pgrid%nPris,pgrid%nPrisTot-pgrid%nPris
    WRITE(stdout,'(A,7X,A,1X,2(1X,I9))')    solver_name,'Pyramids:      ', & 
          pgrid%nPyrs,pgrid%nPyrsTot-pgrid%nPyrs
    WRITE(stdout,'(A,5X,A,4X,I9)')          solver_name,'Patches:       ', & 
          pgrid%nPatches
    WRITE(stdout,'(A,5X,A,3X,2(1X,I9))')    solver_name,'Patch faces:   ', & 
          nbtris+nbquads,nbtristot+nbquadstot-nbtris-nbquads
    WRITE(stdout,'(A,7X,A,1X,2(1X,I9))')    solver_name,'Triangles:     ', & 
          nbtris,nbtristot-nbtris
    WRITE(stdout,'(A,7X,A,1X,2(1X,I9))')    solver_name,'Quadrilaterals:', &
          nbquads,nbquadstot-nbquads
  END IF ! global%verbLevel
  
! ==============================================================================
! Patch dimensions
! ==============================================================================  

  IF ( global%verbLevel >= verbose_med ) THEN 
    IF ( pgrid%nPatches > 0 ) THEN 
      WRITE(stdout,'(A,3X,A)') solver_name,'Patch statistics:'

      DO ipatch = 1,pgrid%nPatches
        ppatch => pregion%patches(ipatch)

        WRITE(stdout,'(A,5X,A,2X,I4)')       solver_name,'Patch:',ipatch   
        WRITE(stdout,'(A,7X,A,6X,2(1X,I9))') solver_name,'Triangles:', & 
              ppatch%nBTris,ppatch%nBTrisTot-ppatch%nBTris
        WRITE(stdout,'(A,7X,A,1X,2(1X,I9))') solver_name,'Quadrilaterals:', &
              ppatch%nBQuads,ppatch%nBQuadsTot-ppatch%nBQuads    
      END DO ! iPatch
    END IF ! pGrid%nPatches
  END IF ! global%verbLevel

! ==============================================================================
! Find locations of extrema and print information on extrema: NOTE Asinine 
! coding needed because of poor FORTRAN interface for MINLOC and MAXLOC
! functions... 
! ==============================================================================

  dummy               = minloc(pgrid%xyz(xcoord,1:pgrid%nVert))
  loc(xcoord,min_val) = dummy(1)

  dummy               = minloc(pgrid%xyz(ycoord,1:pgrid%nVert))
  loc(ycoord,min_val) = dummy(1)

  dummy               = minloc(pgrid%xyz(zcoord,1:pgrid%nVert))
  loc(zcoord,min_val) = dummy(1)


  dummy               = maxloc(pgrid%xyz(xcoord,1:pgrid%nVert))
  loc(xcoord,max_val) = dummy(1)

  dummy               = maxloc(pgrid%xyz(ycoord,1:pgrid%nVert))
  loc(ycoord,max_val) = dummy(1)

  dummy               = maxloc(pgrid%xyz(zcoord,1:pgrid%nVert))
  loc(zcoord,max_val) = dummy(1)


  IF ( global%verbLevel >= verbose_med ) THEN 
     WRITE(stdout,'(A,3X,A)') solver_name,'Coordinate extrema:'
     WRITE(stdout,'(A,5X,A,2(1X,E23.16),2(1X,I9))') & 
                   solver_name,'X-coordinate:', & 
                   minval(pgrid%xyz(xcoord,1:pgrid%nVert)), & 
                   maxval(pgrid%xyz(xcoord,1:pgrid%nVert)), & 
                   loc(xcoord,min_val),loc(xcoord,max_val)
     WRITE(stdout,'(A,5X,A,2(1X,E23.16),2(1X,I9))') & 
                   solver_name,'Y-coordinate:', & 
                   minval(pgrid%xyz(ycoord,1:pgrid%nVert)), & 
                   maxval(pgrid%xyz(ycoord,1:pgrid%nVert)), & 
                   loc(ycoord,min_val),loc(ycoord,max_val)
     WRITE(stdout,'(A,5X,A,2(1X,E23.16),2(1X,I9))') & 
                   solver_name,'Z-coordinate:', & 
                   minval(pgrid%xyz(zcoord,1:pgrid%nVert)), & 
                   maxval(pgrid%xyz(zcoord,1:pgrid%nVert)), & 
                   loc(zcoord,min_val),loc(zcoord,max_val)
  END IF ! global%verbLevel
                  
! ******************************************************************************
! End
! ******************************************************************************

  IF ( global%verbLevel >= verbose_med ) THEN 
    WRITE(stdout,'(A,1X,A)') solver_name,'Printing grid information done.'
    WRITE(stdout,'(A,1X,A)') solver_name
  END IF ! global%verbLevel    
  
  CALL deregisterfunction(global)  

END SUBROUTINE rflu_printgridinfo

! ******************************************************************************
!
! RCS Revision history:
!
! $Log: RFLU_PrintGridInfo.F90,v $
! Revision 1.15  2008/12/06 08:44:12  mtcampbe
! Updated license.
!
! Revision 1.14  2008/11/19 22:17:25  mtcampbe
! Added Illinois Open Source License/Copyright
!
! Revision 1.13  2004/10/19 19:24:45  haselbac
! Removed printing of derived dims, cosmetics
!                                    
! Revision 1.12  2004/01/22 16:04:48  haselbac                        
! Changed declaration to eliminate warning on ALC                     
!
! Revision 1.11  2003/03/15 17:03:38  haselbac                        
! Made changes for parallel calcs, added bVert info                   
!
! Revision 1.10  2003/02/01 00:27:44  haselbac                        
! Increased precision for printing coordinate extrema                 
!
! Revision 1.9  2003/01/28 15:39:16  haselbac                         
! Compute total no of boundary faces (deleted from pGrid), cosmetics  
!
! Revision 1.8  2002/10/27 18:52:56  haselbac                         
! Cosmetic changes, added iRegionGlobal                               
!
! Revision 1.7  2002/10/17 19:57:52  haselbac                         
! Cosmetic changes to output                                          
!
! Revision 1.6  2002/09/09 14:15:01  haselbac                         
! global now under regions                                            
!
! Revision 1.5  2002/06/27 15:38:21  haselbac                         
! Added dummy cells and vertex output                                 
!
! Revision 1.4  2002/06/17 13:31:22  haselbac                         
! Prefixed SOLVER_NAME to all screen output                           
!
! Revision 1.3  2002/06/14 20:09:28  haselbac                         
! Added writing out of iPatchGlobal                                   
!
! Revision 1.2  2002/06/11 22:27:43  haselbac                         
! Added writing of patch statistics                                   
!
! Revision 1.1  2002/06/05 18:34:12  haselbac                         
! Initial revision                                                    
!
! ******************************************************************************