TURB_DerivedInputValues.F90

Go to the documentation of this file.

! *********************************************************************
! * Rocstar Simulation Suite                                          *
! * Copyright@2015, Illinois Rocstar LLC. All rights reserved.        *
! *                                                                   *
! * Illinois Rocstar LLC                                              *
! * Champaign, IL                                                     *
! * www.illinoisrocstar.com                                           *
! * sales@illinoisrocstar.com                                         *
! *                                                                   *
! * License: See LICENSE file in top level of distribution package or *
! * http://opensource.org/licenses/NCSA                               *
! *********************************************************************
! *********************************************************************
! * THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND,   *
! * EXPRESS OR IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES   *
! * OF MERCHANTABILITY, FITNESS FOR A PARTICULAR PURPOSE AND          *
! * NONINFRINGEMENT.  IN NO EVENT SHALL THE CONTRIBUTORS OR           *
! * COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER       *
! * LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE,   *
! * Arising FROM, OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE    *
! * USE OR OTHER DEALINGS WITH THE SOFTWARE.                          *
! *********************************************************************
!******************************************************************************
!
! Purpose: Set values derived from user input.
!
! Description: Derived variables are mostly components of turbInput data type.
!
! Input: regions = Input parameters for all regions.
!
! Output: regions = Derived variables stored as turbInput data.
!
! Notes: none.
!
!******************************************************************************
!
! $Id: TURB_DerivedInputValues.F90,v 1.11 2008/12/06 08:44:41 mtcampbe Exp $
!
! Copyright: (c) 2001 by the University of Illinois
!
!******************************************************************************

SUBROUTINE turb_derivedinputvalues( regions )

  USE moddatatypes
  USE moddatastruct, ONLY : t_region
  USE modglobal, ONLY     : t_global
  USE modturbulence, ONLY : t_turb_input
  USE moderror
  USE modmpi
  USE modparameters
  USE turb_modparameters
  IMPLICIT NONE

! ... parameters
  TYPE(t_region), POINTER :: regions(:)

! ... loop variables
  INTEGER :: ireg, m

! ... local variables
  CHARACTER(CHRLEN) :: rcsidentstring
  TYPE(t_global), POINTER     :: global
  TYPE(t_turb_input), POINTER :: input

  INTEGER :: flowmodel, turbmodel, ilev, nsv, nst, errorflag
#ifdef RFLO
  REAL(RFREAL)      :: one3rd, filtlscale, rndel(3)
#endif

!******************************************************************************

  rcsidentstring = '$RCSfile: TURB_DerivedInputValues.F90,v $'

  global => regions(1)%global
  CALL registerfunction( global,'TURB_DerivedInputValues',&
  'TURB_DerivedInputValues.F90' )

  IF ( global%myProcid == masterproc .AND. &
       global%verbLevel > verbose_none ) THEN
    WRITE(stdout,'(A,1X,A)') solver_name,'Entering TURB_DerivedInputValues...'
  END IF ! global%verbLevel

! set local constants ---------------------------------------------------------

#ifdef RFLO
  one3rd = 1._rfreal/3._rfreal
#endif

! region related data (all levels) --------------------------------------------

#ifdef RFLO
  DO ireg = 1,global%nRegions
#endif
#ifdef RFLU
  DO ireg = lbound(regions,1),ubound(regions,1)
#endif

    flowmodel =  regions(ireg)%mixtInput%flowModel
    turbmodel =  regions(ireg)%mixtInput%turbModel
    input     => regions(ireg)%turbInput

! - number of N-S transport variables

#ifdef RFLO
    DO ilev=1,regions(ireg)%nGridLevels
      regions(ireg)%levels(ilev)%mixt%nTv = 4 
    ENDDO
#endif
#ifdef RFLU
    regions(ireg)%mixtInput%nTv = 4 
#endif

! - number of dummy cells

#ifdef RFLO
    IF (regions(ireg)%nDumCells < 3) THEN
      IF ((turbmodel==turb_model_scalsim).OR. &
          (turbmodel==turb_model_dynsmag)) THEN     ! LES with filtering
        IF ((input%filterWidth(diri) > 1) .OR. &
            (input%filterWidth(dirj) > 1) .OR. &
            (input%filterWidth(dirk) > 1)) THEN
          regions(ireg)%nDumCells = 3
        ENDIF
      ELSEIF (turbmodel==turb_model_dynmixd .OR. &
              turbmodel==turb_model_hdessa) THEN
        regions(ireg)%nDumCells = 3
      ELSE
      ENDIF
    ENDIF
