RFLO_C2fAvgCoeffs.F90

Go to the documentation of this file.

! *********************************************************************
! * Rocstar Simulation Suite                                          *
! * Copyright@2015, Illinois Rocstar LLC. All rights reserved.        *
! *                                                                   *
! * Illinois Rocstar LLC                                              *
! * Champaign, IL                                                     *
! * www.illinoisrocstar.com                                           *
! * sales@illinoisrocstar.com                                         *
! *                                                                   *
! * License: See LICENSE file in top level of distribution package or *
! * http://opensource.org/licenses/NCSA                               *
! *********************************************************************
! *********************************************************************
! * THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND,   *
! * EXPRESS OR IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES   *
! * OF MERCHANTABILITY, FITNESS FOR A PARTICULAR PURPOSE AND          *
! * NONINFRINGEMENT.  IN NO EVENT SHALL THE CONTRIBUTORS OR           *
! * COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER       *
! * LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE,   *
! * Arising FROM, OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE    *
! * USE OR OTHER DEALINGS WITH THE SOFTWARE.                          *
! *********************************************************************
!******************************************************************************
!
! Purpose: Construct cell to face (two points) averaging coefficients.
!
! Description: Averaging coefficients are first computed for the interior 
!              i, j and k faces, then the patches and finally extrapolated
!              to edges and corners, depending on the patch bc.
!
! Input: region = info of current region data
!
! Output: c2fCoI, c2fCoJ, c2fCoK = averaging coefficients at i, j and k faces
!
! Notes: none.
!
!******************************************************************************
!
! $Id: RFLO_C2fAvgCoeffs.F90,v 1.3 2008/12/06 08:44:25 mtcampbe Exp $
!
! Copyright: (c) 2001 by the University of Illinois
!
!******************************************************************************
SUBROUTINE rflo_c2favgcoeffs( region )

  USE moddatatypes
  USE moddatastruct, ONLY      : t_region
  USE modglobal, ONLY          : t_global
  USE modinterfaces, ONLY      : rflo_getdimensdummy, &
                                 rflo_getcelloffset, rflo_getnodeoffset, &
                                 rflo_copyedgefacenorm, rflo_copyedgefaceparal
  USE rflo_modinterfacessolver, ONLY: &
                                 rflo_c2favgcoeffspatch, &
                                 rflo_c2favgcoeffsdummy, rflo_c2favgcoeffsdegec
  USE moderror
  USE modparameters
  IMPLICIT NONE

#include "Indexing.h"

! ... parameters
  TYPE(t_region) :: region

! ... loop variables
  INTEGER :: i, j, k, l, ipatch

! ... local variables
  TYPE(t_global), POINTER :: global

  INTEGER :: idcbeg,idcend,jdcbeg,jdcend,kdcbeg,kdcend
  INTEGER :: ilev,icoff,ijcoff,inoff,ijnoff
  INTEGER, PARAMETER :: idir=1, jdir=2, kdir=3

  REAL(RFREAL), POINTER :: xyz(:,:), avgco(:,:)
  REAL(RFREAL), POINTER :: avgcoi(:,:), avgcoj(:,:), avgcok(:,:)
  REAL(RFREAL), PARAMETER :: real_small = 1.e-16_rfreal

!******************************************************************************

  global => region%global
  CALL registerfunction( global,'RFLO_C2fAvgCoeffs',&
  'RFLO_C2fAvgCoeffs.F90' )

! get indices and pointers ---------------------------------------------------

  ilev   =  region%currLevel
  xyz    => region%levels(ilev)%grid%xyz
  avgcoi => region%levels(ilev)%grid%c2fCoI
  avgcoj => region%levels(ilev)%grid%c2fCoJ
  avgcok => region%levels(ilev)%grid%c2fCoK

  CALL rflo_getdimensdummy( region,ilev,idcbeg,idcend, &
                           jdcbeg,jdcend,kdcbeg,kdcend )
  CALL rflo_getcelloffset( region,ilev,icoff,ijcoff )
  CALL rflo_getnodeoffset( region,ilev,inoff,ijnoff )

! compute averaging coefficient at face i, j, k interior domain

  CALL computeavgco( idir )
  CALL computeavgco( jdir )
  CALL computeavgco( kdir )

