PEUL_ReadSolutionRegion.F90

Go to the documentation of this file.

! *********************************************************************
! * Rocstar Simulation Suite                                          *
! * Copyright@2015, Illinois Rocstar LLC. All rights reserved.        *
! *                                                                   *
! * Illinois Rocstar LLC                                              *
! * Champaign, IL                                                     *
! * www.illinoisrocstar.com                                           *
! * sales@illinoisrocstar.com                                         *
! *                                                                   *
! * License: See LICENSE file in top level of distribution package or *
! * http://opensource.org/licenses/NCSA                               *
! *********************************************************************
! *********************************************************************
! * THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND,   *
! * EXPRESS OR IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES   *
! * OF MERCHANTABILITY, FITNESS FOR A PARTICULAR PURPOSE AND          *
! * NONINFRINGEMENT.  IN NO EVENT SHALL THE CONTRIBUTORS OR           *
! * COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER       *
! * LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE,   *
! * Arising FROM, OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE    *
! * USE OR OTHER DEALINGS WITH THE SOFTWARE.                          *
! *********************************************************************
!******************************************************************************
!
! Purpose: read in flow solution for one region (for Eulerian particles).
!
! Description: the following solution formats are supported:
!              - RocfloMP ASCII
!              - RocfloMP binary.
!
! Input: regions = dimensions of all regions
!        iReg    = region number.
!
! Output: region%levels%peul%cv = conservative variables (current grid level)
!         global%currentTime    = physical time
!         global%peulResInit    = initial residual.
!
! Notes: solution is read in only for the current grid level;
!        solution is also read in for all dummy cells.
!        There is no transfer of data to other processors.
!
!******************************************************************************
!
! $Id: PEUL_ReadSolutionRegion.F90,v 1.3 2008/12/06 08:44:39 mtcampbe Exp $
!
! Copyright: (c) 2003 by the University of Illinois
!
!******************************************************************************

SUBROUTINE peul_readsolutionregion( iReg,regions ) ! PUBLIC

  USE moddatatypes
  USE moddatastruct, ONLY : t_region
  USE modglobal, ONLY     : t_global
  USE modinterfaces, ONLY : rflo_readdatafileint, rflo_readdatafilereal, &
                            rflo_getdimensdummy, rflo_getcelloffset, &
                            rflo_getdimensphysnodes, rflo_getnodeoffset
  USE moderror
  USE modparameters
  IMPLICIT NONE

#include "Indexing.h"

! ... parameters
  INTEGER,        INTENT(IN) :: ireg
  TYPE(t_region), POINTER    :: regions(:)

! ... loop variables
  INTEGER :: iptype, i, j, k, n

! ... local variables
  CHARACTER(2*CHRLEN+22) :: fhead, fname
  CHARACTER(CHRLEN)      :: rcsidentstring, msg, timestring

  INTEGER :: ilev, iregfile, ipc, jpc, kpc, ndumcells, ioff, ijoff, ijk
  INTEGER :: idcbeg, jdcbeg, kdcbeg, idcend, jdcend, kdcend, ijkbeg, ijkend
  INTEGER :: ipnbeg, ipnend, jpnbeg, jpnend, kpnbeg, kpnend, inoff, ijnoff
  INTEGER :: ndimc, ndimn, ncv, errorflag
  INTEGER, ALLOCATABLE :: ivar(:,:)

  LOGICAL :: fileexists

  REAL(RFREAL), POINTER     :: cv(:,:), cvfile(:,:)
  REAL(RFREAL), ALLOCATABLE :: rvar(:,:)

  TYPE(t_global), POINTER :: global

!******************************************************************************

  rcsidentstring = '$RCSfile: PEUL_ReadSolutionRegion.F90,v $ $Revision: 1.3 $'

  global => regions(ireg)%global

  CALL registerfunction( global,'PEUL_ReadSolutionRegion',&
  'PEUL_ReadSolutionRegion.F90' )