#endif

! - GENERAL TURB --------------------------------------------------------------
! - class of turbulence model

    IF ((turbmodel==turb_model_fixsmag).OR. &
        (turbmodel==turb_model_scalsim).OR. &
        (turbmodel==turb_model_dynsmag).OR. &
        (turbmodel==turb_model_dynmixd)) THEN   
      input%modelClass = model_les
    ELSEIF ((turbmodel==turb_model_sa).OR. &
            (turbmodel==turb_model_dessa).OR. &                 
            (turbmodel==turb_model_hdessa)) THEN                 
      input%modelClass = model_rans
    ENDIF

! - number of conservative and derived variables

    input%nCv = 0
    input%nDv = 0
    IF (input%modelClass == model_les) THEN
      input%nDv = 1
    ELSEIF (input%modelClass == model_rans) THEN
      IF ((turbmodel==turb_model_sa).OR. & 
          (turbmodel==turb_model_dessa).OR. &
          (turbmodel==turb_model_hdessa)) THEN
        input%nCv = 1
      ENDIF
    ENDIF

! - number of zero-one switch fields

    IF (turbmodel==turb_model_fixsmag .OR. &
        turbmodel==turb_model_dynsmag .OR. &
        turbmodel==turb_model_dynmixd) THEN
      input%nZof = input%nZof + 1
      global%calcFaceCtr = .true.
    ENDIF

! - number of permanent and collected variables to be time averaged

    input%nFixSt = 3
    nst = 0
#ifdef STATS
    IF ((global%flowType == flow_unsteady) .AND. &
        (global%doStat == active) .AND. &
        (global%turbNStat > 0)) THEN
      nst = 3
    ENDIF
#endif
    input%nSt = 0  ! = nSt to activate

! - number of stress components

    nsv       = 6
    input%nSv = 0  ! = nSv to activate

! - number of gradient variables

    IF ((turbmodel == turb_model_dynsmag).OR. &
        (turbmodel == turb_model_dynmixd)) THEN
#ifdef RFLO
      input%nGrad = 9
#endif
#ifdef RFLU
      input%nGrad = 3
#endif
    ELSEIF ((turbmodel == turb_model_sa).OR. &
            (turbmodel == turb_model_dessa).OR. &
            (turbmodel == turb_model_hdessa)) THEN
#ifdef RFLO
      input%nGrad = 3
#endif
#ifdef RFLU
      input%nGrad = 1
#endif
    ELSE
      input%nGrad = 0
    ENDIF

! - LES SPECIFIC --------------------------------------------------------------
! - filter width scaling factor

#ifdef RFLO
    IF (input%deltaType == deltype_cbrt) THEN
      filtlscale = 1._rfreal
    ELSEIF (input%deltaType == deltype_sqrt) THEN
      filtlscale = 3._rfreal
    ENDIF

    rndel(1) = REAL(input%filterWidth(DIRI)) 
    rndel(2) = REAL(input%filterWidth(DIRJ)) 
    rndel(3) = REAL(input%filterWidth(DIRK)) 
    input%delFac2 = (rndel(1)*rndel(2)*rndel(3))**one3rd
    IF (input%delFac2 < real_small) THEN
      input%delFac2 = sqrt(rndel(1)*rndel(2))+ &
                      sqrt(rndel(1)*rndel(3))+ &
                      sqrt(rndel(2)*rndel(3))
    ENDIF
    IF ((input%filterWidth(diri)/=0.AND.input%filterWidth(dirj)==0      &
                                   .AND.input%filterWidth(dirk)==0).OR. &
        (input%filterWidth(diri)==0.AND.input%filterWidth(dirj)/=0      &
                                   .AND.input%filterWidth(dirk)==0).OR. &
        (input%filterWidth(diri)==0.AND.input%filterWidth(dirj)==0      &
                                   .AND.input%filterWidth(dirk)/=0)) THEN
      input%delFac2 = rndel(1)+rndel(2)+rndel(3)
    ENDIF
    input%delFac2 = filtlscale*input%delFac2**2
#endif
#ifdef RFLU
    input%delFac2 = REAL(input%filterwidth(diri))
    input%delFac2 = input%delFac2**2
