RFLO_LaplaceGridSmoo.F90

Go to the documentation of this file.

! *********************************************************************
! * Rocstar Simulation Suite                                          *
! * Copyright@2015, Illinois Rocstar LLC. All rights reserved.        *
! *                                                                   *
! * Illinois Rocstar LLC                                              *
! * Champaign, IL                                                     *
! * www.illinoisrocstar.com                                           *
! * sales@illinoisrocstar.com                                         *
! *                                                                   *
! * License: See LICENSE file in top level of distribution package or *
! * http://opensource.org/licenses/NCSA                               *
! *********************************************************************
! *********************************************************************
! * THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND,   *
! * EXPRESS OR IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES   *
! * OF MERCHANTABILITY, FITNESS FOR A PARTICULAR PURPOSE AND          *
! * NONINFRINGEMENT.  IN NO EVENT SHALL THE CONTRIBUTORS OR           *
! * COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER       *
! * LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE,   *
! * Arising FROM, OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE    *
! * USE OR OTHER DEALINGS WITH THE SOFTWARE.                          *
! *********************************************************************
!******************************************************************************
!
! Purpose: smooth the distribution of grid points by solving simplified
!          Laplace equation in physical space.
!
! Description: none.
!
! Input: regions = data of all grid regions.
!
! Output: regions%levels%grid%xyz = new grid coordinates
!         resid = convergence of the Jacobi iteration.
!
! Notes: none.
!
!******************************************************************************
!
! $Id: RFLO_LaplaceGridSmoo.F90,v 1.3 2008/12/06 08:44:07 mtcampbe Exp $
!
! Copyright: (c) 2003 by the University of Illinois
!
!******************************************************************************

SUBROUTINE rflo_laplacegridsmoo( regions,resid )

  USE moddatatypes
  USE modbndpatch, ONLY   : t_patch
  USE modglobal, ONLY     : t_global
  USE moddatastruct, ONLY : t_region
  USE modgrid, ONLY       : t_grid
  USE modinterfaces, ONLY : rflo_laplacegridpatch, rflo_laplacegridsolve, &
        rflo_changeinteriorgrid, rflo_generatecoarsegrids, &
        rflo_copygeometrydummy, rflo_extrapolategeometry, &
        rflo_exchangegeometry, rflo_calcfacevectors, rflo_exchangednodecopy, &
        rflo_exchangednodesend, rflo_exchangednoderecv, rflo_clearsendrequests,&
        rflo_getdimensphysnodes, rflo_getnodeoffset
  USE moderror
  USE modparameters
  IMPLICIT NONE

#include "Indexing.h"

! ... parameters
  REAL(RFREAL) :: resid

  TYPE(t_region), POINTER :: regions(:)

! ... loop variables
  INTEGER :: ireg, ipatch, ijk, i, j, k

! ... local variables
  INTEGER :: ipnbeg, ipnend, jpnbeg, jpnend, kpnbeg, kpnend, inoff, ijnoff
  INTEGER :: bctype, iregsrc, ipatchsrc

  REAL(RFREAL) :: dx, dy, dz
  REAL(RFREAL), POINTER :: xyz(:,:), xyzold(:,:)

  TYPE(t_global), POINTER :: global
  TYPE(t_grid), POINTER   :: grid, gridold, gridsrc
  TYPE(t_patch), POINTER  :: patch, patchsrc

!******************************************************************************

  global => regions(1)%global

  CALL registerfunction( global,'RFLO_LaplaceGridSmoo',&
  'RFLO_LaplaceGridSmoo.F90' )

! smooth grid region-wise -----------------------------------------------------

  resid = 0._rfreal

  DO ireg=1,global%nRegions
    IF (regions(ireg)%procid==global%myProcid .AND. &  ! region active and
        regions(ireg)%active==active .AND. &           ! on my processor
        regions(ireg)%mixtInput%moveGrid) THEN         ! and moving

! --- compute movements in the interior and along the boundaries

      CALL rflo_laplacegridsolve( regions(ireg) )

