TURB_floFaceWidth.F90

Go to the documentation of this file.

! *********************************************************************
! * Rocstar Simulation Suite                                          *
! * Copyright@2015, Illinois Rocstar LLC. All rights reserved.        *
! *                                                                   *
! * Illinois Rocstar LLC                                              *
! * Champaign, IL                                                     *
! * www.illinoisrocstar.com                                           *
! * sales@illinoisrocstar.com                                         *
! *                                                                   *
! * License: See LICENSE file in top level of distribution package or *
! * http://opensource.org/licenses/NCSA                               *
! *********************************************************************
! *********************************************************************
! * THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND,   *
! * EXPRESS OR IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES   *
! * OF MERCHANTABILITY, FITNESS FOR A PARTICULAR PURPOSE AND          *
! * NONINFRINGEMENT.  IN NO EVENT SHALL THE CONTRIBUTORS OR           *
! * COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER       *
! * LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE,   *
! * Arising FROM, OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE    *
! * USE OR OTHER DEALINGS WITH THE SOFTWARE.                          *
! *********************************************************************
!******************************************************************************
!
! Purpose: Obtained the width of all faces.
!
! Description: Face width is defined as distance between opposing edge-mids.
!              Each face has two face widths, e.g. face i has fw in j & k dir. 
!
! Input: region  = data of current region
!
! Output: Face width stored in workI,J,K(2,:)
!
! Notes: This routine is employed to construct non-uniform filter coefficients.
!        Hence is only relevant if non-uniform filter is selected.
!
!******************************************************************************
!
! $Id: TURB_floFaceWidth.F90,v 1.5 2008/12/06 08:44:43 mtcampbe Exp $
!
! Copyright: (c) 2001 by the University of Illinois
!
!******************************************************************************
SUBROUTINE turb_flofacewidth( region )

  USE moddatatypes
  USE moddatastruct, ONLY      : t_region
  USE modglobal, ONLY          : t_global
  USE modinterfaces, ONLY      : rflo_getdimensdummy, rflo_getnodeoffset, &
                                 rflo_copyedgefacenorm, rflo_copyedgefaceparal
  USE turb_modinterfaces, ONLY : turb_flofacewidthdummy
  USE moderror
  USE modparameters
  USE turb_modparameters
  IMPLICIT NONE

#include "Indexing.h"

! ... parameters
  TYPE(t_region) :: region

! ... loop variables
  INTEGER :: i, j, k, ijkn, ipatch

! ... local variables
  CHARACTER(CHRLEN)       :: rcsidentstring
  TYPE(t_global), POINTER :: global

  INTEGER           :: ibeg,iend,jbeg,jend,kbeg,kend
  INTEGER           :: idcbeg,idcend,jdcbeg,jdcend,kdcbeg,kdcend
  INTEGER           :: ilev,inoff,ijnoff
  REAL(RFREAL), POINTER :: xyz(:,:), fw(:,:)
  REAL(RFREAL), POINTER :: fwi(:,:), fwj(:,:), fwk(:,:)

!******************************************************************************

  rcsidentstring = '$RCSfile: TURB_floFaceWidth.F90,v $'

  global => region%global
  CALL registerfunction( global,'TURB_FloFaceWidth',&
  'TURB_floFaceWidth.F90' )

! get indices and pointers ---------------------------------------------------

  ilev =  region%currLevel
  xyz  => region%levels(ilev)%grid%xyz
  fwi  => region%levels(ilev)%turb%workI
  fwj  => region%levels(ilev)%turb%workJ
  fwk  => region%levels(ilev)%turb%workK

  CALL rflo_getdimensdummy( region,ilev,idcbeg,idcend, &
                           jdcbeg,jdcend,kdcbeg,kdcend )
  CALL rflo_getnodeoffset( region,ilev,inoff,ijnoff )

! compute averaging coefficient at face i, j, k interior domain

  CALL computefacewidth( diri )
  CALL computefacewidth( dirj )
  CALL computefacewidth( dirk )

! compute averaging coefficient at dummy points

  DO ipatch=1,region%nPatches
    CALL turb_flofacewidthdummy( region,region%levels(ilev)%patches(ipatch) )
  ENDDO

! and copy to edge/corner dummies -------------------------------------------- 
! the edge length is extended that corners are covered to minimize work

  CALL rflo_copyedgefacenorm( region,1,2,fwi,fwj,fwk )
  CALL rflo_copyedgefaceparal( region,1,2,fwi,fwj,fwk )

! finalize --------------------------------------------------------------------

  CALL deregisterfunction( global )

! =============================================================================
!   Face width computation subroutine
! =============================================================================

CONTAINS

  SUBROUTINE computefacewidth( ijk )

! ... parameters
    INTEGER   :: ijk

