RFLU_ComputeIntegralValues.F90

Go to the documentation of this file.

! *********************************************************************
! * Rocstar Simulation Suite                                          *
! * Copyright@2015, Illinois Rocstar LLC. All rights reserved.        *
! *                                                                   *
! * Illinois Rocstar LLC                                              *
! * Champaign, IL                                                     *
! * www.illinoisrocstar.com                                           *
! * sales@illinoisrocstar.com                                         *
! *                                                                   *
! * License: See LICENSE file in top level of distribution package or *
! * http://opensource.org/licenses/NCSA                               *
! *********************************************************************
! *********************************************************************
! * THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND,   *
! * EXPRESS OR IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES   *
! * OF MERCHANTABILITY, FITNESS FOR A PARTICULAR PURPOSE AND          *
! * NONINFRINGEMENT.  IN NO EVENT SHALL THE CONTRIBUTORS OR           *
! * COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER       *
! * LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE,   *
! * Arising FROM, OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE    *
! * USE OR OTHER DEALINGS WITH THE SOFTWARE.                          *
! *********************************************************************
! ******************************************************************************
!
! Purpose: Compute integrals for GENx checking.
!
! Description: None.
!
! Input:
!   regions     Region data
!
! Output:
!   integ       Vector of integrals (for output by Rocman)
!
! Notes: None.
!
! ******************************************************************************
!
! $Id: RFLU_ComputeIntegralValues.F90,v 1.7 2008/12/06 08:44:29 mtcampbe Exp $
!
! Copyright: (c) 2002-2005 by the University of Illinois
!
! ******************************************************************************

#ifdef GENX
SUBROUTINE rflu_computeintegralvalues(regions,integ)
#else
SUBROUTINE rflu_computeintegralvalues(regions)
#endif

  USE modglobal, ONLY: t_global
  USE modparameters
  USE moddatatypes
  USE modbndpatch, ONLY: t_patch
  USE moddatastruct, ONLY: t_region
  USE moderror
  USE modmpi
  
  IMPLICIT NONE

#ifdef GENX
  include 'rocmanf90.h'
#endif

! ******************************************************************************
! Declarations and definitions
! ******************************************************************************

! ==============================================================================
! Arguments
! ==============================================================================

  TYPE(t_region), POINTER :: regions(:)

! ==============================================================================
! Locals
! ==============================================================================

  CHARACTER(CHRLEN) :: rcsidentstring
  INTEGER :: errorflag,i,ic,ifc,ipatch,ireg
  REAL(RFREAL) :: enerlocal,ibarealocal,inbarealocal,masslocal,xmomlocal, & 
                  ymomlocal,zmomlocal,vollocal
#ifdef GENX
  DOUBLE PRECISION, DIMENSION(MAN_INTEG_SIZE) :: integ
  REAL(RFREAL), DIMENSION(MAN_INTEG_SIZE) :: globalvals,localvals
#else
  REAL(RFREAL), DIMENSION(2) :: globalvals,localvals
#endif
  REAL(RFREAL), DIMENSION(:), POINTER :: pvol
  REAL(RFREAL), DIMENSION(:,:), POINTER :: pcv
  TYPE(t_global), POINTER :: global
  TYPE(t_patch), POINTER :: ppatch  
  TYPE(t_region), POINTER :: pregion

! ******************************************************************************
! Start 
! ******************************************************************************

  rcsidentstring = '$RCSfile: RFLU_ComputeIntegralValues.F90,v $ $Revision: 1.7 $'

  global => regions(1)%global

  CALL registerfunction(global,'RFLU_ComputeIntegralValues',&
  'RFLU_ComputeIntegralValues.F90')

! ******************************************************************************
! Compute total volume and total mass
! ******************************************************************************

  vollocal  = 0.0_rfreal
  masslocal = 0.0_rfreal

  DO ireg = 1,global%nRegionsLocal
    pregion => regions(ireg)
    
    pvol => pregion%grid%vol
    pcv  => pregion%mixt%cv
    
    DO ic = 1,pregion%grid%nCells
      vollocal  = vollocal  + pvol(ic)
      masslocal = masslocal + pcv(cv_mixt_dens,ic)*pvol(ic)
    END DO ! ic
  END DO ! iReg