! begin -----------------------------------------------------------------------

! allocate fixed-size temporary data arrays -----------------------------------

  ALLOCATE( ivar(5,1),stat=errorflag )
  ALLOCATE( rvar(2,1),stat=errorflag )
  global%error = errorflag
  IF (global%error /= 0) CALL errorstop( global,err_allocate,__line__ )

! copy time to string ---------------------------------------------------------

  IF (global%flowType == flow_unsteady) THEN
    WRITE(timestring,'(ES11.5)') global%timeStamp
  ELSE
    WRITE(timestring,'(ES11.5)') 0._rfreal
  ENDIF

! open solution file (only if iReg=1) -----------------------------------------

  IF (ireg == 1) THEN

    fhead = trim(global%inDir)//trim(global%casename)

    SELECT CASE(global%solutFormat)
    CASE (format_ascii)
      fhead = trim(fhead)//'.peul_sola_'
    CASE (format_binary)
      fhead = trim(fhead)//'.peul_solb_'
    CASE default
      CALL errorstop( global,err_unknown_format,__line__ )
    END SELECT

    IF (global%flowType == flow_unsteady) THEN
      WRITE(fname,'(A,ES11.5)') trim(fhead), global%timeStamp
    ELSE
      WRITE(fname,'(A,I6.6)')   trim(fhead), global%currentIter
    ENDIF

    INQUIRE(file=fname,exist=fileexists)

    IF (fileexists) THEN

      SELECT CASE(global%solutFormat)
      CASE (format_ascii)
        OPEN(if_peul_solut,file=fname,form=  'formatted',status='old', &
             iostat=errorflag)
      CASE (format_binary)
        OPEN(if_peul_solut,file=fname,form='unformatted',status='old', &
             iostat=errorflag)
      END SELECT
      global%error = errorflag
      IF (global%error /= 0) &
        CALL errorstop( global,err_file_open,__line__,'File: '//trim(fname) )

    ENDIF

! - read time and initial residual

    IF (fileexists) THEN
      CALL rflo_readdatafilereal( global,if_peul_solut,global%solutFormat, &
                                  2,1,rvar )
    ELSE
      rvar(1,1) = 0._rfreal
      rvar(2,1) = 1._rfreal
    ENDIF

    IF (global%flowType==flow_unsteady .AND. global%currentTime>0._rfreal) THEN
      IF (global%currentTime /= rvar(1,1) .AND. &
          .NOT.regions(1)%peulInput%constInit) THEN
        WRITE(msg,1000) rvar(1,1),global%currentTime
        CALL errorstop( global,err_time_solution,__line__,msg//' File: '// &
          trim(fname) )
      ENDIF
    ENDIF
    global%peulResInit = rvar(2,1)

  ENDIF   ! 1st region

! read solution data ----------------------------------------------------------
! get dimensions and pointers

  ilev = regions(ireg)%currLevel
  CALL rflo_getdimensdummy( regions(ireg),ilev,idcbeg,idcend, &
                            jdcbeg,jdcend,kdcbeg,kdcend )
  CALL rflo_getcelloffset( regions(ireg),ilev,ioff,ijoff )
  ijkbeg = indijk(idcbeg,jdcbeg,kdcbeg,ioff,ijoff)
  ijkend = indijk(idcend,jdcend,kdcend,ioff,ijoff)
  ndimc  = ijkend - ijkbeg + 1

  CALL rflo_getdimensphysnodes( regions(ireg),ilev,ipnbeg,ipnend, &
                                jpnbeg,jpnend,kpnbeg,kpnend )
  CALL rflo_getnodeoffset( regions(ireg),ilev,inoff,ijnoff )
  ndimn = (regions(ireg)%levels(ilev)%grid%ipc+1)* &
          (regions(ireg)%levels(ilev)%grid%jpc+1)* &
          (regions(ireg)%levels(ilev)%grid%kpc+1)

  ncv = regions(ireg)%levels(ilev)%peul%nCv

! read region number and dimensions

  CALL rflo_readdatafileint( global,if_peul_solut,global%solutFormat, &
                             5,1,ivar )
  iregfile  = ivar(1,1)
  ipc       = ivar(2,1)
  jpc       = ivar(3,1)
  kpc       = ivar(4,1)
  ndumcells = ivar(5,1)

  IF (iregfile /= ireg) &
    CALL errorstop( global,err_region_number,__line__,'File: '//trim(fname) )
  IF ((ipc /= regions(ireg)%levels(ilev)%grid%ipc) .OR. &
      (jpc /= regions(ireg)%levels(ilev)%grid%jpc) .OR. &
      (kpc /= regions(ireg)%levels(ilev)%grid%kpc)) THEN
    WRITE(msg,1005) ireg,ipc,jpc,kpc
    CALL errorstop( global,err_grid_dimensions,__line__,msg )
  ENDIF
  IF (ndumcells /= regions(ireg)%nDumCells) THEN
    WRITE(msg,1010) ireg,ndumcells,regions(ireg)%nDumCells
    CALL errorstop( global,err_grid_dumcells,__line__,msg )
  ENDIF

! read data

  ALLOCATE( cvfile(ncv,ndimc),stat=errorflag )
  global%error = errorflag
  IF (global%error /= 0) CALL errorstop( global,err_allocate,__line__ )

  CALL rflo_readdatafilereal( global,if_peul_solut,global%solutFormat, &
                              ncv,ndimc,cvfile )

! copy solution into data structure

  cv => regions(ireg)%levels(ilev)%peul%cv

  n = 0
  DO k=kdcbeg,kdcend
    DO j=jdcbeg,jdcend
      DO i=idcbeg,idcend
        n   = n + 1
        ijk = indijk(i,j,k,ioff,ijoff)
        cv(:,ijk) = cvfile(:,n)
      ENDDO
    ENDDO
  ENDDO

  IF (ASSOCIATED(cvfile)) THEN
    DEALLOCATE( cvfile,stat=errorflag )
    global%error = errorflag
    IF (global%error /= 0) CALL errorstop( global,err_deallocate,__line__ )
    nullify( cvfile )
  ENDIF

! finalize --------------------------------------------------------------------

  IF (ireg == global%nRegions) THEN
    CLOSE(if_peul_solut,iostat=errorflag)
    global%error = errorflag
    IF (global%error /= 0) &
      CALL errorstop( global,err_file_close,__line__,'File: '//trim(fname) )
  ENDIF

  CALL deregisterfunction( global )

1000 FORMAT('Time in file is= ',es12.5,' but it should be= ',e12.5,'.')
1005 FORMAT('Region ',i5,', ipc= ',i6,', jpc= ',i6,', kpc= ',i6,'.')
1010 FORMAT('Region ',i5,', # dummy cells=',i2,' but should be= ',i1)

END SUBROUTINE peul_readsolutionregion

!******************************************************************************
!
! RCS Revision history:
!
! $Log: PEUL_ReadSolutionRegion.F90,v $
! Revision 1.3  2008/12/06 08:44:39  mtcampbe
! Updated license.
!
! Revision 1.2  2008/11/19 22:17:51  mtcampbe
! Added Illinois Open Source License/Copyright
!
! Revision 1.1  2004/12/01 21:09:49  haselbac
! Initial revision after changing case
!
! Revision 1.4  2004/04/15 16:04:03  jferry
! minor formatting (removed trailing spaces)
!
! Revision 1.3  2003/09/26 22:52:12  jferry
! changed file number for read/write of rocsmoke solutions
!
! Revision 1.2  2003/05/15 02:57:05  jblazek
! Inlined index function.
!
! Revision 1.1  2003/05/07 15:11:58  jferry
! Added routine PEUL_ReadSolutionRegion
!
!******************************************************************************