TURB_floLesGenC2F.F90

Go to the documentation of this file.

! *********************************************************************
! * Rocstar Simulation Suite                                          *
! * Copyright@2015, Illinois Rocstar LLC. All rights reserved.        *
! *                                                                   *
! * Illinois Rocstar LLC                                              *
! * Champaign, IL                                                     *
! * www.illinoisrocstar.com                                           *
! * sales@illinoisrocstar.com                                         *
! *                                                                   *
! * License: See LICENSE file in top level of distribution package or *
! * http://opensource.org/licenses/NCSA                               *
! *********************************************************************
! *********************************************************************
! * THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND,   *
! * EXPRESS OR IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES   *
! * OF MERCHANTABILITY, FITNESS FOR A PARTICULAR PURPOSE AND          *
! * NONINFRINGEMENT.  IN NO EVENT SHALL THE CONTRIBUTORS OR           *
! * COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER       *
! * LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE,   *
! * Arising FROM, OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE    *
! * USE OR OTHER DEALINGS WITH THE SOFTWARE.                          *
! *********************************************************************
!******************************************************************************
!
! Purpose: Get face values of cv for non-uniform grid.
!
! Description: It is obtained by two point averaging the adjacent cell values
!              using the averaging coefficients avgCoI,J,K.
!
! Input: region = data of current region
!        ijk    = ijk-face is being treated
!
! Output: fVar = face values of cv.
!
! Notes: This routine is currently only relevant if non-uniform filter is 
!        selected.
!
!******************************************************************************
!
! $Id: TURB_floLesGenC2F.F90,v 1.7 2008/12/06 08:44:43 mtcampbe Exp $
!
! Copyright: (c) 2001 by the University of Illinois
!
!******************************************************************************

SUBROUTINE turb_flolesgenc2f( region,ijk )

  USE moddatatypes
  USE moddatastruct, ONLY : t_region
  USE modglobal, ONLY     : t_global
  USE modinterfaces, ONLY : rflo_getdimensphys, &
                            rflo_getcelloffset, rflo_getnodeoffset
  USE moderror
  USE modparameters
  USE turb_modparameters
  IMPLICIT NONE

#include "Indexing.h"

! ... parameters
  TYPE(t_region) :: region
  INTEGER        :: ijk

! ... loop variables
  INTEGER :: i, j, k, m, ijkc0, ijkc1, ijkn, ijkn1

! ... local variables
  CHARACTER(CHRLEN)       :: rcsidentstring
  TYPE(t_global), POINTER :: global

  INTEGER           :: ibeg,iend,jbeg,jend,kbeg,kend, iadd,jadd,kadd
  INTEGER           :: idcbeg,idcend,jdcbeg,jdcend,kdcbeg,kdcend
  INTEGER           :: ilev,icoff,ijcoff,inoff,ijnoff
  INTEGER           :: indxc0(2),indxn(2),indxn1(2)
  REAL(RFREAL), POINTER :: avgco(:,:),cv(:,:),fvar(:,:)

!******************************************************************************

  rcsidentstring = '$RCSfile: TURB_floLesGenC2F.F90,v $'

  global => region%global
  CALL registerfunction( global,'TURB_FloLesGenC2F',&
  'TURB_floLesGenC2F.F90' )

! get indices and pointers ---------------------------------------------------

  ilev   =  region%currLevel
  cv     => region%levels(ilev)%mixt%cv
  fvar   => region%levels(ilev)%turb%fVar

  CALL rflo_getdimensdummy( region,ilev,idcbeg,idcend, &
                            jdcbeg,jdcend,kdcbeg,kdcend )
  CALL rflo_getcelloffset( region,ilev,icoff,ijcoff )
  CALL rflo_getnodeoffset( region,ilev,inoff,ijnoff )
  IF (ijk==diri) THEN
    ibeg = idcbeg+1
    iend = idcend
    jbeg = jdcbeg
    jend = jdcend
    kbeg = kdcbeg
    kend = kdcend
    iadd = -1
    jadd = 0
    kadd = 0
    avgco => region%levels(ilev)%grid%c2fCoI
  ELSEIF (ijk==dirj) THEN
    ibeg = idcbeg
    iend = idcend
    jbeg = jdcbeg+1
    jend = jdcend
    kbeg = kdcbeg
    kend = kdcend
    iadd = 0
    jadd = -1
    kadd = 0
    avgco => region%levels(ilev)%grid%c2fCoJ
  ELSEIF (ijk==dirk) THEN
    ibeg = idcbeg
    iend = idcend
    jbeg = jdcbeg
    jend = jdcend
    kbeg = kdcbeg+1
    kend = kdcend
    iadd = 0
    jadd = 0
    kadd = -1
    avgco => region%levels(ilev)%grid%c2fCoK
  ENDIF

