RFLU_CheckGridSpeeds.F90

Go to the documentation of this file.

! *********************************************************************
! * Rocstar Simulation Suite                                          *
! * Copyright@2015, Illinois Rocstar LLC. All rights reserved.        *
! *                                                                   *
! * Illinois Rocstar LLC                                              *
! * Champaign, IL                                                     *
! * www.illinoisrocstar.com                                           *
! * sales@illinoisrocstar.com                                         *
! *                                                                   *
! * License: See LICENSE file in top level of distribution package or *
! * http://opensource.org/licenses/NCSA                               *
! *********************************************************************
! *********************************************************************
! * THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND,   *
! * EXPRESS OR IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES   *
! * OF MERCHANTABILITY, FITNESS FOR A PARTICULAR PURPOSE AND          *
! * NONINFRINGEMENT.  IN NO EVENT SHALL THE CONTRIBUTORS OR           *
! * COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER       *
! * LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE,   *
! * Arising FROM, OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE    *
! * USE OR OTHER DEALINGS WITH THE SOFTWARE.                          *
! *********************************************************************
!******************************************************************************
!
! Purpose: Check grid speeds.
!
! Description: Compute norms of difference of LHS and RHS of GCL.
!
! Input: 
!   pRegion     Pointer to region
!
! Output: None.
!
! Notes: None.
!
!******************************************************************************
!
! $Id: RFLU_CheckGridSpeeds.F90,v 1.6 2008/12/06 08:44:29 mtcampbe Exp $
!
! Copyright: (c) 2002 by the University of Illinois
!
!******************************************************************************

SUBROUTINE rflu_checkgridspeeds(pRegion)

  USE moddatatypes
  USE modgrid, ONLY: t_grid
  USE moddatastruct, ONLY: t_region
  USE modbndpatch, ONLY: t_patch
  USE modglobal, ONLY: t_global
  USE moderror
  USE modmpi
  USE modparameters
  USE modsortsearch

  USE rflu_modgrid

  IMPLICIT NONE

! *****************************************************************************
! Declarations and definitions
! *****************************************************************************

! =============================================================================
! Arguments
! =============================================================================

  TYPE(t_region), POINTER :: pregion

! =============================================================================
! Locals
! =============================================================================

  CHARACTER(CHRLEN) :: rcsidentstring
  INTEGER :: c1,c2,errorflag,ic,ifc,indgs,ipatch
  REAL(RFREAL) :: fs,nm,term
  REAL(RFREAL), DIMENSION(:), ALLOCATABLE :: checksum,checksumsorted
  REAL(RFREAL), DIMENSION(:,:), POINTER :: pxyz,pxyzold
  TYPE(t_global), POINTER :: global
  TYPE(t_grid), POINTER :: pgrid,pgridold
  TYPE(t_patch), POINTER :: ppatch

! *****************************************************************************
! Start
! *****************************************************************************

  rcsidentstring = '$RCSfile: RFLU_CheckGridSpeeds.F90,v $ $Revision: 1.6 $'

  global => pregion%global

  CALL registerfunction(global,'RFLU_CheckGridSpeeds',&
  'RFLU_CheckGridSpeeds.F90')

  IF ( global%myProcid == masterproc .AND. & 
       global%verbLevel > verbose_low ) THEN
    WRITE(stdout,'(A,1X,A)') solver_name,'Checking grid speeds...'
  END IF ! global%myProcid
  
! *****************************************************************************
! Set pointers and variables
! *****************************************************************************
    
  pgrid    => pregion%grid
  pgridold => pregion%gridOld

  indgs = pgrid%indGs

! *****************************************************************************
! Allocate memory
! *****************************************************************************

  ALLOCATE(checksum(pgrid%nCellsTot),stat=errorflag)
  global%error = errorflag
  IF ( global%error /= err_none ) THEN 
    CALL errorstop(global,err_allocate,__line__,'checkSum')
  END IF ! global%error

  ALLOCATE(checksumsorted(pgrid%nCellsTot),stat=errorflag)
  global%error = errorflag
  IF ( global%error /= err_none ) THEN 
    CALL errorstop(global,err_allocate,__line__,'checkSumSorted')
  END IF ! global%error

  DO ic = 1,pgrid%nCellsTot ! Explicit loop because of ASCI White problem
    checksum(ic) = 0.0_rfreal
  END DO ! ic

