RFLO_C2eAvgCoeffs.F90

Go to the documentation of this file.

! *********************************************************************
! * Rocstar Simulation Suite                                          *
! * Copyright@2015, Illinois Rocstar LLC. All rights reserved.        *
! *                                                                   *
! * Illinois Rocstar LLC                                              *
! * Champaign, IL                                                     *
! * www.illinoisrocstar.com                                           *
! * sales@illinoisrocstar.com                                         *
! *                                                                   *
! * License: See LICENSE file in top level of distribution package or *
! * http://opensource.org/licenses/NCSA                               *
! *********************************************************************
! *********************************************************************
! * THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND,   *
! * EXPRESS OR IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES   *
! * OF MERCHANTABILITY, FITNESS FOR A PARTICULAR PURPOSE AND          *
! * NONINFRINGEMENT.  IN NO EVENT SHALL THE CONTRIBUTORS OR           *
! * COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER       *
! * LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE,   *
! * Arising FROM, OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE    *
! * USE OR OTHER DEALINGS WITH THE SOFTWARE.                          *
! *********************************************************************
!******************************************************************************
!
! Purpose: Construct cell to edge (four points) averaging coefficients.
!
! Description: the coefficients are obtained following an i,j,k cycle:
!              coefficients surrounding edge-i are computed by first performing
!              cell2face averaging in the j direction and then face2edge in the
!              k direction. The same way for edge-j and edge-k.
!
! Input: region = info of current region data
!
! Output: c2eCoI, c2eCoJ, c2eCoK = averaging coefficients at i, j and k edges
!
! Notes: none.
!
!******************************************************************************
!
! $Id: RFLO_C2eAvgCoeffs.F90,v 1.3 2008/12/06 08:44:25 mtcampbe Exp $
!
! Copyright: (c) 2001 by the University of Illinois
!
!******************************************************************************
SUBROUTINE rflo_c2eavgcoeffs( region )

  USE moddatatypes
  USE moddatastruct, ONLY      : t_region
  USE modglobal, ONLY          : t_global
  USE modinterfaces, ONLY      : rflo_getdimensdummy, &
                                 rflo_getcelloffset, rflo_getnodeoffset
  USE rflo_modinterfacessolver, ONLY: rflo_c2eavgcoeffsdegec
  USE moderror
  USE modparameters
  IMPLICIT NONE

#include "Indexing.h"

! ... parameters
  TYPE(t_region) :: region

! ... loop variables
  INTEGER :: i, j, k

! ... local variables
  TYPE(t_global), POINTER :: global

  INTEGER :: idcbeg,idcend,jdcbeg,jdcend,kdcbeg,kdcend
  INTEGER :: ilev,icoff,ijcoff,inoff,ijnoff
  INTEGER, PARAMETER :: idir=1, jdir=2, kdir=3

  REAL(RFREAL), POINTER :: avgco(:,:), c2fco2(:,:), c2fco3(:,:)

!******************************************************************************

  global => region%global
  CALL registerfunction( global,'RFLO_C2eAvgCoeffs',&
  'RFLO_C2eAvgCoeffs.F90' )

! get indices and pointers ---------------------------------------------------

  ilev   =  region%currLevel

  CALL rflo_getdimensdummy( region,ilev,idcbeg,idcend, &
                           jdcbeg,jdcend,kdcbeg,kdcend )
  CALL rflo_getcelloffset( region,ilev,icoff,ijcoff )
  CALL rflo_getnodeoffset( region,ilev,inoff,ijnoff )

! compute averaging coefficient at i, j, k edges

  CALL computeavgco( idir )
  CALL computeavgco( jdir )
  CALL computeavgco( kdir )

! correct averaging coefficients at degenerated edges/corners -----------------

  IF (global%degenrtEc) THEN
    CALL rflo_c2eavgcoeffsdegec( region )
  ENDIF

! finalize --------------------------------------------------------------------

  CALL deregisterfunction( global )

! =============================================================================
!   Averaging coefficients computation subroutine
! =============================================================================

