RFLU_ModConvertCv.F90

Go to the documentation of this file.

! *********************************************************************
! * Rocstar Simulation Suite                                          *
! * Copyright@2015, Illinois Rocstar LLC. All rights reserved.        *
! *                                                                   *
! * Illinois Rocstar LLC                                              *
! * Champaign, IL                                                     *
! * www.illinoisrocstar.com                                           *
! * sales@illinoisrocstar.com                                         *
! *                                                                   *
! * License: See LICENSE file in top level of distribution package or *
! * http://opensource.org/licenses/NCSA                               *
! *********************************************************************
! *********************************************************************
! * THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND,   *
! * EXPRESS OR IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES   *
! * OF MERCHANTABILITY, FITNESS FOR A PARTICULAR PURPOSE AND          *
! * NONINFRINGEMENT.  IN NO EVENT SHALL THE CONTRIBUTORS OR           *
! * COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER       *
! * LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE,   *
! * Arising FROM, OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE    *
! * USE OR OTHER DEALINGS WITH THE SOFTWARE.                          *
! *********************************************************************
! ******************************************************************************
!
! Purpose: Suite of routines to convert state vector.
!
! Description: None.
!
! Notes: 
!   1. The routines which convert scalar conserved vectors assume that that 
!      form contains variables per unit volume (i.e., density times variable
!      per unit mass). 
!
! ******************************************************************************
!
! $Id: RFLU_ModConvertCv.F90,v 1.10 2008/12/06 08:44:20 mtcampbe Exp $
!
! Copyright: (c) 2002-2006 by the University of Illinois
!
! ******************************************************************************

MODULE rflu_modconvertcv

  USE moddatatypes
  USE modparameters
  USE moderror
  USE modglobal, ONLY: t_global
  USE modgrid, ONLY: t_grid
  USE moddatastruct, ONLY: t_region
    
  IMPLICIT NONE
   
  PRIVATE
  PUBLIC :: rflu_convertcvcons2prim, & 
            rflu_convertcvprim2cons, & 
            rflu_scalarconvertcvcons2prim, &
            rflu_scalarconvertcvprim2cons
   
  SAVE    
     
! ******************************************************************************
! Declarations and definitions
! ******************************************************************************  
  
       
! ******************************************************************************
! Routines
! ******************************************************************************

  CONTAINS


  
! ******************************************************************************
!
! Purpose: Convert conserved state vector to primitive variables.
!
! Description: None.
!
! Input: 
!   pRegion             Pointer to data of current region
!   cvStateFuture       Future state of conserved variables
!
! Output: None.
!
! Notes: None.
!
! ******************************************************************************
  
  SUBROUTINE rflu_convertcvcons2prim(pRegion,cvStateFuture)

    USE modinterfaces, ONLY: mixtperf_r_m, &
                             mixtperf_t_dpr

! ******************************************************************************
!   Definitions and declarations
! ******************************************************************************

! ==============================================================================
!   Arguments
! ==============================================================================

    INTEGER, INTENT(IN) :: cvstatefuture
    TYPE(t_region), POINTER :: pregion

! ==============================================================================
!   Locals
! ==============================================================================

    INTEGER :: icg,indmol
    REAL(RFREAL) :: gc,ir,mw,p,r
    REAL(RFREAL), DIMENSION(:,:), POINTER :: pcv,pdv,pgv
    TYPE(t_grid), POINTER :: pgrid
    TYPE(t_global), POINTER :: global

! ******************************************************************************
!   Start
! ******************************************************************************

    global => pregion%global

    CALL registerfunction(global,'RFLU_ConvertCvCons2Prim',&
  'RFLU_ModConvertCv.F90')

#ifdef ROCPROF 
    CALL fprofiler_begins("RFLU::ConvertCvCons2Prim")
#endif

! ******************************************************************************
!   Set pointers and variables
! ******************************************************************************

    pgrid => pregion%grid
    pcv   => pregion%mixt%cv
    pdv   => pregion%mixt%dv
    pgv   => pregion%mixt%gv

    indmol = pregion%mixtInput%indMol

! ******************************************************************************
!   Actual conversion
! ******************************************************************************

    SELECT CASE ( pregion%mixt%cvState )

! ==============================================================================
!     Convert from conservative to primitive form 
! ==============================================================================

      CASE ( cv_mixt_state_cons ) 
        SELECT CASE ( cvstatefuture )

