RFLO_GetDimensions.F90

Go to the documentation of this file.

! *********************************************************************
! * Rocstar Simulation Suite                                          *
! * Copyright@2015, Illinois Rocstar LLC. All rights reserved.        *
! *                                                                   *
! * Illinois Rocstar LLC                                              *
! * Champaign, IL                                                     *
! * www.illinoisrocstar.com                                           *
! * sales@illinoisrocstar.com                                         *
! *                                                                   *
! * License: See LICENSE file in top level of distribution package or *
! * http://opensource.org/licenses/NCSA                               *
! *********************************************************************
! *********************************************************************
! * THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND,   *
! * EXPRESS OR IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES   *
! * OF MERCHANTABILITY, FITNESS FOR A PARTICULAR PURPOSE AND          *
! * NONINFRINGEMENT.  IN NO EVENT SHALL THE CONTRIBUTORS OR           *
! * COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER       *
! * LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE,   *
! * Arising FROM, OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE    *
! * USE OR OTHER DEALINGS WITH THE SOFTWARE.                          *
! *********************************************************************
!******************************************************************************
!
! Purpose: calculate dimensions of the computational domain
!          (start & end index).
!
! Description: file contains the following subroutines:
!
!  - GetDimensDummy        = including dummy cells
!  - GetDimensPhys         = cells within physical domain only
!  - GetDimensDummyNodes   = including dummy nodes
!  - GetDimensPhysNodes    = grid nodes within physical domain only
!  - GetCellOffset         = total # of cells in i-direction and for combination
!                            of i- and j-direction (incl. dummy cells)
!  - GetNodeOffset         = total # of nodes in i-direction and for combination
!                            of i- and j-direction (incl. dummy nodes)
!  - GetEdgeCellsIndices   = dimensions of a "block" of edge cells
!  - GetCornerCellsIndices = dimensions of a "block" of corner cells
!
! Input: region  = current region
!        iLev    = current grid level for region
!        iedge   = edge of a hexahedron (number between 1 and 12)
!        icorner = corner of a hexahedron (number between 1 and 8)
!
! Output: idcbeg, ..., kdcend = dimensions including dummy cells
!         ipcbeg, ..., kpcend = dimensions including physical cells only
!         idnbeg, ..., kdnend = dimensions including dummy nodes
!         ipnbeg, ..., kpnend = dimensions including physical nodes only
!         iebeg, ..., keend   = start & end indices of edge cells
!         icbeg, ..., kcend   = start & end indices of corner cells
!         iCellOffset         = total number of cells in i-direction
!         ijCellOffset        = total number of cells in i*j-direction
!         iNodeOffset         = total number of nodes in i-direction
!         ijNodeOffset        = total number of nodes in i*j-direction
!
! Notes: none.
!
!******************************************************************************
!
! $Id: RFLO_GetDimensions.F90,v 1.3 2008/12/06 08:44:06 mtcampbe Exp $
!
! Copyright: (c) 2001 by the University of Illinois
!
!******************************************************************************

SUBROUTINE rflo_getdimensdummy( region,iLev,idcbeg,idcend,jdcbeg,jdcend, &
                                kdcbeg,kdcend )

  USE moddatastruct, ONLY : t_region
  USE moddatatypes
  USE moderror
  IMPLICIT NONE

! ... parameters
  INTEGER        :: ilev, idcbeg, idcend, jdcbeg, jdcend, kdcbeg, kdcend
  TYPE(t_region) :: region

! ... local variables
  CHARACTER(CHRLEN) :: msg

!******************************************************************************

  CALL registerfunction( region%global,'RFLO_GetDimensDummy',&
  'RFLO_GetDimensions.F90' )

  IF (ilev<1 .OR. ilev>region%nGridLevels) THEN
    WRITE(msg,1000) ilev,region%nGridLevels
    CALL errorstop( region%global,err_grid_level,&
    __line__,msg )
  ENDIF

  idcbeg = 1                            - region%nDumCells
  idcend = region%levels(ilev)%grid%ipc + region%nDumCells
  jdcbeg = 1                            - region%nDumCells
  jdcend = region%levels(ilev)%grid%jpc + region%nDumCells
  kdcbeg = 1                            - region%nDumCells
  kdcend = region%levels(ilev)%grid%kpc + region%nDumCells

  CALL deregisterfunction( region%global )

