RFLO_ReadRegionTopology.F90

Go to the documentation of this file.

! *********************************************************************
! * Rocstar Simulation Suite                                          *
! * Copyright@2015, Illinois Rocstar LLC. All rights reserved.        *
! *                                                                   *
! * Illinois Rocstar LLC                                              *
! * Champaign, IL                                                     *
! * www.illinoisrocstar.com                                           *
! * sales@illinoisrocstar.com                                         *
! *                                                                   *
! * License: See LICENSE file in top level of distribution package or *
! * http://opensource.org/licenses/NCSA                               *
! *********************************************************************
! *********************************************************************
! * THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND,   *
! * EXPRESS OR IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES   *
! * OF MERCHANTABILITY, FITNESS FOR A PARTICULAR PURPOSE AND          *
! * NONINFRINGEMENT.  IN NO EVENT SHALL THE CONTRIBUTORS OR           *
! * COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER       *
! * LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE,   *
! * Arising FROM, OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE    *
! * USE OR OTHER DEALINGS WITH THE SOFTWARE.                          *
! *********************************************************************
!******************************************************************************
!
! Purpose: read in topology of all regions (done on all processors);
!          figure out which l1,l2 directions are aligned on adjacent regions.
!
! Description: none.
!
! Input: none.
!
! Output: global%nRegions = number of regions
!         regions         = region dimensions and topology
!
! Notes: none.
!
!******************************************************************************
!
! $Id: RFLO_ReadRegionTopology.F90,v 1.12 2009/08/27 14:04:49 mtcampbe Exp $
!
! Copyright: (c) 2001 by the University of Illinois
!
!******************************************************************************

SUBROUTINE rflo_readregiontopology( global,regions )

  USE moddatatypes
  USE modbndpatch, ONLY   : t_patch
  USE moddatastruct, ONLY : t_region
  USE modglobal, ONLY     : t_global
  USE moderror
  USE modmpi
  USE modparameters
  IMPLICIT NONE

! ... parameters
  TYPE(t_global), POINTER :: global
  TYPE(t_region), POINTER :: regions(:)

! ... loop variables
  INTEGER :: ireg, ipatch

! ... local variables
  CHARACTER(2*CHRLEN+4) :: fname
  CHARACTER(CHRLEN)     :: msg

  INTEGER :: regionnum, nlevels, npatches, ipc, jpc, kpc, bctype, align
  INTEGER :: ncellstot, errorflag

  TYPE(t_patch), POINTER :: patch

!******************************************************************************

  CALL registerfunction( global,'RFLO_ReadRegionTopology',&
  'RFLO_ReadRegionTopology.F90' )

