TURB_floFaceVolume.F90

Go to the documentation of this file.

! *********************************************************************
! * Rocstar Simulation Suite                                          *
! * Copyright@2015, Illinois Rocstar LLC. All rights reserved.        *
! *                                                                   *
! * Illinois Rocstar LLC                                              *
! * Champaign, IL                                                     *
! * www.illinoisrocstar.com                                           *
! * sales@illinoisrocstar.com                                         *
! *                                                                   *
! * License: See LICENSE file in top level of distribution package or *
! * http://opensource.org/licenses/NCSA                               *
! *********************************************************************
! *********************************************************************
! * THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND,   *
! * EXPRESS OR IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES   *
! * OF MERCHANTABILITY, FITNESS FOR A PARTICULAR PURPOSE AND          *
! * NONINFRINGEMENT.  IN NO EVENT SHALL THE CONTRIBUTORS OR           *
! * COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER       *
! * LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE,   *
! * Arising FROM, OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE    *
! * USE OR OTHER DEALINGS WITH THE SOFTWARE.                          *
! *********************************************************************
!******************************************************************************
!
! Purpose: Define face volume.
!
! Description: The face volume is obtained by averaging the two adjacent cell 
!              volumes then extrapolated to outerst faces.
!
! Input: region  = data of current region
!        ijk     = ijk-face is being treated
!
! Output: Face volume defined at all nodes.
!
! Notes: Face volume is used in several routines, a.o LesMij & LesCalcEddyVis.
!
!******************************************************************************
!
! $Id: TURB_floFaceVolume.F90,v 1.4 2008/12/06 08:44:43 mtcampbe Exp $
!
! Copyright: (c) 2001 by the University of Illinois
!
!******************************************************************************

SUBROUTINE turb_flofacevolume( region,ijk )

  USE moddatatypes
  USE moddatastruct, ONLY : t_region
  USE modglobal, ONLY     : t_global
  USE modinterfaces, ONLY : rflo_getdimensdummynodes, &
                            rflo_getnodeoffset,rflo_getcelloffset
  USE moderror
  USE turb_modparameters
  IMPLICIT NONE

#include "Indexing.h"

! ... parameters
  TYPE(t_region) :: region
  INTEGER        :: ijk

! ... loop variables
  INTEGER :: i, j, k, ijkc0, ijkc1, ijkn, ijkn1

! ... local variables
  CHARACTER(CHRLEN)       :: rcsidentstring
  TYPE(t_global), POINTER :: global

  INTEGER :: ibeg,iend,jbeg,jend,kbeg,kend, iadd,jadd,kadd
  INTEGER :: idnbeg,idnend,jdnbeg,jdnend,kdnbeg,kdnend
  INTEGER :: ilev,inoff,ijnoff,icoff,ijcoff

  REAL(RFREAL), POINTER :: vol(:), fvol(:)

!******************************************************************************

  rcsidentstring = '$RCSfile: TURB_floFaceVolume.F90,v $'

  global => region%global
  CALL registerfunction( global,'TURB_FloFaceVolume',&
  'TURB_floFaceVolume.F90' )

! get indices and pointers --------------------------------------------------

  ilev = region%currLevel
  CALL rflo_getdimensdummynodes( region,ilev,idnbeg,idnend, &
                                 jdnbeg,jdnend,kdnbeg,kdnend )
  CALL rflo_getcelloffset( region,ilev,icoff,ijcoff )
  CALL rflo_getnodeoffset( region,ilev,inoff,ijnoff )
  vol => region%levels(ilev)%grid%vol

  IF (ijk==diri) THEN
    fvol => region%levels(ilev)%turb%fvolI
    ibeg = idnbeg
    iend = idnend
    jbeg = jdnbeg
    jend = jdnend-1
    kbeg = kdnbeg
    kend = kdnend-1
    iadd = -1
    jadd = 0
    kadd = 0
  ELSEIF (ijk==dirj) THEN
    fvol => region%levels(ilev)%turb%fvolJ
    ibeg = idnbeg
    iend = idnend-1
    jbeg = jdnbeg
    jend = jdnend
    kbeg = kdnbeg
    kend = kdnend-1
    iadd = 0
    jadd = -1
    kadd = 0
  ELSEIF (ijk==dirk) THEN
    fvol => region%levels(ilev)%turb%fvolK
    ibeg = idnbeg
    iend = idnend-1
    jbeg = jdnbeg
    jend = jdnend-1
    kbeg = kdnbeg
    kend = kdnend
    iadd = 0
    jadd = 0
    kadd = -1
  ENDIF

! Define face volumes and store in fvol(:)

  DO k=kbeg-kadd,kend+kadd
    DO j=jbeg-jadd,jend+jadd
      DO i=ibeg-iadd,iend+iadd
        ijkc0 = indijk(i     ,j     ,k     ,icoff,ijcoff)
        ijkc1 = ijkc0 + iadd + jadd*icoff + kadd*ijcoff
        ijkn  = indijk(i     ,j     ,k     ,inoff,ijnoff)
        fvol(ijkn) = 0.5_rfreal*(vol(ijkc1)+vol(ijkc0))
      ENDDO
    ENDDO
  ENDDO

  IF (ijk==diri) THEN

