TURB_GetModelStressCell.F90

Go to the documentation of this file.

! *********************************************************************
! * Rocstar Simulation Suite                                          *
! * Copyright@2015, Illinois Rocstar LLC. All rights reserved.        *
! *                                                                   *
! * Illinois Rocstar LLC                                              *
! * Champaign, IL                                                     *
! * www.illinoisrocstar.com                                           *
! * sales@illinoisrocstar.com                                         *
! *                                                                   *
! * License: See LICENSE file in top level of distribution package or *
! * http://opensource.org/licenses/NCSA                               *
! *********************************************************************
! *********************************************************************
! * THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND,   *
! * EXPRESS OR IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES   *
! * OF MERCHANTABILITY, FITNESS FOR A PARTICULAR PURPOSE AND          *
! * NONINFRINGEMENT.  IN NO EVENT SHALL THE CONTRIBUTORS OR           *
! * COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER       *
! * LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE,   *
! * Arising FROM, OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE    *
! * USE OR OTHER DEALINGS WITH THE SOFTWARE.                          *
! *********************************************************************
!******************************************************************************
!
! Purpose: Get subgrid or Reynolds stresses at cell centers.
!
! Description: The cell values are obtained by averaging the face values.
!              The result are stored in turb%sv at cells, including dummmies.
!
! Input: region = data of current region
!
! Output: turb%sv(E11:E33,:) at cell centers incl. dummies.
!
! Notes: Dummy stress obtained by extrapolation as dummy mut not computed.
!
!******************************************************************************
!
! $Id: TURB_GetModelStressCell.F90,v 1.8 2008/12/06 08:44:41 mtcampbe Exp $
!
! Copyright: (c) 2001 by the University of Illinois
!
!******************************************************************************

SUBROUTINE turb_getmodelstresscell( region )

  USE moddatatypes
  USE moddatastruct, ONLY : t_region
  USE modglobal, ONLY     : t_global
#ifdef RFLO
  USE modinterfaces, ONLY : rflo_getdimensphys, rflo_getdimensdummy, &
                            rflo_getcelloffset, rflo_getnodeoffset

#include "Indexing.h"
#endif
  USE moderror
  USE modparameters
  USE turb_modparameters
  IMPLICIT NONE

! ... parameters
  TYPE(t_region) :: region

! ... loop variables
  INTEGER :: i, j, k, l, ic, in, ipatch

! ... local variables
  CHARACTER(CHRLEN)       :: rcsidentstring
  TYPE(t_global), POINTER :: global

  REAL(RFREAL), POINTER :: muet(:,:),siij(:,:), sjij(:,:), skij(:,:), sv(:,:)
#ifdef RFLO
  INTEGER :: ipcbeg, ipcend, jpcbeg, jpcend, kpcbeg, kpcend
  INTEGER :: idcbeg, idcend, jdcbeg, jdcend, kdcbeg, kdcend
  INTEGER :: ilev,icoff,ijcoff,inoff,ijnoff,ijkc,ijkci,ijkn,ijkni,ijknj,ijknk
  REAL(RFREAL) :: one6th
#endif
#ifdef RFLU
  INTEGER :: ic0, ic1, ict, icl, ifg, ifgbeg, nfacespercell
  INTEGER, POINTER      :: c2f(:,:,:)
  REAL(RFREAL), POINTER :: bmuet(:,:), bsiij(:,:)
#endif

!******************************************************************************

  rcsidentstring = '$RCSfile: TURB_GetModelStressCell.F90,v $'

  global => region%global
  CALL registerfunction( global,'Turb_GetModelStressCell',&
  'TURB_GetModelStressCell.F90' )

! get parameters -------------------------------------------------------------

#ifdef RFLO
  one6th = 1._rfreal/6._rfreal
  ilev   = region%currLevel

! get dimensions and pointers

  CALL rflo_getdimensphys( region,ilev,ipcbeg,ipcend, &
                           jpcbeg,jpcend,kpcbeg,kpcend )
  CALL rflo_getdimensdummy( region,ilev,idcbeg,idcend, &
                            jdcbeg,jdcend,kdcbeg,kdcend )
  CALL rflo_getcelloffset( region,ilev,icoff,ijcoff )
  CALL rflo_getnodeoffset( region,ilev,inoff,ijnoff )

  muet => region%levels(ilev)%turb%mueT
  siij => region%levels(ilev)%turb%mISij
  sjij => region%levels(ilev)%turb%mJSij
  skij => region%levels(ilev)%turb%mKSij
  sv   => region%levels(ilev)%turb%sv

