POST_Main.F90

Go to the documentation of this file.

! *********************************************************************
! * Rocstar Simulation Suite                                          *
! * Copyright@2015, Illinois Rocstar LLC. All rights reserved.        *
! *                                                                   *
! * Illinois Rocstar LLC                                              *
! * Champaign, IL                                                     *
! * www.illinoisrocstar.com                                           *
! * sales@illinoisrocstar.com                                         *
! *                                                                   *
! * License: See LICENSE file in top level of distribution package or *
! * http://opensource.org/licenses/NCSA                               *
! *********************************************************************
! *********************************************************************
! * THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND,   *
! * EXPRESS OR IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES   *
! * OF MERCHANTABILITY, FITNESS FOR A PARTICULAR PURPOSE AND          *
! * NONINFRINGEMENT.  IN NO EVENT SHALL THE CONTRIBUTORS OR           *
! * COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER       *
! * LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE,   *
! * Arising FROM, OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE    *
! * USE OR OTHER DEALINGS WITH THE SOFTWARE.                          *
! *********************************************************************
!******************************************************************************
!
! Purpose: write out ROCFLO-MP`s grid and/or solution for visualization.
!
! Description: currently supported formats are:
!              - generic binary
!              - TECPLOT
!
! Input: case name from the list of arguments
!
! Output: to file.
!
! Notes: the output is collected in one file, but the regions are processed
!        separately to save memory.
!
!******************************************************************************
!
! $Id: POST_Main.F90,v 1.5 2008/12/06 08:44:49 mtcampbe Exp $
!
! Copyright: (c) 2001 by the University of Illinois
!
!******************************************************************************

PROGRAM rocflo_post

  USE moddatatypes
  USE moderror
  USE moddatastruct, ONLY : t_region
  USE modglobal, ONLY     : t_global
  USE modgrid, ONLY       : t_grid
  USE modmixture, ONLY    : t_mixt
  USE post_modinterfaces, ONLY : rflo_readregiontopology, &
        rflo_initinputvalues, readinputfile, rflo_derivedinputvalues, &
        rflo_getdimensphysnodes, rflo_getdimensdummy, &
        rflo_getdimensdummynodes, rflo_getnodeoffset, rflo_getcelloffset, &
        rflo_readgridregion, rflo_readsolutionregion, rflo_readstatregion, &
        mixtureproperties, writetecplotascii, writetecplotbinary, writegeneric,&
        rflo_generatecoarsegrids, rflo_copygeometrydummy, buildversionstring, &
        printpostinput
  USE modmpi
  USE modparameters
#ifdef TURB
  USE modturbulence, ONLY : t_turb
  USE post_modinterfaces, ONLY : turb_readinputfile, &
                        turb_derivedinputvalues, turb_ranssageteddyvis, &
                        turb_rflo_readsolutionregion
  USE turb_modparameters
#endif
  IMPLICIT NONE

#include "Indexing.h"

! ... loop variables
  INTEGER :: ireg, ilev

! ... local variables
  CHARACTER(CHRLEN) :: casename, verbosity, msg, versionstring, headerstring

  INTEGER :: ipc, jpc, kpc, ibc, iec, ibn, ien, mixtnstattec, turbnstattec
  INTEGER :: idcbeg, idcend, jdcbeg, jdcend, kdcbeg, kdcend
  INTEGER :: ipnbeg, ipnend, jpnbeg, jpnend, kpnbeg, kpnend
  INTEGER :: idnbeg, idnend, jdnbeg, jdnend, kdnbeg, kdnend
  INTEGER :: icoff, ijcoff, inoff, ijnoff
  INTEGER :: margin, versionwidth, errorflag
  INTEGER, PARAMETER :: headerwidth = 53

  TYPE(t_global), POINTER :: global
  TYPE(t_region), POINTER :: regions(:)
  TYPE(t_grid)  , POINTER :: grid
  TYPE(t_mixt)  , POINTER :: mixt
#ifdef TURB
  TYPE(t_turb)  , POINTER :: turb
#endif
#ifdef STATS
  LOGICAL :: statsactive
#endif

!******************************************************************************

  ALLOCATE( global )

  global%nFunTree = 0
  CALL registerfunction( global,'ROCFLO_Post', &
                        'POST_Main.F90' )

! initialize global parameters ------------------------------------------------

  global%verbLevel = verbose_none

  global%flowType    = flow_steady  ! stationary flow
  global%currentTime = -1._rfreal   ! no physical time set
  global%currentIter = -1           ! no iteration

  global%inDir  = './'              ! directory path
  global%outDir = './'

  global%nProcAlloc = 1
  global%myProcid   = masterproc    ! default process number (not an MPI code)
  global%mpierr     = err_none
  global%error      = err_none

  global%pi  = 4._rfreal*atan(1._rfreal)
  global%rad = global%pi/180._rfreal

! print header ----------------------------------------------------------------

#ifdef MPI
  CALL mpi_init( global%mpierr )
  IF (global%mpierr /=0 ) CALL errorstop( global,err_mpi_trouble,__line__ )
#endif

  CALL buildversionstring( versionstring )

  headerstring = ' '
  versionwidth = len_trim(versionstring)
  margin       = (headerwidth-versionwidth)/2
  headerstring(margin+1:margin+versionwidth) = versionstring(1:versionwidth)
  headerstring(1:1) = '*'
  headerstring(headerwidth:headerwidth) = '*'

  WRITE(stdout,'(/,A)') solver_name//'  *****************************************************'
  WRITE(stdout,  '(A)') solver_name//'  *                                                   *'
  WRITE(stdout,  '(A)') solver_name//'  *        ROCFLO-MP: Solution Postprocessing         *'
  WRITE(stdout,  '(A)') solver_name//'  *        ==================================         *'
  WRITE(stdout,  '(A)') solver_name//'  *                                                   *'
  WRITE(stdout,  '(A)') solver_name//'  '//trim(headerstring)
  WRITE(stdout,  '(A)') solver_name//'  *    Copyright (c) by the University of Illinois    *'
  WRITE(stdout,  '(A)') solver_name//'  *                                                   *'
  WRITE(stdout,'(A,/)') solver_name//'  *****************************************************'

! print required input and read argument list ---------------------------------

  WRITE(stdout,'(/,A,/,A,/,18(A,/))') &
    solver_name//' Required Rocflo-Post input:', &
    solver_name, &
    solver_name//'   <casename>         =>  command line input', &
    solver_name//'   <verbosity>        =>  command line input', &
    solver_name//'   grid level         => .inp file: # MULTIGRID: START', &
    solver_name//'   unsteadiness       => .inp file: # TIMESTEP: FLOWTYPE', &
    solver_name//'   turbulence         => .inp file: # TURBULENCE: TURBMODEL', &
    solver_name//'                      => .inp file: # TURBULENCE: OUTPUTNUMBER', &
    solver_name//'   gas properties     => .inp file: # REFERENCE', &
    solver_name//'                      => .inp file: # VISCMODEL', &
    solver_name//'                      => .inp file: # MATERIAL (if MP is active)', &
    solver_name//'   plot type          => .inp file: # POST: PLTTYPE', &
    solver_name//'   time (unsteady)    => .inp file: # POST: TIME', &
    solver_name//'   iteration (steady) => .inp file: # POST: ITER', &
    solver_name//'   output plot format => .inp file: # POST: OUTFORMAT', &
    solver_name//'   include statistics => .inp file: # POST: STATSFLAG', &
    solver_name//'   include turbulence => .inp file: # POST: TURBFLAG', &
    solver_name//'   include particles  => .inp file: # POST: PLAGFLAG', &
    solver_name//'   include radiation  => .inp file: # POST: RADIFLAG', &
    solver_name//'   include species    => .inp file: # POST: SPECFLAG'

  CALL getarg(1,casename)
  CALL getarg(2,verbosity)

  IF (len_trim(casename)==0 .OR. &
      len_trim(verbosity)==0) THEN
    WRITE(stdout,'(/,A,/)') &
      solver_name//' Usage: rflopost <casename> <verbosity>'
#ifdef MPI
    CALL mpi_finalize( global%mpierr )
#endif
    stop
  ENDIF

  READ(casename ,*) global%casename
  READ(verbosity,*) global%verbLevel

! read region topology --------------------------------------------------------

  WRITE(stdout,'(/,A)') solver_name//' Reading region topology ...'

  CALL rflo_readregiontopology( global,regions )

! get user parameters ---------------------------------------------------------

  WRITE(stdout,'(/,A)') solver_name//' Reading user input ...'

  CALL rflo_initinputvalues( regions )
  CALL readinputfile( regions )

! copy times and iteration to corresponding post values

  global%currentTime = global%postTime
  global%timeStamp   = global%postTime
  global%currentIter = global%postIter
 
! check grid level and obtain region grid size

  DO ireg=1,global%nRegions
    regions(ireg)%startLevel = global%startLevel
    regions(ireg)%currLevel  = global%startLevel
    IF (regions(ireg)%nGridLevels < regions(ireg)%currLevel) THEN
      WRITE(msg,1000) solver_name,ireg,global%startLevel
      CALL errorstop( global,err_grid_level,__line__,msg )
    ENDIF
    DO ilev=2,regions(ireg)%nGridLevels
      ipc = regions(ireg)%levels(ilev-1)%grid%ipc
      jpc = regions(ireg)%levels(ilev-1)%grid%jpc
      kpc = regions(ireg)%levels(ilev-1)%grid%kpc
      regions(ireg)%levels(ilev)%grid%ipc = ipc/2
      regions(ireg)%levels(ilev)%grid%jpc = jpc/2
      regions(ireg)%levels(ilev)%grid%kpc = kpc/2
    ENDDO
  ENDDO

! continue collecting remaining required user input

  CALL rflo_derivedinputvalues( regions )
#ifdef TURB
  CALL turb_readinputfile( regions )
  CALL turb_derivedinputvalues( regions )
#endif

#ifdef STATS
  statsactive = (global%postStatsFlag .AND. &
                (global%flowType == flow_unsteady) .AND. &
                (global%doStat == active))
#endif

! check for TECPLOT library ---------------------------------------------------

#ifdef NO_TECPLOT
  IF (global%postOutFmt == plot_fmt_tecplot) THEN
    WRITE(stdout,'(/,A,/)') solver_name// &
                            ' Sorry, not linked to TECPLOT library.'
#ifdef MPI
    CALL mpi_finalize( global%mpierr )
#endif
    stop
  ENDIF
#endif

! loop over regions -----------------------------------------------------------

  IF (global%postPlotType == plot_grid_only) THEN
    WRITE(stdout,'(A)') solver_name// &
                        ' Reading grid and writing plot file ...'
  ELSE
    WRITE(stdout,'(A)') solver_name// &
                        ' Reading grid+solution and writing plot file ...'
  ENDIF

  DO ireg=1,global%nRegions

! - allocate memory for the grid (all grid levels)

    DO ilev=1,regions(ireg)%nGridLevels
      CALL rflo_getdimensdummynodes( regions(ireg),ilev,idnbeg,idnend, &
                                     jdnbeg,jdnend,kdnbeg,kdnend )
      CALL rflo_getnodeoffset( regions(ireg),ilev,inoff,ijnoff )
      ibn  =  indijk(idnbeg,jdnbeg,kdnbeg,inoff,ijnoff)
      ien  =  indijk(idnend,jdnend,kdnend,inoff,ijnoff)
      grid => regions(ireg)%levels(ilev)%grid
      ALLOCATE( grid%xyz(3,ibn:ien),stat=errorflag )
      global%error = errorflag
      IF (global%error /= 0) CALL errorstop( global,err_allocate,__line__ )
    ENDDO

! - allocate memory for the rest (current grid level)

    ilev =  regions(ireg)%currLevel
    grid => regions(ireg)%levels(ilev)%grid
    mixt => regions(ireg)%levels(ilev)%mixt

    CALL rflo_getdimensdummy( regions(ireg),ilev,idcbeg,idcend, &
                              jdcbeg,jdcend,kdcbeg,kdcend )
    CALL rflo_getcelloffset( regions(ireg),ilev,icoff,ijcoff )
    ibc = indijk(idcbeg,jdcbeg,kdcbeg,icoff,ijcoff)
    iec = indijk(idcend,jdcend,kdcend,icoff,ijcoff)

    CALL rflo_getdimensphysnodes( regions(ireg),ilev,ipnbeg,ipnend, &
                                  jpnbeg,jpnend,kpnbeg,kpnend )
    CALL rflo_getnodeoffset( regions(ireg),ilev,inoff,ijnoff )
    ibn = indijk(ipnbeg,jpnbeg,kpnbeg,inoff,ijnoff)
    ien = indijk(ipnend,jpnend,kpnend,inoff,ijnoff)

    IF (regions(ireg)%mixtInput%moveGrid) THEN
      ALLOCATE( grid%siVel(ibn:ien),stat=errorflag )
      ALLOCATE( grid%sjVel(ibn:ien),stat=errorflag )
      ALLOCATE( grid%skVel(ibn:ien),stat=errorflag )
    ENDIF
    global%error = errorflag
    IF (global%error /= 0) CALL errorstop( global,err_allocate,__line__ )

    IF (global%postPlotType == plot_grid_flow) THEN
      ALLOCATE( mixt%cv(5,ibc:iec) ,stat=errorflag )
      ALLOCATE( mixt%dv(mixt%nDv,ibc:iec),stat=errorflag )
      IF (regions(ireg)%mixtInput%computeTv) THEN
        ALLOCATE( mixt%tv(mixt%nTv,ibc:iec),stat=errorflag )
      ENDIF
      IF (regions(ireg)%mixtInput%gasModel == gas_model_tcperf) THEN
        ALLOCATE( mixt%gv(mixt%nGv,0:1),stat=errorflag )
      ELSE
        ALLOCATE( mixt%gv(mixt%nGv,ibc:iec),stat=errorflag )
      ENDIF
#ifdef TURB
      IF (global%postTurbFlag .AND. &
          regions(ireg)%mixtInput%turbModel /= turb_model_none) THEN
        turb => regions(ireg)%levels(ilev)%turb
        IF (regions(ireg)%turbInput%nOutField > 1) THEN
          ALLOCATE( turb%vort(xcoord:zcoord,ibc:iec),stat=errorflag )
        ENDIF
        IF (regions(ireg)%turbInput%modelClass == model_rans) THEN
          ALLOCATE( turb%cv(regions(ireg)%turbInput%nCv,ibc:iec),stat=errorflag )
          ALLOCATE( turb%lens(ibc:iec),stat=errorflag )
        ENDIF
      ENDIF
#endif
#ifdef STATS
      IF (statsactive) THEN
        IF (global%mixtNStat > 0) THEN
          IF (global%mixtNStat < nstats_tec_mixt) &
            CALL errorstop( global,err_stats_tecplot,__line__, &
                           'mixtNStat < NSTATS_TEC_MIXT' )
          ALLOCATE( mixt%tav(global%mixtNStat,ibc:iec),stat=errorflag )
        ENDIF
#ifdef TURB
        IF (global%turbNStat > 0) THEN
          IF (global%turbNStat < nstats_tec_turb) &
            CALL errorstop( global,err_stats_tecplot,__line__, &
                           'turbNStat < NSTATS_TEC_TURB' )
          IF (global%mixtNStat <=0) &
            CALL errorstop( global,err_stats_tecplot,__line__, &
                           'Tecplot expect mixtNStat>0 if turbNStat>0' )
          ALLOCATE( turb%tav(global%turbNStat,ibc:iec),stat=errorflag )
        ENDIF
#endif
      ENDIF
#endif
      global%error = errorflag
      IF (global%error /= 0) CALL errorstop( global,err_allocate,__line__ )
    ENDIF

! - read grid

    CALL rflo_readgridregion( ireg,regions )
    CALL rflo_generatecoarsegrids( regions(ireg) )
    CALL rflo_copygeometrydummy( regions(ireg) )

! - read solution, calc. mixture properties

    IF (global%postPlotType == plot_grid_flow) THEN
      CALL rflo_readsolutionregion( ireg,regions )
      CALL mixtureproperties( regions(ireg),ibc,iec,.true. )
#ifdef TURB
      IF (global%postTurbFlag .AND. &
          regions(ireg)%mixtInput%turbModel /= turb_model_none) THEN
        IF (regions(ireg)%turbInput%modelClass == model_les) THEN
          CALL turb_rflo_readsolutionregion( ireg,regions )
        ELSEIF ((regions(ireg)%mixtInput%turbModel == turb_model_sa) .OR. &
                (regions(ireg)%mixtInput%turbModel == turb_model_dessa)) THEN
          CALL turb_rflo_readsolutionregion( ireg,regions )
          CALL turb_ranssageteddyvis( regions(ireg) )
        ELSE
        ENDIF
      ENDIF
#endif
#ifdef STATS
      IF (statsactive) THEN
        IF (global%mixtNStat > 0 .OR. global%turbNStat > 0) &
          CALL rflo_readstatregion( ireg,regions )
      ENDIF
#endif
    ENDIF

! - print on screen actual input selected

    IF (global%verbLevel >= verbose_low) CALL printpostinput( regions(ireg) )
    IF (global%verbLevel == verbose_low) WRITE(stdout,'(A,I5.5)') &
                                         solver_name//'   - region ',ireg

! - write data

    IF (global%postOutFmt == plot_fmt_generic) THEN

! --- write data to generic file

      CALL writegeneric( ireg,regions(ireg) )

    ELSE IF (global%postOutFmt == plot_fmt_tecplot) THEN

! --- write data to TECPLOT file (binary)

#ifndef NO_TECPLOT
      CALL writetecplotbinary( ireg,regions(ireg) )
#endif

    ELSE IF (global%postOutFmt == plot_fmt_tecascii) THEN

! --- write data to TECPLOT file (ASCII)

      CALL writetecplotascii( ireg,regions(ireg) )

    ENDIF

! - deallocate memory

    DO ilev=1,regions(ireg)%nGridLevels
      grid => regions(ireg)%levels(ilev)%grid
      DEALLOCATE( grid%xyz,stat=errorflag )
      global%error = errorflag
      IF (global%error /= 0) CALL errorstop( global,err_deallocate,__line__ )
    ENDDO

    ilev = regions(ireg)%currLevel
    IF (regions(ireg)%mixtInput%moveGrid) THEN
      grid => regions(ireg)%levels(ilev)%grid
      DEALLOCATE( grid%siVel,stat=errorflag )
      DEALLOCATE( grid%sjVel,stat=errorflag )
      DEALLOCATE( grid%skVel,stat=errorflag )
    ENDIF
    IF (global%postPlotType == plot_grid_flow) THEN
      DEALLOCATE( mixt%cv ,stat=errorflag )
      DEALLOCATE( mixt%dv ,stat=errorflag )
      DEALLOCATE( mixt%tv ,stat=errorflag )
      DEALLOCATE( mixt%gv ,stat=errorflag )
    ENDIF
    global%error = errorflag
    IF (global%error /= 0) CALL errorstop( global,err_deallocate,__line__ )

#ifdef TURB
    IF (global%postTurbFlag .AND. &
        regions(ireg)%mixtInput%turbModel /= turb_model_none) THEN

      IF (ASSOCIATED(turb%vort)) DEALLOCATE( turb%vort,stat=errorflag ) !general
      IF (ASSOCIATED(turb%cv))   DEALLOCATE( turb%cv  ,stat=errorflag ) !RANS
      IF (ASSOCIATED(turb%lens)) DEALLOCATE( turb%lens,stat=errorflag ) !RANS
    ENDIF
#endif

#ifdef STATS
    IF (statsactive) THEN
      IF (ASSOCIATED( mixt%tav )) DEALLOCATE( mixt%tav,stat=errorflag )
#ifdef TURB
      IF (ASSOCIATED( turb%tav )) DEALLOCATE( turb%tav,stat=errorflag )
#endif
    ENDIF
#endif

  ENDDO   ! iReg

! finalize --------------------------------------------------------------------

  CALL deregisterfunction( global )

  WRITE(stdout,'(/,A)') solver_name//' Finished.'

#ifdef MPI
  CALL mpi_finalize( global%mpierr )
#endif

1000 FORMAT(a,' Region ',i5,', grid level= ',i2,'.')

END PROGRAM rocflo_post

!******************************************************************************
!
! RCS Revision history:
!
! $Log: POST_Main.F90,v $
! Revision 1.5  2008/12/06 08:44:49  mtcampbe
! Updated license.
!
! Revision 1.4  2008/11/19 22:17:59  mtcampbe
! Added Illinois Open Source License/Copyright
!
! Revision 1.3  2005/10/31 21:09:38  haselbac
! Changed specModel and SPEC_MODEL_NONE
!
! Revision 1.2  2004/12/03 03:20:04  wasistho
! rflo_modinterfacespost to post_modinterfaces
!
! Revision 1.1  2004/12/03 02:03:16  wasistho
! added prefix
!
! Revision 1.1  2004/12/03 00:32:01  wasistho
! lower to upper case
!
! Revision 1.39  2004/11/09 10:49:30  wasistho
! added statistics to rflopost
!
! Revision 1.38  2004/08/27 04:00:41  wasistho
! fixed dimensions of relative vels when grid moves
!
! Revision 1.37  2004/08/26 01:15:43  wasistho
! more complete screen-display of required input parameters
!
! Revision 1.36  2004/08/26 00:44:30  wasistho
! bug fixed interconnection turbFlag and turbModel
!
! Revision 1.35  2004/08/10 17:40:04  wasistho
! do not compile writeTecplotBinary if there is no tecplot library
!
! Revision 1.34  2004/07/28 01:50:17  wasistho
! added print input
!
! Revision 1.33  2004/07/24 03:50:15  wasistho
! use postSection instead of command line input
!
! Revision 1.32  2004/03/11 03:36:07  wasistho
! changed rocturb nomenclature
!
! Revision 1.31  2004/03/05 21:16:17  wasistho
! fixed usage to include turbulence
!
! Revision 1.30  2004/03/03 23:55:40  jferry
! Allowed particles to be run with Euler case
!
! Revision 1.29  2004/02/11 03:25:33  wasistho
! added feature: variable number of turbulence output fields
!
! Revision 1.28  2004/02/07 01:18:37  wasistho
! added turbulence related results in rocflo post processing
!
! Revision 1.27  2003/09/19 22:38:11  jblazek
! Added turbulence input.
!
! Revision 1.26  2003/05/15 02:57:07  jblazek
! Inlined index function.
!
! Revision 1.25  2003/03/20 22:23:47  haselbac
! Renamed ModInterfaces
!
! Revision 1.24  2003/03/20 19:41:26  haselbac
! Corrected mistake in phased check-in
!
! Revision 1.23  2003/03/20 19:34:37  haselbac
! Modified RegFun call to avoid probs with long 'POST_Main.F90' names
!
! Revision 1.22  2002/10/19 00:40:31  jblazek
! Added utility (rflosurf) to write out surface grids for GenX.
!
! Revision 1.21  2002/10/12 03:20:51  jblazek
! Replaced [io]stat=global%error with local errorFlag for Rocflo.
!
! Revision 1.20  2002/09/20 22:22:37  jblazek
! Finalized integration into GenX.
!
! Revision 1.19  2002/09/05 17:40:22  jblazek
! Variable global moved into regions().
!
! Revision 1.18  2002/08/30 01:47:58  jblazek
! Added support for moving grids.
!
! Revision 1.17  2002/08/16 21:33:48  jblazek
! Changed interface to MixtureProperties.
!
! Revision 1.16  2002/08/15 19:48:05  jblazek
! Implemented grid deformation capability.
!
! Revision 1.15  2002/08/07 20:51:26  jblazek
! Enhanced for moving grids.
!
! Revision 1.14  2002/07/20 00:42:05  jblazek
! Added ASCII Tecplot format.
!
! Revision 1.13  2002/07/16 21:34:37  jblazek
! Prefixed screen output with SOLVER_NAME.
!
! Revision 1.12  2002/07/12 21:50:07  jblazek
! Added tool to split single grid into multiple regions.
!
! Revision 1.11  2002/06/14 17:16:41  jblazek
! Added version string.
!
! Revision 1.10  2002/06/07 16:40:37  jblazek
! Grid & solution for all regions in one file.
!
! Revision 1.9  2002/04/11 21:10:27  jblazek
! Set correct time when writing grid only for Tecplot.
!
! Revision 1.8  2002/03/18 21:31:54  jblazek
! Made codes compatible with MPI.
!
! Revision 1.7  2002/02/22 20:30:39  jblazek
! Changed generic format. Enhanced Tecplot title.
!
! Revision 1.6  2002/02/22 00:05:44  jblazek
! Changed TECPLOT link option.
!
! Revision 1.4  2002/02/16 07:16:00  jblazek
! Added implicit residual smoothing.
!
! Revision 1.3  2002/02/09 01:47:01  jblazek
! Added multi-probe option, residual smoothing, physical time step.
!
! Revision 1.2  2002/01/12 00:02:49  jblazek
! Added postprocessor.
!
! Revision 1.1.1.1  2001/12/03 21:44:05  jblazek
! Import of RocfluidMP
!
!******************************************************************************