! ------------------------------------------------------------------------------      
!         Convert to duvwp form        
! ------------------------------------------------------------------------------

          CASE ( cv_mixt_state_duvwp )
            pregion%mixt%cvState = cv_mixt_state_duvwp          
          
            DO icg = 1,pgrid%nCellsTot
              ir = 1.0_rfreal/pcv(cv_mixt_dens,icg)

              pcv(cv_mixt_xvel,icg) = ir*pcv(cv_mixt_xmom,icg)
              pcv(cv_mixt_yvel,icg) = ir*pcv(cv_mixt_ymom,icg)
              pcv(cv_mixt_zvel,icg) = ir*pcv(cv_mixt_zmom,icg)
              pcv(cv_mixt_pres,icg) = pdv(dv_mixt_pres,icg)
            END DO ! icg

! ------------------------------------------------------------------------------          
!         Convert to duvwt form             
! ------------------------------------------------------------------------------

          CASE (cv_mixt_state_duvwt)
            pregion%mixt%cvState = cv_mixt_state_duvwt

            SELECT CASE ( pregion%mixtInput%fluidModel ) 

! ----------- Compressible fluid model -----------------------------------------

              CASE ( fluid_model_comp )              
                SELECT CASE ( pregion%mixtInput%gasModel )
                
! --------------- TC perfect gas or mixture thereof, pseudo-gas                 
                
                  CASE ( gas_model_tcperf, &
                         gas_model_mixt_tcperf, & 
                         gas_model_mixt_pseudo )
                    DO icg = 1,pgrid%nCellsTot                
                      r  = pcv(cv_mixt_dens,icg)
                      p  = pdv(dv_mixt_pres,icg)                
                      ir = 1.0_rfreal/r

                      pcv(cv_mixt_xvel,icg) = ir*pcv(cv_mixt_xmom,icg)
                      pcv(cv_mixt_yvel,icg) = ir*pcv(cv_mixt_ymom,icg)
                      pcv(cv_mixt_zvel,icg) = ir*pcv(cv_mixt_zmom,icg)

                      mw = pgv(gv_mixt_mol,indmol*icg)
                      gc = mixtperf_r_m(mw)

                      pcv(cv_mixt_temp,icg) = mixtperf_t_dpr(r,p,gc)
                    END DO ! icg 
                    
! --------------- Gas-liquid mixture                    
                    
                  CASE ( gas_model_mixt_gasliq ) 
                    DO icg = 1,pgrid%nCellsTot
                      ir = 1.0_rfreal/pcv(cv_mixt_dens,icg)

                      pcv(cv_mixt_xvel,icg) = ir*pcv(cv_mixt_xmom,icg)
                      pcv(cv_mixt_yvel,icg) = ir*pcv(cv_mixt_ymom,icg)
                      pcv(cv_mixt_zvel,icg) = ir*pcv(cv_mixt_zmom,icg)

                      pcv(cv_mixt_temp,icg) = pdv(dv_mixt_temp,icg) 
                    END DO ! icg                                                   
                  CASE default
                    CALL errorstop(global,err_reached_default,__line__)
                END SELECT ! pRegion%mixtInput%gasModel              

! ----------- Default ----------------------------------------------------------

              CASE default
                CALL errorstop(global,err_reached_default,__line__)     
            END SELECT ! pRegion%mixtInput%fluidModel 
             
! ------------------------------------------------------------------------------          
!         Default            
! ------------------------------------------------------------------------------
  
          CASE default
            CALL errorstop(global,err_reached_default,__line__)   
        END SELECT ! cvStateFuture

! ==============================================================================
!     Error - invalid input
! ==============================================================================

      CASE default
        CALL errorstop(global,err_reached_default,__line__)
    END SELECT ! pRegion%mixt%cvStateFuture

! ******************************************************************************
!   End
! ******************************************************************************

#ifdef ROCPROF
    CALL fprofiler_ends("RFLU::ConvertCvCons2Prim")
#endif

    CALL deregisterfunction(global)

  END SUBROUTINE rflu_convertcvcons2prim