! ... local variables
    INTEGER   :: i2,i3,i4,j2,j3,j4,k2,k3,k4
    INTEGER   :: corner(4)
    REAL(RFREAL) :: fc1(xcoord:zcoord), fc2(xcoord:zcoord)

! - Set limits and pointers ---------------------------------------------------
    IF (ijk==diri) THEN
      ibeg = idcbeg
      iend = idcend+1
      jbeg = jdcbeg
      jend = jdcend
      kbeg = kdcbeg
      kend = kdcend
      i2   = 0
      i3   = 0
      i4   = 0
      j2   = 0
      j3   = 1
      j4   = 1
      k2   = 1
      k3   = 1
      k4   = 0
      fw   => region%levels(ilev)%turb%workI
    ELSEIF (ijk==dirj) THEN
      ibeg = idcbeg
      iend = idcend
      jbeg = jdcbeg
      jend = jdcend+1
      kbeg = kdcbeg
      kend = kdcend
      i2   = 0
      i3   = 1
      i4   = 1
      j2   = 0
      j3   = 0
      j4   = 0
      k2   = 1
      k3   = 1
      k4   = 0
      fw   => region%levels(ilev)%turb%workJ
    ELSEIF (ijk==dirk) THEN
      ibeg = idcbeg
      iend = idcend
      jbeg = jdcbeg
      jend = jdcend
      kbeg = kdcbeg
      kend = kdcend+1
      i2   = 0
      i3   = 1
      i4   = 1
      j2   = 1
      j3   = 1
      j4   = 0
      k2   = 0
      k3   = 0
      k4   = 0
      fw   => region%levels(ilev)%turb%workK
    ENDIF

! define 2 face-widths for each face of non-uniform grid;
! face I has face-widths in J and K direction, and so on

    DO k=kbeg,kend
      DO j=jbeg,jend
        DO i=ibeg,iend
          ijkn  = indijk(i     ,j     ,k     ,inoff,ijnoff)
          corner(1) = indijk(i    ,j    ,k    ,inoff,ijnoff)
          corner(2) = indijk(i+i2 ,j+j2 ,k+k2 ,inoff,ijnoff)
          corner(3) = indijk(i+i3 ,j+j3 ,k+k3 ,inoff,ijnoff)
          corner(4) = indijk(i+i4 ,j+j4 ,k+k4 ,inoff,ijnoff)
         
          fc1(xcoord:zcoord) = 0.5_rfreal* &
                               (xyz(xcoord:zcoord,corner(1))+ &
                                xyz(xcoord:zcoord,corner(2)))
          fc2(xcoord:zcoord) = 0.5_rfreal* &
                               (xyz(xcoord:zcoord,corner(3))+ &
                                xyz(xcoord:zcoord,corner(4)))
          fw(1,ijkn) = sqrt((fc2(xcoord)-fc1(xcoord))**2 + &
                            (fc2(ycoord)-fc1(ycoord))**2 + &
                            (fc2(zcoord)-fc1(zcoord))**2)
         
          fc1(xcoord:zcoord) = 0.5_rfreal* &
                               (xyz(xcoord:zcoord,corner(1))+ &
                                xyz(xcoord:zcoord,corner(4)))
          fc2(xcoord:zcoord) = 0.5_rfreal* &
                               (xyz(xcoord:zcoord,corner(2))+ &
                                xyz(xcoord:zcoord,corner(3)))
          fw(2,ijkn) = sqrt((fc2(xcoord)-fc1(xcoord))**2 + &
                            (fc2(ycoord)-fc1(ycoord))**2 + &
                            (fc2(zcoord)-fc1(zcoord))**2)

        ENDDO   ! i
      ENDDO     ! j
    ENDDO       ! k

  END SUBROUTINE computefacewidth

END SUBROUTINE turb_flofacewidth

!******************************************************************************
!
! RCS Revision history:
!
! $Log: TURB_floFaceWidth.F90,v $
! Revision 1.5  2008/12/06 08:44:43  mtcampbe
! Updated license.
!
! Revision 1.4  2008/11/19 22:17:55  mtcampbe
! Added Illinois Open Source License/Copyright
!
! Revision 1.3  2004/08/04 02:49:20  wasistho
! removed turb%avgCoI,J,K as it is defined as grid%c2fCoI,J,K
!
! Revision 1.2  2004/03/12 02:55:35  wasistho
! changed rocturb routine names
!
! Revision 1.1  2004/03/08 23:35:45  wasistho
! changed turb nomenclature
!
! Revision 1.2  2003/05/15 02:57:06  jblazek
! Inlined index function.
!
! Revision 1.1  2002/10/14 23:55:29  wasistho
! Install Rocturb
!
!
!******************************************************************************