RFLO_GenerateCoarseGrids.F90

Go to the documentation of this file.

! *********************************************************************
! * Rocstar Simulation Suite                                          *
! * Copyright@2015, Illinois Rocstar LLC. All rights reserved.        *
! *                                                                   *
! * Illinois Rocstar LLC                                              *
! * Champaign, IL                                                     *
! * www.illinoisrocstar.com                                           *
! * sales@illinoisrocstar.com                                         *
! *                                                                   *
! * License: See LICENSE file in top level of distribution package or *
! * http://opensource.org/licenses/NCSA                               *
! *********************************************************************
! *********************************************************************
! * THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND,   *
! * EXPRESS OR IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES   *
! * OF MERCHANTABILITY, FITNESS FOR A PARTICULAR PURPOSE AND          *
! * NONINFRINGEMENT.  IN NO EVENT SHALL THE CONTRIBUTORS OR           *
! * COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER       *
! * LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE,   *
! * Arising FROM, OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE    *
! * USE OR OTHER DEALINGS WITH THE SOFTWARE.                          *
! *********************************************************************
!******************************************************************************
!
! Purpose: generate coarse grids from the finest grid.
!
! Description: the coarse grids are generated by omitting every second
!              grid node in all three directions (standard coarsening).
!
! Input: region = current region.
!
! Output: region%levels%grid%xyz = grid coordinates.
!
! Notes: none.
!
!******************************************************************************
!
! $Id: RFLO_GenerateCoarseGrids.F90,v 1.3 2008/12/06 08:44:06 mtcampbe Exp $
!
! Copyright: (c) 2001 by the University of Illinois
!
!******************************************************************************

SUBROUTINE rflo_generatecoarsegrids( region )

  USE moddatatypes
  USE moddatastruct, ONLY : t_region
  USE modinterfaces, ONLY : rflo_getdimensphysnodes, rflo_getnodeoffset
  USE moderror
  USE modparameters
  IMPLICIT NONE

#include "Indexing.h"

! ... parameters
  TYPE(t_region) :: region

! ... loop variables
  INTEGER :: ilev, i, j, k

! ... local variables
  INTEGER :: ipnbegf, ipnendf, jpnbegf, jpnendf, kpnbegf, kpnendf
  INTEGER :: ipnbegc, ipnendc, jpnbegc, jpnendc, kpnbegc, kpnendc
  INTEGER :: iofffine, ijofffine, ioffcoarse, ijoffcoarse, ijkf, ijkc
  INTEGER :: ii, jj, kk

  REAL(RFREAL), POINTER :: xyzfine(:,:), xyzcoarse(:,:)

!******************************************************************************

  CALL registerfunction( region%global,'RFLO_GenerateCoarseGrids',&
  'RFLO_GenerateCoarseGrids.F90' )

! loop over higher levels (>1)

  DO ilev=2,region%nGridLevels

    xyzfine   => region%levels(ilev-1)%grid%xyz
    xyzcoarse => region%levels(ilev  )%grid%xyz

    CALL rflo_getdimensphysnodes( region,ilev-1,ipnbegf,ipnendf, &
                                  jpnbegf,jpnendf,kpnbegf,kpnendf )
    CALL rflo_getdimensphysnodes( region,ilev  ,ipnbegc,ipnendc, &
                                  jpnbegc,jpnendc,kpnbegc,kpnendc )
    CALL rflo_getnodeoffset( region,ilev-1,iofffine  ,ijofffine   )
    CALL rflo_getnodeoffset( region,ilev  ,ioffcoarse,ijoffcoarse )

    DO k=kpnbegc,kpnendc
      kk = (k-kpnbegc)*2 + kpnbegf
      DO j=jpnbegc,jpnendc
        jj = (j-jpnbegc)*2 + jpnbegf
        DO i=ipnbegc,ipnendc
          ii   = (i-ipnbegc)*2 + ipnbegf
          ijkf = indijk(ii,jj,kk,iofffine  ,ijofffine  )
          ijkc = indijk(i ,j ,k ,ioffcoarse,ijoffcoarse)
          xyzcoarse(xcoord,ijkc) = xyzfine(xcoord,ijkf)
          xyzcoarse(ycoord,ijkc) = xyzfine(ycoord,ijkf)
          xyzcoarse(zcoord,ijkc) = xyzfine(zcoord,ijkf)
        ENDDO  ! i
      ENDDO    ! j
    ENDDO      ! k

  ENDDO        ! iLev

! finalize

  CALL deregisterfunction( region%global )

END SUBROUTINE rflo_generatecoarsegrids

!******************************************************************************
!
! RCS Revision history:
!
! $Log: RFLO_GenerateCoarseGrids.F90,v $
! Revision 1.3  2008/12/06 08:44:06  mtcampbe
! Updated license.
!
! Revision 1.2  2008/11/19 22:17:20  mtcampbe
! Added Illinois Open Source License/Copyright
!
! Revision 1.1  2004/11/29 21:25:16  wasistho
! lower to upper case
!
! Revision 1.6  2003/11/20 16:40:34  mdbrandy
! Backing out RocfluidMP changes from 11-17-03
!
! Revision 1.3  2003/05/15 02:57:01  jblazek
! Inlined index function.
!
! Revision 1.2  2002/09/05 17:40:19  jblazek
! Variable global moved into regions().
!
! Revision 1.1  2002/06/07 16:40:36  jblazek
! Grid & solution for all regions in one file.
!
!******************************************************************************