RFLO_MoveGridGlobal.F90

Go to the documentation of this file.

! *********************************************************************
! * Rocstar Simulation Suite                                          *
! * Copyright@2015, Illinois Rocstar LLC. All rights reserved.        *
! *                                                                   *
! * Illinois Rocstar LLC                                              *
! * Champaign, IL                                                     *
! * www.illinoisrocstar.com                                           *
! * sales@illinoisrocstar.com                                         *
! *                                                                   *
! * License: See LICENSE file in top level of distribution package or *
! * http://opensource.org/licenses/NCSA                               *
! *********************************************************************
! *********************************************************************
! * THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND,   *
! * EXPRESS OR IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES   *
! * OF MERCHANTABILITY, FITNESS FOR A PARTICULAR PURPOSE AND          *
! * NONINFRINGEMENT.  IN NO EVENT SHALL THE CONTRIBUTORS OR           *
! * COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER       *
! * LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE,   *
! * Arising FROM, OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE    *
! * USE OR OTHER DEALINGS WITH THE SOFTWARE.                          *
! *********************************************************************
!******************************************************************************
!
! Purpose: redistribute grid nodes according to the movement of the
!          boundaries. This function smoothes the grid globally by
!          solving the Laplace equation for node coordinates.
!
! Description: none.
!
! Input: regions = data of all grid regions.
!
! Output: regions%levels%grid%xyz = new grid coordinates.
!
! Notes: grid%xyz temporarily stores nodal displacements. The deformation
!        is applied to the finest grid first.
!
!******************************************************************************
!
! $Id: RFLO_MoveGridGlobal.F90,v 1.9 2008/12/06 08:44:27 mtcampbe Exp $
!
! Copyright: (c) 2003 by the University of Illinois
!
!******************************************************************************

SUBROUTINE rflo_movegridglobal( regions )

  USE moddatatypes
  USE modbndpatch, ONLY   : t_patch
  USE modglobal, ONLY     : t_global
  USE moddatastruct, ONLY : t_region
  USE modgrid, ONLY       : t_grid
  USE modinterfaces, ONLY : rflo_movegridsurfaces, rflo_movegridinterfaces, &
        rflo_changeinteriorgrid, rflo_generatecoarsegrids, &
        rflo_copygeometrydummy, rflo_extrapolategeometry, &
        rflo_exchangegeometry, rflo_calcfacevectors, rflo_calccontrolvolumes, &
        rflo_calccellcentroids, rflo_c2favgcoeffs, rflo_c2eavgcoeffs, &
        rflo_checkmetrics, rflo_calcgridspeeds, rflo_boundarydeformation, &
        rflo_gridremesh
  USE rflo_modlaplacesmoothing, ONLY : rflo_laplacegridsmoo
  USE moderror
  USE modmpi
  USE modparameters
  IMPLICIT NONE

#ifdef GENX
  include 'roccomf90.h'
#endif

! ... parameters
  TYPE(t_region), POINTER :: regions(:)

! ... loop variables
  INTEGER :: ireg, iter, ipatch, ijk

! ... local variables
  LOGICAL :: somemoved, someremesh

  INTEGER :: bctype, iremesh, jremesh, nremesh

  REAL(RFREAL)          :: resid, globalresid
  REAL(RFREAL), POINTER :: xyz(:,:), xyzold(:,:)

  TYPE(t_grid), POINTER   :: grid, gridold
  TYPE(t_global), POINTER :: global
  TYPE(t_patch), POINTER  :: patch
#ifdef GENX
  DOUBLE PRECISION :: dalpha
#endif

!******************************************************************************

  global => regions(1)%global

  CALL registerfunction( global,'RFLO_MoveGridGlobal',&
  'RFLO_MoveGridGlobal.F90' )

#ifdef GENX
! update geometry buffers -----------------------------------------------------

  dalpha = global%dtMin/global%dTimeSystem
  CALL com_call_function( global%genxHandleGm,1,dalpha )
#endif

! receive and distribute deformations for each region -------------------------

  CALL rflo_movegridsurfaces( regions,somemoved )

! fix interfaces between regions ----------------------------------------------

  IF (somemoved) THEN
    CALL rflo_movegridinterfaces( regions )
  ENDIF

! update grid, dummy, corner and edge cells -----------------------------------

  IF (somemoved) THEN
    DO ireg=1,global%nRegions
      IF (regions(ireg)%procid==global%myProcid .AND. &  ! region active and
          regions(ireg)%active==active .AND. &           ! on my processor
          regions(ireg)%mixtInput%moveGrid) THEN         ! and moving