1000 FORMAT('Grid level= ',i2,' but should be 1-',i1,'.')

END SUBROUTINE rflo_getdimensdummy

! #############################################################################
! #############################################################################

SUBROUTINE rflo_getdimensphys( region,iLev,ipcbeg,ipcend,jpcbeg,jpcend, &
                               kpcbeg,kpcend )

  USE moddatastruct, ONLY : t_region
  USE moddatatypes
  USE moderror
  IMPLICIT NONE

! ... parameters
  INTEGER        :: ilev, ipcbeg, ipcend, jpcbeg, jpcend, kpcbeg, kpcend
  TYPE(t_region) :: region

! ... local variables
  CHARACTER(CHRLEN) :: msg

!******************************************************************************

  CALL registerfunction( region%global,'RFLO_GetDimensPhys',&
  'RFLO_GetDimensions.F90' )

  IF (ilev<1 .OR. ilev>region%nGridLevels) THEN
    WRITE(msg,1000) ilev,region%nGridLevels
    CALL errorstop( region%global,err_grid_level,&
    __line__,msg )
  ENDIF

  ipcbeg = 1
  ipcend = region%levels(ilev)%grid%ipc
  jpcbeg = 1
  jpcend = region%levels(ilev)%grid%jpc
  kpcbeg = 1
  kpcend = region%levels(ilev)%grid%kpc

  CALL deregisterfunction( region%global )

1000 FORMAT('Grid level= ',i2,' but should be 1-',i1,'.')

END SUBROUTINE rflo_getdimensphys

! #############################################################################
! #############################################################################

SUBROUTINE rflo_getdimensdummynodes( region,iLev,idnbeg,idnend,jdnbeg,jdnend, &
                                     kdnbeg,kdnend )

  USE moddatastruct, ONLY : t_region
  USE moddatatypes
  USE moderror
  IMPLICIT NONE

! ... parameters
  INTEGER        :: ilev, idnbeg, idnend, jdnbeg, jdnend, kdnbeg, kdnend
  TYPE(t_region) :: region

! ... local variables
  CHARACTER(CHRLEN) :: msg

!******************************************************************************

  CALL registerfunction( region%global,'RFLO_GetDimensDummyNodes',&
  'RFLO_GetDimensions.F90' )

  IF (ilev<1 .OR. ilev>region%nGridLevels) THEN
    WRITE(msg,1000) ilev,region%nGridLevels
    CALL errorstop( region%global,err_grid_level,&
    __line__,msg )
  ENDIF

  idnbeg = 1 - region%nDumCells
  idnend = 1 + region%nDumCells + region%levels(ilev)%grid%ipc
  jdnbeg = 1 - region%nDumCells
  jdnend = 1 + region%nDumCells + region%levels(ilev)%grid%jpc
  kdnbeg = 1 - region%nDumCells
  kdnend = 1 + region%nDumCells + region%levels(ilev)%grid%kpc

  CALL deregisterfunction( region%global )

1000 FORMAT('Grid level= ',i2,' but should be 1-',i1,'.')

END SUBROUTINE rflo_getdimensdummynodes

! #############################################################################
! #############################################################################

SUBROUTINE rflo_getdimensphysnodes( region,iLev,ipnbeg,ipnend,jpnbeg,jpnend, &
                                    kpnbeg,kpnend )

  USE moddatastruct, ONLY : t_region
  USE moddatatypes
  USE moderror
  IMPLICIT NONE

! ... parameters
  INTEGER        :: ilev, ipnbeg, ipnend, jpnbeg, jpnend, kpnbeg, kpnend
  TYPE(t_region) :: region

