TURB_LesCalcEddyVis.F90

Go to the documentation of this file.

! *********************************************************************
! * Rocstar Simulation Suite                                          *
! * Copyright@2015, Illinois Rocstar LLC. All rights reserved.        *
! *                                                                   *
! * Illinois Rocstar LLC                                              *
! * Champaign, IL                                                     *
! * www.illinoisrocstar.com                                           *
! * sales@illinoisrocstar.com                                         *
! *                                                                   *
! * License: See LICENSE file in top level of distribution package or *
! * http://opensource.org/licenses/NCSA                               *
! *********************************************************************
! *********************************************************************
! * THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND,   *
! * EXPRESS OR IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES   *
! * OF MERCHANTABILITY, FITNESS FOR A PARTICULAR PURPOSE AND          *
! * NONINFRINGEMENT.  IN NO EVENT SHALL THE CONTRIBUTORS OR           *
! * COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER       *
! * LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE,   *
! * Arising FROM, OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE    *
! * USE OR OTHER DEALINGS WITH THE SOFTWARE.                          *
! *********************************************************************
!******************************************************************************
!
! Purpose: Compute turbulent viscosity mu_t.
!
! Description: The eddy viscosity is computed at faces using the model 
!              coefficient depending on the model selected by user.
!
! Input: region  = data of current region
!        ibn,ien = begin and end nodes index
!        ijk     = integer identifying wich face is being treated
!
! Output: mueT(ijk,:) = eddy viscosity at ijk face
!
! Notes: The face values contribution are collected here for model coeffs. 
!        at cell centers.
!
!******************************************************************************
!
! $Id: TURB_LesCalcEddyVis.F90,v 1.17 2009/08/12 04:15:59 mtcampbe Exp $
!
! Copyright: (c) 2001 by the University of Illinois
!
!******************************************************************************

SUBROUTINE turb_lescalceddyvis( region,ibn,ien,ijk )

  USE moddatatypes
  USE moddatastruct, ONLY      : t_region
  USE modturbulence, ONLY      : t_turb
  USE modglobal, ONLY          : t_global
#ifdef RFLU
  USE modbndpatch, ONLY        : t_patch
  USE turb_modinterfaces, ONLY : turb_flulesc2f
#endif
#ifdef RFLO
  USE modinterfaces, ONLY      : rflo_getdimensphys, &
                                 rflo_getcelloffset, rflo_getnodeoffset
  USE turb_modinterfaces, ONLY : turb_flolesgenc2f
                                 
#include "Indexing.h"
#endif
  USE turb_modinterfaces, ONLY : turb_lescoefdynsmag, turb_lescoefdynmixd
  USE moderror
  USE modparameters
  USE turb_modparameters
  IMPLICIT NONE

! ... parameters
#ifdef RFLO
  TYPE(t_region), TARGET  :: region
#endif
#ifdef RFLU
  TYPE(t_region), POINTER :: region
#endif
  INTEGER                 :: ibn,ien,ijk

! ... loop variables
  INTEGER :: i, j, k, m, ijkn, ipatch, ifl

! ... local variables
  CHARACTER(CHRLEN)       :: rcsidentstring
  TYPE(t_global), POINTER :: global
  TYPE(t_turb), POINTER   :: turb
#ifdef RFLU
  TYPE(t_patch), POINTER  :: patch
#endif

  INTEGER :: turbmodel, zofid, xco, yco, zco, errorflag
  INTEGER :: ibeg, iend, jbeg, jend, kbeg, kend, ijkc0, ijkc1
  REAL(RFREAL)          :: two3rd,csmag,delfac2,delta2, zoffac,bzoffac
  REAL(RFREAL)          :: vormag,volface,rhoface,muturb,rhomin,mutmin
  REAL(RFREAL)          :: sxx,sxy,sxz,syy,syz,szz
  REAL(RFREAL), POINTER :: fvol(:),fvar(:,:),cmodel(:,:),muet(:,:)
  REAL(RFREAL), POINTER :: tdv(:,:),sij(:,:),zof(:,:,:)