! ----- change the interior grid

        grid    => regions(ireg)%levels(1)%grid
        gridold => regions(ireg)%levels(1)%gridOld
        CALL rflo_changeinteriorgrid( regions(ireg),grid%boundMoved, &
                                      grid%edgeMoved,grid%arcLen12, &
                                      grid%arcLen34,grid%arcLen56, &
                                      gridold%xyzOld,grid%xyz )

! ----- update coarse grids and dummy cells

        CALL rflo_generatecoarsegrids( regions(ireg) )   ! coarsen finest grid
        CALL rflo_copygeometrydummy( regions(ireg) )     ! copy to dummy nodes
        CALL rflo_extrapolategeometry( regions(ireg) )   ! extrapolate
      ENDIF     ! region on this processor and active, grid moving
    ENDDO       ! iReg
    CALL rflo_exchangegeometry( regions )                ! exchange geometry
  ENDIF

! smooth grid by solving Laplace equation -------------------------------------

  IF (somemoved) THEN
    DO iter=1,global%moveGridNiter
      CALL rflo_laplacegridsmoo( regions,resid )
    ENDDO

    IF (global%verbLevel /= verbose_none) THEN
#ifdef MPI
      CALL mpi_reduce( resid,globalresid,1,mpi_rfreal,mpi_sum, &
                       masterproc,global%mpiComm,global%mpierr )
      IF (global%mpierr /= 0) CALL errorstop( global,err_mpi_trouble,__line__ )
#else
      globalresid = resid
#endif
      IF (global%myProcid == masterproc) THEN
        WRITE(stdout,1000) solver_name,global%moveGridNiter,sqrt(globalresid)
      ENDIF
    ENDIF    ! verbLevel
  ENDIF      ! someMoved

! update grid, dummy, corner and edge cells -----------------------------------

  DO ireg=1,global%nRegions
    IF (regions(ireg)%procid==global%myProcid .AND. &  ! region active and
        regions(ireg)%active==active .AND. &           ! on my processor
        regions(ireg)%mixtInput%moveGrid) THEN         ! and moving

! --- change xyz from coordinates to deformations

      xyz    => regions(ireg)%levels(1)%grid%xyz
      xyzold => regions(ireg)%levels(1)%gridOld%xyz

      DO ijk=lbound(xyz,2),ubound(xyz,2)
        xyz(xcoord,ijk) = xyz(xcoord,ijk) - xyzold(xcoord,ijk)
        xyz(ycoord,ijk) = xyz(ycoord,ijk) - xyzold(ycoord,ijk)
        xyz(zcoord,ijk) = xyz(zcoord,ijk) - xyzold(zcoord,ijk)
      ENDDO

! --- redistribute deformations at boundaries

      grid    => regions(ireg)%levels(1)%grid
      gridold => regions(ireg)%levels(1)%gridOld
      grid%boundMoved(:) = .true.
      grid%edgeMoved(:)  = .true.
      DO ipatch=1,regions(ireg)%nPatches
        patch  => regions(ireg)%levels(1)%patches(ipatch)
        bctype =  patch%bcType
        IF ((bctype>=bc_symmetry .AND. bctype<=bc_symmetry+bc_range)) THEN
          grid%boundMoved(patch%lbound) = .false.
        ENDIF  ! bcType
      ENDDO    ! iPatch
      CALL rflo_boundarydeformation( regions(ireg),grid%boundMoved, &
                                     grid%edgeMoved,grid%arcLen12, &
                                     grid%arcLen34,grid%arcLen56, &
                                     gridold%xyzOld,grid%xyz )

! --- change xyz from deformations to coordinates

      CALL rflo_changeinteriorgrid( regions(ireg),grid%boundMoved, &
                                    grid%edgeMoved,grid%arcLen12, &
                                    grid%arcLen34,grid%arcLen56, &
                                    gridold%xyzOld,grid%xyz )

! --- update coarse grids and dummy cells

      CALL rflo_generatecoarsegrids( regions(ireg) )   ! coarsen finest grid
      CALL rflo_copygeometrydummy( regions(ireg) )     ! copy to dummy nodes
      CALL rflo_extrapolategeometry( regions(ireg) )   ! extrapolate
    ENDIF     ! region on this processor and active, grid moving
  ENDDO       ! iReg

  CALL rflo_exchangegeometry( regions )                ! exchange geometry