! perform averaging of stress tensor

  DO k=kpcbeg,kpcend
    DO j=jpcbeg,jpcend
      DO i=ipcbeg,ipcend

        ijkc  = indijk(i     ,j     ,k     ,icoff,ijcoff)
        ijkn  = indijk(i     ,j     ,k     ,inoff,ijnoff)
        ijkni = ijkn + 1
        ijknj = ijkn + inoff
        ijknk = ijkn + ijnoff

        DO l = e11, e33
          sv(l,ijkc) = &
          muet(diri,ijkn)*siij(l,ijkn)+muet(diri,ijkni)*siij(l,ijkni)+ &
          muet(dirj,ijkn)*sjij(l,ijkn)+muet(dirj,ijknj)*siij(l,ijknj)+ &
          muet(dirk,ijkn)*skij(l,ijkn)+muet(dirk,ijknk)*siij(l,ijknk)
          sv(l,ijkc) = one6th*sv(l,ijkc)
        ENDDO ! l
      ENDDO   ! i
    ENDDO     ! j
  ENDDO       ! k
#endif

#ifdef RFLU
  muet  => region%turb%mueT
  bmuet => region%turb%bMueT
  siij  => region%turb%mISij
  bsiij => region%turb%bmISij
  sv    => region%turb%sv
  sv(:,:) = 0._rfreal