! compute averaging coefficient at dummy points

  DO ipatch=1,region%nPatches
    CALL rflo_c2favgcoeffspatch( region,region%levels(ilev)%patches(ipatch) )
    CALL rflo_c2favgcoeffsdummy( region,region%levels(ilev)%patches(ipatch) )
  ENDDO

! and copy to edge/corner dummies -------------------------------------------- 
! the edge length is extended that corners are covered to minimize work

  CALL rflo_copyedgefacenorm( region,1,2,avgcoi,avgcoj,avgcok )
  CALL rflo_copyedgefaceparal( region,1,2,avgcoi,avgcoj,avgcok )

! correct averaging coefficients at degenerated edges/corners -----------------

  IF (global%degenrtEc) THEN
    CALL rflo_c2favgcoeffsdegec( region )
  ENDIF

! finalize --------------------------------------------------------------------

  CALL deregisterfunction( global )

! =============================================================================
!   Averaging coefficients computation subroutine
! =============================================================================

CONTAINS

  SUBROUTINE computeavgco( ijk )

! ... parameters
    INTEGER   :: ijk 

! ... local variables
    INTEGER   :: ibeg,iend,jbeg,jend,kbeg,kend, iadd,jadd,kadd
    INTEGER   :: i2,i3,i4,j2,j3,j4,k2,k3,k4
    INTEGER   :: corner(12)
    REAL(RFREAL) :: denom,segment(2),facecenter(xcoord:zcoord)
    REAL(RFREAL) :: cel0center(xcoord:zcoord),cel1center(xcoord:zcoord)

! - Set limits and pointers ---------------------------------------------------
    IF (ijk==idir) THEN
      ibeg = idcbeg+1
      iend = idcend
      jbeg = jdcbeg
      jend = jdcend
      kbeg = kdcbeg
      kend = kdcend
      iadd = -1
      jadd = 0
      kadd = 0
      i2   = 0
      i3   = 0
      i4   = 0
      j2   = 0
      j3   = 1
      j4   = 1
      k2   = 1
      k3   = 1
      k4   = 0
      avgco => region%levels(ilev)%grid%c2fCoI
    ELSEIF (ijk==jdir) THEN
      ibeg = idcbeg
      iend = idcend
      jbeg = jdcbeg+1
      jend = jdcend
      kbeg = kdcbeg
      kend = kdcend
      iadd = 0
      jadd = -1
      kadd = 0
      i2   = 0
      i3   = 1
      i4   = 1
      j2   = 0
      j3   = 0
      j4   = 0
      k2   = 1
      k3   = 1
      k4   = 0
      avgco => region%levels(ilev)%grid%c2fCoJ
    ELSEIF (ijk==kdir) THEN
      ibeg = idcbeg
      iend = idcend
      jbeg = jdcbeg
      jend = jdcend
      kbeg = kdcbeg+1
      kend = kdcend
      iadd = 0
      jadd = 0
      kadd = -1
      i2   = 0
      i3   = 1
      i4   = 1
      j2   = 1
      j3   = 1
      j4   = 0
      k2   = 0
      k3   = 0
      k4   = 0
      avgco => region%levels(ilev)%grid%c2fCoK
    ENDIF

