TURB_coViscousFluxesFlo.F90

Go to the documentation of this file.

! *********************************************************************
! * Rocstar Simulation Suite                                          *
! * Copyright@2015, Illinois Rocstar LLC. All rights reserved.        *
! *                                                                   *
! * Illinois Rocstar LLC                                              *
! * Champaign, IL                                                     *
! * www.illinoisrocstar.com                                           *
! * sales@illinoisrocstar.com                                         *
! *                                                                   *
! * License: See LICENSE file in top level of distribution package or *
! * http://opensource.org/licenses/NCSA                               *
! *********************************************************************
! *********************************************************************
! * THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND,   *
! * EXPRESS OR IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES   *
! * OF MERCHANTABILITY, FITNESS FOR A PARTICULAR PURPOSE AND          *
! * NONINFRINGEMENT.  IN NO EVENT SHALL THE CONTRIBUTORS OR           *
! * COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER       *
! * LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE,   *
! * Arising FROM, OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE    *
! * USE OR OTHER DEALINGS WITH THE SOFTWARE.                          *
! *********************************************************************
!******************************************************************************
!
! Purpose: Compute total viscous fluxes and add them to dissipation.
!
! Description: total viscous flux is superposition of laminar and turbulent:
!              fv_total = sigma_ij + tau_ij
!                       = mu_l.S_ij + tau_ij
!              for eddy viscosity type turbulence model:
!              fv_total = (mu_l+mu_t).S_ij, otherwise
!              fv_total = mu_l.S_ij + m_ij, where m_ij is a model for tau_ij
!
! Input: region = data of current region.
!
! Output: mixt%diss = total viscous fluxes + num. dissipation
!
! Notes: This routine is similar to routine ViscousFluxes for laminar flow.
!
!******************************************************************************
!
! $Id: TURB_coViscousFluxesFlo.F90,v 1.11 2008/12/06 08:44:43 mtcampbe Exp $
!
! Copyright: (c) 2001 by the University of Illinois
!
!******************************************************************************

SUBROUTINE turb_coviscousfluxes( region ) ! PUBLIC

  USE moddatatypes
  USE modbndpatch, ONLY   : t_patch
  USE moddatastruct, ONLY : t_region
  USE modturbulence, ONLY : t_turb
  USE modglobal, ONLY     : t_global
  USE modinterfaces, ONLY : rflo_getdimensdummy, rflo_getdimensdummynodes, &
                            rflo_getcelloffset, rflo_getnodeoffset, &
                            rflo_calcgradvector
  USE modinterfaces, ONLY : rflo_viscousflux
  USE turb_modinterfaces, ONLY : turb_calcstrainrate, turb_getmodelstresscell, &
                                 turb_gettvcell,      turb_lesfluxfixsmag, &
                                 turb_lesfluxscalsim, turb_lesgeteddyvis, &
                                 turb_ranssavisflux,  turb_ranssageteddyvis, &
                                 turb_ranstotaltv,    turb_visfluxeddy, & 
                                 turb_flofacevolume,  turb_flofacewidth, &
                                 turb_flolesgencocc,  turb_flolesgencoff, &
                                 turb_flowlmmetric
  USE moderror
  USE modparameters
  USE turb_modparameters
  IMPLICIT NONE

#include "Indexing.h"

! ... parameters
  TYPE(t_region), TARGET :: region

! ... local variables
  CHARACTER(CHRLEN)       :: rcsidentstring
  TYPE(t_global), POINTER :: global
  TYPE(t_turb), POINTER   :: turb
  
  INTEGER :: ilev, turbmodel, modelclass
  INTEGER :: idcbeg, idcend, jdcbeg, jdcend, kdcbeg, kdcend
  INTEGER :: idnbeg, idnend, jdnbeg, jdnend, kdnbeg, kdnend, errorflag
  INTEGER :: icoff, ijcoff,inoff, ijnoff, ibc, iec, ibn, ien, gradindx(9)

  REAL(RFREAL), POINTER :: gradi(:,:), gradj(:,:),  gradk(:,:)
 