! ******************************************************************************
!
! Purpose: Convert primitive state vector to consverved variables.
!
! Description: None.
!
! Input: 
!   pRegion             Pointer to data of current region
!   cvStateFuture       Future state of conserved variables
!
! Output: None.
!
! Notes: 
!   1. Strictly speaking, cvStateFuture is not needed (there is only one
!      state for conserved variables), but kept for consistency with 
!      RFLU_ConvertCvCons2Prim.
!
! ******************************************************************************
  
  SUBROUTINE rflu_convertcvprim2cons(pRegion,cvStateFuture)

    USE modinterfaces, ONLY: mixtperf_cv_cpr, &
                             mixtgasliq_eo_cvmtvm2, &
                             mixtperf_eo_dgpuvw, &
                             mixtperf_g_cpr, &
                             mixtperf_r_m

! ******************************************************************************
!   Definitions and declarations
! ******************************************************************************

! ==============================================================================
!   Arguments
! ==============================================================================

    INTEGER, INTENT(IN) :: cvstatefuture
    TYPE(t_region), POINTER :: pregion

! ==============================================================================
!   Locals
! ==============================================================================

    INTEGER :: icg,indcp,indmol
    REAL(RFREAL) :: cp,cvm,cvg,cvl,cvv,g,gc,mw,p,r,rg,rv,ryg,ryl,ryv,t,u,v, &
                    vm2,w
    REAL(RFREAL), DIMENSION(:,:), POINTER :: pcv,pdv,pgv
#ifdef SPEC
    REAL(RFREAL), DIMENSION(:,:), POINTER :: pcvspec
#endif    
    TYPE(t_grid), POINTER :: pgrid
    TYPE(t_global), POINTER :: global

! ******************************************************************************
!   Start
! ******************************************************************************

    global => pregion%global

    CALL registerfunction(global,'RFLU_ConvertCvPrim2Cons',&
  'RFLU_ModConvertCv.F90')

#ifdef ROCPROF 
    CALL fprofiler_begins("RFLU::ConvertCvPrim2Cons")
#endif

! ******************************************************************************
!   Set pointers and variables
! ******************************************************************************

    pgrid => pregion%grid
    pcv   => pregion%mixt%cv
    pdv   => pregion%mixt%dv
    pgv   => pregion%mixt%gv

#ifdef SPEC
    pcvspec => pregion%spec%cv
#endif

    indcp  = pregion%mixtInput%indCp
    indmol = pregion%mixtInput%indMol

! ******************************************************************************
!   Actual conversion
! ******************************************************************************
  
    IF ( pregion%mixt%cvState == cv_mixt_state_duvwp .OR. & 
         pregion%mixt%cvState == cv_mixt_state_duvwt ) THEN 

! ==============================================================================
!     Convert from primitive to conservative form 
! ==============================================================================

      SELECT CASE ( cvstatefuture )
        CASE ( cv_mixt_state_cons )
          pregion%mixt%cvState = cv_mixt_state_cons          

          SELECT CASE ( pregion%mixtInput%gasModel )

! ------------------------------------------------------------------------------
!           Thermally and calorically perfect gas or pseudo-gas
! ------------------------------------------------------------------------------

            CASE ( gas_model_tcperf, & 
                   gas_model_mixt_tcperf, & 
                   gas_model_mixt_pseudo )
              DO icg = 1,pgrid%nCellsTot
                r = pcv(cv_mixt_dens,icg)
                u = pcv(cv_mixt_xvel,icg)
                v = pcv(cv_mixt_yvel,icg)
                w = pcv(cv_mixt_zvel,icg)
                p = pdv(dv_mixt_pres,icg)

                pcv(cv_mixt_xmom,icg) = r*u
                pcv(cv_mixt_ymom,icg) = r*v
                pcv(cv_mixt_zmom,icg) = r*w

                cp = pgv(gv_mixt_cp,indcp*icg)
                mw = pgv(gv_mixt_mol,indmol*icg)                  
                gc = mixtperf_r_m(mw)
                g  = mixtperf_g_cpr(cp,gc)

                pcv(cv_mixt_ener,icg) = r*mixtperf_eo_dgpuvw(r,g,p,u,v,w)
              END DO ! icg 

! ------------------------------------------------------------------------------
!           Mixture of gas, liquid, and vapor
! ------------------------------------------------------------------------------

            CASE ( gas_model_mixt_gasliq )  
