TURB_GetTvCell.F90

Go to the documentation of this file.

! *********************************************************************
! * Rocstar Simulation Suite                                          *
! * Copyright@2015, Illinois Rocstar LLC. All rights reserved.        *
! *                                                                   *
! * Illinois Rocstar LLC                                              *
! * Champaign, IL                                                     *
! * www.illinoisrocstar.com                                           *
! * sales@illinoisrocstar.com                                         *
! *                                                                   *
! * License: See LICENSE file in top level of distribution package or *
! * http://opensource.org/licenses/NCSA                               *
! *********************************************************************
! *********************************************************************
! * THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND,   *
! * EXPRESS OR IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES   *
! * OF MERCHANTABILITY, FITNESS FOR A PARTICULAR PURPOSE AND          *
! * NONINFRINGEMENT.  IN NO EVENT SHALL THE CONTRIBUTORS OR           *
! * COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER       *
! * LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE,   *
! * Arising FROM, OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE    *
! * USE OR OTHER DEALINGS WITH THE SOFTWARE.                          *
! *********************************************************************
!******************************************************************************
!
! Purpose: Get turbulent variables mu_t, kapp_t and cdyn at cell centers.
!
! Description: The cell values are obtained by averaging the face values.
!              Mu_t and kappa_t are defined at all cells, including dummmies.
!              Cdyn, stored in turb%dv, is available only at interior cells.
!
! Input: region  = data of current region
!
! Output: mixt%tv(TV_MIXT_MUET:TV_MIXT_TCOT,:) at cell centers and
!         turb%dv(DV_TURB_CDYN,:) at interior cells.
!
! Notes: Mu_t and kapp_t at dummy cells are obtained by extrapolation.
!        If needed they can be computed directly in routine LesCalcEddyVis.
!
!******************************************************************************
!
! $Id: TURB_GetTvCell.F90,v 1.14 2008/12/06 08:44:41 mtcampbe Exp $
!
! Copyright: (c) 2001 by the University of Illinois
!
!******************************************************************************

SUBROUTINE turb_gettvcell( region )

  USE moddatatypes
  USE moddatastruct, ONLY : t_region
  USE modglobal, ONLY     : t_global
  USE moderror
  USE modparameters
  USE turb_modparameters
#ifdef RFLO
  USE turb_modinterfaces, ONLY : turb_floextrapolcellvec
  USE modinterfaces, ONLY : rflo_getdimensphys, rflo_getdimensdummy, &
                            rflo_getcelloffset, rflo_getnodeoffset

#include "Indexing.h"
#endif
  IMPLICIT NONE

! ... parameters
  TYPE(t_region) :: region

! ... loop variables
  INTEGER :: i, j, k, ic, ijkc, in, ijkn, ipatch, ift, ifl

! ... local variables
  CHARACTER(CHRLEN)       :: rcsidentstring
  TYPE(t_global), POINTER :: global

  INTEGER :: indcp
  REAL(RFREAL), POINTER :: muet(:,:),tv(:,:), gv(:,:), tdv(:,:)
  REAL(RFREAL)          :: rprt,cpprt

#ifdef RFLO
  INTEGER :: ipcbeg, ipcend, jpcbeg, jpcend, kpcbeg, kpcend
  INTEGER :: idcbeg, idcend, jdcbeg, jdcend, kdcbeg, kdcend
  INTEGER :: ilev,icoff,ijcoff,inoff,ijnoff,ijkni,ijknj,ijknk
  REAL(RFREAL) :: one6th
#endif
#ifdef RFLU
  INTEGER :: ifg, ifgbeg, ic0, ic1, ict, icl, nfacespercell
  INTEGER, POINTER      :: c2f(:,:,:)
  REAL(RFREAL), POINTER :: bmuet(:,:)
#endif

!******************************************************************************

  rcsidentstring = '$RCSfile: TURB_GetTvCell.F90,v $'

  global => region%global
  CALL registerfunction( global,'Turb_GetTvCell',&
  'TURB_GetTvCell.F90' )

! get parameters ----------------------------------------------------