! define 2-point averaging coefficients for non-uniform grid

    DO k=kbeg,kend
      DO j=jbeg,jend
        DO i=ibeg,iend
          corner(1) = indijk(i    ,j    ,k    ,inoff,ijnoff)
          corner(2) = indijk(i+i2 ,j+j2 ,k+k2 ,inoff,ijnoff)
          corner(3) = indijk(i+i3 ,j+j3 ,k+k3 ,inoff,ijnoff)
          corner(4) = indijk(i+i4 ,j+j4 ,k+k4 ,inoff,ijnoff)
          corner(5) = indijk(i-iadd    ,j-jadd   ,k-kadd     ,inoff,ijnoff)
          corner(6) = indijk(i+i2-iadd ,j+j2-jadd ,k+k2-kadd ,inoff,ijnoff)
          corner(7) = indijk(i+i3-iadd ,j+j3-jadd ,k+k3-kadd ,inoff,ijnoff)
          corner(8) = indijk(i+i4-iadd ,j+j4-jadd ,k+k4-kadd ,inoff,ijnoff)
          corner(9) = indijk(i+iadd    ,j+jadd   ,k+kadd     ,inoff,ijnoff)
          corner(10)= indijk(i+i2+iadd ,j+j2+jadd ,k+k2+kadd ,inoff,ijnoff)
          corner(11)= indijk(i+i3+iadd ,j+j3+jadd ,k+k3+kadd ,inoff,ijnoff)
          corner(12)= indijk(i+i4+iadd ,j+j4+jadd ,k+k4+kadd ,inoff,ijnoff)
         
          DO l=1,3
            facecenter(l) = 0.25_rfreal*(xyz(l,corner(1))+ &
                                         xyz(l,corner(2))+ &
                                         xyz(l,corner(3))+ &
                                         xyz(l,corner(4)))
          ENDDO         
          DO l=1,3
            cel0center(l) = 0.125_rfreal*(xyz(l,corner(1))+ &
                                          xyz(l,corner(2))+ &
                                          xyz(l,corner(3))+ &
                                          xyz(l,corner(4))+ &
                                          xyz(l,corner(5))+ &
                                          xyz(l,corner(6))+ &
                                          xyz(l,corner(7))+ &
                                          xyz(l,corner(8)))
          ENDDO         
          DO l=1,3
            cel1center(l) = 0.125_rfreal*(xyz(l,corner(1)) + &
                                          xyz(l,corner(2)) + &
                                          xyz(l,corner(3)) + &
                                          xyz(l,corner(4)) + &
                                          xyz(l,corner(9)) + &
                                          xyz(l,corner(10))+ &
                                          xyz(l,corner(11))+ &
                                          xyz(l,corner(12)))
          ENDDO

          segment(1) = sqrt((facecenter(xcoord)-cel1center(xcoord))**2 + &
                            (facecenter(ycoord)-cel1center(ycoord))**2 + &
                            (facecenter(zcoord)-cel1center(zcoord))**2)

          segment(2) = sqrt((facecenter(xcoord)-cel0center(xcoord))**2 + &
                            (facecenter(ycoord)-cel0center(ycoord))**2 + &
                            (facecenter(zcoord)-cel0center(zcoord))**2)

!          IF (segment(1) < REAL_SMALL) THEN
!            segment(1) = 0._RFREAL
!          ENDIF
!          IF (segment(2) < REAL_SMALL) THEN
!            segment(2) = 0._RFREAL
!          ENDIF
!          IF ((segment(1)+segment(2)) < REAL_SMALL) THEN
!            denom = REAL_SMALL
!          ELSE
!            denom = (segment(1)+segment(2))        
!          ENDIF

          denom = max( segment(1)+segment(2),real_small ) 
          avgco(2,corner(1)) = segment(1)/denom
          avgco(1,corner(1)) = 1._rfreal-avgco(2,corner(1))
        ENDDO   ! i
      ENDDO     ! j
    ENDDO       ! k

  END SUBROUTINE computeavgco

END SUBROUTINE rflo_c2favgcoeffs

!******************************************************************************
!
! RCS Revision history:
!
! $Log: RFLO_C2fAvgCoeffs.F90,v $
! Revision 1.3  2008/12/06 08:44:25  mtcampbe
! Updated license.
!
! Revision 1.2  2008/11/19 22:17:36  mtcampbe
! Added Illinois Open Source License/Copyright
!
! Revision 1.1  2004/11/29 20:51:38  wasistho
! lower to upper case
!
! Revision 1.6  2004/08/25 07:45:18  wasistho
! added RFLO_C2fAvgCoeffsDegec
!
! Revision 1.5  2004/08/09 21:43:51  wasistho
! removed TURB_ModParameters
!
! Revision 1.4  2004/08/03 03:17:49  wasistho
! replaced IF statement inside do loop by MAX statement
!
! Revision 1.3  2004/08/03 00:51:45  wasistho
! changed avgCo to c2fCo in the description
!
! Revision 1.2  2004/08/02 19:32:56  wasistho
! changed grid%avgCo to grid%c2fCo
!
! Revision 1.1  2004/07/30 17:30:31  wasistho
! initial import routines starting with RFLO_c2fAvg...
!
!
!******************************************************************************