#ifdef SPEC                          
              rg  = mixtperf_r_m(pregion%specInput%specType(1)% &
                                 pmaterial%molw)
              cvg = mixtperf_cv_cpr(pregion%specInput%specType(1)% &
                                    pmaterial%spht,rg)
              rv  = mixtperf_r_m(pregion%specInput%specType(2)% &
                                 pmaterial%molw)
              cvv = mixtperf_cv_cpr(pregion%specInput%specType(2)% &
                                    pmaterial%spht,rv)
              cvl = global%refCvLiq

              DO icg = 1,pgrid%nCellsTot
                r = pcv(cv_mixt_dens,icg)
                u = pcv(cv_mixt_xvel,icg)
                v = pcv(cv_mixt_yvel,icg)
                w = pcv(cv_mixt_zvel,icg)
                t = pdv(dv_mixt_temp,icg)

                pcv(cv_mixt_xmom,icg) = r*u
                pcv(cv_mixt_ymom,icg) = r*v
                pcv(cv_mixt_zmom,icg) = r*w

                ryg = pcvspec(1,icg)
                ryv = pcvspec(2,icg)
                ryl = r - ryg - ryv 

                cvm = (ryl*cvl + ryg*cvg + ryv*cvv)/r
                vm2 = u*u + v*v + w*w

                pcv(cv_mixt_ener,icg) = r*mixtgasliq_eo_cvmtvm2(cvm,t,vm2)
              END DO ! icg
#else
              CALL errorstop(global,err_gasmodel_invalid,__line__, & 
                             'Can only be used with species module.')              
#endif

! ------------------------------------------------------------------------------
!           Other or invalid gas models             
! ------------------------------------------------------------------------------

            CASE default 
              CALL errorstop(global,err_reached_default,__line__)
          END SELECT ! pRegion%mixtInput
          
        CASE default
          CALL errorstop(global,err_reached_default,__line__)
      END SELECT ! cvStateFuture

! ==============================================================================
!   Error - invalid input
! ==============================================================================

    ELSE
      CALL errorstop(global,err_reached_default,__line__)
    END IF ! pRegion%mixt%cvState                   
                         
! ******************************************************************************
!   End
! ******************************************************************************

#ifdef ROCPROF
    CALL fprofiler_ends("RFLU::ConvertCvPrim2Cons")
#endif

    CALL deregisterfunction(global)

  END SUBROUTINE rflu_convertcvprim2cons




! ******************************************************************************
!
! Purpose: Convert conserved state vector to primitive variables.
!
! Description: None.
!
! Input: 
!   pRegion             Pointer to data of current region
!   cvScal              State vector of conserved variables
!   cvScalStateCurrent  Current state of conserved variables
!
! Output: None.
!
! Notes: None.
!
! ******************************************************************************
  
  SUBROUTINE rflu_scalarconvertcvcons2prim(pRegion,cvScal,cvScalStateCurrent)

! ******************************************************************************
!   Definitions and declarations
! ******************************************************************************

! ==============================================================================
!   Arguments
! ==============================================================================

    INTEGER, INTENT(INOUT) :: cvscalstatecurrent
    REAL(RFREAL), DIMENSION(:,:) :: cvscal
    TYPE(t_region), POINTER :: pregion

! ==============================================================================
!   Locals
! ==============================================================================

    INTEGER :: icg,iscal,nscal
    REAL(RFREAL) :: ir
    REAL(RFREAL), DIMENSION(:,:), POINTER :: pcv
    TYPE(t_grid), POINTER :: pgrid
    TYPE(t_global), POINTER :: global

! ******************************************************************************
!   Start
! ******************************************************************************

    global => pregion%global

    CALL registerfunction(global,'RFLU_ScalarConvertCvCons2Prim',&
  'RFLU_ModConvertCv.F90')

! ******************************************************************************
!   Set pointers and variables
! ******************************************************************************

    pgrid => pregion%grid
    pcv   => pregion%mixt%cv

    nscal = SIZE(cvscal,1)

! ******************************************************************************
!   Actual conversion
! ******************************************************************************

    SELECT CASE ( cvscalstatecurrent )

! ==============================================================================
!     Conserved, so convert to primitive variables     
! ==============================================================================

      CASE ( cv_mixt_state_cons )
        cvscalstatecurrent = cv_mixt_state_prim         

        DO icg = 1,pgrid%nCellsTot
          ir = 1.0_rfreal/pcv(cv_mixt_dens,icg)

          DO iscal = 1,nscal
            cvscal(iscal,icg) = ir*cvscal(iscal,icg)
          END DO ! iScal
        END DO ! icg