! perform 2-point averaging of rho,rhou1,rhou2 and rhou3 from centers to faces

  DO k=kbeg,kend
    DO j=jbeg,jend
      DO i=ibeg,iend

          ijkc0 = indijk(i     ,j     ,k     ,icoff,ijcoff)
          ijkc1 = ijkc0 + iadd + jadd*icoff + kadd*ijcoff
          ijkn  = indijk(i     ,j     ,k     ,inoff,ijnoff)

          fvar(cv_turb_dens,ijkn)=avgco(2,ijkn)*cv(cv_mixt_dens,ijkc0)+ &
                                  avgco(1,ijkn)*cv(cv_mixt_dens,ijkc1)
          fvar(cv_turb_xmom,ijkn)=avgco(2,ijkn)*cv(cv_mixt_xmom,ijkc0)+ &
                                  avgco(1,ijkn)*cv(cv_mixt_xmom,ijkc1)
          fvar(cv_turb_ymom,ijkn)=avgco(2,ijkn)*cv(cv_mixt_ymom,ijkc0)+ &
                                  avgco(1,ijkn)*cv(cv_mixt_ymom,ijkc1)
          fvar(cv_turb_zmom,ijkn)=avgco(2,ijkn)*cv(cv_mixt_zmom,ijkc0)+ &
                                  avgco(1,ijkn)*cv(cv_mixt_zmom,ijkc1)

        ENDDO   ! i
      ENDDO     ! j
    ENDDO       ! k