#ifdef RFLU
  REAL(RFREAL), POINTER :: bfvol(:),bfvar(:,:),bcmodel(:,:),bmuet(:,:),bsij(:,:)
  REAL(RFREAL), POINTER :: bzof(:,:,:)
#endif

#ifdef RFLO
  INTEGER :: ipcbeg, ipcend, jpcbeg, jpcend, kpcbeg, kpcend, iadd, jadd, kadd
  INTEGER :: ilev, icoff, ijcoff, inoff, ijnoff, filtertype
#endif
#ifdef RFLU
  INTEGER :: bctype
  INTEGER :: ifg,ifgt,ifgbeg,ifgtbeg
  INTEGER :: npatches,nfaces,nfacestot,nbfaces,nbfacestot
  REAL(RFREAL) :: bvalfactor
#endif

!******************************************************************************

  rcsidentstring = '$RCSfile: TURB_LesCalcEddyVis.F90,v $'

  global => region%global
  CALL registerfunction( global,'Turb_LesCalcEddyVis',&
  'TURB_LesCalcEddyVis.F90' )

! get parameters and coefficients -------------------------------------------

  xco        = xcoord
  yco        = ycoord
  zco        = zcoord
  zofid      = zof_les_eddyvis
  turbmodel  = region%mixtInput%turbModel
  csmag      = region%turbInput%cSmag
  delfac2    = region%turbInput%delFac2
#ifdef RFLO
  filtertype = region%turbInput%filterType
  ilev       = region%currLevel
#endif

  rhomin = 10000._rfreal
  mutmin = 10000._rfreal
  two3rd = 2._rfreal/3._rfreal

! allocate required arrays within this scope

#ifdef RFLO
  turb   => region%levels(ilev)%turb

  ALLOCATE( turb%coef(1,ibn:ien),stat=errorflag )
  ALLOCATE( turb%fVar(cv_turb_nelm,ibn:ien),stat=errorflag )    
  global%error = errorflag
  IF (global%error /= 0) CALL errorstop( global,err_allocate,__line__ )
#endif
#ifdef RFLU
  npatches   = region%grid%nPatches
  nfaces     = region%grid%nFaces
  nfacestot  = region%grid%nFacesTot
  nbfaces    = 0
  nbfacestot = 0

  DO ipatch = 1,npatches
    patch => region%patches(ipatch)

    nbfaces    = nbfaces    + patch%nBTris    + patch%nBQuads
    nbfacestot = nbfacestot + patch%nBTrisTot + patch%nBQuadsTot
  END DO ! iPatch

  IF (ijk /= diri) THEN
    CALL errorstop( global,err_turb_fixparam,__line__,'RFLU but ijk/=DIRI' )
  ENDIF
  turb   => region%turb

  ALLOCATE( turb%coef( 1,ibn:ien),stat=errorflag )
  ALLOCATE( turb%bCoef(1,nbfaces),stat=errorflag )
  global%error = errorflag
  IF (global%error /= 0) CALL errorstop( global,err_allocate,__line__ )

  ALLOCATE( turb%fVar( cv_turb_nelm, nfaces),stat=errorflag )    
  ALLOCATE( turb%bfVar(cv_turb_nelm,nbfaces),stat=errorflag )    
  global%error = errorflag
  IF (global%error /= 0) CALL errorstop( global,err_allocate,__line__ )
#endif

! get model coefficients -----------------------------------------------

  IF (turbmodel==turb_model_fixsmag) THEN
    
#ifdef RFLO
    CALL turb_flolesgenc2f( region,ijk )
    DO ijkn = ibn,ien
      turb%fVar(cv_turb_dens,ijkn) = 1._rfreal/turb%fVar(cv_turb_dens,ijkn)
      turb%coef(1,ijkn) = csmag*csmag
    ENDDO
#endif
#ifdef RFLU
    CALL turb_flulesc2f( region )
    DO ijkn = ibn,ien
      turb%coef(1,ijkn)             = csmag*csmag
      turb%fVar(cv_turb_dens,ijkn)  = 1._rfreal/turb%fVar(cv_turb_dens,ijkn)
    ENDDO
    DO ijkn = 1,nbfaces
      turb%bCoef(1,ijkn)            = csmag*csmag
      turb%bfVar(cv_turb_dens,ijkn) = 1._rfreal/turb%bfVar(cv_turb_dens,ijkn)
    ENDDO