#ifdef RFLO
  ilev   = region%currLevel
  one6th = 1._rfreal/6._rfreal
  rprt   = 1._rfreal/region%levels(ilev)%mixt%prTurb
  indcp  = region%levels(ilev)%mixt%indCp

! get dimensions and pointers

  CALL rflo_getdimensphys( region,ilev,ipcbeg,ipcend, &
                           jpcbeg,jpcend,kpcbeg,kpcend )
  CALL rflo_getdimensdummy( region,ilev,idcbeg,idcend, &
                            jdcbeg,jdcend,kdcbeg,kdcend )
  CALL rflo_getcelloffset( region,ilev,icoff,ijcoff )
  CALL rflo_getnodeoffset( region,ilev,inoff,ijnoff )

  muet => region%levels(ilev)%turb%mueT
  tv   => region%levels(ilev)%mixt%tv
  gv   => region%levels(ilev)%mixt%gv
  tdv  => region%levels(ilev)%turb%dv

  DO k=kpcbeg-1,kpcend+1
    DO j=jpcbeg-1,jpcend+1
      DO i=ipcbeg-1,ipcend+1

        ijkc  = indijk(i     ,j     ,k     ,icoff,ijcoff)
        ijkn  = indijk(i     ,j     ,k     ,inoff,ijnoff)
        ijkni = ijkn + 1
        ijknj = ijkn + inoff
        ijknk = ijkn + ijnoff

! ----- summing muet from the six faces has to be done here
!       since not all LES models calls TURB_LesCalcEddyVis
    
        tv(tv_mixt_muet,ijkc) = muet(diri,ijkn)+muet(diri,ijkni) + &
                                muet(dirj,ijkn)+muet(dirj,ijknj) + &
                                muet(dirk,ijkn)+muet(dirk,ijknk)
        tv(tv_mixt_muet,ijkc) = one6th*tv(tv_mixt_muet,ijkc)
        tdv(dv_turb_cdyn,ijkc)= one6th*tdv(dv_turb_cdyn,ijkc)

      ENDDO   ! i
    ENDDO     ! j
  ENDDO       ! k
#endif
#ifdef RFLU
  rprt  =  1._rfreal/region%mixtInput%prTurb
  indcp =  region%mixtInput%indCp
  muet  => region%turb%mueT
  bmuet => region%turb%bMueT
  tv    => region%mixt%tv
  gv    => region%mixt%gv
  tdv   => region%turb%dv