!******************************************************************************

  rcsidentstring = '$RCSfile: TURB_coViscousFluxesFlo.F90,v $'

  global => region%global
  CALL registerfunction( global,'TURB_CoViscousFluxes',&
  'TURB_coViscousFluxesFlo.F90' )

! get node dimensions ------------------------------------------------------

  ilev      =  region%currLevel
  CALL rflo_getdimensdummy( region,ilev,idcbeg,idcend, &
                            jdcbeg,jdcend,kdcbeg,kdcend )
  CALL rflo_getcelloffset( region,ilev,icoff,ijcoff )
  ibc = indijk(idcbeg,jdcbeg,kdcbeg,icoff,ijcoff)
  iec = indijk(idcend,jdcend,kdcend,icoff,ijcoff)

  CALL rflo_getdimensdummynodes( region,ilev,idnbeg,idnend, &
                                 jdnbeg,jdnend,kdnbeg,kdnend )
  CALL rflo_getnodeoffset( region,ilev,inoff,ijnoff )
  ibn = indijk(idnbeg,jdnbeg,kdnbeg,inoff,ijnoff)
  ien = indijk(idnend,jdnend,kdnend,inoff,ijnoff)

! get pointers and parameters
 
  turbmodel =  region%mixtInput%turbModel
  modelclass=  region%turbInput%modelClass
  turb      => region%levels(ilev)%turb

! get mixture strain rate tensor and store in mISij, mJSij and mKSij

  gradi  => region%levels(ilev)%mixt%gradi
  gradj  => region%levels(ilev)%mixt%gradj
  gradk  => region%levels(ilev)%mixt%gradk

  gradindx(1) = gr_mixt_ux
  gradindx(2) = gr_mixt_vx
  gradindx(3) = gr_mixt_wx
  gradindx(4) = gr_mixt_uy
  gradindx(5) = gr_mixt_vy
  gradindx(6) = gr_mixt_wy
  gradindx(7) = gr_mixt_uz
  gradindx(8) = gr_mixt_vz
  gradindx(9) = gr_mixt_wz

  ALLOCATE( turb%mISij(tensor_symm_nelm,ibn:ien),stat=errorflag )
  ALLOCATE( turb%mJSij(tensor_symm_nelm,ibn:ien),stat=errorflag )
  ALLOCATE( turb%mKSij(tensor_symm_nelm,ibn:ien),stat=errorflag )
  global%error = errorflag
  IF (global%error /= 0) CALL errorstop( global,err_allocate,__line__ )

  CALL turb_calcstrainrate( region,ibn,ien,gradindx,gradi,gradj,gradk, &
                            turb%mISij,turb%mJSij,turb%mKSij )

! get new non-uniform filter and averaging coefficients if the grid move

  IF (region%mixtInput%moveGrid) THEN
    IF (region%irkStep == 1) THEN
      CALL turb_lesmovegrid
    ENDIF
  ENDIF

! allocate and initiate LES arrays required within this scope

  IF (modelclass == model_les) THEN
    ALLOCATE( turb%mueT(diri:dirk,ibn:ien),stat=errorflag )
    ALLOCATE( turb%trace(ibn:ien),stat=errorflag )
    global%error = errorflag
    IF (global%error /= 0) CALL errorstop( global,err_allocate,__line__ )

    turb%mueT    = 0._rfreal
    turb%trace   = 0._rfreal
    turb%dv      = 0._rfreal
  ENDIF

! get total viscous flux based on selected turbulence model

  IF (turbmodel==turb_model_fixsmag) THEN
    CALL turb_lesfluxfixsmag( region,ibn,ien )

  ELSEIF ((turbmodel==turb_model_dynsmag) .OR. &
          (turbmodel==turb_model_dynmixd)) THEN