#ifdef GENX
! ******************************************************************************
! Compute momenta components and energy
! ******************************************************************************

  xmomlocal = 0.0_rfreal ! Not computed at present
  ymomlocal = 0.0_rfreal
  zmomlocal = 0.0_rfreal
  enerlocal = 0.0_rfreal 

! ******************************************************************************
! Compute interacting surface areas
! ******************************************************************************

  inbarealocal = 0.0_rfreal
  ibarealocal  = 0.0_rfreal

  DO ireg = 1,global%nRegionsLocal 
    pregion => regions(ireg)  
  
    DO ipatch = 1,pregion%grid%nPatches
      ppatch => pregion%patches(ipatch)
    
      IF ( ppatch%bcCoupled == bc_burning ) THEN  
        DO ifc = 1,ppatch%nBFaces
          ibarealocal = ibarealocal + ppatch%fn(xyzmag,ifc)
        END DO ! ifc  
      ELSE IF ( ppatch%bcCoupled == bc_not_burning ) THEN
        DO ifc = 1,ppatch%nBFaces
          inbarealocal = inbarealocal + ppatch%fn(xyzmag,ifc)
        END DO ! ifc   
      END IF ! pPatach%bcCoupled
    END DO ! iPatch
  END DO ! iReg
#endif 

! ******************************************************************************
! Gather data
! ******************************************************************************

#ifdef GENX
  localvals(man_integ_vol    ) = vollocal
  localvals(man_integ_mass   ) = masslocal
  localvals(man_integ_xmom   ) = xmomlocal
  localvals(man_integ_ymom   ) = ymomlocal
  localvals(man_integ_zmom   ) = zmomlocal
  localvals(man_integ_ener   ) = enerlocal
  localvals(man_integ_ibarea ) = ibarealocal  
  localvals(man_integ_inbarea) = inbarealocal      
#else
  localvals(1) = vollocal
  localvals(2) = masslocal  
#endif

! ******************************************************************************
! Perform reduction operation
! ******************************************************************************

  CALL mpi_reduce(localvals,globalvals,SIZE(localvals,1),mpi_rfreal,mpi_sum, &
                  masterproc,global%mpiComm,errorflag)
  global%error = errorflag
  IF ( global%error /= err_none ) THEN 
    CALL errorstop(global,err_mpi_trouble,__line__)
  END IF ! global%errorFlag
 
! ******************************************************************************
! Scatter data
! ******************************************************************************

#ifdef GENX
  DO i = 1,man_integ_size ! Explicit loop to avoid ASCI White problem
    integ(i) = globalvals(i)
  END DO ! i
#else
  global%totalVol  = globalvals(1)
  global%totalMass = globalvals(2)  
#endif

! ******************************************************************************
! End
! ******************************************************************************

  CALL deregisterfunction(global)

END SUBROUTINE rflu_computeintegralvalues

!* *****************************************************************************
!
! RCS Revision history:
!
! $Log: RFLU_ComputeIntegralValues.F90,v $
! Revision 1.7  2008/12/06 08:44:29  mtcampbe
! Updated license.
!
! Revision 1.6  2008/11/19 22:17:42  mtcampbe
! Added Illinois Open Source License/Copyright
!
! Revision 1.5  2006/04/07 15:19:22  haselbac
! Removed tabs
!
! Revision 1.4  2005/04/15 15:07:14  haselbac
! Converted to MPI, cosmetics
!
! Revision 1.3  2003/04/23 13:58:56  haselbac
! Bug fix
!
! Revision 1.2  2003/01/28 14:32:16  haselbac
! Use parameters in fn
!
! Revision 1.1  2002/11/15 21:27:46  haselbac
! Initial revision
!
! ******************************************************************************