RFLO_CalcCellCentroids.F90

Go to the documentation of this file.

! *********************************************************************
! * Rocstar Simulation Suite                                          *
! * Copyright@2015, Illinois Rocstar LLC. All rights reserved.        *
! *                                                                   *
! * Illinois Rocstar LLC                                              *
! * Champaign, IL                                                     *
! * www.illinoisrocstar.com                                           *
! * sales@illinoisrocstar.com                                         *
! *                                                                   *
! * License: See LICENSE file in top level of distribution package or *
! * http://opensource.org/licenses/NCSA                               *
! *********************************************************************
! *********************************************************************
! * THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND,   *
! * EXPRESS OR IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES   *
! * OF MERCHANTABILITY, FITNESS FOR A PARTICULAR PURPOSE AND          *
! * NONINFRINGEMENT.  IN NO EVENT SHALL THE CONTRIBUTORS OR           *
! * COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER       *
! * LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE,   *
! * Arising FROM, OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE    *
! * USE OR OTHER DEALINGS WITH THE SOFTWARE.                          *
! *********************************************************************
!******************************************************************************
!
! Purpose: calculate cell centroids (optionally).
!
! Description: none.
!
! Input: region%levels%grid = dimensions, coordinates (current region)
!
! Output: region%levels%grid%cofg = cell centroids
!
! Notes: centroids are defined only for the physical cells.
!
!******************************************************************************
!
! $Id: RFLO_CalcCellCentroids.F90,v 1.3 2008/12/06 08:44:06 mtcampbe Exp $
!
! Copyright: (c) 2001 by the University of Illinois
!
!******************************************************************************

SUBROUTINE rflo_calccellcentroids( region )

  USE moddatatypes
  USE moddatastruct, ONLY : t_region
  USE modinterfaces, ONLY : rflo_getdimensphys, rflo_getcelloffset, &
                            rflo_getnodeoffset, centroidhexa
  USE moderror
  USE modparameters
  IMPLICIT NONE

#include "Indexing.h"

! ... parameters
  TYPE(t_region) :: region

! ... loop variables
  INTEGER :: ilev, i, j, k

! ... local variables
  INTEGER :: ipcbeg, ipcend, jpcbeg, jpcend, kpcbeg, kpcend
  INTEGER :: icoff, ijcoff, inoff, ijnoff, corner(8), ijkcell

  REAL(RFREAL)          :: xyzhexa(3,8)
  REAL(RFREAL), POINTER :: xyz(:,:), cofg(:,:)

!******************************************************************************

  CALL registerfunction( region%global,'RFLO_CalcCellCentroids',&
       'RFLO_CalcCellCentroids.F90' )

! loop over all grid levels

  DO ilev=1,region%nGridLevels

    IF (ASSOCIATED(region%levels(ilev)%grid%cofg)) THEN      ! CG needed
      CALL rflo_getdimensphys( region,ilev,ipcbeg,ipcend, &
                               jpcbeg,jpcend,kpcbeg,kpcend )
      CALL rflo_getcelloffset( region,ilev,icoff,ijcoff )
      CALL rflo_getnodeoffset( region,ilev,inoff,ijnoff )

      xyz  => region%levels(ilev)%grid%xyz
      cofg => region%levels(ilev)%grid%cofg

      DO k=kpcbeg,kpcend
        DO j=jpcbeg,jpcend
          DO i=ipcbeg,ipcend
            ijkcell   = indijk(i,j,k,icoff,ijcoff)
            corner(1) = indijk(i  ,j  ,k  ,inoff,ijnoff)
            corner(2) = indijk(i  ,j  ,k+1,inoff,ijnoff)
            corner(3) = indijk(i  ,j+1,k+1,inoff,ijnoff)
            corner(4) = indijk(i  ,j+1,k  ,inoff,ijnoff)
            corner(5) = indijk(i+1,j  ,k  ,inoff,ijnoff)
            corner(6) = indijk(i+1,j  ,k+1,inoff,ijnoff)
            corner(7) = indijk(i+1,j+1,k+1,inoff,ijnoff)
            corner(8) = indijk(i+1,j+1,k  ,inoff,ijnoff)

            xyzhexa(1:3,1) = xyz(1:3,corner(1))
            xyzhexa(1:3,2) = xyz(1:3,corner(2))
            xyzhexa(1:3,3) = xyz(1:3,corner(3))
            xyzhexa(1:3,4) = xyz(1:3,corner(4))
            xyzhexa(1:3,5) = xyz(1:3,corner(5))
            xyzhexa(1:3,6) = xyz(1:3,corner(6))
            xyzhexa(1:3,7) = xyz(1:3,corner(7))
            xyzhexa(1:3,8) = xyz(1:3,corner(8))

            CALL centroidhexa( xyzhexa, &
                               cofg(xcoord,ijkcell), &
                               cofg(ycoord,ijkcell), &
                               cofg(zcoord,ijkcell) )
          ENDDO  ! i
        ENDDO    ! j
      ENDDO      ! k
    ENDIF        ! cofg allocated?

  ENDDO          ! iLev

! finalize

  CALL deregisterfunction( region%global )

END SUBROUTINE rflo_calccellcentroids

!******************************************************************************
!
! RCS Revision history:
!
! $Log: RFLO_CalcCellCentroids.F90,v $
! Revision 1.3  2008/12/06 08:44:06  mtcampbe
! Updated license.
!
! Revision 1.2  2008/11/19 22:17:19  mtcampbe
! Added Illinois Open Source License/Copyright
!
! Revision 1.1  2004/11/29 21:25:15  wasistho
! lower to upper case
!
! Revision 1.6  2003/11/20 16:40:34  mdbrandy
! Backing out RocfluidMP changes from 11-17-03
!
! Revision 1.3  2003/05/15 02:57:01  jblazek
! Inlined index function.
!
! Revision 1.2  2002/09/05 17:40:19  jblazek
! Variable global moved into regions().
!
! Revision 1.1  2002/08/15 19:48:05  jblazek
! Implemented grid deformation capability.
!
! Revision 1.3  2002/02/21 23:25:05  jblazek
! Blocks renamed as regions.
!
! Revision 1.2  2002/01/23 03:51:25  jblazek
! Added low-level time-stepping routines.
!
! Revision 1.1  2002/01/08 22:09:17  jblazek
! Added calculation of face vectors and volumes.
!
!******************************************************************************