! - allocate arrays for strain rate of filtered velocities in LesGetEddyVis
    ALLOCATE( turb%fISij(tensor_symm_nelm,ibn:ien),stat=errorflag )
    ALLOCATE( turb%fJSij(tensor_symm_nelm,ibn:ien),stat=errorflag )
    ALLOCATE( turb%fKSij(tensor_symm_nelm,ibn:ien),stat=errorflag )
    global%error = errorflag
    IF (global%error /= 0) CALL errorstop( global,err_allocate,__line__ )

! - get eddy viscosity of dynamic Smagorinsky and dynamic Mixed models 
    CALL turb_lesgeteddyvis( region,ibc,iec,ibn,ien )

! - get viscous fluxes
    IF (turbmodel==turb_model_dynsmag) THEN
      CALL turb_visfluxeddy( region )
    ELSEIF (turbmodel==turb_model_dynmixd) THEN
      CALL turb_vfluxhybrid( region )
    ENDIF

! - deallocate retired arrays
    DEALLOCATE( turb%fISij,turb%fJSij,turb%fKSij )

  ELSEIF (turbmodel==turb_model_scalsim) THEN
    CALL turb_lesfluxscalsim( region,ibn,ien )

  ELSEIF ((turbmodel==turb_model_sa).OR. &
          (turbmodel==turb_model_dessa).OR. &
          (turbmodel==turb_model_hdessa)) THEN

! - viscous fluxes of SA equation
    CALL turb_ranssavisflux( region )

! - allocate total tv for NS viscous fluxes
    ALLOCATE( turb%tv(tvt_rans_nelm,ibc:iec),stat=errorflag )
    global%error = errorflag
    IF (global%error /= 0) CALL errorstop( global,err_allocate,__line__ )

! - compute total RaNS tv and use it to obtain NS viscous fluxes 
    CALL turb_ranstotaltv( region,tvt_rans_mue,tvt_rans_tco,turb%tv )
    CALL rflo_viscousflux( region,tvt_rans_mue,tvt_rans_tco,turb%tv )

! - deallocate retired arrays
    DEALLOCATE( turb%tv )

  ENDIF

! finalize viscous flux treatment
! if desired, interpolate model stresses to cell centers for statistics

  IF (region%turbInput%nSv > 0) CALL turb_getmodelstresscell( region )
  DEALLOCATE( turb%mISij,turb%mJSij,turb%mKSij )

  IF (modelclass == model_les) THEN
! - interpolate transport variables at cell centers
    CALL turb_gettvcell( region )

! - deallocate LES arrays
    DEALLOCATE( turb%mueT,turb%trace )
  ENDIF

! finalize --------------------------------------------------------------------

  CALL deregisterfunction( global )

! =============================================================================
!   Calls to filtering and averaging coefficients routines
! =============================================================================

CONTAINS

  SUBROUTINE turb_lesmovegrid

! - local variables
    TYPE(t_patch), POINTER :: patch
    INTEGER :: ipatch
    LOGICAL :: dowlm

! - compute face volumes needed for lesMij and lesCalcEddyVis
    IF ((turbmodel==turb_model_fixsmag) .OR. &
        (turbmodel==turb_model_dynsmag) .OR. &
        (turbmodel==turb_model_dynmixd)) THEN
      CALL turb_flofacevolume( region,diri )
      CALL turb_flofacevolume( region,dirj )
      CALL turb_flofacevolume( region,dirk )
    ENDIF

! - compute filter coefficients
    IF (((turbmodel==turb_model_scalsim)  .OR. &
         (turbmodel==turb_model_dynsmag)  .OR. &
         (turbmodel==turb_model_dynmixd)) .AND. &
         (region%turbInput%filterType == filtype_nonunif)) THEN

      ALLOCATE( turb%workI(2,ibn:ien),stat=errorflag )
      ALLOCATE( turb%workJ(2,ibn:ien),stat=errorflag )
      ALLOCATE( turb%workK(2,ibn:ien),stat=errorflag )
      global%error = errorflag
      IF (global%error /= 0) CALL errorstop( global,err_allocate,__line__ )

      CALL turb_flofacewidth( region )
      CALL turb_flolesgencocc( region )
      CALL turb_flolesgencoff( region )
      DEALLOCATE( turb%workI,turb%workJ,turb%workK )
    ENDIF

