TURB_fluLesC2F.F90

Go to the documentation of this file.

! *********************************************************************
! * Rocstar Simulation Suite                                          *
! * Copyright@2015, Illinois Rocstar LLC. All rights reserved.        *
! *                                                                   *
! * Illinois Rocstar LLC                                              *
! * Champaign, IL                                                     *
! * www.illinoisrocstar.com                                           *
! * sales@illinoisrocstar.com                                         *
! *                                                                   *
! * License: See LICENSE file in top level of distribution package or *
! * http://opensource.org/licenses/NCSA                               *
! *********************************************************************
! *********************************************************************
! * THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND,   *
! * EXPRESS OR IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES   *
! * OF MERCHANTABILITY, FITNESS FOR A PARTICULAR PURPOSE AND          *
! * NONINFRINGEMENT.  IN NO EVENT SHALL THE CONTRIBUTORS OR           *
! * COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER       *
! * LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE,   *
! * Arising FROM, OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE    *
! * USE OR OTHER DEALINGS WITH THE SOFTWARE.                          *
! *********************************************************************
!******************************************************************************
!
! Purpose: Get face values of cv for unstructured grid.
!
! Description: It is obtained by two point averaging the adjacent cell values
!              using the averaging coefficients avgCo.
!
! Input: region = data of current region
!
! Output: fVar = face values of cv.
!
! Notes: none.
!
!******************************************************************************
!
! $Id: TURB_fluLesC2F.F90,v 1.5 2008/12/06 08:44:44 mtcampbe Exp $
!
! Copyright: (c) 2001 by the University of Illinois
!
!******************************************************************************

SUBROUTINE turb_flulesc2f( region )

  USE moddatatypes
  USE moddatastruct, ONLY : t_region
  USE modglobal, ONLY     : t_global
  USE modbndpatch, ONLY   : t_patch
  USE moderror
  USE modparameters
  USE turb_modparameters
  IMPLICIT NONE

! ... parameters
  TYPE(t_region) :: region

! ... loop variables
  INTEGER :: if, ifl, ipatch

! ... local variables
  CHARACTER(CHRLEN)       :: rcsidentstring
  TYPE(t_global), POINTER :: global
  TYPE(t_patch), POINTER  :: patch

  INTEGER :: ijkc0, ijkc1, ifg, bctype
  REAL(RFREAL), POINTER :: cv(:,:), avgco(:,:), fvar(:,:), bfvar(:,:)
  INTEGER, POINTER      :: f2c(:,:), bf2c(:)

!******************************************************************************

  rcsidentstring = '$RCSfile: TURB_fluLesC2F.F90,v $ $Revision: 1.5 $'

  global => region%global
  CALL registerfunction( global,'TURB_FluLesC2F',&
  'TURB_fluLesC2F.F90' )

! get indices and pointers ---------------------------------------------------

  cv         => region%mixt%cv
  f2c        => region%grid%f2c
  avgco      => region%turb%avgCoI
  fvar       => region%turb%fVar
  bfvar      => region%turb%bfVar
  avgco(:,:) =  0.5_rfreal  ! for now, waiting for proper average coefficients

! perform 2-point averaging of rho,rhou1,rhou2 and rhou3 from centers to faces

  DO if = 1,region%grid%nFaces
    ijkc0 = f2c(1,if)
    ijkc1 = f2c(2,if)

    fvar(cv_turb_dens,if)=avgco(2,if)*cv(cv_mixt_dens,ijkc0)+ &
                          avgco(1,if)*cv(cv_mixt_dens,ijkc1)
    fvar(cv_turb_xmom,if)=avgco(2,if)*cv(cv_mixt_xmom,ijkc0)+ &
                          avgco(1,if)*cv(cv_mixt_xmom,ijkc1)
    fvar(cv_turb_ymom,if)=avgco(2,if)*cv(cv_mixt_ymom,ijkc0)+ &
                          avgco(1,if)*cv(cv_mixt_ymom,ijkc1)
    fvar(cv_turb_zmom,if)=avgco(2,if)*cv(cv_mixt_zmom,ijkc0)+ &
                          avgco(1,if)*cv(cv_mixt_zmom,ijkc1)
  ENDDO  ! if

  ifg = 0
  DO ipatch = 1,region%grid%nPatches
    patch  => region%patches(ipatch)
    bf2c   => patch%bf2c
    bctype =  patch%bcType

    IF (bctype>=bc_noslipwall .AND. bctype>=bc_noslipwall+bc_range) THEN   

      DO ifl = 1,patch%nBFaces
        ijkc0 = bf2c(ifl)
        ifg   = ifg + 1

        bfvar(cv_turb_dens,ifg) = cv(cv_mixt_dens,ijkc0)
        bfvar(cv_turb_xmom,ifg) = 0._rfreal
        bfvar(cv_turb_ymom,ifg) = 0._rfreal
        bfvar(cv_turb_zmom,ifg) = 0._rfreal
      ENDDO  ! ifl
    ELSE
      DO ifl = 1,patch%nBFaces
        ijkc0 = bf2c(ifl)
        ifg   = ifg + 1

        bfvar(cv_turb_dens,ifg) = cv(cv_mixt_dens,ijkc0)
        bfvar(cv_turb_xmom,ifg) = cv(cv_mixt_xmom,ijkc0)
        bfvar(cv_turb_ymom,ifg) = cv(cv_mixt_ymom,ijkc0)
        bfvar(cv_turb_zmom,ifg) = cv(cv_mixt_zmom,ijkc0)
      ENDDO  ! ifl
    ENDIF

  ENDDO  ! iPatch

! finalize --------------------------------------------------------------------

  CALL deregisterfunction( global )

END SUBROUTINE turb_flulesc2f

!******************************************************************************
!
! RCS Revision history:
!
! $Log: TURB_fluLesC2F.F90,v $
! Revision 1.5  2008/12/06 08:44:44  mtcampbe
! Updated license.
!
! Revision 1.4  2008/11/19 22:17:56  mtcampbe
! Added Illinois Open Source License/Copyright
!
! Revision 1.3  2004/05/28 02:00:01  wasistho
! update unstructured grid LES
!
! Revision 1.2  2004/03/27 02:16:42  wasistho
! compiled with Rocflu
!
! Revision 1.1  2004/03/19 02:54:58  wasistho
! prepared for RFLU
!
!
!******************************************************************************