RFLU_PrintWriteConvergence.F90

Go to the documentation of this file.

! *********************************************************************
! * Rocstar Simulation Suite                                          *
! * Copyright@2015, Illinois Rocstar LLC. All rights reserved.        *
! *                                                                   *
! * Illinois Rocstar LLC                                              *
! * Champaign, IL                                                     *
! * www.illinoisrocstar.com                                           *
! * sales@illinoisrocstar.com                                         *
! *                                                                   *
! * License: See LICENSE file in top level of distribution package or *
! * http://opensource.org/licenses/NCSA                               *
! *********************************************************************
! *********************************************************************
! * THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND,   *
! * EXPRESS OR IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES   *
! * OF MERCHANTABILITY, FITNESS FOR A PARTICULAR PURPOSE AND          *
! * NONINFRINGEMENT.  IN NO EVENT SHALL THE CONTRIBUTORS OR           *
! * COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER       *
! * LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE,   *
! * Arising FROM, OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE    *
! * USE OR OTHER DEALINGS WITH THE SOFTWARE.                          *
! *********************************************************************
! ******************************************************************************
!
! Purpose: Print and write convergence history.
!
! Description: None.
!
! Input: 
!   global      Pointer to global data
!
! Output: None.
!
! Notes: None.
!
! ******************************************************************************
!
! $Id: RFLU_PrintWriteConvergence.F90,v 1.4 2008/12/06 08:44:30 mtcampbe Exp $
!
! Copyright: (c) 2005 by the University of Illinois
!
! ******************************************************************************

SUBROUTINE rflu_printwriteconvergence(global)

  USE modparameters
  USE moddatatypes
  USE modglobal, ONLY: t_global
  USE moderror
  USE modmpi

  USE modtools, ONLY: makenonzero

  IMPLICIT NONE

! ******************************************************************************
! Definitions and declarations
! ******************************************************************************

! ==============================================================================
! Arguments
! ==============================================================================

  TYPE(t_global), POINTER :: global

! ==============================================================================
! Locals
! ==============================================================================

  INTEGER :: errorflag
  REAL(RFREAL) :: resnorm
  REAL(RFREAL), DIMENSION(6) :: localvals,globalvals

! ******************************************************************************
! Start
! ******************************************************************************

  CALL registerfunction(global,'RFLU_PrintWriteConvergence',&
  'RFLU_PrintWriteConvergence.F90')

! ******************************************************************************
! Reduce data
! ******************************************************************************

  localvals(1) = global%forceX
  localvals(2) = global%forceY
  localvals(3) = global%forceZ
  localvals(4) = global%massIn
  localvals(5) = global%massOut
  localvals(6) = global%stopRun

  CALL mpi_allreduce(localvals,globalvals,6,mpi_rfreal,mpi_sum,global%mpiComm, &
                     errorflag)
  global%error = errorflag
  IF ( global%error /= err_none ) THEN 
    CALL errorstop(global,err_mpi_trouble,__line__)
  END IF ! global%errorFlag

  global%forceX  = globalvals(1)
  global%forceY  = globalvals(2)
  global%forceZ  = globalvals(3)
  global%massIn  = globalvals(4)
  global%massOut = globalvals(5)
  global%stopRun = globalvals(6)

! ******************************************************************************
! Print and write global data
! ******************************************************************************

! ==============================================================================
! Steady flow 
! ==============================================================================

  IF ( (global%flowType == flow_steady) .AND. & 
       (global%myProcid == masterproc) ) THEN
    IF ( global%currentIter == 1 ) THEN
      resnorm = 1.0_rfreal
    ELSE
      resnorm = global%residual/makenonzero(global%resInit)
      resnorm = makenonzero(resnorm)
    END IF ! global%currentIter

    IF ( global%verbLevel /= verbose_none ) THEN
      WRITE(stdout,'(A,1X,I6,1PE13.4,5E13.4)') solver_name, & 
        global%currentIter,log10(resnorm), &
        global%forceX,global%forceY,global%forceZ, &
        global%massIn,global%massOut
    END IF ! global%verbLevel

    WRITE(if_conver,'(I6,1PE13.4,5E13.4)') & 
      global%currentIter,log10(resnorm), &
      global%forceX,global%forceY,global%forceZ, &
      global%massIn,global%massOut

! ==============================================================================
! Unsteady flow 
! ==============================================================================

  ELSE IF ( (global%flowType == flow_unsteady) .AND. & 
            (global%myProcid==masterproc) ) THEN
    IF ( global%verbLevel /= verbose_none ) THEN 
      WRITE(stdout,'(A,1X,1PE12.5,6E13.4)') solver_name, & 
        global%currentTime,global%dtMin, &
        global%forceX,global%forceY,global%forceZ, &
        global%massIn,global%massOut
    END IF ! global%verbLevel

    WRITE(if_conver,'(1PE12.5,6E13.4)') & 
      global%currentTime,global%dtMin, &
      global%forceX,global%forceY,global%forceZ, &
      global%massIn,global%massOut
  END IF ! global%flowType

! ******************************************************************************
! Start
! ******************************************************************************

  CALL deregisterfunction(global)

END SUBROUTINE rflu_printwriteconvergence

! ******************************************************************************
!
! RCS Revision history:
!
! $Log: RFLU_PrintWriteConvergence.F90,v $
! Revision 1.4  2008/12/06 08:44:30  mtcampbe
! Updated license.
!
! Revision 1.3  2008/11/19 22:17:43  mtcampbe
! Added Illinois Open Source License/Copyright
!
! Revision 1.2  2006/04/07 15:19:22  haselbac
! Removed tabs
!
! Revision 1.1  2005/04/15 15:07:10  haselbac
! Initial revision
!
! ******************************************************************************