! --- zero out movements along certain boundaries

      DO ipatch=1,regions(ireg)%nPatches
        patch  => regions(ireg)%levels(1)%patches(ipatch)
        bctype =  patch%bcType
        IF ((bctype>=bc_inflow     .AND. bctype<=bc_inflow    +bc_range) .OR. &
            (bctype>=bc_outflow    .AND. bctype<=bc_outflow   +bc_range) .OR. &
            (bctype>=bc_slipwall   .AND. bctype<=bc_slipwall  +bc_range) .OR. &
            (bctype>=bc_noslipwall .AND. bctype<=bc_noslipwall+bc_range) .OR. &
            (bctype>=bc_farfield   .AND. bctype<=bc_farfield  +bc_range) .OR. &
            (bctype>=bc_injection  .AND. bctype<=bc_injection +bc_range) .OR. &
            (bctype>=bc_tra_peri   .AND. bctype<=bc_tra_peri  +bc_range) .OR. &
            (bctype>=bc_rot_peri   .AND. bctype<=bc_rot_peri  +bc_range)) THEN
          CALL rflo_laplacegridpatch( regions(ireg),patch )
        ENDIF  ! bcType
      ENDDO    ! iPatch

      CALL rflo_getdimensphysnodes( regions(ireg),1,ipnbeg,ipnend, &
                                    jpnbeg,jpnend,kpnbeg,kpnend )
      CALL rflo_getnodeoffset( regions(ireg),1,inoff,ijnoff )

      xyz    => regions(ireg)%levels(1)%grid%xyz
      xyzold => regions(ireg)%levels(1)%grid%xyzOld

      DO k=kpnbeg,kpnend
        DO j=jpnbeg,jpnend
          DO i=ipnbeg,ipnend
            ijk   = indijk(i,j,k,inoff,ijnoff)
            dx    = xyz(xcoord,ijk) - xyzold(xcoord,ijk)
            dy    = xyz(ycoord,ijk) - xyzold(ycoord,ijk)
            dz    = xyz(zcoord,ijk) - xyzold(zcoord,ijk)
            resid = resid + dx*dx + dy*dy +dz*dz
          ENDDO
        ENDDO
      ENDDO

    ENDIF  ! region on this processor and active, grid moving
  ENDDO    ! iReg

! fix interfaces between regions ----------------------------------------------
! copy / send deformations

  DO ireg=1,global%nRegions
    IF (regions(ireg)%procid==global%myProcid .AND. &  ! region active and
        regions(ireg)%active==active .AND. &           ! on my processor
        regions(ireg)%mixtInput%moveGrid) THEN         ! and moving

      grid    => regions(ireg)%levels(1)%grid
      gridold => regions(ireg)%levels(1)%gridOld

      DO ipatch=1,regions(ireg)%nPatches
        patch  => regions(ireg)%levels(1)%patches(ipatch)
        bctype =  patch%bcType
        IF ((bctype>=bc_regionconf .AND. bctype<=bc_regionconf+bc_range) .OR. &
            (bctype>=bc_tra_peri   .AND. bctype<=bc_tra_peri  +bc_range) .OR. &
            (bctype>=bc_rot_peri   .AND. bctype<=bc_rot_peri  +bc_range)) THEN
          iregsrc   =  patch%srcRegion
          ipatchsrc =  patch%srcPatch
          patchsrc  => regions(iregsrc)%levels(1)%patches(ipatchsrc)
          gridsrc   => regions(iregsrc)%levels(1)%grid

          IF (regions(iregsrc)%procid == global%myProcid) THEN
            CALL rflo_exchangednodecopy( regions(ireg),regions(iregsrc), &
                                         patch,patchsrc,.true., &
                                         grid%xyz,gridsrc%xyz )
          ELSE
            CALL rflo_exchangednodesend( regions(ireg),regions(iregsrc), &
                                         patch,grid%xyz )
          ENDIF
        ENDIF  ! bcType
      ENDDO    ! iPatch

    ENDIF  ! region on this processor and active, grid moving
  ENDDO    ! iReg

