utilities/rocsmoke/post/Main.F90

Go to the documentation of this file.

! *********************************************************************
! * Rocstar Simulation Suite                                          *
! * Copyright@2015, Illinois Rocstar LLC. All rights reserved.        *
! *                                                                   *
! * Illinois Rocstar LLC                                              *
! * Champaign, IL                                                     *
! * www.illinoisrocstar.com                                           *
! * sales@illinoisrocstar.com                                         *
! *                                                                   *
! * License: See LICENSE file in top level of distribution package or *
! * http://opensource.org/licenses/NCSA                               *
! *********************************************************************
! *********************************************************************
! * THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND,   *
! * EXPRESS OR IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES   *
! * OF MERCHANTABILITY, FITNESS FOR A PARTICULAR PURPOSE AND          *
! * NONINFRINGEMENT.  IN NO EVENT SHALL THE CONTRIBUTORS OR           *
! * COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER       *
! * LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE,   *
! * Arising FROM, OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE    *
! * USE OR OTHER DEALINGS WITH THE SOFTWARE.                          *
! *********************************************************************
!******************************************************************************
!
! Purpose: write out ROCFLO-MP`s grid and/or solution for visualization,
!          with smoke fields included
!
! Description: currently supported formats are:
!              - TECPLOT Ascii
!
! Input: case name from the list of arguments
!
! Output: to file.
!
! Notes: the output is collected in one file, but the regions are processed
!        separately to save memory.
!
!******************************************************************************
!
! $Id: Main.F90,v 1.4 2008/12/06 08:45:08 mtcampbe Exp $
!
! Copyright: (c) 2003 by the University of Illinois
!
!******************************************************************************

PROGRAM peul_rocflo_post

  USE moddatatypes
  USE moderror
  USE moddatastruct, ONLY : t_region
  USE modglobal, ONLY     : t_global
  USE modgrid, ONLY       : t_grid
  USE modmixture, ONLY    : t_mixt
  USE modparteul, ONLY    : t_peul
  USE rflo_modinterfacespost, ONLY : rflo_readregiontopology, &
        rflo_initinputvalues, readinputfile, rflo_derivedinputvalues, &
        rflo_getdimensdummynodes, rflo_getdimensdummy, rflo_getnodeoffset, &
        rflo_getcelloffset, rflo_readgridregion, rflo_readsolutionregion, &
        mixtureproperties, writetecplotascii, &
        rflo_generatecoarsegrids, rflo_copygeometrydummy, buildversionstring
   USE rflo_modinterfacespost, ONLY : peul_readsolutionregion
#ifdef TURB
   USE rflo_modinterfacespost, ONLY : turb_readinputfile, &
                                      turb_derivedinputvalues
#endif
  USE modmpi
  USE modparameters
  IMPLICIT NONE

#include "Indexing.h"

! ... loop variables
  INTEGER :: ireg, ilev

! ... local variables
  CHARACTER(CHRLEN) :: plttype, level, stamp, outfmt, msg, &
                       versionstring, headerstring, npeulstr

  INTEGER :: plottype, outputformat, npeul
  INTEGER :: ipc, jpc, kpc, ibc, iec, ibn, ien
  INTEGER :: idcbeg, idcend, jdcbeg, jdcend, kdcbeg, kdcend
  INTEGER :: idnbeg, idnend, jdnbeg, jdnend, kdnbeg, kdnend
  INTEGER :: icoff, ijcoff, inoff, ijnoff
  INTEGER :: margin, versionwidth, errorflag
  INTEGER, PARAMETER :: headerwidth = 53

  TYPE(t_global), POINTER :: global
  TYPE(t_region), POINTER :: regions(:)
  TYPE(t_grid)  , POINTER :: grid
  TYPE(t_mixt)  , POINTER :: mixt
  TYPE(t_peul)  , POINTER :: peul

!******************************************************************************

  ALLOCATE( global )

  global%nFunTree = 0
  CALL registerfunction( global,'PEUL_ROCFLO_Post', &
                        'Main.F90' )

! initialize global parameters ------------------------------------------------

  global%verbLevel = verbose_none

  global%flowType    = flow_steady  ! stationary flow
  global%currentTime = -1._rfreal   ! no physical time set
  global%currentIter = -1           ! no iteration

  global%inDir  = './'              ! directory path
  global%outDir = './'

  global%nProcAlloc = 1
  global%myProcid   = masterproc    ! default process number (not an MPI code)
  global%mpierr     = err_none
  global%error      = err_none

  global%pi  = 4._rfreal*atan(1._rfreal)
  global%rad = global%pi/180._rfreal

! print header ----------------------------------------------------------------

#ifdef MPI
  CALL mpi_init( global%mpierr )
  IF (global%mpierr /=0 ) CALL errorstop( global,err_mpi_trouble,__line__ )
#endif

  CALL buildversionstring( versionstring )

  headerstring = ' '
  versionwidth = len_trim(versionstring)
  margin       = (headerwidth-versionwidth)/2
  headerstring(margin+1:margin+versionwidth) = versionstring(1:versionwidth)
  headerstring(1:1) = '*'
  headerstring(headerwidth:headerwidth) = '*'

  WRITE(stdout,'(/,A)') solver_name//'  *****************************************************'
  WRITE(stdout,  '(A)') solver_name//'  *                                                   *'
  WRITE(stdout,  '(A)') solver_name//'  *        ROCSMOKE: Solution Postprocessing          *'
  WRITE(stdout,  '(A)') solver_name//'  *        =================================          *'
  WRITE(stdout,  '(A)') solver_name//'  *                                                   *'
  WRITE(stdout,  '(A)') solver_name//'  '//trim(headerstring)
  WRITE(stdout,  '(A)') solver_name//'  *    Copyright (c) by the University of Illinois    *'
  WRITE(stdout,  '(A)') solver_name//'  *                                                   *'
  WRITE(stdout,'(A,/)') solver_name//'  *****************************************************'

! read argument list ----------------------------------------------------------

  CALL getarg(1,global%casename)
  CALL getarg(2,plttype)
  CALL getarg(3,level)
  CALL getarg(4,stamp)
  CALL getarg(5,outfmt)
  CALL getarg(6,npeulstr)

  IF (len_trim(global%casename)==0 .OR. &
      len_trim(plttype)==0         .OR. &
      len_trim(level)==0           .OR. &
      len_trim(stamp)==0           .OR. &
      len_trim(outfmt)==0          .OR. &
      len_trim(npeulstr)==0 ) THEN
    WRITE(stdout,'(/,A,/,A,/,9(A,/))') &
      solver_name//' Usage: peulpost <casename> <type> <level> <time/iter> <format> <nPeul>', &
      solver_name, &
      solver_name//'        type      = 1 - grid + smoke only', &
      solver_name//'                  = 2 - grid + fluid + smoke fields', &
      solver_name//' ', &
      solver_name//'        level     = grid level (>0)', &
      solver_name//'        time/iter = time or iteration number', &
      solver_name//' ', &
      solver_name//'        format    = 3 - Tecplot ASCII', &
      solver_name//'        nPeul     = number of smoke fields included'
#ifdef MPI
    CALL mpi_finalize( global%mpierr )
#endif
    stop
  ENDIF

  READ(plttype ,*) plottype
  READ(level   ,*) global%startLevel
  READ(outfmt  ,*) outputformat
  READ(npeulstr,*) npeul

  IF (plottype <= 1) THEN
    plottype = plot_grid_only
  ELSE
    plottype = plot_grid_flow
  ENDIF

  IF (outputformat == 3) THEN
    outputformat = plot_fmt_tecascii
  ELSE
    WRITE(stdout,'(/,A,/)') solver_name// &
                            ' Sorry, binary output not yet supported.'
#ifdef MPI
    CALL mpi_finalize( global%mpierr )
#endif
    stop
  ENDIF

! read region topology --------------------------------------------------------

  WRITE(stdout,'(/,A)') solver_name//' Reading region topology ...'

  CALL rflo_readregiontopology( global,regions )

  DO ireg=1,global%nRegions
    regions(ireg)%startLevel = global%startLevel
    regions(ireg)%currLevel  = global%startLevel
    IF (regions(ireg)%nGridLevels < regions(ireg)%currLevel) THEN
      WRITE(msg,1000) solver_name,ireg,global%startLevel
      CALL errorstop( global,err_grid_level,__line__,msg )
    ENDIF
    DO ilev=2,regions(ireg)%nGridLevels
      ipc = regions(ireg)%levels(ilev-1)%grid%ipc
      jpc = regions(ireg)%levels(ilev-1)%grid%jpc
      kpc = regions(ireg)%levels(ilev-1)%grid%kpc
      regions(ireg)%levels(ilev)%grid%ipc = ipc/2
      regions(ireg)%levels(ilev)%grid%jpc = jpc/2
      regions(ireg)%levels(ilev)%grid%kpc = kpc/2
    ENDDO
  ENDDO

! get user parameters ---------------------------------------------------------

  WRITE(stdout,'(/,A)') solver_name//' Reading user input ...'

  CALL rflo_initinputvalues( regions )
  CALL readinputfile( regions )
  CALL rflo_derivedinputvalues( regions )
#ifdef TURB
  CALL turb_readinputfile( regions )
  CALL turb_derivedinputvalues( regions )
#endif

  IF (global%flowType == flow_steady) THEN
    READ(stamp,*) global%currentIter
  ELSE
    READ(stamp,*) global%timeStamp
    global%currentTime = global%timeStamp
  ENDIF

! loop over regions -----------------------------------------------------------

  IF (plottype == plot_grid_only) THEN
    WRITE(stdout,'(A)') solver_name// &
                        ' Reading grid + smoke and writing plot file ...'
  ELSE
    WRITE(stdout,'(A)') solver_name// &
                        ' Reading grid + fluid + smoke and writing plot file ...'
  ENDIF

  DO ireg=1,global%nRegions

    WRITE(stdout,'(A,I5.5)') solver_name//'   - region ',ireg

! - allocate memory for the grid (all grid levels)

    DO ilev=1,regions(ireg)%nGridLevels
      CALL rflo_getdimensdummynodes( regions(ireg),ilev,idnbeg,idnend, &
                                     jdnbeg,jdnend,kdnbeg,kdnend )
      CALL rflo_getnodeoffset( regions(ireg),ilev,inoff,ijnoff )
      ibn  =  indijk(idnbeg,jdnbeg,kdnbeg,inoff,ijnoff)
      ien  =  indijk(idnend,jdnend,kdnend,inoff,ijnoff)
      grid => regions(ireg)%levels(ilev)%grid
      ALLOCATE( grid%xyz(3,ibn:ien),stat=errorflag )
      global%error = errorflag
      IF (global%error /= 0) CALL errorstop( global,err_allocate,__line__ )
    ENDDO

! - allocate memory for the rest (current grid level)

    ilev =  regions(ireg)%currLevel
    grid => regions(ireg)%levels(ilev)%grid
    mixt => regions(ireg)%levels(ilev)%mixt
    peul => regions(ireg)%levels(ilev)%peul

    CALL rflo_getdimensdummy( regions(ireg),ilev,idcbeg,idcend, &
                              jdcbeg,jdcend,kdcbeg,kdcend )
    CALL rflo_getcelloffset( regions(ireg),ilev,icoff,ijcoff )
    ibc = indijk(idcbeg,jdcbeg,kdcbeg,icoff,ijcoff)
    iec = indijk(idcend,jdcend,kdcend,icoff,ijcoff)

    CALL rflo_getdimensdummynodes( regions(ireg),ilev,idnbeg,idnend, &
                                   jdnbeg,jdnend,kdnbeg,kdnend )
    CALL rflo_getnodeoffset( regions(ireg),ilev,inoff,ijnoff )
    ibn = indijk(idnbeg,jdnbeg,kdnbeg,inoff,ijnoff)
    ien = indijk(idnend,jdnend,kdnend,inoff,ijnoff)

    IF (regions(ireg)%mixtInput%moveGrid) THEN
      ALLOCATE( grid%siVel(ibn:ien),stat=errorflag )
      ALLOCATE( grid%sjVel(ibn:ien),stat=errorflag )
      ALLOCATE( grid%skVel(ibn:ien),stat=errorflag )
    ENDIF
    global%error = errorflag
    IF (global%error /= 0) CALL errorstop( global,err_allocate,__line__ )

    IF (plottype == plot_grid_flow) THEN
      ALLOCATE( mixt%cv(5,ibc:iec),stat=errorflag )
      ALLOCATE( mixt%dv(mixt%nDv,ibc:iec),stat=errorflag )
      IF (regions(ireg)%mixtInput%computeTv) THEN
        ALLOCATE( mixt%tv(mixt%nTv,ibc:iec),stat=errorflag )
      ENDIF
      IF (regions(ireg)%mixtInput%gasModel == gas_model_tcperf) THEN
        ALLOCATE( mixt%gv(mixt%nGv,0:1),stat=errorflag )
      ELSE
        ALLOCATE( mixt%gv(mixt%nGv,ibc:iec),stat=errorflag )
      ENDIF
    ENDIF

    peul%nCv = npeul
    regions(ireg)%peulInput%nPtypes = npeul
    IF (npeul > 0) THEN
      ALLOCATE( peul%cv(npeul,ibc:iec),stat=errorflag )
    ENDIF

    global%error = errorflag
    IF (global%error /= 0) CALL errorstop( global,err_allocate,__line__ )

! - read grid

    CALL rflo_readgridregion( ireg,regions )
    CALL rflo_generatecoarsegrids( regions(ireg) )
    CALL rflo_copygeometrydummy( regions(ireg) )

! - read solution, calc. mixture properties

    IF (plottype == plot_grid_flow) THEN
      CALL rflo_readsolutionregion( ireg,regions )
      CALL mixtureproperties( regions(ireg),ibc,iec,.true. )
    ENDIF

! - read smoke solution

    IF (npeul > 0) THEN
      WRITE(*,*) ' Entering PEUL_ReadSolutionRegion: iReg = ', ireg
      CALL peul_readsolutionregion( ireg,regions )
      WRITE(*,*) ' Exiting  PEUL_ReadSolutionRegion: iReg = ', ireg
    ENDIF

    IF (outputformat == plot_fmt_tecascii) THEN

! --- write data to TECPLOT file (ASCII)

      CALL writetecplotascii( ireg,ilev,plottype,regions(ireg) )

    ENDIF

! - deallocate memory

    DO ilev=1,regions(ireg)%nGridLevels
      grid => regions(ireg)%levels(ilev)%grid
      DEALLOCATE( grid%xyz,stat=errorflag )
      global%error = errorflag
      IF (global%error /= 0) CALL errorstop( global,err_deallocate,__line__ )
    ENDDO

    ilev = regions(ireg)%currLevel
    IF (regions(ireg)%mixtInput%moveGrid) THEN
      grid => regions(ireg)%levels(ilev)%grid
      DEALLOCATE( grid%siVel,stat=errorflag )
      DEALLOCATE( grid%sjVel,stat=errorflag )
      DEALLOCATE( grid%skVel,stat=errorflag )
    ENDIF
    IF (plottype == plot_grid_flow) THEN
      DEALLOCATE( mixt%cv ,stat=errorflag )
      DEALLOCATE( mixt%dv ,stat=errorflag )
      DEALLOCATE( mixt%tv ,stat=errorflag )
      DEALLOCATE( mixt%gv ,stat=errorflag )
    ENDIF
    IF (npeul > 0) DEALLOCATE( peul%cv ,stat=errorflag )
    global%error = errorflag
    IF (global%error /= 0) CALL errorstop( global,err_deallocate,__line__ )

  ENDDO   ! iReg

! finalize --------------------------------------------------------------------

  CALL deregisterfunction( global )

  WRITE(stdout,'(/,A)') solver_name//' Finished.'

#ifdef MPI
  CALL mpi_finalize( global%mpierr )
#endif

1000 FORMAT(a,' Region ',i5,', grid level= ',i2,'.')

END PROGRAM peul_rocflo_post

!******************************************************************************
!
! RCS Revision history:
!
! $Log: Main.F90,v $
! Revision 1.4  2008/12/06 08:45:08  mtcampbe
! Updated license.
!
! Revision 1.3  2008/11/19 22:18:18  mtcampbe
! Added Illinois Open Source License/Copyright
!
! Revision 1.2  2005/10/31 21:09:39  haselbac
! Changed specModel and SPEC_MODEL_NONE
!
! Revision 1.1  2004/12/01 22:29:09  fnajjar
! Initial revision after changing case
!
! Revision 1.3  2004/03/03 23:55:42  jferry
! Allowed particles to be run with Euler case
!
! Revision 1.2  2003/09/26 22:51:04  jferry
! changed header printed out
!
! Revision 1.1  2003/09/25 15:40:22  jferry
! Implented Rocsmoke post-processing
!
!
!******************************************************************************