! ==============================================================================
!     Error - invalid input
! ==============================================================================

      CASE default
        CALL errorstop(global,err_reached_default,__line__)
    END SELECT ! cvScalStateCurrent

! ******************************************************************************
!   End
! ******************************************************************************

    CALL deregisterfunction(global)

  END SUBROUTINE rflu_scalarconvertcvcons2prim




! ******************************************************************************
!
! Purpose: Convert primitive state vector to conserved variables.
!
! Description: None.
!
! Input: 
!   pRegion             Pointer to data of current region
!   cvScal              State vector of conserved variables
!   cvScalStateCurrent  Current state of conserved variables
!
! Output: None.
!
! Notes: None.
!
! ******************************************************************************
  
  SUBROUTINE rflu_scalarconvertcvprim2cons(pRegion,cvScal,cvScalStateCurrent)

! ******************************************************************************
!   Definitions and declarations
! ******************************************************************************

! ==============================================================================
!   Arguments
! ==============================================================================

    INTEGER, INTENT(INOUT) :: cvscalstatecurrent
    REAL(RFREAL), DIMENSION(:,:) :: cvscal
    TYPE(t_region), POINTER :: pregion

! ==============================================================================
!   Locals
! ==============================================================================

    INTEGER :: icg,iscal,nscal
    REAL(RFREAL) :: r
    REAL(RFREAL), DIMENSION(:,:), POINTER :: pcv
    TYPE(t_grid), POINTER :: pgrid
    TYPE(t_global), POINTER :: global

! ******************************************************************************
!   Start
! ******************************************************************************

    global => pregion%global

    CALL registerfunction(global,'RFLU_ScalarConvertCvPrim2Cons',&
  'RFLU_ModConvertCv.F90')

! ******************************************************************************
!   Set pointers and variables
! ******************************************************************************

    pgrid => pregion%grid
    pcv   => pregion%mixt%cv

    nscal = SIZE(cvscal,1)

! ******************************************************************************
!   Actual conversion
! ******************************************************************************

    SELECT CASE ( cvscalstatecurrent )

! ==============================================================================
!     Primitive, so convert to conserved variables     
! ==============================================================================

      CASE ( cv_mixt_state_prim )
        cvscalstatecurrent = cv_mixt_state_cons         

        DO icg = 1,pgrid%nCellsTot
          r = pcv(cv_mixt_dens,icg)

          DO iscal = 1,nscal
            cvscal(iscal,icg) = r*cvscal(iscal,icg)
          END DO ! iScal
        END DO ! icg

! ==============================================================================
!     Error - invalid input
! ==============================================================================

      CASE default
        CALL errorstop(global,err_reached_default,__line__)
    END SELECT ! cvScalStateCurrent

! ******************************************************************************
!   End
! ******************************************************************************

    CALL deregisterfunction(global)

  END SUBROUTINE rflu_scalarconvertcvprim2cons





! ******************************************************************************
! End
! ******************************************************************************

END MODULE rflu_modconvertcv


! ******************************************************************************
!
! RCS Revision history:
!
! $Log: RFLU_ModConvertCv.F90,v $
! Revision 1.10  2008/12/06 08:44:20  mtcampbe
! Updated license.
!
! Revision 1.9  2008/11/19 22:17:32  mtcampbe
! Added Illinois Open Source License/Copyright
!
! Revision 1.8  2006/04/07 15:19:19  haselbac
! Removed tabs
!
! Revision 1.7  2006/03/26 20:22:00  haselbac
! Added support for GL model, cosmetics
!
! Revision 1.6  2005/11/14 16:59:08  haselbac
! Added support for pseudo-gas model
!
! Revision 1.5  2005/11/10 02:26:54  haselbac
! Cosmetics only
!
! Revision 1.4  2005/10/31 21:09:36  haselbac
! Changed specModel and SPEC_MODEL_NONE
!
! Revision 1.3  2005/07/07 22:45:01  haselbac
! Added profiling calls
!              
! Revision 1.2  2004/01/29 22:57:35  haselbac  
! Added routines for scalars                   
!
! Revision 1.1  2002/09/09 15:17:58  haselbac  
! Initial revision                             
!
! ******************************************************************************