TURB_rFLO_ReadSolutionRegion.F90

Go to the documentation of this file.

! *********************************************************************
! * Rocstar Simulation Suite                                          *
! * Copyright@2015, Illinois Rocstar LLC. All rights reserved.        *
! *                                                                   *
! * Illinois Rocstar LLC                                              *
! * Champaign, IL                                                     *
! * www.illinoisrocstar.com                                           *
! * sales@illinoisrocstar.com                                         *
! *                                                                   *
! * License: See LICENSE file in top level of distribution package or *
! * http://opensource.org/licenses/NCSA                               *
! *********************************************************************
! *********************************************************************
! * THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND,   *
! * EXPRESS OR IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES   *
! * OF MERCHANTABILITY, FITNESS FOR A PARTICULAR PURPOSE AND          *
! * NONINFRINGEMENT.  IN NO EVENT SHALL THE CONTRIBUTORS OR           *
! * COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER       *
! * LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE,   *
! * Arising FROM, OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE    *
! * USE OR OTHER DEALINGS WITH THE SOFTWARE.                          *
! *********************************************************************
!******************************************************************************
!
! Purpose: read in turbulence solution.
!
! Description: the following solution formats are supported:
!              - RocfloMP ASCII
!              - RocfloMP binary.
!
! Input: regions = dimensions of all regions.
!        iReg    = region number.
!
! Output: 
!        globalClass LES  : region%levels%mixt%tv = turbulent viscosity
!        globalClass RANS : no yet defined
!        global%currentTime    = physical time
!        global%resInit        = initial residual
!
! Notes: solution is read in only for the current grid level;
!        solution is also read in for all dummy cells. There is no transfer
!        of data to other processors.
!
!******************************************************************************
!
! $Id: TURB_rFLO_ReadSolutionRegion.F90,v 1.4 2008/12/06 08:44:45 mtcampbe Exp $
!
! Copyright: (c) 2001 by the University of Illinois
!
!******************************************************************************

SUBROUTINE turb_rflo_readsolutionregion( iReg,regions ) ! PUBLIC

  USE moddatatypes
  USE moddatastruct, ONLY : t_region
  USE modglobal, ONLY     : t_global
  USE modinterfaces, ONLY : rflo_readdatafileint, rflo_readdatafilereal, &
                            rflo_getdimensdummy, rflo_getcelloffset
  USE moderror
  USE modparameters
  USE turb_modparameters
  IMPLICIT NONE

#include "Indexing.h"

! ... parameters
  INTEGER :: ireg
  TYPE(t_region), POINTER :: regions(:)

! ... loop variables
  INTEGER :: i, j, k, n

! ... local variables
  CHARACTER(2*CHRLEN+17) :: fname
  CHARACTER(CHRLEN)      :: msg, timestring

  INTEGER :: ilev, iregfile, ipc, jpc, kpc, ndumcells, nfield, ioff, ijoff, ijk
  INTEGER :: idcbeg, jdcbeg, kdcbeg, idcend, jdcend, kdcend, ijkbeg, ijkend
  INTEGER :: ndimc, nrvar, noutsol, globalclass, errorflag
  INTEGER, ALLOCATABLE :: ivar(:,:)

  REAL(RFREAL), POINTER     :: tv(:,:), tcv(:,:), vort(:,:), lens(:)
  REAL(RFREAL), ALLOCATABLE :: rvar(:,:), solfile(:,:)

  TYPE(t_global), POINTER :: global

!******************************************************************************

  global => regions(ireg)%global

  CALL registerfunction( global,'TURB_RFLO_ReadSolutionRegion',&
  'TURB_rFLO_ReadSolutionRegion.F90' )

! allocate fixed-size temporary data arrays -----------------------------------

  nrvar = 4

  ALLOCATE( ivar(6,1),stat=errorflag )
  ALLOCATE( rvar(nrvar,1),stat=errorflag )
  global%error = errorflag
  IF (global%error /= 0) CALL errorstop( global,err_allocate,__line__ )

! copy time to string ---------------------------------------------------------

  IF (global%flowType == flow_unsteady) THEN
    WRITE(timestring,'(1PE11.5)') global%timeStamp
  ELSE
    WRITE(timestring,'(1PE11.5)') 0._rfreal
  ENDIF

! open solution file (only if iReg=1) -----------------------------------------

  IF (ireg == 1) THEN

! - unsteady flow

    IF (global%flowType == flow_unsteady) THEN
      IF (global%solutFormat == format_ascii) THEN
        WRITE(fname,'(A,1PE11.5)') trim(global%inDir)//trim(global%casename)//'.turba_', &
                                   global%timeStamp
        OPEN(if_turb_solut,file=fname,form='formatted',status='old',iostat=errorflag)
      ELSE IF (global%solutFormat == format_binary) THEN
        WRITE(fname,'(A,1PE11.5)') trim(global%inDir)//trim(global%casename)//'.turbb_', &
                                   global%timeStamp
        OPEN(if_turb_solut,file=fname,form='unformatted',status='old',iostat=errorflag)
      ELSE
        CALL errorstop( global,err_unknown_format,__line__ )
      ENDIF