! open file & read number of regions

  fname = trim(global%inDir)//trim(global%casename)//'.top'
  OPEN(if_topol,file=fname,form='formatted',status='old',iostat=errorflag)
  global%error = errorflag
  IF (global%error /= 0) &
    CALL errorstop( global,err_file_open,&
    __line__,'File: '//trim(fname) )

  READ(if_topol,'(1X)',err=10,end=10)
  READ(if_topol,'(1X)',err=10,end=10)
  READ(if_topol,   *  ,err=10,end=10) global%nRegions

! allocate memory for region structure

  ALLOCATE( regions(global%nRegions),stat=errorflag )
  global%error = errorflag
  IF (global%error /= 0) CALL errorstop( global,err_allocate,__line__ )

! read topology of each region; store data at grid level 1 (finest grid)

  ncellstot = 0

  DO ireg=1,global%nRegions
    READ(if_topol,*,err=10,end=10) regionnum,nlevels
    READ(if_topol,*,err=10,end=10) npatches,ipc,jpc,kpc

    ALLOCATE( regions(regionnum)%levels(nlevels),stat=errorflag )
    ALLOCATE( regions(regionnum)%levels(1)%patches(npatches),stat=errorflag )
    global%error = errorflag
    IF (global%error /= 0) CALL errorstop( global,err_allocate,__line__ )

    regions(regionnum)%iRegionGlobal        = regionnum
    regions(regionnum)%nGridLevels          = nlevels
    regions(regionnum)%nPatches             = npatches
    regions(regionnum)%levels(1)%grid%ipc   = ipc
    regions(regionnum)%levels(1)%grid%jpc   = jpc
    regions(regionnum)%levels(1)%grid%kpc   = kpc
    regions(regionnum)%active               = active
    regions(regionnum)%mixtInput%externalBc = .false.

    ncellstot = ncellstot + ipc*jpc*kpc

! - set pointer "global" within regions

    regions(regionnum)%global => global

! - loop over all patches of a region

    DO ipatch=1,npatches
      patch => regions(regionnum)%levels(1)%patches(ipatch)
      READ(if_topol,*,err=10,end=10)     &
        patch%bcType   ,patch%lbound   , &
        patch%l1beg    ,patch%l1end    , &
        patch%l2beg    ,patch%l2end    , &
        patch%srcRegion,patch%srcLbound, &
        patch%srcL1beg ,patch%srcL1end , &
        patch%srcL2beg ,patch%srcL2end , &
        patch%bcCoupled

      IF (patch%bcCoupled <= 0) THEN
        patch%bcCoupled = bc_internal
        patch%bcMotion  = bc_internal
      ELSE
        patch%bcCoupled = bc_external
        patch%bcMotion  = bc_external
      ENDIF
      IF (patch%bcType == bc_slipwall_free   .OR. &
          patch%bcType == bc_slipwall_fixed  .OR. &
          patch%bcType == bc_slipwall_xslide .OR. &
          patch%bcType == bc_slipwall_yslide .OR. &
          patch%bcType == bc_slipwall_zslide .OR. &
          patch%bcType == bc_slipwall_xyslide .OR. &
          patch%bcType == bc_slipwall_xzslide .OR. &
          patch%bcType == bc_slipwall_yzslide) THEN
        patch%bcMotion  = bc_external
      ENDIF
      IF (patch%bcType == bc_symmetry_free   .OR. &
          patch%bcType == bc_symmetry_fixed  .OR. &
          patch%bcType == bc_symmetry_xslide .OR. &
          patch%bcType == bc_symmetry_yslide .OR. &
          patch%bcType == bc_symmetry_zslide .OR. &
          patch%bcType == bc_symmetry_xyslide .OR. &
          patch%bcType == bc_symmetry_xzslide .OR. &
          patch%bcType == bc_symmetry_yzslide) THEN
        patch%bcMotion  = bc_external
      ENDIF
      IF (patch%bcType == bc_noslipwall_free   .OR. &
          patch%bcType == bc_noslipwall_fixed  .OR. &
          patch%bcType == bc_noslipwall_xslide .OR. &
          patch%bcType == bc_noslipwall_yslide .OR. &
          patch%bcType == bc_noslipwall_zslide .OR. &
          patch%bcType == bc_noslipwall_xyslide .OR. &
          patch%bcType == bc_noslipwall_xzslide .OR. &
          patch%bcType == bc_noslipwall_yzslide) THEN
        patch%bcMotion  = bc_external
      ENDIF
      IF (patch%bcType == bc_outflow_free   .OR. &
          patch%bcType == bc_outflow_fixed  .OR. &
          patch%bcType == bc_outflow_xslide .OR. &
          patch%bcType == bc_outflow_yslide .OR. &
          patch%bcType == bc_outflow_zslide .OR. &
          patch%bcType == bc_outflow_xyslide .OR. &
          patch%bcType == bc_outflow_xzslide .OR. &
          patch%bcType == bc_outflow_yzslide) THEN
        patch%bcMotion  = bc_external
      ENDIF
      IF (patch%bcCoupled == bc_external) &
        regions(regionnum)%mixtInput%externalBc = .true.

! --- check if BC type within range
      IF (patch%bcType<bc_code_min .OR. patch%bcType>bc_code_max) THEN
        WRITE(msg,'(A,I5,A)') 'Boundary code ',patch%bcType," ???"
        CALL errorstop( global,err_unknown_bc,__line__,msg )
      ENDIF

! --- check if region face between 1 and 6
      IF (patch%lbound<1 .OR. patch%lbound>6) &
        CALL errorstop( global,err_wrong_regionface,__line__ )

! --- initialize patch data
      patch%mixt%bcSet     = .true.          ! defaults: BC set
      patch%mixt%distrib   = bcdat_constant  !   no distribution
      patch%mixt%nData     = 0               !   no data
      patch%mixt%nSwitches = 0               !   no switches

      patch%turb%bcSet     = .true.          ! defaults: BC set
      patch%turb%distrib   = bcdat_constant  !   no distribution
      patch%turb%nData     = 0               !   no data
      patch%turb%nSwitches = 0               !   no switches

      patch%spec%bcSet     = .true.          ! defaults: BC set
      patch%spec%distrib   = bcdat_constant  !   no distribution
      patch%spec%nData     = 0               !   no data
      patch%spec%nSwitches = 0               !   no switches

      patch%peul%bcSet     = .true.          ! defaults: BC set
      patch%peul%distrib   = bcdat_constant  !   no distribution
      patch%peul%nData     = 0               !   no data
      patch%peul%nSwitches = 0               !   no switches

      patch%valRadi%bcSet     = .true.          ! defaults: BC set
      patch%valRadi%distrib   = bcdat_constant  !   no distribution
      patch%valRadi%nData     = 0               !   no data
      patch%valRadi%nSwitches = 0               !   no switches

! --- unset BCs for certain types (where user input required)
      bctype = patch%bcType

      IF ((bctype>=bc_slipwall   .AND. bctype<=bc_slipwall  +bc_range) .OR. &
          (bctype>=bc_noslipwall .AND. bctype<=bc_noslipwall+bc_range) .OR. &
          (bctype>=bc_inflow     .AND. bctype<=bc_inflow    +bc_range) .OR. &
          (bctype>=bc_outflow    .AND. bctype<=bc_outflow   +bc_range) .OR. &
          (bctype>=bc_farfield   .AND. bctype<=bc_farfield  +bc_range) .OR. &
          (bctype>=bc_injection  .AND. bctype<=bc_injection +bc_range)) THEN
        patch%mixt%bcSet = .false.     ! will be set to true if BC defined
      ENDIF

      IF ((bctype>=bc_inflow     .AND. bctype<=bc_inflow    +bc_range) .OR. &
          (bctype>=bc_farfield   .AND. bctype<=bc_farfield  +bc_range) .OR. &
          (bctype>=bc_injection  .AND. bctype<=bc_injection +bc_range)) THEN
        patch%peul%bcSet = .false.     ! will be set to true if BC defined
      ENDIF

    ENDDO   ! iPatch
  ENDDO     ! iReg

  CLOSE(if_topol,iostat=errorflag)
  global%error = errorflag
  IF (global%error /= 0) &
    CALL errorstop( global,err_file_close,__line__,'File: '//trim(fname) )

! find aligned l1,l2 coordinates ----------------------------------------------

  DO ireg=1,global%nRegions
    DO ipatch=1,regions(ireg)%nPatches

      patch => regions(ireg)%levels(1)%patches(ipatch)

! --- patch with a neighbor

      bctype = patch%bcType
      IF ((bctype>=bc_regionconf .AND. bctype<=bc_regionconf+bc_range) .OR. &
          (bctype>=bc_regionint  .AND. bctype<=bc_regionint +bc_range) .OR. &
          (bctype>=bc_regnonconf .AND. bctype<=bc_regnonconf+bc_range) .OR. &
          (bctype>=bc_tra_peri   .AND. bctype<=bc_tra_peri  +bc_range) .OR. &
          (bctype>=bc_rot_peri   .AND. bctype<=bc_rot_peri  +bc_range)) THEN

! ----- check if source region within possible range

        IF (patch%srcRegion > global%nRegions) &
          CALL errorstop( global,err_region_range,__line__ )

! ----- check number of source region face

        IF (patch%srcLbound<1 .OR. patch%srcLbound>6) &
          CALL errorstop( global,err_wrong_regionface,__line__,'(source region).' )

! ----- present patch
        IF (patch%l1beg<0 .OR. patch%l1end<0 ) THEN        ! 1st direction
          align       = 10
          patch%l1beg = abs(patch%l1beg)
          patch%l1end = abs(patch%l1end)
          IF (patch%l2beg<0 .OR. patch%l2end<0 ) &
            CALL errorstop( global,err_patch_2align,__line__ )
        ELSE IF (patch%l2beg<0 .OR. patch%l2end<0 ) THEN   ! 2nd direction
          align       = 20
          patch%l2beg = abs(patch%l2beg)
          patch%l2end = abs(patch%l2end)
        ELSE
          CALL errorstop( global,err_patch_noalign,__line__ )
        ENDIF

! ----- source patch
        IF (patch%srcL1beg<0 .OR. patch%srcL1end<0 ) THEN  ! 1st direction
          align          = align + 1
          patch%srcL1beg = abs(patch%srcL1beg)
          patch%srcL1end = abs(patch%srcL1end)
          IF (patch%srcL2beg<0 .OR. patch%srcL2end<0 ) &
            CALL errorstop( global,err_patch_2align,__line__ )
        ELSE IF (patch%srcL2beg<0 .OR. patch%srcL2end<0 ) THEN   ! 2nd dir.
          align          = align + 2
          patch%srcL2beg = abs(patch%srcL2beg)
          patch%srcL2end = abs(patch%srcL2end)
        ELSE
          CALL errorstop( global,err_patch_noalign,__line__ )
        ENDIF

! ----- set alignment flag (1=yes, 0=no)
        IF (align==11 .OR. align==22) THEN
          patch%align = .true.
        ELSE
          patch%align = .false.
        ENDIF

! --- no neighbor

      ELSE
        patch%srcRegion = -999
        patch%srcPatch  = -999
        patch%align     = .true.
        patch%srcLbound = -999
        patch%srcL1beg  = -999
        patch%srcL1end  = -999
        patch%srcL2beg  = -999
        patch%srcL2end  = -999
      ENDIF

    ENDDO   ! iPatch
  ENDDO     ! iReg

! print some info -------------------------------------------------------------

  IF (global%myProcid==masterproc .AND. global%verbLevel>=verbose_med) THEN
    WRITE(stdout,'(/,A,I8)') solver_name//' total no. of cells  = ',ncellstot
    WRITE(stdout,'(A,I8,/)') solver_name//' no. of grid regions = ', &
                             global%nRegions
  ENDIF

! error handling --------------------------------------------------------------

  CALL deregisterfunction( global )
  goto 999

10  CONTINUE
  CALL errorstop( global,err_file_read,__line__,'File: '//trim(fname) )

999 CONTINUE

END SUBROUTINE rflo_readregiontopology

!******************************************************************************
!
! RCS Revision history:
!
! $Log: RFLO_ReadRegionTopology.F90,v $
! Revision 1.12  2009/08/27 14:04:49  mtcampbe
! Updated to enable burning motion with symmetry boundaries and enhanced
! burnout code.
!
! Revision 1.11  2008/12/06 08:44:07  mtcampbe
! Updated license.
!
! Revision 1.10  2008/11/19 22:17:21  mtcampbe
! Added Illinois Open Source License/Copyright
!
! Revision 1.9  2006/08/28 11:42:12  rfiedler
! Add grid motion constraint types for outflow BC.
!
! Revision 1.8  2006/08/24 13:15:36  rfiedler
! Rocflo now supports XYSLIDE, XZSLIDE, and YZSLIDE instead of TANGEN constraint.
!
! Revision 1.7  2006/08/19 15:38:22  mparmar
! Renamed patch variables
!
! Revision 1.6  2006/05/08 22:30:40  wasistho
! added prop-NS capability
!
! Revision 1.5  2006/05/04 04:24:28  wasistho
! include BC_SLIPWALL_FIXED in bcMotion externals
!
! Revision 1.4  2005/06/20 20:24:25  wasistho
! changed bcType to patch%bcType since bcType wasn't defined yet
!
! Revision 1.3  2005/06/19 05:31:16  wasistho
! shift index rocprop slipwalls
!
! Revision 1.2  2005/06/13 21:44:44  wasistho
! added new patch variable patch%bcMotion
!
! Revision 1.1  2004/11/29 21:25:16  wasistho
! lower to upper case
!
! Revision 1.14  2004/07/02 23:01:28  wasistho
! filled iRegionGlobal for Rocflo
!
! Revision 1.13  2003/05/15 02:57:01  jblazek
! Inlined index function.
!
! Revision 1.12  2003/02/11 22:52:50  jferry
! Initial import of Rocsmoke
!
! Revision 1.11  2002/10/12 03:20:50  jblazek
! Replaced [io]stat=global%error with local errorFlag for Rocflo.
!
! Revision 1.10  2002/09/27 03:34:04  jblazek
! BH seems to need "" around ??? in line 122.
!
! Revision 1.9  2002/09/27 00:57:09  jblazek
! Changed makefiles - no makelinks needed.
!
! Revision 1.8  2002/09/20 22:22:35  jblazek
! Finalized integration into GenX.
!
! Revision 1.7  2002/09/05 17:40:19  jblazek
! Variable global moved into regions().
!
! Revision 1.6  2002/08/15 19:48:05  jblazek
! Implemented grid deformation capability.
!
! Revision 1.5  2002/07/16 21:34:37  jblazek
! Prefixed screen output with SOLVER_NAME.
!
! Revision 1.4  2002/07/12 21:50:07  jblazek
! Added tool to split single grid into multiple regions.
!
! Revision 1.3  2002/03/18 21:56:39  jblazek
! Finished multiblock and MPI.
!
! Revision 1.2  2002/02/27 18:38:19  jblazek
! Changed extrapol. to dummy cells at injection boundaries and slip walls.
!
! Revision 1.1  2002/02/21 23:25:04  jblazek
! Blocks renamed as regions.
!
! Revision 1.6  2002/02/01 00:00:24  jblazek
! Edge and corner cells defined for each level.
!
! Revision 1.5  2002/01/11 17:13:30  jblazek
! Added time stamp or iteration number to file names.
!
! Revision 1.4  2001/12/22 00:09:36  jblazek
! Added routines to store grid and solution.
!
! Revision 1.3  2001/12/19 23:09:20  jblazek
! Added routines to read grid and solution.
!
! Revision 1.2  2001/12/08 00:18:41  jblazek
! Added routines to read BC input file.
!
! Revision 1.1.1.1  2001/12/03 21:44:05  jblazek
! Import of RocfluidMP
!
!******************************************************************************