! average muet at faces into cells 
! waiting for Andreas` routine for proper averaging

  tv(tv_mixt_muet,:) = 0._rfreal

  DO ift = 1,region%grid%nFaces
    ic0 = region%grid%f2c(1,ift)
    ic1 = region%grid%f2c(2,ift)
    tv(tv_mixt_muet,ic0) = tv(tv_mixt_muet,ic0) + muet(diri,ift)
    tv(tv_mixt_muet,ic1) = tv(tv_mixt_muet,ic1) + muet(diri,ift)
  ENDDO    ! ift

  DO ipatch = 1,region%grid%nPatches
! TEMPORARY : removing usage of bf2bg from everywhere
!    ifgBeg = region%patches(iPatch)%bf2bg(BF2BG_BEG)
    ifg    = ifgbeg
    DO ifl = 1,region%patches(ipatch)%nBFaces
      ic0 = region%patches(ipatch)%bf2c(ifl)
      tv(tv_mixt_muet,ic0) = tv(tv_mixt_muet,ic0) + bmuet(diri,ifg)
      ifg = ifg + 1
    ENDDO    ! ifl
  ENDDO      ! iPatch

  DO ic = 1,region%grid%nCells
    ict = region%grid%cellGlob2Loc(1,ic) ! cell type
    icl = region%grid%cellGlob2Loc(2,ic) ! local (type) cell index
    SELECT CASE ( ict ) 
      CASE ( cell_type_tet ) 
        nfacespercell = 4
        c2f => region%grid%tet2f              
      CASE ( cell_type_hex ) 
        nfacespercell = 6
        c2f => region%grid%hex2f              
      CASE ( cell_type_pri ) 
        nfacespercell = 5    
        c2f => region%grid%pri2f                         
      CASE ( cell_type_pyr ) 
        nfacespercell = 5
        c2f => region%grid%pyr2f                
      CASE default  
        CALL errorstop(global,err_reached_default,__line__)
    END SELECT ! ict

    tv( tv_mixt_muet,ic) = tv( tv_mixt_muet,ic)/nfacespercell
    tdv(dv_turb_cdyn,ic) = tdv(dv_turb_cdyn,ic)/nfacespercell
  ENDDO    ! iC
#endif

! extrapolate to dummy faces at the six sides of region; simple extrapolation 
! provides the original face TV values (through two point averaging) needed in 
! the computation of viscous fluxes

#ifdef RFLO
! extrapolate solution to dummy cells

  CALL turb_floextrapolcellvec( region,tv_mixt_muet,tv_mixt_muet,tv )
#endif

! get turbulent thermal conductivity

#ifdef RFLO
  DO k=kdcbeg,kdcend
    DO j=jdcbeg,jdcend
      DO i=idcbeg,idcend

        ijkc  = indijk(i     ,j     ,k     ,icoff,ijcoff)
#endif
#ifdef RFLU
  DO ic = 1,region%grid%nCells
     ijkc = ic
#endif
        tv(tv_mixt_muet,ijkc) = max( tv(tv_mixt_muet,ijkc), 0._rfreal )
        cpprt = gv(gv_mixt_cp,ijkc*indcp)*rprt
        tv(tv_mixt_tcot,ijkc) = cpprt*tv(tv_mixt_muet,ijkc)
#ifdef RFLO
      ENDDO  ! i
    ENDDO    ! j
  ENDDO      ! k
#endif
#ifdef RFLU
  ENDDO      ! iC
#endif

! finalize --------------------------------------------------------------------

  CALL deregisterfunction( global )

END SUBROUTINE turb_gettvcell

!******************************************************************************
!
! RCS Revision history:
! 
! $Log: TURB_GetTvCell.F90,v $
! Revision 1.14  2008/12/06 08:44:41  mtcampbe
! Updated license.
!
! Revision 1.13  2008/11/19 22:17:53  mtcampbe
! Added Illinois Open Source License/Copyright
!
! Revision 1.12  2006/08/19 15:40:57  mparmar
! Removed bf2bg
!
! Revision 1.11  2006/01/13 03:47:11  wasistho
! initialize tv(muet,:) in Rocflu
!
! Revision 1.10  2005/12/30 23:21:29  wasistho
! bug fixed face indexing in patch
!
! Revision 1.9  2005/01/12 01:12:59  wasistho
! removed single quote signs since SUN has trouble with it
!
! Revision 1.8  2004/05/28 02:00:31  wasistho
! update unstructured grid LES
!
! Revision 1.7  2004/05/18 03:15:29  wasistho
! changed FloExtrapIntCellVec to FloExtrapolCellVec
!
! Revision 1.6  2004/05/17 20:47:48  wasistho
! compute first layer dummy mu_t instead of extrapolated
!
! Revision 1.5  2004/03/27 02:16:42  wasistho
! compiled with Rocflu
!
! Revision 1.4  2004/03/24 03:37:02  wasistho
! prepared for RFLU
!
! Revision 1.3  2004/03/19 02:46:57  wasistho
! prepared for RFLU
!
! Revision 1.2  2004/03/12 02:55:35  wasistho
! changed rocturb routine names
!
! Revision 1.1  2004/03/05 04:37:00  wasistho
! changed nomenclature
!
! Revision 1.4  2004/02/18 02:23:11  wasistho
! used extrapolation routine to fill in dummy mut and klipped it
!
! Revision 1.3  2003/10/09 23:07:17  wasistho
! renamed CalcEddyVis to LesCalcEddyVis
!
! Revision 1.2  2003/05/15 02:57:06  jblazek
! Inlined index function.
!
! Revision 1.1  2002/10/14 23:55:29  wasistho
! Install Rocturb
!
!******************************************************************************