CONTAINS

  SUBROUTINE computeavgco( ijk )

! ... parameters
    INTEGER   :: ijk 

! ... local variables
    INTEGER   :: ibeg,iend,jbeg,jend,kbeg,kend
    INTEGER   :: i2,j2,k2, i3,j3,k3
    INTEGER   :: corner(3)
    REAL(RFREAL) :: ec0, ec1

! - Set limits and pointers ---------------------------------------------------
    IF (ijk==idir) THEN
      ibeg = idcbeg
      iend = idcend
      jbeg = jdcbeg+1
      jend = jdcend
      kbeg = kdcbeg+1
      kend = kdcend
      i2   = 0
      j2   = 0
      k2   = -1
      i3   = 0
      j3   = -1
      k3   = 0
      avgco  => region%levels(ilev)%grid%c2eCoI
      c2fco2 => region%levels(ilev)%grid%c2fCoJ
      c2fco3 => region%levels(ilev)%grid%c2fCoK
    ELSEIF (ijk==jdir) THEN
      ibeg = idcbeg+1
      iend = idcend
      jbeg = jdcbeg
      jend = jdcend
      kbeg = kdcbeg+1
      kend = kdcend
      i2   = -1
      j2   = 0
      k2   = 0
      i3   = 0
      j3   = 0
      k3   = -1
      avgco  => region%levels(ilev)%grid%c2eCoJ
      c2fco2 => region%levels(ilev)%grid%c2fCoK
      c2fco3 => region%levels(ilev)%grid%c2fCoI
    ELSEIF (ijk==kdir) THEN
      ibeg = idcbeg+1
      iend = idcend
      jbeg = jdcbeg+1
      jend = jdcend
      kbeg = kdcbeg
      kend = kdcend
      i2   = 0
      j2   = -1
      k2   = 0
      i3   = -1
      j3   = 0
      k3   = 0
      avgco  => region%levels(ilev)%grid%c2eCoK
      c2fco2 => region%levels(ilev)%grid%c2fCoI
      c2fco3 => region%levels(ilev)%grid%c2fCoJ
    ENDIF

! - define 4-points averaging coefficients for non-uniform grid

    DO k=kbeg,kend
      DO j=jbeg,jend
        DO i=ibeg,iend
          corner(1) = indijk(i       ,j       ,k       ,inoff,ijnoff)
          corner(2) = indijk(i+i2    ,j+j2    ,k+k2    ,inoff,ijnoff)
          corner(3) = indijk(i+i3    ,j+j3    ,k+k3    ,inoff,ijnoff)

          ec0 = 0.5_rfreal*(c2fco3(1,corner(1))+c2fco3(1,corner(3)))
          ec1 = 1._rfreal-ec0

          avgco(1,corner(1)) = ec1*c2fco2(2,corner(2))
          avgco(2,corner(1)) = ec1*c2fco2(1,corner(2))
          avgco(3,corner(1)) = ec0*c2fco2(1,corner(1))
          avgco(4,corner(1)) = ec0*c2fco2(2,corner(1))
        ENDDO   ! i
      ENDDO     ! j
    ENDDO       ! k

  END SUBROUTINE computeavgco

END SUBROUTINE rflo_c2eavgcoeffs

!******************************************************************************
!
! RCS Revision history:
!
! $Log: RFLO_C2eAvgCoeffs.F90,v $
! Revision 1.3  2008/12/06 08:44:25  mtcampbe
! Updated license.
!
! Revision 1.2  2008/11/19 22:17:36  mtcampbe
! Added Illinois Open Source License/Copyright
!
! Revision 1.1  2004/11/29 20:51:38  wasistho
! lower to upper case
!
! Revision 1.3  2004/08/25 07:45:33  wasistho
! added RFLO_C2eAvgCoeffsDegec
!
! Revision 1.2  2004/08/09 21:44:00  wasistho
! removed TURB_ModParameters
!
! Revision 1.1  2004/08/03 22:46:50  wasistho
! added RFLO_c2eAvgCoeffs
!
!
!******************************************************************************