TURB_coViscousFluxesFlu.F90

Go to the documentation of this file.

! *********************************************************************
! * Rocstar Simulation Suite                                          *
! * Copyright@2015, Illinois Rocstar LLC. All rights reserved.        *
! *                                                                   *
! * Illinois Rocstar LLC                                              *
! * Champaign, IL                                                     *
! * www.illinoisrocstar.com                                           *
! * sales@illinoisrocstar.com                                         *
! *                                                                   *
! * License: See LICENSE file in top level of distribution package or *
! * http://opensource.org/licenses/NCSA                               *
! *********************************************************************
! *********************************************************************
! * THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND,   *
! * EXPRESS OR IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES   *
! * OF MERCHANTABILITY, FITNESS FOR A PARTICULAR PURPOSE AND          *
! * NONINFRINGEMENT.  IN NO EVENT SHALL THE CONTRIBUTORS OR           *
! * COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER       *
! * LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE,   *
! * Arising FROM, OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE    *
! * USE OR OTHER DEALINGS WITH THE SOFTWARE.                          *
! *********************************************************************
!******************************************************************************
!
! Purpose: Compute total viscous fluxes and add them to dissipation.
!
! Description: total viscous flux is superposition of laminar and turbulent:
!              fv_total = sigma_ij + tau_ij
!                       = mu_l.S_ij + tau_ij
!              for eddy viscosity type turbulence model:
!              fv_total = (mu_l+mu_t).S_ij, otherwise
!              fv_total = mu_l.S_ij + m_ij, where m_ij is a model for tau_ij
!
! Input: region = data of current region.
!
! Output: mixt%diss = total viscous fluxes + num. dissipation
!
! Notes: 
!   1. This routine is similar to routine ViscousFluxes for laminar flow.
!   2. THIS ROUTINE IS BROKEN FOR ROCFLU - CANNOT ADAPT EASILY TO CHANGES
!      IN ROCFLU, WILL NOT BE USED IN ROCFLU.
!
!******************************************************************************
!
! $Id: TURB_coViscousFluxesFlu.F90,v 1.9 2008/12/06 08:44:43 mtcampbe Exp $
!
! Copyright: (c) 2001 by the University of Illinois
!
!******************************************************************************

SUBROUTINE turb_coviscousfluxes( region ) ! PUBLIC

  USE moddatatypes
  USE modbndpatch, ONLY   : t_patch
  USE moddatastruct, ONLY : t_region
  USE modturbulence, ONLY : t_turb
  USE modglobal, ONLY     : t_global
  USE rflu_modviscousflux, ONLY: rflu_viscousfluxes, rflu_viscousfluxespatches  
  USE rflu_modconvertcv, ONLY  : rflu_convertcvcons2prim, & 
                                 rflu_convertcvprim2cons  
  USE turb_modinterfaces, ONLY : turb_calcstrainrate, turb_getmodelstresscell, &
                                 turb_gettvcell,      turb_lesfluxfixsmag, &
                                 turb_lesfluxscalsim, turb_lesgeteddyvis, &
                                 turb_ranssavisflux,  turb_ranssageteddyvis, &
                                 turb_ranstotaltv,    turb_visfluxeddy
  USE moderror
  USE modparameters
  USE turb_modparameters
  IMPLICIT NONE

! ... parameters
  TYPE(t_region), POINTER :: region

! ... loop variables
  INTEGER :: ipatch

! ... local variables
  CHARACTER(CHRLEN)       :: rcsidentstring
  TYPE(t_global), POINTER :: global
  TYPE(t_turb), POINTER   :: turb
  TYPE(t_patch), POINTER  :: patch
 
  INTEGER :: turbmodel, modelclass, errorflag, prevcvstate
  INTEGER :: npatches, ncellstot, nfaces, nfacestot, nbfaces, nbfacestot
  INTEGER :: ibc, iec, ibn, ien, gradindx(3)

  REAL(RFREAL), POINTER :: gradi(:,:,:), bgradi(:,:,:)
 