! ... local variables
  CHARACTER(CHRLEN) :: msg

!******************************************************************************

  CALL registerfunction( region%global,'RFLO_GetDimensPhysNodes',&
  'RFLO_GetDimensions.F90' )

  IF (ilev<1 .OR. ilev>region%nGridLevels) THEN
    WRITE(msg,1000) ilev,region%nGridLevels
    CALL errorstop( region%global,err_grid_level,&
    __line__,msg )
  ENDIF

  ipnbeg = 1
  ipnend = region%levels(ilev)%grid%ipc + 1
  jpnbeg = 1
  jpnend = region%levels(ilev)%grid%jpc + 1
  kpnbeg = 1
  kpnend = region%levels(ilev)%grid%kpc + 1

  CALL deregisterfunction( region%global )

1000 FORMAT('Grid level= ',i2,' but should be 1-',i1,'.')

END SUBROUTINE rflo_getdimensphysnodes

! #############################################################################
! #############################################################################

SUBROUTINE rflo_getcelloffset( region,iLev,iCellOffset,ijCellOffset )

  USE moderror
  USE moddatastruct, ONLY : t_region
  USE modinterfaces, ONLY : rflo_getdimensdummy
  IMPLICIT NONE

! ... parameters
  INTEGER        :: ilev, icelloffset, ijcelloffset
  TYPE(t_region) :: region

! ... local variables
  INTEGER :: idcbeg, idcend, jdcbeg, jdcend, kdcbeg, kdcend

!******************************************************************************

  CALL registerfunction( region%global,'RFLO_GetCellOffset',&
  'RFLO_GetDimensions.F90' )

  CALL rflo_getdimensdummy( region,ilev,idcbeg,idcend, &
                            jdcbeg,jdcend,kdcbeg,kdcend )

  icelloffset  = idcend - idcbeg + 1
  ijcelloffset = icelloffset*(jdcend-jdcbeg+1)

  CALL deregisterfunction( region%global )

END SUBROUTINE rflo_getcelloffset

! #############################################################################
! #############################################################################

SUBROUTINE rflo_getnodeoffset( region,iLev,iNodeOffset,ijNodeOffset )

  USE moderror
  USE moddatastruct, ONLY : t_region
  USE modinterfaces, ONLY : rflo_getdimensdummynodes
  IMPLICIT NONE

! ... parameters
  INTEGER        :: ilev, inodeoffset, ijnodeoffset
  TYPE(t_region) :: region

! ... local variables
  INTEGER :: idnbeg, idnend, jdnbeg, jdnend, kdnbeg, kdnend

!******************************************************************************

  CALL registerfunction( region%global,'RFLO_GetNodeOffset',&
  'RFLO_GetDimensions.F90' )

  CALL rflo_getdimensdummynodes( region,ilev,idnbeg,idnend, &
                                 jdnbeg,jdnend,kdnbeg,kdnend )

  inodeoffset  = idnend - idnbeg + 1
  ijnodeoffset = inodeoffset*(jdnend-jdnbeg+1)

  CALL deregisterfunction( region%global )

END SUBROUTINE rflo_getnodeoffset

! #############################################################################
! #############################################################################

SUBROUTINE rflo_getedgecellsindices( region,iLev,iedge, &
                                     iebeg,ieend,jebeg,jeend,kebeg,keend )

  USE moderror
  USE moddatastruct, ONLY : t_region
  USE modinterfaces, ONLY : rflo_getdimensdummy, rflo_getdimensphys
  IMPLICIT NONE

! ... parameters
  INTEGER        :: ilev, iedge
  INTEGER        :: iebeg, ieend, jebeg, jeend, kebeg, keend
  TYPE(t_region) :: region

! ... local variables
  INTEGER :: idcbeg, idcend, jdcbeg, jdcend, kdcbeg, kdcend
  INTEGER :: ipcbeg, ipcend, jpcbeg, jpcend, kpcbeg, kpcend