! - if wlm is active, recompute mapping coefficients

    DO ipatch=1,region%nPatches
      patch  => region%levels(ilev)%patches(ipatch)

      dowlm = .false.
      IF (patch%bcType>=bc_noslipwall .AND. &
          patch%bcType<=bc_noslipwall+bc_range) THEN ! my boundary type
        IF (patch%valBola%switches(wlm_input_model) /= wlm_model_nomodel) THEN
          dowlm = .true.
        ENDIF
      ENDIF

      IF (dowlm) THEN
! ----- compute mapping coeffs. from body fitted to cartesian and wlm-metric
        CALL turb_flowlmmetric( region,patch )
      ENDIF    ! doWlm
    ENDDO      ! iPatch

  END SUBROUTINE turb_lesmovegrid

END SUBROUTINE turb_coviscousfluxes

!******************************************************************************
!
! RCS Revision history:
!
! $Log: TURB_coViscousFluxesFlo.F90,v $
! Revision 1.11  2008/12/06 08:44:43  mtcampbe
! Updated license.
!
! Revision 1.10  2008/11/19 22:17:55  mtcampbe
! Added Illinois Open Source License/Copyright
!
! Revision 1.9  2005/03/07 05:03:51  wasistho
! install hybrid DESSA turbulence model
!
! Revision 1.8  2004/08/04 02:47:30  wasistho
! removed turb%avgCoI,J,K as it is defined as grid%c2fCoI,J,K
!
! Revision 1.7  2004/08/02 23:09:21  wasistho
! mv libfloflu/viscousFluxEddy(Patch) to rocflo/RFLO_viscousFlux(Patch)
!
! Revision 1.6  2004/06/03 02:10:39  wasistho
! enabled non-uniform fix-Smagorinsky
!
! Revision 1.5  2004/05/17 20:33:04  wasistho
! reordering gradIndx for more efficient cache memory addressing
!
! Revision 1.4  2004/03/19 02:54:58  wasistho
! prepared for RFLU
!
! Revision 1.3  2004/03/13 03:12:50  wasistho
! get rid of flo/flu identifier in TURB_Co.. routines
!
! Revision 1.2  2004/03/12 02:55:35  wasistho
! changed rocturb routine names
!
! Revision 1.1  2004/03/08 23:33:31  wasistho
! changed turb nomenclature
!
! Revision 1.14  2004/02/26 21:25:07  wasistho
! delete esg1Sum
!
! Revision 1.13  2004/01/23 00:26:44  wasistho
! insert condition istage=1 for calling TURB_LesMoveGrid
!
! Revision 1.12  2004/01/22 03:53:27  wasistho
! move TURB_ransSAGetEddyVis from TURB_viscousFluxes to TURB_ransClearSendRequests
!
! Revision 1.11  2003/10/09 23:07:50  wasistho
! renamed CalcEddyVis to LesCalcEddyVis
!
! Revision 1.10  2003/10/07 02:08:02  wasistho
! initial installation of RaNS-SA and DES
!
! Revision 1.9  2003/09/12 20:08:03  wasistho
!  == should be /= in TURB_LesMoveGrid
!
! Revision 1.8  2003/08/29 01:42:36  wasistho
! Added TARGET attribute to region variable, since pointers are cached into it
!
! Revision 1.7  2003/05/31 01:48:23  wasistho
! installed turb. wall layer model
!
! Revision 1.6  2003/05/24 02:05:36  wasistho
! turbulence statistics expanded
!
! Revision 1.5  2003/05/16 05:43:05  wasistho
! modified array range of CC-filtered
!
! Revision 1.4  2003/05/15 02:57:06  jblazek
! Inlined index function.
!
! Revision 1.3  2002/10/16 07:47:58  wasistho
! Enable Fix Smagorinsky
!
! Revision 1.2  2002/10/16 02:01:28  wasistho
! Changed global%error flag
!
! Revision 1.1  2002/10/14 23:55:30  wasistho
! Install Rocturb
!
!
!******************************************************************************