RFLO_MoveGridInterfaces.F90

Go to the documentation of this file.

! *********************************************************************
! * Rocstar Simulation Suite                                          *
! * Copyright@2015, Illinois Rocstar LLC. All rights reserved.        *
! *                                                                   *
! * Illinois Rocstar LLC                                              *
! * Champaign, IL                                                     *
! * www.illinoisrocstar.com                                           *
! * sales@illinoisrocstar.com                                         *
! *                                                                   *
! * License: See LICENSE file in top level of distribution package or *
! * http://opensource.org/licenses/NCSA                               *
! *********************************************************************
! *********************************************************************
! * THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND,   *
! * EXPRESS OR IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES   *
! * OF MERCHANTABILITY, FITNESS FOR A PARTICULAR PURPOSE AND          *
! * NONINFRINGEMENT.  IN NO EVENT SHALL THE CONTRIBUTORS OR           *
! * COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER       *
! * LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE,   *
! * Arising FROM, OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE    *
! * USE OR OTHER DEALINGS WITH THE SOFTWARE.                          *
! *********************************************************************
!******************************************************************************
!
! Purpose: exchange deformations between the regions as to ensure
!          matching grid nodes at the interfaces.
!
! Description: none.
!
! Input: regions = data of all grid regions, deformations.
!
! Output: regions%levels%grid%xyz = deformations at the boundaries.
!
! Notes: grid%xyz temporarily stores nodal displacements. The deformation
!        is applied to the finest grid first.
!
!******************************************************************************
!
! $Id: RFLO_MoveGridInterfaces.F90,v 1.4 2008/12/06 08:44:27 mtcampbe Exp $
!
! Copyright: (c) 2003 by the University of Illinois
!
!******************************************************************************

SUBROUTINE rflo_movegridinterfaces( regions )

  USE moddatatypes
  USE modbndpatch, ONLY   : t_patch
  USE modglobal, ONLY     : t_global
  USE moddatastruct, ONLY : t_region
  USE modgrid, ONLY       : t_grid
  USE modinterfaces, ONLY : rflo_exchangednodecopy, rflo_edgedeformation, &
        rflo_boundarydeformation, rflo_exchangednodesend, &
        rflo_exchangednoderecv, rflo_clearsendrequests
  USE moderror
  USE modparameters
  IMPLICIT NONE

! ... parameters
  TYPE(t_region), POINTER :: regions(:)

! ... loop variables
  INTEGER :: ireg, ipatch, ipass

! ... local variables
  INTEGER :: bctype, iregsrc, ipatchsrc

  TYPE(t_grid), POINTER   :: grid, gridold, gridsrc
  TYPE(t_global), POINTER :: global
  TYPE(t_patch), POINTER  :: patch, patchsrc

!******************************************************************************

  global => regions(1)%global

  CALL registerfunction( global,'RFLO_MoveGridInterfaces',&
  'RFLO_MoveGridInterfaces.F90' )

! fix interfaces between regions ----------------------------------------------

  DO ipass=1,2

! - copy / send deformations

    DO ireg=1,global%nRegions
      IF (regions(ireg)%procid==global%myProcid .AND. &  ! region active and
          regions(ireg)%active==active .AND. &           ! on my processor
          regions(ireg)%mixtInput%moveGrid) THEN         ! and moving

        grid    => regions(ireg)%levels(1)%grid
        gridold => regions(ireg)%levels(1)%gridOld

        DO ipatch=1,regions(ireg)%nPatches
          patch  => regions(ireg)%levels(1)%patches(ipatch)
          bctype =  patch%bcType
          IF ((bctype>=bc_regionconf .AND. bctype<=bc_regionconf+bc_range) .OR. &
              (bctype>=bc_tra_peri   .AND. bctype<=bc_tra_peri  +bc_range) .OR. &
              (bctype>=bc_rot_peri   .AND. bctype<=bc_rot_peri  +bc_range)) THEN
            iregsrc   =  patch%srcRegion
            ipatchsrc =  patch%srcPatch
            patchsrc  => regions(iregsrc)%levels(1)%patches(ipatchsrc)
            gridsrc   => regions(iregsrc)%levels(1)%grid

            IF (regions(iregsrc)%procid == global%myProcid) THEN
              CALL rflo_exchangednodecopy( regions(ireg),regions(iregsrc), &
                                           patch,patchsrc,.false., &
                                           grid%xyz,gridsrc%xyz )
              CALL rflo_edgedeformation( regions(ireg),grid%boundMoved, &
                                         grid%edgeMoved,grid%arcLen12, &
                                         grid%arcLen34,grid%arcLen56, &
                                         gridold%xyzOld,grid%xyz )
              CALL rflo_boundarydeformation( regions(ireg),grid%boundMoved, &
                                             grid%edgeMoved,grid%arcLen12, &
                                             grid%arcLen34,grid%arcLen56, &
                                             gridold%xyzOld,grid%xyz )
            ELSE
              CALL rflo_exchangednodesend( regions(ireg),regions(iregsrc), &
                                           patch,grid%xyz )
            ENDIF
          ENDIF  ! bcType
        ENDDO    ! iPatch

      ENDIF  ! region on this processor and active, grid moving
    ENDDO    ! iReg