#endif
  ELSEIF (turbmodel==turb_model_dynsmag) THEN   
    CALL turb_lescoefdynsmag( region,ibn,ien,ijk )
  ELSEIF (turbmodel==turb_model_dynmixd) THEN   
    CALL turb_lescoefdynmixd( region,ibn,ien,ijk )
  ENDIF

! apply spatial tripping to eddy viscosity
    
#ifdef RFLO
  IF (ijk==diri) THEN
    zof => turb%zofi
  ELSEIF (ijk==dirj) THEN
    zof => turb%zofj
  ELSEIF (ijk==dirk) THEN
    zof => turb%zofk
  ENDIF    
  DO ijkn = ibn,ien
    zoffac = zof(xco,zofid,ijkn)*zof(yco,zofid,ijkn)*zof(zco,zofid,ijkn)
    turb%coef(1,ijkn) = zoffac*turb%coef(1,ijkn)
  ENDDO
#endif
#ifdef RFLU
  zof  => turb%zofi
  bzof => turb%bZofi
  DO ijkn = ibn,ien
    zoffac = zof(xco,zofid,ijkn)*zof(yco,zofid,ijkn)*zof(zco,zofid,ijkn)
    turb%coef(1,ijkn)  = zoffac*turb%coef(1,ijkn)
  ENDDO
  DO ijkn = 1,nbfaces
    bzoffac = bzof(xco,zofid,ijkn)*bzof(yco,zofid,ijkn)*bzof(zco,zofid,ijkn)
    turb%bCoef(1,ijkn) = bzoffac*turb%bCoef(1,ijkn)
  ENDDO
#endif

! get dimensions and pointers

  tdv    => turb%dv
  fvar   => turb%fVar
  cmodel => turb%coef
  muet   => turb%mueT

#ifdef RFLO

  CALL rflo_getdimensphys( region,ilev,ipcbeg,ipcend, &
                           jpcbeg,jpcend,kpcbeg,kpcend )
  CALL rflo_getcelloffset( region,ilev,icoff,ijcoff )
  CALL rflo_getnodeoffset( region,ilev,inoff,ijnoff )

  IF (ijk==diri) THEN
! - pointers and indices for i-direction
    ibeg = ipcbeg-1
    iend = ipcend+2
    jbeg = jpcbeg-1
    jend = jpcend+1
    kbeg = kpcbeg-1
    kend = kpcend+1
    iadd = -1
    jadd = 0
    kadd = 0
    fvol => turb%fvolI
    sij  => turb%mISij
  ELSEIF (ijk==dirj) THEN
! - pointers and indices for j-direction
    ibeg = ipcbeg-1
    iend = ipcend+1
    jbeg = jpcbeg-1
    jend = jpcend+2
    kbeg = kpcbeg-1
    kend = kpcend+1
    iadd = 0
    jadd = -1
    kadd = 0
    fvol => turb%fvolJ
    sij  => turb%mJSij
  ELSEIF (ijk==dirk) THEN
! - pointers and indices for k-direction
    ibeg = ipcbeg-1
    iend = ipcend+1
    jbeg = jpcbeg-1
    jend = jpcend+1
    kbeg = kpcbeg-1
    kend = kpcend+2
    iadd = 0
    jadd = 0
    kadd = -1
    fvol => turb%fvolK
    sij  => turb%mKSij
  END IF

! compute eddy viscosity; note that face density is stored in fVar as 1/rho
! which is leftover from lesLij; so we devide by fVar(1,:) instead of multiply

  DO k=kbeg,kend
    DO j=jbeg,jend
      DO i=ibeg,iend

        ijkc0 = indijk(i     ,j     ,k     ,icoff,ijcoff)
        ijkc1 = ijkc0 + iadd + jadd*icoff + kadd*ijcoff
        ijkn  = indijk(i     ,j     ,k     ,inoff,ijnoff)
#endif
#ifdef RFLU

  fvol => turb%fvolI
  sij  => turb%mISij

  DO ijkn =ibn,ien
