RFLO_CalcControlVolumes.F90

Go to the documentation of this file.

! *********************************************************************
! * Rocstar Simulation Suite                                          *
! * Copyright@2015, Illinois Rocstar LLC. All rights reserved.        *
! *                                                                   *
! * Illinois Rocstar LLC                                              *
! * Champaign, IL                                                     *
! * www.illinoisrocstar.com                                           *
! * sales@illinoisrocstar.com                                         *
! *                                                                   *
! * License: See LICENSE file in top level of distribution package or *
! * http://opensource.org/licenses/NCSA                               *
! *********************************************************************
! *********************************************************************
! * THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND,   *
! * EXPRESS OR IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES   *
! * OF MERCHANTABILITY, FITNESS FOR A PARTICULAR PURPOSE AND          *
! * NONINFRINGEMENT.  IN NO EVENT SHALL THE CONTRIBUTORS OR           *
! * COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER       *
! * LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE,   *
! * Arising FROM, OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE    *
! * USE OR OTHER DEALINGS WITH THE SOFTWARE.                          *
! *********************************************************************
!******************************************************************************
!
! Purpose: calculate cell volumes.
!
! Description: cell volumes are calculated based on the divergence theorem.
!              See the corresponding subroutine for the reference.
!
! Input: region%levels%grid = dimensions, coordinates, face vectors
!                             (current region)
!
! Output: region%levels%grid%vol = cell volumes
!
! Notes: volumes are first calculated for all cells. In a second step,
!        volumes are copied from interior to dummy cells at all but
!        inter-region or periodic boundaries. Face vectors must be already
!        defined before this routine is called.
!
!******************************************************************************
!
! $Id: RFLO_CalcControlVolumes.F90,v 1.3 2008/12/06 08:44:26 mtcampbe Exp $
!
! Copyright: (c) 2001 by the University of Illinois
!
!******************************************************************************

SUBROUTINE rflo_calccontrolvolumes( region )

  USE moddatatypes
  USE moddatastruct, ONLY : t_region
  USE modinterfaces, ONLY : rflo_getdimensdummy, rflo_getdimensphys, &
        rflo_getcelloffset, rflo_getnodeoffset, volumehexa, &
        rflo_copyvectorpatches, rflo_copyvectoredges, rflo_copyvectorcorners
  USE moderror
  IMPLICIT NONE

#include "Indexing.h"

! ... parameters
  TYPE(t_region) :: region

! ... loop variables
  INTEGER :: ilev, i, j, k

! ... local variables
  INTEGER :: idcbeg, idcend, jdcbeg, jdcend, kdcbeg, kdcend
  INTEGER :: icoff, ijcoff, inoff, ijnoff, ijkcell, corner(8)

  REAL(RFREAL)          :: xyzhexa(3,8), facevecs(3,6)
  REAL(RFREAL), POINTER :: xyz(:,:), si(:,:), sj(:,:), sk(:,:), vol(:)

!******************************************************************************

  CALL registerfunction( region%global,'RFLO_CalcControlVolumes',&
  'RFLO_CalcControlVolumes.F90' )

! volumes of all cells

  DO ilev=1,region%nGridLevels               ! all grid levels

    CALL rflo_getdimensdummy( region,ilev,idcbeg,idcend, &
                              jdcbeg,jdcend,kdcbeg,kdcend )
    CALL rflo_getcelloffset( region,ilev,icoff,ijcoff )
    CALL rflo_getnodeoffset( region,ilev,inoff,ijnoff )

    xyz => region%levels(ilev)%grid%xyz
    si  => region%levels(ilev)%grid%si
    sj  => region%levels(ilev)%grid%sj
    sk  => region%levels(ilev)%grid%sk
    vol => region%levels(ilev)%grid%vol

    DO k=kdcbeg,kdcend
      DO j=jdcbeg,jdcend
        DO i=idcbeg,idcend
          ijkcell   = indijk(i,j,k,icoff,ijcoff)
          corner(1) = indijk(i  ,j  ,k  ,inoff,ijnoff)
          corner(2) = indijk(i  ,j  ,k+1,inoff,ijnoff)
          corner(3) = indijk(i  ,j+1,k+1,inoff,ijnoff)
          corner(4) = indijk(i  ,j+1,k  ,inoff,ijnoff)
          corner(5) = indijk(i+1,j  ,k  ,inoff,ijnoff)
          corner(6) = indijk(i+1,j  ,k+1,inoff,ijnoff)
          corner(7) = indijk(i+1,j+1,k+1,inoff,ijnoff)
          corner(8) = indijk(i+1,j+1,k  ,inoff,ijnoff)

          xyzhexa(1:3,1) = xyz(1:3,corner(1))
          xyzhexa(1:3,2) = xyz(1:3,corner(2))
          xyzhexa(1:3,3) = xyz(1:3,corner(3))
          xyzhexa(1:3,4) = xyz(1:3,corner(4))
          xyzhexa(1:3,5) = xyz(1:3,corner(5))
          xyzhexa(1:3,6) = xyz(1:3,corner(6))
          xyzhexa(1:3,7) = xyz(1:3,corner(7))
          xyzhexa(1:3,8) = xyz(1:3,corner(8))

          facevecs(1:3,1) =  si(1:3,corner(1))
          facevecs(1:3,2) = -si(1:3,corner(5))
          facevecs(1:3,3) =  sj(1:3,corner(1))
          facevecs(1:3,4) = -sj(1:3,corner(4))
          facevecs(1:3,5) =  sk(1:3,corner(1))
          facevecs(1:3,6) = -sk(1:3,corner(2))

          CALL volumehexa( xyzhexa,facevecs,vol(ijkcell) )
        ENDDO
      ENDDO
    ENDDO

! - copy to dummy cells at patches

    CALL rflo_copyvectorpatches( ilev,region,vol )

! - copy to dummy cells at edges

    CALL rflo_copyvectoredges( ilev,region,vol )

! - copy to dummy cells at corners

    CALL rflo_copyvectorcorners( ilev,region,vol )

  ENDDO   ! iLev

! finalize

  CALL deregisterfunction( region%global )

END SUBROUTINE rflo_calccontrolvolumes

!******************************************************************************
!
! RCS Revision history:
!
! $Log: RFLO_CalcControlVolumes.F90,v $
! Revision 1.3  2008/12/06 08:44:26  mtcampbe
! Updated license.
!
! Revision 1.2  2008/11/19 22:17:37  mtcampbe
! Added Illinois Open Source License/Copyright
!
! Revision 1.1  2004/11/29 20:51:38  wasistho
! lower to upper case
!
! Revision 1.9  2003/11/20 16:40:36  mdbrandy
! Backing out RocfluidMP changes from 11-17-03
!
! Revision 1.5  2003/05/15 02:57:03  jblazek
! Inlined index function.
!
! Revision 1.4  2002/09/05 17:40:21  jblazek
! Variable global moved into regions().
!
! Revision 1.3  2002/02/21 23:25:05  jblazek
! Blocks renamed as regions.
!
! Revision 1.2  2002/01/23 03:51:25  jblazek
! Added low-level time-stepping routines.
!
! Revision 1.1  2002/01/08 22:09:17  jblazek
! Added calculation of face vectors and volumes.
!
!******************************************************************************