! compute stress tensor at faces then average it from faces to cells 
! waiting for Andreas` routine for proper averaging

  DO in = 1,region%grid%nFaces
    ic0 = region%grid%f2c(1,in)
    ic1 = region%grid%f2c(2,in)
    DO l = e11, e33
      sv(l,ic0) = sv(l,ic0) + muet(diri,in)*siij(l,in)
      sv(l,ic1) = sv(l,ic1) + muet(diri,in)*siij(l,in)
    ENDDO  ! l
  ENDDO    ! iN

  DO ipatch = 1,region%grid%nPatches
! TEMPORARY : removing usage of bf2bg from everywhere
!    ifgBeg = region%patches(iPatch)%bf2bg(BF2BG_BEG)
    DO in = 1,region%patches(ipatch)%nBFaces
      ic0 = region%patches(ipatch)%bf2c(in)
      ifg = in + ifgbeg-1
      DO l = e11, e33
        sv(l,ic0) = sv(l,ic0) + bmuet(diri,ifg)*bsiij(l,ifg)
      ENDDO  ! l
    ENDDO    ! iN
  ENDDO      ! iPatch

  DO ic = 1,region%grid%nCells
    ict = region%grid%cellGlob2Loc(1,ic) ! cell type
    icl = region%grid%cellGlob2Loc(2,ic) ! local (type) cell index
    SELECT CASE ( ict ) 
      CASE ( cell_type_tet ) 
        nfacespercell = 4
        c2f => region%grid%tet2f              
      CASE ( cell_type_hex ) 
        nfacespercell = 6
        c2f => region%grid%hex2f              
      CASE ( cell_type_pri ) 
        nfacespercell = 5    
        c2f => region%grid%pri2f                         
      CASE ( cell_type_pyr ) 
        nfacespercell = 5
        c2f => region%grid%pyr2f                
      CASE default  
        CALL errorstop(global,err_reached_default,__line__)
    END SELECT ! ict

    DO l = e11, e33
      sv(l,ic) = sv(l,ic)/nfacespercell
    ENDDO  ! l
  ENDDO    ! iC

#endif

! linear extrapolate to the six sides of region

#ifdef RFLO
  DO k=kdcbeg,kdcend
    DO j=jdcbeg,jdcend

      ijkn  = indijk(ipcbeg   ,j    ,k     ,inoff,ijnoff)
      DO i=idcbeg,ipcbeg-1
        ijkc  = indijk(i            ,j     ,k     ,icoff,ijcoff)
        ijkci = indijk(2*ipcbeg-i-1 ,j     ,k     ,icoff,ijcoff)

        DO l = e11, e33
          sv(l,ijkc) = 2._rfreal*muet(diri,ijkn)*siij(l,ijkn) - &
                                 sv(l,ijkci)
        ENDDO       
      ENDDO  
      ijkn  = indijk(ipcend+1  ,j    ,k     ,inoff,ijnoff)
      DO i=ipcend+1,idcend
        ijkc  = indijk(i            ,j     ,k     ,icoff,ijcoff)
        ijkci = indijk(2*ipcend-i+1 ,j     ,k     ,icoff,ijcoff)

        DO l = e11, e33
          sv(l,ijkc) = 2._rfreal*muet(diri,ijkn)*siij(l,ijkn) - &
                                 sv(l,ijkci)
        ENDDO       
      ENDDO   ! i
    ENDDO     ! j
  ENDDO       ! k
  DO k=kdcbeg,kdcend
    DO i=idcbeg,idcend

      ijkn  = indijk(i    ,jpcbeg   ,k    ,inoff,ijnoff)
      DO j=jdcbeg,jpcbeg-1
        ijkc  = indijk(i     ,j     ,k     ,icoff,ijcoff)
        ijkci = indijk(i     ,2*jpcbeg-j-1 ,k     ,icoff,ijcoff)

        DO l = e11, e33
          sv(l,ijkc) = 2._rfreal*muet(dirj,ijkn)*sjij(l,ijkn) - &
                                 sv(l,ijkci)
        ENDDO       
      ENDDO  
      ijkn  = indijk(i    ,jpcend+1 ,k    ,inoff,ijnoff)
      DO j=jpcend+1,jdcend
        ijkc  = indijk(i     ,j     ,k     ,icoff,ijcoff)
        ijkci = indijk(i     ,2*jpcend-j+1 ,k     ,icoff,ijcoff)

        DO l = e11, e33
          sv(l,ijkc) = 2._rfreal*muet(dirj,ijkn)*sjij(l,ijkn) - &
                                 sv(l,ijkci)
        ENDDO       
      ENDDO   ! j
    ENDDO     ! i
  ENDDO       ! k
  DO j=jdcbeg,jdcend
    DO i=idcbeg,idcend

      ijkn  = indijk(i    ,j     ,kpcbeg ,inoff,ijnoff)
      DO k=kdcbeg,kpcbeg-1
        ijkc  = indijk(i     ,j     ,k     ,icoff,ijcoff)
        ijkci = indijk(i     ,j     ,2*kpcbeg-k-1 ,icoff,ijcoff)

        DO l = e11, e33
          sv(l,ijkc) = 2._rfreal*muet(dirk,ijkn)*skij(l,ijkn) - &
                                 sv(l,ijkci)
        ENDDO       
      ENDDO  
      ijkn  = indijk(i    ,j    ,kpcend+1 ,inoff,ijnoff)
      DO k=kpcend+1,kdcend
        ijkc  = indijk(i     ,j     ,k     ,icoff,ijcoff)
        ijkci = indijk(i     ,j     ,2*kpcend-k+1 ,icoff,ijcoff)

        DO l = e11, e33
          sv(l,ijkc) = 2._rfreal*muet(dirk,ijkn)*skij(l,ijkn) - &
                                 sv(l,ijkci)
        ENDDO       
      ENDDO   ! k
    ENDDO     ! i
  ENDDO       ! j
#endif

! finalize --------------------------------------------------------------------

  CALL deregisterfunction( global )

END SUBROUTINE turb_getmodelstresscell

!******************************************************************************
!
! RCS Revision history:
! 
! $Log: TURB_GetModelStressCell.F90,v $
! Revision 1.8  2008/12/06 08:44:41  mtcampbe
! Updated license.
!
! Revision 1.7  2008/11/19 22:17:53  mtcampbe
! Added Illinois Open Source License/Copyright
!
! Revision 1.6  2006/08/19 15:40:55  mparmar
! Removed bf2bg
!
! Revision 1.5  2005/12/29 19:53:05  wasistho
! modified face indexing in f2c averaging
!
! Revision 1.4  2005/01/12 01:12:53  wasistho
! removed single quote signs since SUN has trouble with it
!
! Revision 1.3  2004/03/27 02:16:42  wasistho
! compiled with Rocflu
!
! Revision 1.2  2004/03/19 02:46:48  wasistho
! prepared for RFLU
!
! Revision 1.1  2004/03/05 04:37:00  wasistho
! changed nomenclature
!
! Revision 1.1  2003/05/24 02:30:28  wasistho
! turbulence statistics expanded
!
!
!******************************************************************************