! - receive deformations

    DO ireg=1,global%nRegions
      IF (regions(ireg)%procid==global%myProcid .AND. &  ! region active and
          regions(ireg)%active==active .AND. &           ! on my processor
          regions(ireg)%mixtInput%moveGrid) THEN         ! and moving

        grid    => regions(ireg)%levels(1)%grid
        gridold => regions(ireg)%levels(1)%gridOld

        DO ipatch=1,regions(ireg)%nPatches
          patch  => regions(ireg)%levels(1)%patches(ipatch)
          bctype =  patch%bcType
          IF ((bctype>=bc_regionconf .AND. bctype<=bc_regionconf+bc_range) .OR. &
              (bctype>=bc_tra_peri   .AND. bctype<=bc_tra_peri  +bc_range) .OR. &
              (bctype>=bc_rot_peri   .AND. bctype<=bc_rot_peri  +bc_range)) THEN
            iregsrc   =  patch%srcRegion
            ipatchsrc =  patch%srcPatch
            patchsrc  => regions(iregsrc)%levels(1)%patches(ipatchsrc)
            gridsrc   => regions(iregsrc)%levels(1)%grid

            IF (regions(iregsrc)%procid /= global%myProcid) THEN
              CALL rflo_exchangednoderecv( regions(ireg),regions(iregsrc), &
                                           patch,patchsrc,.false.,grid%xyz )
              CALL rflo_edgedeformation( regions(ireg),grid%boundMoved, &
                                         grid%edgeMoved,grid%arcLen12, &
                                         grid%arcLen34,grid%arcLen56, &
                                         gridold%xyzOld,grid%xyz )
              CALL rflo_boundarydeformation( regions(ireg),grid%boundMoved, &
                                             grid%edgeMoved,grid%arcLen12, &
                                             grid%arcLen34,grid%arcLen56, &
                                             gridold%xyzOld,grid%xyz )
            ENDIF
          ENDIF  ! bcType
        ENDDO    ! iPatch

      ENDIF  ! region on this processor and active, grid moving
    ENDDO    ! iReg

! - clear send requests

    DO ireg=1,global%nRegions
      IF (regions(ireg)%procid==global%myProcid .AND. &  ! region active and
          regions(ireg)%active==active .AND. &           ! on my processor
          regions(ireg)%mixtInput%moveGrid) THEN         ! and moving
        CALL rflo_clearsendrequests( regions,ireg,.true. )
      ENDIF
    ENDDO

  ENDDO    ! iPass

! finalize --------------------------------------------------------------------

  CALL deregisterfunction( global )

END SUBROUTINE rflo_movegridinterfaces

!******************************************************************************
!
! RCS Revision history:
!
! $Log: RFLO_MoveGridInterfaces.F90,v $
! Revision 1.4  2008/12/06 08:44:27  mtcampbe
! Updated license.
!
! Revision 1.3  2008/11/19 22:17:38  mtcampbe
! Added Illinois Open Source License/Copyright
!
! Revision 1.2  2006/03/05 19:03:04  wasistho
! set computational space coordinates from initial grid
!
! Revision 1.1  2004/11/29 20:51:39  wasistho
! lower to upper case
!
! Revision 1.5  2003/11/20 16:40:39  mdbrandy
! Backing out RocfluidMP changes from 11-17-03
!
! Revision 1.1  2003/08/11 21:51:18  jblazek
! Added basic global grid smoothing scheme.
!
!******************************************************************************