!******************************************************************************

  rcsidentstring = '$RCSfile: TURB_coViscousFluxesFlu.F90,v $ $Revision: 1.9 $'

  global => region%global
  CALL registerfunction( global,'TURB_CoViscousFluxes',&
  'TURB_coViscousFluxesFlu.F90' )

! Specific Rocflu ------------------------------------------------------------ 
! check the state of cv first and convert to conservative if not yet

  IF (region%mixt%cvState /= cv_mixt_state_cons) THEN
    prevcvstate = region%mixt%cvState
    CALL rflu_convertcvprim2cons(region,cv_mixt_state_cons)
  ENDIF

! get cell and node dimensions -----------------------------------------------
  ncellstot = region%grid%nCellsTot
  nfaces    = region%grid%nFaces
  nfacestot = region%grid%nFacesTot
  ibc       = 1
  iec       = ncellstot
  ibn       = 1
  ien       = nfaces
  npatches  = region%grid%nPatches

  nbfaces    = 0
  nbfacestot = 0

  DO ipatch = 1,npatches
    patch => region%patches(ipatch)

    nbfaces    = nbfaces    + patch%nBTris    + patch%nBQuads
    nbfacestot = nbfacestot + patch%nBTrisTot + patch%nBQuadsTot
  END DO ! iPatch

! get pointers and parameters
 
  turbmodel =  region%mixtInput%turbModel
  modelclass=  region%turbInput%modelClass
  turb      => region%turb

! get mixture strain rate tensor and store in mISij

  gradi  => region%mixt%gradFace
! TEMPORARY 
!  bGradi => region%mixt%bGradFace

  gradindx(1) = grf_mixt_xvel
  gradindx(2) = grf_mixt_yvel
  gradindx(3) = grf_mixt_zvel

  ALLOCATE( turb%mISij(tensor_symm_nelm, nfaces ),stat=errorflag )
  global%error = errorflag
  IF (global%error /= 0) CALL errorstop( global,err_allocate,__line__ )

  ALLOCATE( turb%bmISij(tensor_symm_nelm,nbfaces),stat=errorflag )
  global%error = errorflag
  IF (global%error /= 0) CALL errorstop( global,err_allocate,__line__ )

  CALL turb_calcstrainrate( region,1, nfaces,gradindx, gradi, turb%mISij )
  IF (npatches > 0) &
  CALL turb_calcstrainrate( region,1,nbfaces,gradindx,bgradi,turb%bmISij )

! get new non-uniform filter and averaging coefficients if the grid moves

!  IF (region%mixtInput%moveGrid) THEN  ! better performed in TURB_CalcMetric
!    IF (region%irkStep == 1) THEN
!      CALL TURB_FluLesMoveGrid
!    ENDIF
!  ENDIF

! allocate and initiate LES arrays required within this scope

  IF (modelclass == model_les) THEN
    ALLOCATE( turb%mueT( diri, nfaces),stat=errorflag )
    global%error = errorflag
    IF (global%error /= 0) CALL errorstop( global,err_allocate,__line__ )

    ALLOCATE( turb%bMueT(diri,nbfaces),stat=errorflag )
    global%error = errorflag
    IF (global%error /= 0) CALL errorstop( global,err_allocate,__line__ )

    ALLOCATE( turb%trace(ibc:iec),stat=errorflag )
    global%error = errorflag
    IF (global%error /= 0) CALL errorstop( global,err_allocate,__line__ )

    turb%dv      = 0._rfreal  ! cell dynamic coefficient is stored in dv
    turb%mueT    = 0._rfreal
    turb%bMueT   = 0._rfreal
    turb%trace   = 0._rfreal
  ENDIF

! get total viscous flux based on selected turbulence model

  IF (turbmodel==turb_model_fixsmag) THEN
    CALL turb_lesfluxfixsmag( region,ibn,ien )

  ELSEIF ((turbmodel==turb_model_dynsmag) .OR. &
          (turbmodel==turb_model_dynmixd)) THEN

