TURB_LesCoefDynMixd.F90

Go to the documentation of this file.

! *********************************************************************
! * Rocstar Simulation Suite                                          *
! * Copyright@2015, Illinois Rocstar LLC. All rights reserved.        *
! *                                                                   *
! * Illinois Rocstar LLC                                              *
! * Champaign, IL                                                     *
! * www.illinoisrocstar.com                                           *
! * sales@illinoisrocstar.com                                         *
! *                                                                   *
! * License: See LICENSE file in top level of distribution package or *
! * http://opensource.org/licenses/NCSA                               *
! *********************************************************************
! *********************************************************************
! * THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND,   *
! * EXPRESS OR IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES   *
! * OF MERCHANTABILITY, FITNESS FOR A PARTICULAR PURPOSE AND          *
! * NONINFRINGEMENT.  IN NO EVENT SHALL THE CONTRIBUTORS OR           *
! * COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER       *
! * LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE,   *
! * Arising FROM, OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE    *
! * USE OR OTHER DEALINGS WITH THE SOFTWARE.                          *
! *********************************************************************
!******************************************************************************
!
! Purpose: Obtain model coefficient for dynamic mixed model.
!
! Description: none.
!
! Input: region  = data of current region
!        ibn,ien = begin and end node index
!        ijk     = ijk-face is being treated
!
! Output: cModel = turb%coef = model coefficient
!
! Notes: none.
!
!******************************************************************************
!
! $Id: TURB_LesCoefDynMixd.F90,v 1.7 2008/12/06 08:44:41 mtcampbe Exp $
!
! Copyright: (c) 2001 by the University of Illinois
!
!******************************************************************************

SUBROUTINE turb_lescoefdynmixd( region,ibn,ien,ijk )

  USE moddatatypes
  USE moddatastruct, ONLY      : t_region
  USE modturbulence, ONLY      : t_turb
  USE modglobal, ONLY          : t_global
#ifdef RFLU
  USE modbndpatch, ONLY        : t_patch
  USE turb_modinterfaces, ONLY : turb_flulesblij, turb_flulesbmij
  USE turb_modinterfaces, ONLY : turb_flulesc2f
#endif                                 
#ifdef RFLO
  USE turb_modinterfaces, ONLY : turb_flolesgenc2f
#endif                                 
  USE turb_modinterfaces, ONLY : turb_leslij, turb_leshij, turb_lesmij, &
                                 turb_lescontract
  USE moderror
  USE modparameters
  USE turb_modparameters
  IMPLICIT NONE

! ... parameters
#ifdef RFLO
  TYPE(t_region), TARGET  :: region
#endif
#ifdef RFLU
  TYPE(t_region), POINTER :: region
#endif
  INTEGER                 :: ibn,ien,ijk

! ... loop variables
  INTEGER :: ipatch

! ... local variables
  CHARACTER(CHRLEN)       :: rcsidentstring
  TYPE(t_global), POINTER :: global
  TYPE(t_turb), POINTER   :: turb
#ifdef RFLU
  TYPE(t_patch), POINTER  :: patch
#endif

  REAL(RFREAL), POINTER :: lij(:,:)
  INTEGER               :: tndel(diri:dirk), errorflag
#ifdef RFLO
  INTEGER               :: ilev, filtertype
#endif
#ifdef RFLU
  INTEGER               :: npatches, nbfaces
  REAL(RFREAL), POINTER :: blij(:,:)
#endif

!******************************************************************************

  rcsidentstring = '$RCSfile: TURB_LesCoefDynMixd.F90,v $'

  global => region%global
  CALL registerfunction( global,'Turb_LesCoefDynMixd',&
  'TURB_LesCoefDynMixd.F90' )

! get some parameters --------------------------------------------------------

#ifdef RFLO
  ilev       =  region%currLevel
  filtertype =  region%turbInput%filterType
  turb       => region%levels(ilev)%turb
#endif
#ifdef RFLU
  npatches = region%grid%nPatches
  nbfaces  = 0

  DO ipatch = 1,npatches
    patch   => region%patches(ipatch)
    nbfaces =  nbfaces + patch%nBTris + patch%nBQuads
  END DO ! iPatch
  turb => region%turb
#endif

