TURB_LesGetEddyVis.F90

Go to the documentation of this file.

! *********************************************************************
! * Rocstar Simulation Suite                                          *
! * Copyright@2015, Illinois Rocstar LLC. All rights reserved.        *
! *                                                                   *
! * Illinois Rocstar LLC                                              *
! * Champaign, IL                                                     *
! * www.illinoisrocstar.com                                           *
! * sales@illinoisrocstar.com                                         *
! *                                                                   *
! * License: See LICENSE file in top level of distribution package or *
! * http://opensource.org/licenses/NCSA                               *
! *********************************************************************
! *********************************************************************
! * THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND,   *
! * EXPRESS OR IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES   *
! * OF MERCHANTABILITY, FITNESS FOR A PARTICULAR PURPOSE AND          *
! * NONINFRINGEMENT.  IN NO EVENT SHALL THE CONTRIBUTORS OR           *
! * COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER       *
! * LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE,   *
! * Arising FROM, OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE    *
! * USE OR OTHER DEALINGS WITH THE SOFTWARE.                          *
! *********************************************************************
!******************************************************************************
!
! Purpose: Get eddy viscosity based the dynamic LES model.
!
! Description: First, cell filtered cv is computed, then the filtered 
!              velocities are obtained from this. The gradients of the 
!              filtered velocities are computed. This is in turn used
!              to construct the strain rate tensor of the filtered field.
!              The strain rate tensor of filtered field is employed in the 
!              formulation of the eddy viscosity of the dynamic models.
!
! Input: region  = data of current region
!        ibn,ien = begin and end node index 
!
! Output: eddy viscosity (mueT), stored in turb%mueT(DIRI:DIRK,:)
!
! Notes: none.
!
!******************************************************************************
!
! $Id: TURB_LesGetEddyVis.F90,v 1.13 2008/12/06 08:44:41 mtcampbe Exp $
!
! Copyright: (c) 2001 by the University of Illinois
!
!******************************************************************************

SUBROUTINE turb_lesgeteddyvis( region,ibc,iec,ibn,ien )

  USE moddatatypes
  USE moddatastruct, ONLY : t_region
  USE modturbulence, ONLY : t_turb
  USE modglobal, ONLY     : t_global
#ifdef RFLU
  USE modbndpatch, ONLY   : t_patch
  USE rflu_moddifferentiationfaces, ONLY: rflu_computegradfaceswrapper
  USE rflu_moddifferentiationbfaces, ONLY: rflu_computegradbfaceswrapper
  USE modinterfaces, ONLY: rflu_decideneedbgradface
#endif
#ifdef RFLO
  USE modinterfaces, ONLY : rflo_calcgradvector
#endif
  USE turb_modinterfaces, ONLY : turb_lestestrhov, turb_calcstrainrate, &
                                 turb_lescalceddyvis
  USE moderror
  USE modparameters
  USE turb_modparameters
  IMPLICIT NONE

! ... parameters
#ifdef RFLO
  TYPE(t_region),  TARGET :: region
#endif
#ifdef RFLU
  TYPE(t_region), POINTER :: region
#endif
  INTEGER :: ibc, iec, ibn, ien

! ... loop variables
  INTEGER :: ipatch

! ... local variables
  CHARACTER(CHRLEN)       :: rcsidentstring
  TYPE(t_global), POINTER :: global
  TYPE(t_turb), POINTER   :: turb
#ifdef RFLU
  TYPE(t_patch), POINTER  :: ppatch
#endif
  
  INTEGER               :: ibegv, iendv, ibegg, iendg, ngrad, errorflag
  REAL(RFREAL), POINTER :: ccvar(:,:)
#ifdef RFLO
  INTEGER               :: ilev, gradindx(9)
  REAL(RFREAL), POINTER :: gradi(:,:), gradj(:,:), gradk(:,:)