!******************************************************************************

  CALL registerfunction( region%global,'RFLO_GetEdgeCellsIndices',&
  'RFLO_GetDimensions.F90' )

  IF (iedge<0 .OR. iedge>12) &
    CALL errorstop( region%global,err_volume_edges,&
    __line__ )

  CALL rflo_getdimensdummy( region,ilev,idcbeg,idcend,jdcbeg,jdcend, &
                            kdcbeg,kdcend )
  CALL rflo_getdimensphys( region,ilev,ipcbeg,ipcend,jpcbeg,jpcend, &
                           kpcbeg,kpcend )

  SELECT CASE (iedge)
    CASE (1)
      iebeg = idcbeg
      ieend = ipcbeg - 1
      jebeg = jdcbeg
      jeend = jpcbeg - 1
      kebeg = kpcbeg
      keend = kpcend
    CASE (2)
      iebeg = idcbeg
      ieend = ipcbeg - 1
      jebeg = jpcbeg
      jeend = jpcend
      kebeg = kpcend + 1
      keend = kdcend
    CASE (3)
      iebeg = idcbeg
      ieend = ipcbeg - 1
      jebeg = jpcend + 1
      jeend = jdcend
      kebeg = kpcbeg
      keend = kpcend
    CASE (4)
      iebeg = idcbeg
      ieend = ipcbeg - 1
      jebeg = jpcbeg
      jeend = jpcend
      kebeg = kdcbeg
      keend = kpcbeg - 1
    CASE (5)
      iebeg = ipcend + 1
      ieend = idcend
      jebeg = jdcbeg
      jeend = jpcbeg - 1
      kebeg = kpcbeg
      keend = kpcend
    CASE (6)
      iebeg = ipcend + 1
      ieend = idcend
      jebeg = jpcbeg
      jeend = jpcend
      kebeg = kpcend + 1
      keend = kdcend
    CASE (7)
      iebeg = ipcend + 1
      ieend = idcend
      jebeg = jpcend + 1
      jeend = jdcend
      kebeg = kpcbeg
      keend = kpcend
    CASE (8)
      iebeg = ipcend + 1
      ieend = idcend
      jebeg = jpcbeg
      jeend = jpcend
      kebeg = kdcbeg
      keend = kpcbeg - 1
    CASE (9)
      iebeg = ipcbeg
      ieend = ipcend
      jebeg = jdcbeg
      jeend = jpcbeg - 1
      kebeg = kdcbeg
      keend = kpcbeg - 1
    CASE (10)
      iebeg = ipcbeg
      ieend = ipcend
      jebeg = jdcbeg
      jeend = jpcbeg - 1
      kebeg = kpcend + 1
      keend = kdcend
    CASE (11)
      iebeg = ipcbeg
      ieend = ipcend
      jebeg = jpcend + 1
      jeend = jdcend
      kebeg = kpcend + 1
      keend = kdcend
    CASE (12)
      iebeg = ipcbeg
      ieend = ipcend
      jebeg = jpcend + 1
      jeend = jdcend
      kebeg = kdcbeg
      keend = kpcbeg - 1
  END SELECT

  CALL deregisterfunction( region%global )

END SUBROUTINE rflo_getedgecellsindices

! #############################################################################
! #############################################################################

SUBROUTINE rflo_getcornercellsindices( region,iLev,icorner, &
                                       icbeg,icend,jcbeg,jcend,kcbeg,kcend )

  USE moderror
  USE moddatastruct, ONLY : t_region
  USE modinterfaces, ONLY : rflo_getdimensdummy, rflo_getdimensphys
  IMPLICIT NONE

! ... parameters
  INTEGER        :: ilev, icorner, icbeg, icend, jcbeg, jcend, kcbeg, kcend
  TYPE(t_region) :: region

! ... local variables
  INTEGER :: idcbeg, idcend, jdcbeg, jdcend, kdcbeg, kdcend
  INTEGER :: ipcbeg, ipcend, jpcbeg, jpcend, kpcbeg, kpcend