! settle the filter-width for the test-filter 

  tndel(diri) = 2*region%turbInput%filterWidth(diri)
#ifdef RFLO
  tndel(dirj) = 2*region%turbInput%filterWidth(dirj)
  tndel(dirk) = 2*region%turbInput%filterWidth(dirk)
#endif
#ifdef RFLU
  tndel(dirj) = 0._rfreal
  tndel(dirk) = 0._rfreal
#endif

! first transfer rho and rho*ui from the centers to the faces since we 
! require the turbulent stress tensor in these points; store the results 
! in rhof, rhou1f, rhou2f and rhou3f; face-cv, fVar, is already allocated  

#ifdef RFLO
  CALL turb_flolesgenc2f( region,ijk )
#endif
#ifdef RFLU
  CALL turb_flulesc2f( region )
#endif

! allocate and point arrays required by LesLij (ffVar, lij), LesMij (ffVar),
! lesHij (ffVar,lij) and by lesContract (lij)
  
  ALLOCATE( turb%ffVar(cv_turb_nelm,ibn:ien),stat=errorflag )    
  ALLOCATE( turb%lij(tensor_symm_nelm,ibn:ien),stat=errorflag )  
  ALLOCATE( turb%mij(tensor_symm_nelm,ibn:ien),stat=errorflag )  
  global%error = errorflag
  IF (global%error /= 0) CALL errorstop( global,err_allocate,__line__ )

  lij => turb%lij

#ifdef RFLU  
  ALLOCATE( turb%bffVar(cv_turb_nelm,nbfaces),stat=errorflag )    
  ALLOCATE( turb%bLij(tensor_symm_nelm,nbfaces),stat=errorflag )  
  ALLOCATE( turb%bMij(tensor_symm_nelm,nbfaces),stat=errorflag )  
  global%error = errorflag
  IF (global%error /= 0) CALL errorstop( global,err_allocate,__line__ )

  blij => turb%bLij
#endif

! determine components of lij for which we use the routine TURB_LesLij
! with test-filter instead of bar-filter

  CALL turb_leslij( region,ijk,tndel,lij )
#ifdef RFLU
  CALL turb_flulesblij( region,tndel,blij )
#endif

! determine components of mij which we store in mij using rhof and rhoftb 
! already available from TURB_LesLij

  CALL turb_lesmij( region,ijk )
#ifdef RFLU
  CALL turb_flulesbmij( region )
#endif

! adjust L_{ij} and subtract H_{ij} from it and store this in lij again

#ifdef RFLO
  CALL turb_leshij( region,ijk )
  DEALLOCATE( turb%ffVar )
#endif
#ifdef RFLU
  DEALLOCATE( turb%bffVar )
#endif

! contract lij and mij to obtain model-coefficient at cell faces

  CALL turb_lescontract( region,ijk )
  DEALLOCATE( turb%lij,turb%mij )
#ifdef RFLU
  DEALLOCATE( turb%bLij,turb%bMij )
#endif

! finalize --------------------------------------------------------------------

  CALL deregisterfunction( global )

END SUBROUTINE turb_lescoefdynmixd

!******************************************************************************
!
! RCS Revision history:
! 
! $Log: TURB_LesCoefDynMixd.F90,v $
! Revision 1.7  2008/12/06 08:44:41  mtcampbe
! Updated license.
!
! Revision 1.6  2008/11/19 22:17:54  mtcampbe
! Added Illinois Open Source License/Copyright
!
! Revision 1.5  2004/07/30 22:34:22  wasistho
! replaced floLesUniC2F by floLesGenC2F
!
! Revision 1.4  2004/05/28 02:00:50  wasistho
! update unstructured grid LES
!
! Revision 1.3  2004/03/19 02:49:12  wasistho
! prepared for RFLU
!
! Revision 1.2  2004/03/12 02:55:35  wasistho
! changed rocturb routine names
!
! Revision 1.1  2004/03/05 04:37:00  wasistho
! changed nomenclature
!
! Revision 1.3  2003/08/29 01:40:50  wasistho
! Added TARGET attribute to region variable, since pointers are cached into it
!
! Revision 1.2  2002/10/16 01:59:21  wasistho
! Changed global%error flag
!
! Revision 1.1  2002/10/14 23:55:29  wasistho
! Install Rocturb
!
!
!******************************************************************************