! - allocate arrays for strain rate of filtered velocities in LesGetEddyVis,
!   and for space of tauij (in Dynamic Mixed model)

    ALLOCATE( turb%fISij( tensor_symm_nelm, nfaces),stat=errorflag )
    global%error = errorflag
    IF (global%error /= 0) CALL errorstop( global,err_allocate,__line__ )

    ALLOCATE( turb%bfISij(tensor_symm_nelm,nbfaces),stat=errorflag )
    global%error = errorflag
    IF (global%error /= 0) CALL errorstop( global,err_allocate,__line__ )

! - get eddy viscosity of dynamic Smagorinsky and dynamic Mixed models 
    CALL turb_lesgeteddyvis( region,ibc,iec,ibn,ien )

! - get viscous fluxes
    IF (turbmodel==turb_model_dynsmag) THEN
      CALL turb_visfluxeddy( region )
    ELSEIF (turbmodel==turb_model_dynmixd) THEN
      CALL turb_vfluxhybrid( region )
    ENDIF

! - deallocate retired arrays
    DEALLOCATE( turb%fISij, turb%bfISij )

  ELSEIF (turbmodel==turb_model_scalsim) THEN
    CALL turb_lesfluxscalsim( region,ibn,ien )


  ELSEIF ((turbmodel==turb_model_sa).OR. &
          (turbmodel==turb_model_dessa).OR. &
          (turbmodel==turb_model_hdessa)) THEN

! - viscous fluxes of SA equation
    CALL turb_ranssavisflux( region )

! - allocate total tv for NS viscous fluxes
    ALLOCATE( turb%tv(tvt_rans_nelm,ibc:iec),stat=errorflag )
    global%error = errorflag
    IF (global%error /= 0) CALL errorstop( global,err_allocate,__line__ )

! - compute total RaNS tv and use it to obtain NS viscous fluxes 
    CALL turb_ranstotaltv( region,tvt_rans_mue,tvt_rans_tco,turb%tv )
    CALL rflu_viscousfluxes( region,turb%tv,tvt_rans_mue,tvt_rans_tco )
    CALL rflu_viscousfluxespatches( region,turb%tv,tvt_rans_mue,tvt_rans_tco )

! - deallocate retired arrays
    DEALLOCATE( turb%tv )

  ENDIF

! finalize viscous flux treatment
! if desired, interpolate model stresses to cell centers for statistics

  IF (region%turbInput%nSv > 0) CALL turb_getmodelstresscell( region )
  DEALLOCATE( turb%mISij, turb%bmISij )

  IF (modelclass == model_les) THEN
! - interpolate transport variables at cell centers
    CALL turb_gettvcell( region )

! - deallocate LES arrays
    DEALLOCATE( turb%mueT, turb%bMueT, turb%trace )
  ENDIF

! convert cv back to the previous state before entering this routine

  IF (region%mixt%cvState /= prevcvstate) &
      CALL rflu_convertcvcons2prim( region,prevcvstate )  

! finalize --------------------------------------------------------------------

  CALL deregisterfunction( global )

END SUBROUTINE turb_coviscousfluxes

!******************************************************************************
!
! RCS Revision history:
!
! $Log: TURB_coViscousFluxesFlu.F90,v $
! Revision 1.9  2008/12/06 08:44:43  mtcampbe
! Updated license.
!
! Revision 1.8  2008/11/19 22:17:55  mtcampbe
! Added Illinois Open Source License/Copyright
!
! Revision 1.7  2006/08/19 15:40:43  mparmar
! Commented use of region%mixt%bGradFace
!
! Revision 1.6  2005/12/29 19:52:06  wasistho
! modified allocation for bMISij
!
! Revision 1.5  2005/12/20 20:44:19  wasistho
! adapted to changing in Rocflu on viscous fluxes routines
!
! Revision 1.4  2005/03/07 05:03:58  wasistho
! install hybrid DESSA turbulence model
!
! Revision 1.3  2004/05/28 01:58:35  wasistho
! update unstructured grid LES
!
! Revision 1.2  2004/03/27 02:16:42  wasistho
! compiled with Rocflu
!
! Revision 1.1  2004/03/25 04:42:58  wasistho
! prepared for RFLU
!
!
!
!******************************************************************************