#endif
#ifdef RFLU
  INTEGER               :: npatches, nbfaces, nbfacestot, gradindx(3)
  REAL(RFREAL), POINTER :: gradi(:,:,:), bgradi(:,:,:)
#endif

!******************************************************************************

  rcsidentstring = '$RCSfile: TURB_LesGetEddyVis.F90,v $'

  global => region%global
  CALL registerfunction( global,'TURB_LesGetEddyVis',&
  'TURB_LesGetEddyVis.F90' )

! get pointers and parameters ------------------------------------------------
  ngrad =  region%turbInput%nGrad
#ifdef RFLO
  ilev  =  region%currLevel
  turb  => region%levels(ilev)%turb
#endif
#ifdef RFLU
  npatches   = region%grid%nPatches
  nbfaces    = 0
  nbfacestot = 0

  DO ipatch = 1,npatches
    ppatch => region%patches(ipatch)

    nbfaces    = nbfaces    + ppatch%nBTris    + ppatch%nBQuads
    nbfacestot = nbfacestot + ppatch%nBTrisTot + ppatch%nBQuadsTot
  END DO ! iPatch
  turb  => region%turb
#endif

! allocate and point arrays required by LesTestRhoV and CalcGradVector

  ALLOCATE( turb%ccVar(cv_turb_nelm,ibc:iec),stat=errorflag ) 
  global%error = errorflag
  IF (global%error /= 0) CALL errorstop( global,err_allocate,__line__ )

#ifdef RFLO
  ALLOCATE( turb%gradi(ngrad,ibn:ien),stat=errorflag )         
  global%error = errorflag
  IF (global%error /= 0) CALL errorstop( global,err_allocate,__line__ )

  ALLOCATE( turb%gradj(ngrad,ibn:ien),stat=errorflag )         
  global%error = errorflag
  IF (global%error /= 0) CALL errorstop( global,err_allocate,__line__ )

  ALLOCATE( turb%gradk(ngrad,ibn:ien),stat=errorflag )
  global%error = errorflag
  IF (global%error /= 0) CALL errorstop( global,err_allocate,__line__ )
#endif
#ifdef RFLU
  ALLOCATE( turb%gradi(xcoord:zcoord,ngrad,ibn:ien),stat=errorflag )
  global%error = errorflag
  IF (global%error /= 0) CALL errorstop( global,err_allocate,__line__ )

  ALLOCATE( turb%bGradi(xcoord:zcoord,ngrad,nbfaces),stat=errorflag )
  global%error = errorflag
  IF (global%error /= 0) CALL errorstop( global,err_allocate,__line__ )
#endif

  ccvar  => turb%ccVar
  gradi  => turb%gradi
#ifdef RFLO
  gradj  => turb%gradj
  gradk  => turb%gradk
#endif
#ifdef RFLU
  bgradi => turb%bGradi
#endif

! compute cell-filtered cv and store in ccVar
  CALL turb_lestestrhov( region,ibc,iec )

! compute gradients of ccVar
#ifdef RFLO
  ibegv =  cv_turb_uvel
  iendv =  cv_turb_wvel
  ibegg =  gr_turb_ux
  iendg =  gr_turb_wz
  CALL rflo_calcgradvector( region,ibegv,iendv,ibegg,iendg,ccvar, &
                            gradi,gradj,gradk )
#endif
#ifdef RFLU
  ibegv  =  cv_turb_uvel
  iendv  =  cv_turb_wvel
  ibegg  =  gr_turb_ux
  iendg  =  gr_turb_wx
  CALL rflu_computegradfaceswrapper( region,ibegv,iendv,ibegg,iendg,ccvar,gradi )
  DO ipatch = 1,npatches
    ppatch => region%patches(ipatch)

    IF ( rflu_decideneedbgradface(region,ppatch) .EQV. .true. ) THEN
      CALL rflu_computegradbfaceswrapper( region,ppatch,ibegv,iendv,ibegg,iendg, &
                                          ccvar,bgradi )
    END IF ! RFLU_DecideNeedBGradFace
  ENDDO ! iPatch 