! - extrapolation to outerst layers

    DO k=kbeg,kend
      DO j=jbeg,jend
        i = ibeg
        ijkc0 = indijk(i     ,j     ,k     ,icoff,ijcoff)
        ijkn  = indijk(i     ,j     ,k     ,inoff,ijnoff)
        fvol(ijkn) = vol(ijkc0)
        i = iend
        ijkc1 = indijk(i+iadd,j+jadd,k+kadd,icoff,ijcoff)
        ijkn  = indijk(i     ,j     ,k     ,inoff,ijnoff)
        fvol(ijkn) = vol(ijkc1)
      ENDDO
    ENDDO

    DO k=kdnbeg,kdnend
      DO i=idnbeg,idnend
        ijkn  = indijk(i    ,jdnend ,k     ,inoff,ijnoff)
        ijkn1 = ijkn - inoff
        fvol(ijkn) = fvol(ijkn1)
        fvol(ijkn) = fvol(ijkn1)
        fvol(ijkn) = fvol(ijkn1) 
        fvol(ijkn) = fvol(ijkn1)
      ENDDO     ! i
    ENDDO       ! k
    DO j=jdnbeg,jdnend
      DO i=idnbeg,idnend
        ijkn  = indijk(i    ,j    ,kdnend  ,inoff,ijnoff)
        ijkn1 = ijkn - ijnoff
        fvol(ijkn) = fvol(ijkn1)
        fvol(ijkn) = fvol(ijkn1)
        fvol(ijkn) = fvol(ijkn1) 
        fvol(ijkn) = fvol(ijkn1)
      ENDDO     ! i
    ENDDO       ! j

  ELSEIF (ijk==dirj) THEN

! - extrapolation to outerst layers

    DO k=kbeg,kend
      DO i=ibeg,iend
        j = jbeg
        ijkc0 = indijk(i     ,j     ,k     ,icoff,ijcoff)
        ijkn  = indijk(i     ,j     ,k     ,inoff,ijnoff)
        fvol(ijkn) = vol(ijkc0)
        j = jend
        ijkc1 = indijk(i+iadd,j+jadd,k+kadd,icoff,ijcoff)
        ijkn  = indijk(i     ,j     ,k     ,inoff,ijnoff)
        fvol(ijkn) = vol(ijkc1)
      ENDDO
    ENDDO

    DO k=kdnbeg,kdnend
      DO j=jdnbeg,jdnend
        ijkn  = indijk(idnend  ,j     ,k     ,inoff,ijnoff)
        ijkn1 = ijkn - 1
        fvol(ijkn) = fvol(ijkn1)
        fvol(ijkn) = fvol(ijkn1)
        fvol(ijkn) = fvol(ijkn1) 
        fvol(ijkn) = fvol(ijkn1)
      ENDDO     ! j
    ENDDO       ! k
    DO j=jdnbeg,jdnend
      DO i=idnbeg,idnend
        ijkn  = indijk(i    ,j    ,kdnend  ,inoff,ijnoff)
        ijkn1 = ijkn - ijnoff
        fvol(ijkn) = fvol(ijkn1)
        fvol(ijkn) = fvol(ijkn1)
        fvol(ijkn) = fvol(ijkn1) 
        fvol(ijkn) = fvol(ijkn1)
      ENDDO     ! i
    ENDDO       ! j

  ELSEIF (ijk==dirk) THEN

! - extrapolation to outerst layers

    DO j=jbeg,jend
      DO i=ibeg,iend
        k = kbeg
        ijkc0 = indijk(i     ,j     ,k     ,icoff,ijcoff)
        ijkn  = indijk(i     ,j     ,k     ,inoff,ijnoff)
        fvol(ijkn) = vol(ijkc0)
        k = kend
        ijkc1 = indijk(i+iadd,j+jadd,k+kadd,icoff,ijcoff)
        ijkn  = indijk(i     ,j     ,k     ,inoff,ijnoff)
        fvol(ijkn) = vol(ijkc1)
      ENDDO
    ENDDO

    DO k=kdnbeg,kdnend
      DO j=jdnbeg,jdnend
        ijkn  = indijk(idnend  ,j     ,k     ,inoff,ijnoff)
        ijkn1 = ijkn - 1
        fvol(ijkn) = fvol(ijkn1)
        fvol(ijkn) = fvol(ijkn1)
        fvol(ijkn) = fvol(ijkn1) 
        fvol(ijkn) = fvol(ijkn1)
      ENDDO     ! j
    ENDDO       ! k
    DO k=kdnbeg,kdnend
      DO i=idnbeg,idnend
        ijkn  = indijk(i    ,jdnend  ,k     ,inoff,ijnoff)
        ijkn1 = ijkn - inoff
        fvol(ijkn) = fvol(ijkn1)
        fvol(ijkn) = fvol(ijkn1)
        fvol(ijkn) = fvol(ijkn1) 
        fvol(ijkn) = fvol(ijkn1)
      ENDDO     ! i
    ENDDO       ! k

  ENDIF

! finalize --------------------------------------------------------------------

  CALL deregisterfunction( global )

END SUBROUTINE turb_flofacevolume

!******************************************************************************
!
! RCS Revision history:
!
! $Log: TURB_floFaceVolume.F90,v $
! Revision 1.4  2008/12/06 08:44:43  mtcampbe
! Updated license.
!
! Revision 1.3  2008/11/19 22:17:55  mtcampbe
! Added Illinois Open Source License/Copyright
!
! Revision 1.2  2004/03/12 02:55:35  wasistho
! changed rocturb routine names
!
! Revision 1.1  2004/03/08 23:35:45  wasistho
! changed turb nomenclature
!
! Revision 1.3  2003/10/09 23:07:08  wasistho
! renamed CalcEddyVis to LesCalcEddyVis
!
! Revision 1.2  2003/05/15 02:57:06  jblazek
! Inlined index function.
!
! Revision 1.1  2002/10/14 23:55:29  wasistho
! Install Rocturb
!
!
!******************************************************************************