! *****************************************************************************
! Interior faces
! *****************************************************************************

  DO ifc = 1,pgrid%nFaces
    c1 = pgrid%f2c(1,ifc)
    c2 = pgrid%f2c(2,ifc)
    
    nm = pgrid%fn(xyzmag,ifc)
    fs = pgrid%gs(indgs*ifc)      
    
    checksum(c1) = checksum(c1) + fs*nm
    checksum(c2) = checksum(c2) - fs*nm    
  END DO ! ifc

! *****************************************************************************
! Boundary faces
! *****************************************************************************

  DO ipatch = 1,pgrid%nPatches
    ppatch => pregion%patches(ipatch)
    
    DO ifc = 1,ppatch%nBFaces
      c1 = ppatch%bf2c(ifc)
      
      nm = ppatch%fn(xyzmag,ifc)
      fs = ppatch%gs(indgs*ifc)
      
      checksum(c1) = checksum(c1) + fs*nm
    END DO ! ifc  
  END DO ! iPatch

! *****************************************************************************
! Check values and compute norms
! *****************************************************************************

  DO ic = 1,pgrid%nCells
    checksum(ic) = checksum(ic)*global%dtMin - (pgrid%vol(ic)-pgridold%vol(ic))
    checksumsorted(ic) = checksum(ic)
  END DO ! ic

  CALL quicksortrfreal(checksumsorted(1:pgrid%nCells),pgrid%nCells)

  term = 0.0_rfreal

  DO ic = 1,pgrid%nCells
    term = term + checksumsorted(ic)*checksumsorted(ic)
  END DO ! ic

  term = sqrt(term/REAL(pgrid%ncells,rfreal))
  
  IF ( global%myProcid == masterproc .AND. & 
       global%verbLevel > verbose_low ) THEN 
    WRITE(stdout,'(A,3X,A)') solver_name,'Error in GCL:'
    WRITE(stdout,'(A,5X,A,1X,E15.8)') solver_name,'L2-norm:',term
    WRITE(stdout,'(A,5X,A,1X,E15.8,1X,I6)') solver_name,'L8-norm:', & 
                                            maxval(checksum(1:pgrid%nCells)), & 
                                            maxloc(checksum(1:pgrid%nCells))
  END IF ! global%myProcid

! *****************************************************************************
! End
! *****************************************************************************

  DEALLOCATE(checksum,stat=errorflag)
  global%error = errorflag
  IF ( global%error /= err_none ) THEN 
    CALL errorstop(global,err_deallocate,__line__,'checkSum')
  END IF ! global%error
  
  DEALLOCATE(checksumsorted,stat=errorflag)
  global%error = errorflag
  IF ( global%error /= err_none ) THEN 
    CALL errorstop(global,err_deallocate,__line__,'checkSum')
  END IF ! global%error  

  IF ( global%myProcid == masterproc .AND. & 
       global%verbLevel > verbose_low ) THEN
    WRITE(stdout,'(A,1X,A)') solver_name,'Checking grid speeds done.'
  END IF ! global%myProcid

  CALL deregisterfunction(global)

END SUBROUTINE rflu_checkgridspeeds

!******************************************************************************
!
! RCS Revision history:
!
! $Log: RFLU_CheckGridSpeeds.F90,v $
! Revision 1.6  2008/12/06 08:44:29  mtcampbe
! Updated license.
!
! Revision 1.5  2008/11/19 22:17:42  mtcampbe
! Added Illinois Open Source License/Copyright
!
! Revision 1.4  2003/03/27 14:32:18  haselbac
! Fixed bug: Must not use MINLOC/MAXLOC on sorted list
!
! Revision 1.3  2003/03/15 18:25:54  haselbac
! Changed loop limit
!
! Revision 1.2  2003/01/28 14:27:13  haselbac
! Cosmetic changes only, use parameters in fn
!
! Revision 1.1  2002/11/08 21:55:20  haselbac
! Initial revision
!
! Revision 1.1  2002/10/27 19:20:08  haselbac
! Initial revision
!
!******************************************************************************