#endif

        sxx = sij(e11,ijkn)
        sxy = sij(e12,ijkn)
        sxz = sij(e13,ijkn)

        syy = sij(e22,ijkn)
        syz = sij(e23,ijkn)

        szz = sij(e33,ijkn)

        vormag = 0.5_rfreal*(sxx*sxx+syy*syy+szz*szz)+sxy*sxy+sxz*sxz+syz*syz
        vormag = sqrt(vormag)

        volface= fvol(ijkn)
        delta2 = volface**two3rd  ! another option: delta2=3.*volFace**two3rd

!        rhoFace= 1._RFREAL/fVar(CV_TURB_DENS,ijkN)
        muturb = cmodel(1,ijkn)/fvar(cv_turb_dens,ijkn)*delfac2*delta2*vormag

! Temporary clipping fix 
        muturb = max(muturb,real_small)
!

!        rhoMin = MIN(rhoFace,rhoMin)
!        muTMin = MIN(muTurb ,muTMin)

        muet(ijk,ijkn) = muturb

#ifdef RFLO
        tdv(dv_turb_cdyn,ijkc0) = tdv(dv_turb_cdyn,ijkc0)+cmodel(1,ijkn)
        tdv(dv_turb_cdyn,ijkc1) = tdv(dv_turb_cdyn,ijkc1)+cmodel(1,ijkn)
      ENDDO   ! i
    ENDDO     ! j
  ENDDO       ! k
#endif
#ifdef RFLU
  ENDDO       ! ijkN

! sum model coefficient from faces; the division by nfaces is in GetTvCell
  DO ijkn = 1,region%grid%nFaces
    ijkc0 = region%grid%f2c(1,ijkn)
    ijkc1 = region%grid%f2c(2,ijkn)

    tdv(dv_turb_cdyn,ijkc0) = tdv(dv_turb_cdyn,ijkc0)+cmodel(1,ijkn)
    tdv(dv_turb_cdyn,ijkc1) = tdv(dv_turb_cdyn,ijkc1)+cmodel(1,ijkn)
  ENDDO  ! ijkN
#endif

! RFLU boundary treatment =====================================================

#ifdef RFLU
  bfvol   => turb%bfVolI
  bfvar   => turb%bfVar
  bcmodel => turb%bCoef
  bmuet   => turb%bMueT
  bsij    => turb%bmISij

  DO ipatch = 1,region%grid%nPatches
    patch  => region%patches(ipatch)
! TEMPORARY : removing usage of bf2bg from everywhere
!    ifgBeg =  patch%bf2bg(BF2BG_BEG)
!    ifgtBeg=  patch%bf2bgTot(BF2BG_BEG)

    bctype = patch%bcType
    IF (bctype>=bc_noslipwall .AND. bctype<=bc_noslipwall+bc_range .OR. &
        bctype>=bc_injection .AND. bctype<=bc_injection+bc_range) THEN
      IF (turbmodel==turb_model_fixsmag) THEN
        bvalfactor = 1._rfreal
      ELSE
        bvalfactor = 0._rfreal
      ENDIF ! turbModel
    ELSE
      bvalfactor = 1._rfreal
    ENDIF

! - sum model coefficient from bFaces; the division by nfaces is in GetTvCell
!   Note, bValFactor is needed for Rocflu to set eddy viscosity explicitly
!   to zero at injection and noslip-walls if desired.

    DO ifl = 1,patch%nBFaces
      ijkc0 = patch%bf2c(ifl)
      ifg   = ifl + ifgbeg-1

      sxx = bsij(e11,ifg)
      sxy = bsij(e12,ifg)
      sxz = bsij(e13,ifg)

      syy = bsij(e22,ifg)
      syz = bsij(e23,ifg)

      szz = bsij(e33,ifg)

      vormag = 0.5_rfreal*(sxx*sxx+syy*syy+szz*szz)+sxy*sxy+sxz*sxz+syz*syz
      vormag = sqrt(vormag)

      volface= bfvol(ifg)
      delta2 = volface**two3rd  ! another option: delta2=3.*volFace**two3rd