! calculate new metrics and grid speeds ---------------------------------------

  someremesh = .false.
  iremesh = 0
  DO ireg=1,global%nRegions
    IF (regions(ireg)%procid==global%myProcid .AND. &    ! region active and
        regions(ireg)%active==active .AND. &             ! on my processor
        regions(ireg)%mixtInput%moveGrid) THEN           ! and moving
      CALL rflo_calcfacevectors( regions(ireg) )         ! faces
      CALL rflo_calccontrolvolumes( regions(ireg) )      ! volumes
      CALL rflo_calccellcentroids( regions(ireg) )       ! cell centroids
      IF (regions(ireg)%mixtInput%faceEdgeAvg==fe_avg_linear) &
        CALL rflo_c2favgcoeffs( regions(ireg) )          ! cell2face averaging
      CALL rflo_c2eavgcoeffs( regions(ireg) )            ! cell2edge averaging
      CALL rflo_checkmetrics( ireg,regions(ireg) )       ! check metrics
!      IF (regions(iReg)%levels(1)%grid%remesh==1) THEN
!        CALL RFLO_GridRemesh( regions(iReg) )            ! grid remeshing
!        iRemesh=1
!      ENDIF
      CALL rflo_calcgridspeeds( regions(ireg) )          ! grid speeds
    ENDIF   ! region on this processor and active, grid moving
  ENDDO     ! iReg

#ifdef MPI
  CALL mpi_allreduce( iremesh, nremesh, 1, mpi_integer, mpi_sum, &
                      global%mpiComm, global%mpierr )
  IF (global%mpierr /=0 ) CALL errorstop( global,err_mpi_trouble,__line__ )
  IF (nremesh > 0) someremesh = .true.
#endif

  IF (someremesh) THEN
    CALL rflo_exchangegeometry( regions )    ! exchange geometry
    DO ireg=1,global%nRegions
      IF (regions(ireg)%procid==global%myProcid .AND. &    ! region active and
          regions(ireg)%active==active .AND. &             ! on my processor
          iremesh==1) THEN                                  ! and remeshing
        CALL rflo_calcfacevectors( regions(ireg) )         ! faces
        CALL rflo_calccontrolvolumes( regions(ireg) )      ! volumes
        CALL rflo_calccellcentroids( regions(ireg) )       ! cell centroids
        IF (regions(ireg)%mixtInput%faceEdgeAvg==fe_avg_linear) &
          CALL rflo_c2favgcoeffs( regions(ireg) )          ! cell2face averaging
        CALL rflo_c2eavgcoeffs( regions(ireg) )            ! cell2edge averaging
      ENDIF   ! region on this processor and active, grid moving
    ENDDO     ! iReg
  ENDIF

! finalize --------------------------------------------------------------------

  CALL deregisterfunction( global )

1000 FORMAT(a,1x,'Block Laplacian grid motion: ',i6,1pe13.4)

END SUBROUTINE rflo_movegridglobal

!******************************************************************************
!
! RCS Revision history:
!
! $Log: RFLO_MoveGridGlobal.F90,v $
! Revision 1.9  2008/12/06 08:44:27  mtcampbe
! Updated license.
!
! Revision 1.8  2008/11/19 22:17:38  mtcampbe
! Added Illinois Open Source License/Copyright
!
! Revision 1.7  2006/03/05 19:13:57  wasistho
! set computational space coordinates from initial grid
!
! Revision 1.6  2006/03/03 00:48:28  wasistho
! renamed global grid motion to block laplacian motion
!
! Revision 1.5  2005/11/03 02:40:28  wasistho
! activate boundaryDeformation and chngInteriorGrid
!
! Revision 1.4  2005/10/27 05:51:48  wasistho
! added USE RFLO_ModLaplaceSmoothing
!
! Revision 1.3  2005/05/28 05:52:32  wasistho
! refrain from grid remeshing
!
! Revision 1.2  2005/05/27 01:51:17  wasistho
! added remeshing
!
! Revision 1.1  2004/11/29 20:51:39  wasistho
! lower to upper case
!
! Revision 1.10  2004/09/02 02:35:26  wasistho
! added face-edge averaging input-option parameter in Rocflo
!
! Revision 1.9  2004/08/03 22:46:18  wasistho
! added RFLO_c2eAvgCoeffs
!
! Revision 1.8  2004/07/30 17:26:12  wasistho
! provide cell2face averaging coefficients
!
! Revision 1.7  2003/11/20 16:40:39  mdbrandy
! Backing out RocfluidMP changes from 11-17-03
!
! Revision 1.3  2003/08/27 23:58:10  jblazek
! Removed 2nd interface to RFLO_ChangeInteriorGrid.
!
! Revision 1.2  2003/08/25 21:51:24  jblazek
! Full version of global grid motion scheme.
!
! Revision 1.1  2003/08/11 21:51:18  jblazek
! Added basic global grid smoothing scheme.
!
!******************************************************************************