! receive deformations

  DO ireg=1,global%nRegions
    IF (regions(ireg)%procid==global%myProcid .AND. &  ! region active and
        regions(ireg)%active==active .AND. &           ! on my processor
        regions(ireg)%mixtInput%moveGrid) THEN         ! and moving

      grid    => regions(ireg)%levels(1)%grid
      gridold => regions(ireg)%levels(1)%gridOld

      DO ipatch=1,regions(ireg)%nPatches
        patch  => regions(ireg)%levels(1)%patches(ipatch)
        bctype =  patch%bcType
        IF ((bctype>=bc_regionconf .AND. bctype<=bc_regionconf+bc_range) .OR. &
            (bctype>=bc_tra_peri   .AND. bctype<=bc_tra_peri  +bc_range) .OR. &
            (bctype>=bc_rot_peri   .AND. bctype<=bc_rot_peri  +bc_range)) THEN
          iregsrc   =  patch%srcRegion
          ipatchsrc =  patch%srcPatch
          patchsrc  => regions(iregsrc)%levels(1)%patches(ipatchsrc)
          gridsrc   => regions(iregsrc)%levels(1)%grid

          IF (regions(iregsrc)%procid /= global%myProcid) THEN
            CALL rflo_exchangednoderecv( regions(ireg),regions(iregsrc), &
                                         patch,patchsrc,.true.,grid%xyz )
          ENDIF
        ENDIF  ! bcType
      ENDDO    ! iPatch

    ENDIF  ! region on this processor and active, grid moving
  ENDDO    ! iReg

! clear send requests

  DO ireg=1,global%nRegions
    IF (regions(ireg)%procid==global%myProcid .AND. &  ! region active and
        regions(ireg)%active==active .AND. &           ! on my processor
        regions(ireg)%mixtInput%moveGrid) THEN         ! and moving
      CALL rflo_clearsendrequests( regions,ireg,.true. )
    ENDIF
  ENDDO

! update grid, dummy, corner and edge cells -----------------------------------

  DO ireg=1,global%nRegions
    IF (regions(ireg)%procid==global%myProcid .AND. &  ! region active and
        regions(ireg)%active==active .AND. &           ! on my processor
        regions(ireg)%mixtInput%moveGrid) THEN         ! and moving

! --- change xyz from deformations to coordinates

      xyz    => regions(ireg)%levels(1)%grid%xyz
      xyzold => regions(ireg)%levels(1)%gridOld%xyz

      DO ijk=lbound(xyz,2),ubound(xyz,2)
        xyz(xcoord,ijk) = xyz(xcoord,ijk) + xyzold(xcoord,ijk)
        xyz(ycoord,ijk) = xyz(ycoord,ijk) + xyzold(ycoord,ijk)
        xyz(zcoord,ijk) = xyz(zcoord,ijk) + xyzold(zcoord,ijk)
      ENDDO

! --- update coarse grids and dummy cells

      CALL rflo_generatecoarsegrids( regions(ireg) )   ! coarsen finest grid
      CALL rflo_copygeometrydummy( regions(ireg) )     ! copy to dummy nodes
      CALL rflo_extrapolategeometry( regions(ireg) )   ! extrapolate
    ENDIF     ! region on this processor and active, grid moving
  ENDDO       ! iReg

  CALL rflo_exchangegeometry( regions )                ! exchange geometry

! finalize --------------------------------------------------------------------

  CALL deregisterfunction( global )

END SUBROUTINE rflo_laplacegridsmoo

!******************************************************************************
!
! RCS Revision history:
!
! $Log: RFLO_LaplaceGridSmoo.F90,v $
! Revision 1.3  2008/12/06 08:44:07  mtcampbe
! Updated license.
!
! Revision 1.2  2008/11/19 22:17:20  mtcampbe
! Added Illinois Open Source License/Copyright
!
! Revision 1.1  2004/11/29 21:25:16  wasistho
! lower to upper case
!
! Revision 1.5  2003/11/20 16:40:34  mdbrandy
! Backing out RocfluidMP changes from 11-17-03
!
! Revision 1.2  2003/08/25 21:51:23  jblazek
! Full version of global grid motion scheme.
!
! Revision 1.1  2003/08/11 21:51:17  jblazek
! Added basic global grid smoothing scheme.
!
!******************************************************************************