!$startcopy TURB_FloLesUniC2F
! extrapolation to outerst layers

  IF (ijk==diri) THEN
    indxn1(1)=ibeg-1
    indxc0(1)=ibeg-1
    indxn(1) =ibeg
    indxn1(2)=iend+1
    indxc0(2)=iend
    indxn(2) =iend
    DO m=1,2
      DO k=kbeg,kend
        DO j=jbeg,jend
          ijkn  = indijk(indxn(m)   ,j     ,k     ,inoff,ijnoff)
          ijkn1 = ijkn + indxn1(m)-indxn(m)
          ijkc0 = indijk(indxc0(m)  ,j     ,k     ,icoff,ijcoff)

          fvar(cv_turb_dens,ijkn1)=2._rfreal*cv(cv_mixt_dens,ijkc0)- &
                                           fvar(cv_turb_dens,ijkn)
          fvar(cv_turb_xmom,ijkn1)=2._rfreal*cv(cv_mixt_xmom,ijkc0)- &
                                           fvar(cv_turb_xmom,ijkn)
          fvar(cv_turb_ymom,ijkn1)=2._rfreal*cv(cv_mixt_ymom,ijkc0)- &
                                           fvar(cv_turb_ymom,ijkn)
          fvar(cv_turb_zmom,ijkn1)=2._rfreal*cv(cv_mixt_zmom,ijkc0)- &
                                           fvar(cv_turb_zmom,ijkn)
        ENDDO     ! j
      ENDDO       ! k
    ENDDO         ! m

    DO k=kdcbeg,kdcend+1
      DO i=idcbeg,idcend+1
        ijkn  = indijk(i    ,jdcend+1 ,k     ,inoff,ijnoff)
        ijkn1 = ijkn - inoff
        fvar(cv_turb_dens,ijkn) = fvar(cv_turb_dens,ijkn1)
        fvar(cv_turb_xmom,ijkn) = fvar(cv_turb_xmom,ijkn1)
        fvar(cv_turb_ymom,ijkn) = fvar(cv_turb_ymom,ijkn1) 
        fvar(cv_turb_zmom,ijkn) = fvar(cv_turb_zmom,ijkn1)
      ENDDO     ! i
    ENDDO       ! k
    DO j=jdcbeg,jdcend+1
      DO i=idcbeg,idcend+1
        ijkn  = indijk(i    ,j    ,kdcend+1  ,inoff,ijnoff)
        ijkn1 = ijkn - ijnoff
        fvar(cv_turb_dens,ijkn) = fvar(cv_turb_dens,ijkn1)
        fvar(cv_turb_xmom,ijkn) = fvar(cv_turb_xmom,ijkn1)
        fvar(cv_turb_ymom,ijkn) = fvar(cv_turb_ymom,ijkn1) 
        fvar(cv_turb_zmom,ijkn) = fvar(cv_turb_zmom,ijkn1)
      ENDDO     ! i
    ENDDO       ! j

  ELSEIF (ijk==dirj) THEN
    indxn1(1)=jbeg-1
    indxc0(1)=jbeg-1
    indxn(1) =jbeg
    indxn1(2)=jend+1
    indxc0(2)=jend
    indxn(2) =jend
    DO m=1,2
      DO k=kbeg,kend
        DO i=ibeg,iend
          ijkn  = indijk(i     ,indxn(m)     ,k     ,inoff,ijnoff)
          ijkn1 = ijkn + (indxn1(m)-indxn(m))*inoff
          ijkc0 = indijk(i     ,indxc0(m)    ,k     ,icoff,ijcoff)

          fvar(cv_turb_dens,ijkn1)=2._rfreal*cv(cv_mixt_dens,ijkc0)- &
                                           fvar(cv_turb_dens,ijkn)
          fvar(cv_turb_xmom,ijkn1)=2._rfreal*cv(cv_mixt_xmom,ijkc0)- &
                                           fvar(cv_turb_xmom,ijkn)
          fvar(cv_turb_ymom,ijkn1)=2._rfreal*cv(cv_mixt_ymom,ijkc0)- &
                                           fvar(cv_turb_ymom,ijkn)
          fvar(cv_turb_zmom,ijkn1)=2._rfreal*cv(cv_mixt_zmom,ijkc0)- &
                                           fvar(cv_turb_zmom,ijkn)
        ENDDO     ! i
      ENDDO       ! k
    ENDDO         ! m

    DO k=kdcbeg,kdcend+1
      DO j=jdcbeg,jdcend+1
        ijkn  = indijk(idcend+1 ,j     ,k     ,inoff,ijnoff)
        ijkn1 = ijkn - 1
        fvar(cv_turb_dens,ijkn) = fvar(cv_turb_dens,ijkn1)
        fvar(cv_turb_xmom,ijkn) = fvar(cv_turb_xmom,ijkn1)
        fvar(cv_turb_ymom,ijkn) = fvar(cv_turb_ymom,ijkn1) 
        fvar(cv_turb_zmom,ijkn) = fvar(cv_turb_zmom,ijkn1)
      ENDDO     ! j
    ENDDO       ! k
    DO j=jdcbeg,jdcend+1
      DO i=idcbeg,idcend+1
        ijkn  = indijk(i    ,j    ,kdcend+1  ,inoff,ijnoff)
        ijkn1 = ijkn - ijnoff
        fvar(cv_turb_dens,ijkn) = fvar(cv_turb_dens,ijkn1)
        fvar(cv_turb_xmom,ijkn) = fvar(cv_turb_xmom,ijkn1)
        fvar(cv_turb_ymom,ijkn) = fvar(cv_turb_ymom,ijkn1) 
        fvar(cv_turb_zmom,ijkn) = fvar(cv_turb_zmom,ijkn1)
      ENDDO     ! i
    ENDDO       ! j

  ELSEIF (ijk==dirk) THEN
    indxn1(1)=kbeg-1
    indxc0(1)=kbeg-1
    indxn(1) =kbeg
    indxn1(2)=kend+1
    indxc0(2)=kend
    indxn(2) =kend
    DO m=1,2
      DO j=jbeg,jend
        DO i=ibeg,iend
          ijkn  = indijk(i     ,j     ,indxn(m)     ,inoff,ijnoff)
          ijkn1 = ijkn + (indxn1(m)-indxn(m))*ijnoff
          ijkc0 = indijk(i     ,j     ,indxc0(m)    ,icoff,ijcoff)

          fvar(cv_turb_dens,ijkn1)=2._rfreal*cv(cv_mixt_dens,ijkc0)- &
                                           fvar(cv_turb_dens,ijkn)
          fvar(cv_turb_xmom,ijkn1)=2._rfreal*cv(cv_mixt_xmom,ijkc0)- &
                                           fvar(cv_turb_xmom,ijkn)
          fvar(cv_turb_ymom,ijkn1)=2._rfreal*cv(cv_mixt_ymom,ijkc0)- &
                                           fvar(cv_turb_ymom,ijkn)
          fvar(cv_turb_zmom,ijkn1)=2._rfreal*cv(cv_mixt_zmom,ijkc0)- &
                                           fvar(cv_turb_zmom,ijkn)
        ENDDO     ! i
      ENDDO       ! j
    ENDDO         ! m

    DO k=kdcbeg,kdcend+1
      DO j=jdcbeg,jdcend+1
        ijkn  = indijk(idcend+1 ,j     ,k     ,inoff,ijnoff)
        ijkn1 = ijkn - 1
        fvar(cv_turb_dens,ijkn) = fvar(cv_turb_dens,ijkn1)
        fvar(cv_turb_xmom,ijkn) = fvar(cv_turb_xmom,ijkn1)
        fvar(cv_turb_ymom,ijkn) = fvar(cv_turb_ymom,ijkn1) 
        fvar(cv_turb_zmom,ijkn) = fvar(cv_turb_zmom,ijkn1)
      ENDDO     ! j
    ENDDO       ! k
    DO k=kdcbeg,kdcend+1
      DO i=idcbeg,idcend+1
        ijkn  = indijk(i    ,jdcend+1  ,k     ,inoff,ijnoff)
        ijkn1 = ijkn - inoff
        fvar(cv_turb_dens,ijkn) = fvar(cv_turb_dens,ijkn1)
        fvar(cv_turb_xmom,ijkn) = fvar(cv_turb_xmom,ijkn1)
        fvar(cv_turb_ymom,ijkn) = fvar(cv_turb_ymom,ijkn1) 
        fvar(cv_turb_zmom,ijkn) = fvar(cv_turb_zmom,ijkn1)
      ENDDO     ! i
    ENDDO       ! k

  ENDIF         ! ijk
!$endcopy

! finalize --------------------------------------------------------------------

  CALL deregisterfunction( global )

END SUBROUTINE turb_flolesgenc2f

!******************************************************************************
!
! RCS Revision history:
!
! $Log: TURB_floLesGenC2F.F90,v $
! Revision 1.7  2008/12/06 08:44:43  mtcampbe
! Updated license.
!
! Revision 1.6  2008/11/19 22:17:55  mtcampbe
! Added Illinois Open Source License/Copyright
!
! Revision 1.5  2004/08/02 19:33:49  wasistho
! changed grid%avgCo to grid%c2fCo
!
! Revision 1.4  2004/07/30 17:46:48  wasistho
! replaced turb face averaging by rflo face averaging
!
! Revision 1.3  2004/03/19 02:52:51  wasistho
! prepared for RFLU
!
! Revision 1.2  2004/03/12 02:55:36  wasistho
! changed rocturb routine names
!
! Revision 1.1  2004/03/08 23:35:45  wasistho
! changed turb nomenclature
!
! Revision 1.2  2003/05/15 02:57:06  jblazek
! Inlined index function.
!
! Revision 1.1  2002/10/14 23:55:29  wasistho
! Install Rocturb
!
!
!******************************************************************************