!******************************************************************************

  CALL registerfunction( region%global,'RFLO_GetCornerCellsIndices',&
  'RFLO_GetDimensions.F90' )

  IF (icorner<0 .OR. icorner>8) &
    CALL errorstop( region%global,err_volume_corners,&
    __line__ )

  CALL rflo_getdimensdummy( region,ilev,idcbeg,idcend,jdcbeg,jdcend, &
                            kdcbeg,kdcend )
  CALL rflo_getdimensphys( region,ilev,ipcbeg,ipcend,jpcbeg,jpcend, &
                           kpcbeg,kpcend )

  SELECT CASE (icorner)
    CASE (1)
      icbeg = idcbeg
      icend = ipcbeg - 1
      jcbeg = jdcbeg
      jcend = jpcbeg - 1
      kcbeg = kdcbeg
      kcend = kpcbeg - 1
    CASE (2)
      icbeg = idcbeg
      icend = ipcbeg - 1
      jcbeg = jdcbeg
      jcend = jpcbeg - 1
      kcbeg = kpcend + 1
      kcend = kdcend
    CASE (3)
      icbeg = idcbeg
      icend = ipcbeg - 1
      jcbeg = jpcend + 1
      jcend = jdcend
      kcbeg = kpcend + 1
      kcend = kdcend
    CASE (4)
      icbeg = idcbeg
      icend = ipcbeg - 1
      jcbeg = jpcend + 1
      jcend = jdcend
      kcbeg = kdcbeg
      kcend = kpcbeg - 1
    CASE (5)
      icbeg = ipcend + 1
      icend = idcend
      jcbeg = jdcbeg
      jcend = jpcbeg - 1
      kcbeg = kdcbeg
      kcend = kpcbeg - 1
    CASE (6)
      icbeg = ipcend + 1
      icend = idcend
      jcbeg = jdcbeg
      jcend = jpcbeg - 1
      kcbeg = kpcend + 1
      kcend = kdcend
    CASE (7)
      icbeg = ipcend + 1
      icend = idcend
      jcbeg = jpcend + 1
      jcend = jdcend
      kcbeg = kpcend + 1
      kcend = kdcend
    CASE (8)
      icbeg = ipcend + 1
      icend = idcend
      jcbeg = jpcend + 1
      jcend = jdcend
      kcbeg = kdcbeg
      kcend = kpcbeg - 1
  END SELECT

  CALL deregisterfunction( region%global )

END SUBROUTINE rflo_getcornercellsindices

!******************************************************************************
!
! RCS Revision history:
!
! $Log: RFLO_GetDimensions.F90,v $
! Revision 1.3  2008/12/06 08:44:06  mtcampbe
! Updated license.
!
! Revision 1.2  2008/11/19 22:17:20  mtcampbe
! Added Illinois Open Source License/Copyright
!
! Revision 1.1  2004/11/29 21:25:16  wasistho
! lower to upper case
!
! Revision 1.11  2003/11/20 16:40:34  mdbrandy
! Backing out RocfluidMP changes from 11-17-03
!
! Revision 1.8  2003/02/03 19:20:46  jblazek
! Added treatment of edge and corner cells for one processor.
!
! Revision 1.7  2002/09/05 17:40:19  jblazek
! Variable global moved into regions().
!
! Revision 1.6  2002/02/21 23:25:04  jblazek
! Blocks renamed as regions.
!
! Revision 1.5  2002/01/31 20:56:30  jblazek
! Added basic boundary conditions.
!
! Revision 1.4  2002/01/08 22:09:16  jblazek
! Added calculation of face vectors and volumes.
!
! Revision 1.3  2002/01/02 16:20:18  jblazek
! Added flow initialization and dummy cell geometry.
!
! Revision 1.2  2001/12/19 23:09:20  jblazek
! Added routines to read grid and solution.
!
! Revision 1.1  2001/12/11 21:59:28  jblazek
! memory allocation added.
!
!******************************************************************************