#endif
  DEALLOCATE( turb%ccVar )

! compute sij based on cell-filtered cv, Sij(v) = Sij(test[bar(u_i)]) 
! and store this in fISij, fJSij, fKSij
  gradindx(1) = gr_turb_ux
  gradindx(2) = gr_turb_vx
  gradindx(3) = gr_turb_wx
#ifdef RFLO
  gradindx(4) = gr_turb_uy
  gradindx(5) = gr_turb_vy
  gradindx(6) = gr_turb_wy
  gradindx(7) = gr_turb_uz
  gradindx(8) = gr_turb_vz
  gradindx(9) = gr_turb_wz

  CALL turb_calcstrainrate( region,ibn,ien,gradindx,gradi,gradj,gradk, &
                            turb%fISij,turb%fJSij,turb%fKSij )
  DEALLOCATE( turb%gradi,turb%gradj,turb%gradk )
#endif
#ifdef RFLU
  CALL turb_calcstrainrate( region, ibn,ien, gradindx, gradi, turb%fISij )
  IF (npatches > 0) &
  CALL turb_calcstrainrate( region,1,nbfaces,gradindx,bgradi,turb%bfISij )
  DEALLOCATE( turb%gradi, turb%bGradi )
#endif

! obtain eddyviscosity in i, j and k faces
  CALL turb_lescalceddyvis( region,ibn,ien,diri )
#ifdef RFLO
  CALL turb_lescalceddyvis( region,ibn,ien,dirj )
  CALL turb_lescalceddyvis( region,ibn,ien,dirk )
#endif

! finalize --------------------------------------------------------------------

  CALL deregisterfunction( global )

END SUBROUTINE turb_lesgeteddyvis

!******************************************************************************
!
! RCS Revision history:
!
! $Log: TURB_LesGetEddyVis.F90,v $
! Revision 1.13  2008/12/06 08:44:41  mtcampbe
! Updated license.
!
! Revision 1.12  2008/11/19 22:17:54  mtcampbe
! Added Illinois Open Source License/Copyright
!
! Revision 1.11  2006/08/19 15:40:36  mparmar
! Added use of RFLU_DecideNeedBGradFace
!
! Revision 1.10  2006/04/07 15:06:06  haselbac
! Bug fix: Incorrect ifs
!
! Revision 1.9  2006/04/07 14:56:02  haselbac
! Adapted to changes in f and bf grad routines
!
! Revision 1.8  2005/12/20 20:43:29  wasistho
! adapted to changing in Rocflu on face gradient routines
!
! Revision 1.7  2004/05/28 01:58:49  wasistho
! update unstructured grid LES
!
! Revision 1.6  2004/05/17 20:33:39  wasistho
! reordering gradIndx for more efficient cache memory addressing
!
! Revision 1.5  2004/03/27 02:16:42  wasistho
! compiled with Rocflu
!
! Revision 1.4  2004/03/25 04:40:41  wasistho
! prepared for RFLU
!
! Revision 1.3  2004/03/20 03:28:29  wasistho
! prepared for RFLU
!
! Revision 1.2  2004/03/19 02:50:18  wasistho
! prepared for RFLU
!
! Revision 1.1  2004/03/05 04:37:00  wasistho
! changed nomenclature
!
! Revision 1.5  2003/10/09 23:07:41  wasistho
! renamed CalcEddyVis to LesCalcEddyVis
!
! Revision 1.4  2003/08/29 01:42:25  wasistho
! Added TARGET attribute to region variable, since pointers are cached into it
!
! Revision 1.3  2003/05/16 05:43:34  wasistho
! modified array range of CC-filtered
!
! Revision 1.2  2002/10/16 02:00:06  wasistho
! Changed global%error flag
!
! Revision 1.1  2002/10/14 23:55:30  wasistho
! Install Rocturb
!
!
!******************************************************************************