#endif

    IF (turbmodel==turb_model_fixsmag) THEN
      input%delFac2 = 1._rfreal
    ENDIF

! - RANS SPECIFIC -------------------------------------------------------------
! - model constants

#ifdef RFLO
    IF (global%flowType == flow_unsteady) THEN
      input%smoocf = -1._rfreal
    ENDIF
#endif

    IF ((turbmodel == turb_model_sa).OR. &
        (turbmodel == turb_model_dessa).OR. &
        (turbmodel == turb_model_hdessa)) THEN
      ALLOCATE( input%const(mc_sa_nelm),stat=errorflag )
      global%error = errorflag
      IF (global%error /= 0) CALL errorstop( global,err_allocate,__line__ )

      input%const(mc_sa_cb1)   = 0.1355_rfreal
      input%const(mc_sa_cb2)   = 0.622_rfreal
      input%const(mc_sa_cw2)   = 0.3_rfreal
      input%const(mc_sa_cw3)   = 2.0_rfreal
      input%const(mc_sa_cv1)   = 7.1_rfreal
      input%const(mc_sa_rsig)  = 3.0_rfreal/2.0_rfreal
      input%const(mc_sa_rkap)  = 1.0_rfreal/0.41_rfreal
      input%const(mc_sa_cw1)   = &
            input%const(mc_sa_cb1)*input%const(mc_sa_rkap)**2 + &
            (1._rfreal+input%const(mc_sa_cb2))*input%const(mc_sa_rsig)
    ELSE
      nullify( input%const )
    ENDIF

  ENDDO   ! iReg

! finalize --------------------------------------------------------------------

  IF ( global%myProcid == masterproc .AND. &
       global%verbLevel > verbose_none ) THEN
    WRITE(stdout,'(A,1X,A)') solver_name,'Leaving TURB_DerivedInputValues.'
  END IF ! global%verbLevel

  CALL deregisterfunction( global )

END SUBROUTINE turb_derivedinputvalues

!******************************************************************************
!
! RCS Revision history:
!
! $Log: TURB_DerivedInputValues.F90,v $
! Revision 1.11  2008/12/06 08:44:41  mtcampbe
! Updated license.
!
! Revision 1.10  2008/11/19 22:17:53  mtcampbe
! Added Illinois Open Source License/Copyright
!
! Revision 1.9  2006/02/04 05:00:05  wasistho
! added enter and leave statements
!
! Revision 1.8  2006/01/17 17:25:22  wasistho
! applied tripping to all eddy viscosity models
!
! Revision 1.7  2006/01/12 09:49:56  wasistho
! enabled tripping fixed Smagorinsky
!
! Revision 1.6  2005/04/18 21:40:02  wasistho
! use nDumCell=3 for hybrid DES
!
! Revision 1.5  2005/03/09 06:34:51  wasistho
! incorporated HDESSA
!
! Revision 1.4  2004/10/22 23:16:35  wasistho
! set max. number of collected extra statistics, nSt to 3
!
! Revision 1.3  2004/08/09 18:38:40  wasistho
! fixed input%delFac2 for RFLU
!
! Revision 1.2  2004/03/19 02:45:21  wasistho
! prepared for RFLU
!
! Revision 1.1  2004/03/05 04:37:00  wasistho
! changed nomenclature
!
! Revision 1.10  2003/10/26 00:24:52  wasistho
! another slightly more accurate model constant
!
! Revision 1.9  2003/10/24 20:56:49  wasistho
! corrected SA model constant cb2
!
! Revision 1.8  2003/10/07 23:56:05  wasistho
! set RaNS smoocf to -1.0 for unsteady flow
!
! Revision 1.6  2003/08/01 22:17:25  wasistho
! prepared rocturb for Genx
!
! Revision 1.5  2003/07/22 02:59:09  wasistho
! prepare more accurate rocturb restart
!
! Revision 1.4  2003/05/24 02:41:56  wasistho
! sv collector turned off
!
! Revision 1.3  2003/05/24 02:10:51  wasistho
! turbulence statistics expanded
!
! Revision 1.2  2002/10/15 00:00:00  wasistho
! Removed temporary safety
!
! Revision 1.1  2002/10/14 23:55:29  wasistho
! Install Rocturb
!
!
!******************************************************************************