!      rhoFace= 1._RFREAL/bfVar(CV_TURB_DENS,ifg)
      muturb = cmodel(1,ifg)/bfvar(cv_turb_dens,ifg)*delfac2*delta2*vormag
! Temporary clipping fix
      muturb = max(muturb,real_small)
!

!      rhoMin = MIN(rhoFace,rhoMin)
!      muTMin = MIN(muTurb ,muTMin)

      bmuet(ijk,ifg) = bvalfactor*muturb
      tdv(dv_turb_cdyn,ijkc0) = tdv(dv_turb_cdyn,ijkc0)+bcmodel(1,ifg)
    ENDDO    ! ifl
  ENDDO      ! iPatch
#endif

! check minimum density

  IF (rhomin < 0._rfreal) THEN
    write(*,*) 'TURB_LesCalcEddyVis: rhoMin < 0'
  ENDIF
  IF (mutmin < 0._rfreal) THEN
    write(*,*) 'TURB_LesCalcEddyVis: muTMin < 0'
  ENDIF

! deallocate temporary arrays

  DEALLOCATE( turb%coef, turb%fVar )
#ifdef RFLU
  DEALLOCATE( turb%bCoef, turb%bfVar )
#endif

! finalize --------------------------------------------------------------------

  CALL deregisterfunction( global )

END SUBROUTINE turb_lescalceddyvis

!******************************************************************************
!
! RCS Revision history:
! 
! $Log: TURB_LesCalcEddyVis.F90,v $
! Revision 1.17  2009/08/12 04:15:59  mtcampbe
! Major update, bugfix from Abe development, more propagation compatibility,
! some Rocstar IO changes, Ju's temporary clipping fix for turbulence. A bug
! fix for initialization IO.
!
! Revision 1.16  2008/12/06 08:44:41  mtcampbe
! Updated license.
!
! Revision 1.15  2008/11/19 22:17:53  mtcampbe
! Added Illinois Open Source License/Copyright
!
! Revision 1.14  2006/08/19 15:40:59  mparmar
! Removed bf2bg, bf2bgTot
!
! Revision 1.13  2006/01/17 17:51:55  wasistho
! applied tripping to all eddy viscosity models
!
! Revision 1.12  2006/01/13 07:13:49  wasistho
! set rflu bValFactor=1 for FixSM and 0 else
!
! Revision 1.11  2006/01/13 06:53:42  wasistho
! set rflu bValFactor=1 for more stable sim
!
! Revision 1.10  2006/01/12 09:48:31  wasistho
! enabled tripping fixed Smagorinsky
!
! Revision 1.9  2006/01/01 00:11:03  wasistho
! multiplied muturb by bValFactor for rocflu
!
! Revision 1.8  2005/12/29 19:51:00  wasistho
! modified face indexing for sij
!
! Revision 1.7  2004/07/30 22:33:54  wasistho
! replaced floLesUniC2F by floLesGenC2F
!
! Revision 1.6  2004/05/28 02:00:17  wasistho
! update unstructured grid LES
!
! Revision 1.5  2004/05/17 20:47:39  wasistho
! compute first layer dummy mu_t instead of extrapolated
!
! Revision 1.4  2004/03/27 02:16:42  wasistho
! compiled with Rocflu
!
! Revision 1.3  2004/03/19 02:48:36  wasistho
! prepared for RFLU
!
! Revision 1.2  2004/03/12 02:55:35  wasistho
! changed rocturb routine names
!
! Revision 1.1  2004/03/05 04:37:00  wasistho
! changed nomenclature
!
! Revision 1.1  2003/10/09 23:10:45  wasistho
! renamed CalcEddyVis to LesCalcEddyVis
!
! Revision 1.5  2003/08/29 01:42:51  wasistho
! Added TARGET attribute to region variable, since pointers are cached into it
!
! Revision 1.4  2003/05/15 02:57:06  jblazek
! Inlined index function.
!
! Revision 1.3  2002/10/16 07:47:41  wasistho
! Enable Fix Smagorinsky
!
! Revision 1.2  2002/10/16 01:59:03  wasistho
! Changed global%error flag
!
! Revision 1.1  2002/10/14 23:55:29  wasistho
! Install Rocturb
!
!
!******************************************************************************