! - steady flow

    ELSE
      IF (global%solutFormat == format_ascii) THEN
        WRITE(fname,'(A,I6.6)') trim(global%inDir)//trim(global%casename)//'.turba_', &
                                global%currentIter
        OPEN(if_turb_solut,file=fname,form='formatted',status='old',iostat=errorflag)
      ELSE IF (global%solutFormat == format_binary) THEN
        WRITE(fname,'(A,I6.6)') trim(global%inDir)//trim(global%casename)//'.turbb_', &
                                global%currentIter
        OPEN(if_turb_solut,file=fname,form='unformatted',status='old',iostat=errorflag)
      ELSE
        CALL errorstop( global,err_unknown_format,__line__ )
      ENDIF
    ENDIF

    global%error = errorflag
    IF (global%error /= 0) &
      CALL errorstop( global,err_file_open,__line__,'File: '//trim(fname) )

! - read time and initial residual

    CALL rflo_readdatafilereal( global,if_turb_solut,global%solutFormat,nrvar,1,rvar )

    IF (global%flowType==flow_unsteady .AND. global%currentTime>0._rfreal) THEN
      IF (global%currentTime /= rvar(1,1)) THEN
        WRITE(msg,1000) rvar(1,1),global%currentTime
        CALL errorstop( global,err_time_solution,__line__,msg//' File: '//trim(fname) )
      ENDIF
    ELSE
      global%currentTime = rvar(1,1)
    ENDIF
    global%resInit = rvar(2,1)
    global%esg1Sum = rvar(3,1)
    global%esg4Sum = rvar(4,1)

  ENDIF   ! 1st region

! read solution data ----------------------------------------------------------

! first define no.of output solution by subsquent selection (order matters)

  IF (regions(ireg)%procid == global%myProcid) THEN
    IF (regions(ireg)%turbInput%modelClass == model_les) THEN
      globalclass = model_les
    ENDIF
  ENDIF

  IF (regions(ireg)%procid == global%myProcid) THEN
    IF ((regions(ireg)%mixtInput%turbModel == turb_model_sa) .OR. &
        (regions(ireg)%mixtInput%turbModel == turb_model_dessa) .OR. &
        (regions(ireg)%mixtInput%turbModel == turb_model_hdessa)) THEN
      globalclass = model_rans
    ENDIF
  ENDIF

! get dimensions and pointers

  ilev = regions(ireg)%currLevel
  CALL rflo_getdimensdummy( regions(ireg),ilev,idcbeg,idcend, &
                            jdcbeg,jdcend,kdcbeg,kdcend )
  CALL rflo_getcelloffset( regions(ireg),ilev,ioff,ijoff )
  ijkbeg = indijk(idcbeg,jdcbeg,kdcbeg,ioff,ijoff)
  ijkend = indijk(idcend,jdcend,kdcend,ioff,ijoff)
  ndimc  = ijkend - ijkbeg + 1

! read region number and dimensions

  CALL rflo_readdatafileint( global,if_turb_solut,global%solutFormat,6,1,ivar )
  iregfile  = ivar(1,1)
  ipc       = ivar(2,1)
  jpc       = ivar(3,1)
  kpc       = ivar(4,1)
  ndumcells = ivar(5,1)
  nfield    = ivar(6,1)
      
  IF (iregfile /= ireg) &
    CALL errorstop( global,err_region_number,__line__,'File: '//trim(fname) )
  IF ((ipc /= regions(ireg)%levels(ilev)%grid%ipc) .OR. &
      (jpc /= regions(ireg)%levels(ilev)%grid%jpc) .OR. &
      (kpc /= regions(ireg)%levels(ilev)%grid%kpc)) THEN
    WRITE(msg,1005) ireg,ipc,jpc,kpc
    CALL errorstop( global,err_grid_dimensions,__line__,msg )
  ENDIF
  IF (ndumcells /= regions(ireg)%nDumCells) THEN
    WRITE(msg,1010) ireg,ndumcells,regions(ireg)%nDumCells
    CALL errorstop( global,err_grid_dumcells,__line__,msg )
  ENDIF

! read data

  noutsol = nfield
  ALLOCATE( solfile(noutsol,ndimc),stat=errorflag )
  global%error = errorflag
  IF (global%error /= 0) CALL errorstop( global,err_allocate,__line__ )

  CALL rflo_readdatafilereal( global,if_turb_solut,global%solutFormat, &
                              noutsol,ndimc,solfile )

! copy solution into data structure

  IF (regions(ireg)%turbInput%modelClass == model_les) THEN
    tv => regions(ireg)%levels(ilev)%mixt%tv
    n  = 0
    DO k=kdcbeg,kdcend
      DO j=jdcbeg,jdcend
        DO i=idcbeg,idcend
          n   = n + 1
          ijk = indijk(i,j,k,ioff,ijoff)
          tv(tv_mixt_muet,ijk) = solfile(1,n)
        ENDDO
      ENDDO
    ENDDO
    IF (noutsol == 2) THEN
      vort => regions(ireg)%levels(ilev)%turb%vort
      n  = 0
      DO k=kdcbeg,kdcend
        DO j=jdcbeg,jdcend
          DO i=idcbeg,idcend
            n   = n + 1
            ijk = indijk(i,j,k,ioff,ijoff)
            vort(xcoord,ijk) = solfile(2,n)
          ENDDO
        ENDDO
      ENDDO
    ENDIF  ! nOutSol
  ENDIF
  IF ((regions(ireg)%mixtInput%turbModel == turb_model_sa) .OR. &
      (regions(ireg)%mixtInput%turbModel == turb_model_dessa) .OR. &
      (regions(ireg)%mixtInput%turbModel == turb_model_hdessa)) THEN
    tcv => regions(ireg)%levels(ilev)%turb%cv
    n  = 0
    DO k=kdcbeg,kdcend
      DO j=jdcbeg,jdcend
        DO i=idcbeg,idcend
          n   = n + 1
          ijk = indijk(i,j,k,ioff,ijoff)
          tcv(cv_sa_nutil,ijk) = solfile(1,n)
        ENDDO
      ENDDO
    ENDDO
    IF (noutsol == 2) THEN
      vort => regions(ireg)%levels(ilev)%turb%vort
      n  = 0
      DO k=kdcbeg,kdcend
        DO j=jdcbeg,jdcend
          DO i=idcbeg,idcend
            n   = n + 1
            ijk = indijk(i,j,k,ioff,ijoff)
            vort(xcoord,ijk) = solfile(2,n)
          ENDDO
        ENDDO
      ENDDO
    ENDIF  ! nOutSol
    IF (noutsol == 3) THEN
      vort => regions(ireg)%levels(ilev)%turb%vort
      lens => regions(ireg)%levels(ilev)%turb%lens
      n  = 0
      DO k=kdcbeg,kdcend
        DO j=jdcbeg,jdcend
          DO i=idcbeg,idcend
            n   = n + 1
            ijk = indijk(i,j,k,ioff,ijoff)
            vort(xcoord,ijk) = solfile(2,n)
            lens(ijk)        = solfile(3,n)
          ENDDO
        ENDDO
      ENDDO
    ENDIF  ! nOutSol
  ENDIF    ! turbModel/modelClass

  DEALLOCATE( ivar   ,stat=errorflag )
  DEALLOCATE( rvar   ,stat=errorflag )
  DEALLOCATE( solfile,stat=errorflag )
  global%error = errorflag
  IF (global%error /= 0) CALL errorstop( global,err_deallocate,__line__ )

! finalize --------------------------------------------------------------------

  IF (ireg == global%nRegions) THEN
    CLOSE(if_turb_solut,iostat=errorflag)
    global%error = errorflag
    IF (global%error /= 0) &
      CALL errorstop( global,err_file_close,__line__,'File: '//trim(fname) )
  ENDIF

  CALL deregisterfunction( global )

1000 FORMAT('Time in file is= ',1pe12.5,' but it should be= ',e12.5,'.')
1005 FORMAT('Region ',i5,', ipc= ',i6,', jpc= ',i6,', kpc= ',i6,'.')
1010 FORMAT('Region ',i5,', # dummy cells=',i2,' but should be= ',i1)

END SUBROUTINE turb_rflo_readsolutionregion

!******************************************************************************
!
! RCS Revision history:
!
! $Log: TURB_rFLO_ReadSolutionRegion.F90,v $
! Revision 1.4  2008/12/06 08:44:45  mtcampbe
! Updated license.
!
! Revision 1.3  2008/11/19 22:17:56  mtcampbe
! Added Illinois Open Source License/Copyright
!
! Revision 1.2  2005/03/09 06:37:40  wasistho
! incorporated HDESSA
!
! Revision 1.1  2004/03/11 03:26:34  wasistho
! changed rocturb nomenclature
!
! Revision 1.1  2004/03/08 23:35:46  wasistho
! changed turb nomenclature
!
! Revision 1.3  2004/02/26 21:28:14  wasistho
! added esg1Sum and esg4Sum to Real heading for restart
!
! Revision 1.2  2004/02/11 03:25:07  wasistho
! added feature: variable number of turbulence output fields
!
! Revision 1.1  2004/02/07 01:21:19  wasistho
! added TURB_ReadSolutionRegion to be used in utilities/rocflo/post
!
!
!******************************************************************************