TURB_LesLij.F90

Go to the documentation of this file.

! *********************************************************************
! * Rocstar Simulation Suite                                          *
! * Copyright@2015, Illinois Rocstar LLC. All rights reserved.        *
! *                                                                   *
! * Illinois Rocstar LLC                                              *
! * Champaign, IL                                                     *
! * www.illinoisrocstar.com                                           *
! * sales@illinoisrocstar.com                                         *
! *                                                                   *
! * License: See LICENSE file in top level of distribution package or *
! * http://opensource.org/licenses/NCSA                               *
! *********************************************************************
! *********************************************************************
! * THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND,   *
! * EXPRESS OR IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES   *
! * OF MERCHANTABILITY, FITNESS FOR A PARTICULAR PURPOSE AND          *
! * NONINFRINGEMENT.  IN NO EVENT SHALL THE CONTRIBUTORS OR           *
! * COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER       *
! * LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE,   *
! * Arising FROM, OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE    *
! * USE OR OTHER DEALINGS WITH THE SOFTWARE.                          *
! *********************************************************************
!******************************************************************************
!
! Purpose: Compute the scale similarity turbulent stress tensor, which
!          is the same as the Leonard stress term in the dynamic LES
!          models. SS-tauij uses bar-filter while Leonard stress uses
!          test-filter.
!
! Description: The turbulent stress tensor follows the SS model and can
!              be seen as Leonard tensor if the outer bar filter is replaced
!              by test filter. This tensor is defined by
!              l_{ij}=bar(bar[rho*ui]bar[rho*uj]/bar[rho])
!                    -bar(bar[rho*ui])bar(bar[rho*uj])/bar(bar[rho])
!              where bar denotes the bar-filter with filter-width defined by
!              nDel(DIRI:DIRK). On entry we have the solution components 
!              at cell faces and perform the filtering from face to face. 
!              We return the resulting tensor at all cell faces including  
!              dummies. Also 1/bar(bar[rho]) is available stored ffVar(1,:).
!
! Input: region = data of current region
!        ijk    = ijk-face is being treated
!        nDel   = three components filter width paramater
!
! Output: lij = resulting stress tensor of scale similarity or Leonard term
!
! Notes: none.
!
!******************************************************************************
!
! $Id: TURB_LesLij.F90,v 1.9 2008/12/06 08:44:41 mtcampbe Exp $
!
! Copyright: (c) 2001 by the University of Illinois
!
!******************************************************************************

SUBROUTINE turb_leslij( region,ijk,nDel,lij )

  USE moddatatypes
  USE moddatastruct, ONLY : t_region
  USE modglobal, ONLY     : t_global
#ifdef RFLU
  USE rflu_modinterpolation, ONLY : rflu_interpcells2faces
#endif
#ifdef RFLO
  USE modinterfaces, ONLY : rflo_getdimensdummynodes, &
                            rflo_getnodeoffset
  USE turb_modinterfaces, ONLY : turb_flolesunifiltff, turb_flolesgenfiltff

#include "Indexing.h"
#endif
  USE moderror
  USE turb_modparameters
  IMPLICIT NONE

! ... parameters
#ifdef RFLO
  TYPE(t_region)          :: region
#endif
#ifdef RFLU
  TYPE(t_region), POINTER :: region
#endif
  INTEGER                 :: ijk, ndel(diri:dirk)
  REAL(RFREAL), POINTER   :: lij(:,:)

! ... loop variables
  INTEGER :: ijkn

! ... local variables
  CHARACTER(CHRLEN)       :: rcsidentstring
  TYPE(t_global), POINTER :: global

  INTEGER :: ibn,ien,idbeg,idend
  REAL(RFREAL), POINTER :: fvar(:,:),ffvar(:,:)
  REAL(RFREAL), POINTER :: tens(:,:),tensbar(:,:)
#ifdef RFLO
  INTEGER :: idnbeg,idnend,jdnbeg,jdnend,kdnbeg,kdnend
  INTEGER :: ilev,inoff,ijnoff
#endif
#ifdef RFLU
  REAL(RFREAL), POINTER :: cv(:,:)
#endif

!******************************************************************************

  rcsidentstring = '$RCSfile: TURB_LesLij.F90,v $'

  global => region%global
  CALL registerfunction( global,'TURB_LesLij',&
  'TURB_LesLij.F90' )

! get indices and pointers --------------------------------------------------

#ifdef RFLO
  ilev   = region%currLevel
  CALL rflo_getdimensdummynodes( region,ilev,idnbeg,idnend, &
                                 jdnbeg,jdnend,kdnbeg,kdnend )
  CALL rflo_getnodeoffset( region,ilev,inoff,ijnoff )

  fvar  => region%levels(ilev)%turb%fVar
  ffvar => region%levels(ilev)%turb%ffVar
  ibn   =  indijk(idnbeg,jdnbeg,kdnbeg,inoff,ijnoff)
  ien   =  indijk(idnend,jdnend,kdnend,inoff,ijnoff)
#endif
#ifdef RFLU
  cv    => region%mixt%cv
  fvar  => region%turb%fVar
  ffvar => region%turb%ffVar
  ibn   =  1
  ien   =  region%grid%nFaces
#endif

! allocate temporary arrays

  ALLOCATE( tens(e11:e33,ibn:ien),tensbar(e11:e33,ibn:ien) )

! ff-filtering bRhoF and bRhoUiF (i=1,3) stored in fVar to get 
! bar[bRhoF] and bar[bRhoUiF] stored in fbVar

  idbeg = cv_turb_dens
  idend = cv_turb_zmom
#ifdef RFLO
  IF (region%turbInput%filterType == filtype_uniform) then
    CALL turb_flolesunifiltff( region,ijk,ndel,idbeg,idend,fvar,ffvar )
  ELSE
    CALL turb_flolesgenfiltff( region,ijk,ndel,idbeg,idend,fvar,ffvar )
  ENDIF
#endif
#ifdef RFLU
  CALL rflu_interpcells2faces( region,cv(idbeg:idend,:),ffvar )
#endif

! for efficiency we store 1/bRhoF in bRhoF and 1/bbRhoF in bbRhoF;
! next, build components of scale-similarity (Bardina) turbulent stress 
! tensor lij-component: store bRhoUi*bRhoUj/bRho in tens

  DO ijkn = ibn,ien
    fvar(cv_turb_dens,ijkn)=1._rfreal/fvar(cv_turb_dens,ijkn)
    ffvar(cv_turb_dens,ijkn)=1._rfreal/ffvar(cv_turb_dens,ijkn)

    tens(e11,ijkn) = fvar(cv_turb_xmom,ijkn)*fvar(cv_turb_xmom,ijkn)* &
                     fvar(cv_turb_dens,ijkn)
    tens(e12,ijkn) = fvar(cv_turb_xmom,ijkn)*fvar(cv_turb_ymom,ijkn)* &
                     fvar(cv_turb_dens,ijkn)
    tens(e13,ijkn) = fvar(cv_turb_xmom,ijkn)*fvar(cv_turb_zmom,ijkn)* &
                     fvar(cv_turb_dens,ijkn)
    tens(e22,ijkn) = fvar(cv_turb_ymom,ijkn)*fvar(cv_turb_ymom,ijkn)* &
                     fvar(cv_turb_dens,ijkn)
    tens(e23,ijkn) = fvar(cv_turb_ymom,ijkn)*fvar(cv_turb_zmom,ijkn)* &
                     fvar(cv_turb_dens,ijkn)
    tens(e33,ijkn) = fvar(cv_turb_zmom,ijkn)*fvar(cv_turb_zmom,ijkn)* &
                     fvar(cv_turb_dens,ijkn)
  ENDDO

! ff-filter bRhoUi*bRhoUj/bRho stored in tens to get 
! bar[bRhoUi*bRhoUj/bRho] in tensBar

  idbeg = e11
  idend = e33
#ifdef RFLO
  IF (region%turbInput%filterType == filtype_uniform) then
    CALL turb_flolesunifiltff( region,ijk,ndel,idbeg,idend,tens,tensbar )
  ELSE
    CALL turb_flolesgenfiltff( region,ijk,ndel,idbeg,idend,tens,tensbar )
  ENDIF
#endif
#ifdef RFLU
!  CALL RFLU_InterpFaces2Faces( region,tens,tensBar )
  tensbar(idbeg:idend,:) = tens(idbeg:idend,:)
#endif

! combine and find lij=bar[bRhoUi*bRhoUj/bRho]-bbRhoUi*bbRhoUj/bbRho

  DO ijkn=ibn,ien
    lij(e11,ijkn)=tensbar(e11,ijkn)-ffvar(cv_turb_dens,ijkn)* &
                  ffvar(cv_turb_xmom,ijkn)*ffvar(cv_turb_xmom,ijkn)

    lij(e12,ijkn)=tensbar(e12,ijkn)-ffvar(cv_turb_dens,ijkn)* &
                  ffvar(cv_turb_xmom,ijkn)*ffvar(cv_turb_ymom,ijkn)

    lij(e13,ijkn)=tensbar(e13,ijkn)-ffvar(cv_turb_dens,ijkn)* &
                  ffvar(cv_turb_xmom,ijkn)*ffvar(cv_turb_zmom,ijkn)

    lij(e22,ijkn)=tensbar(e22,ijkn)-ffvar(cv_turb_dens,ijkn)* &
                  ffvar(cv_turb_ymom,ijkn)*ffvar(cv_turb_ymom,ijkn)

    lij(e23,ijkn)=tensbar(e23,ijkn)-ffvar(cv_turb_dens,ijkn)* &
                  ffvar(cv_turb_ymom,ijkn)*ffvar(cv_turb_zmom,ijkn)

    lij(e33,ijkn)=tensbar(e33,ijkn)-ffvar(cv_turb_dens,ijkn)* &
                  ffvar(cv_turb_zmom,ijkn)*ffvar(cv_turb_zmom,ijkn)
  ENDDO

! deallocate temporary arrays

  DEALLOCATE( tens,tensbar )

! finalize --------------------------------------------------------------------

  CALL deregisterfunction( global )

END SUBROUTINE turb_leslij

!******************************************************************************
!
! RCS Revision history:
!
! $Log: TURB_LesLij.F90,v $
! Revision 1.9  2008/12/06 08:44:41  mtcampbe
! Updated license.
!
! Revision 1.8  2008/11/19 22:17:54  mtcampbe
! Added Illinois Open Source License/Copyright
!
! Revision 1.7  2005/12/31 23:28:56  wasistho
! copy in lack of filter in rocflu temporarily
!
! Revision 1.6  2005/12/28 03:24:34  wasistho
! simply copy variables in waiting for Rocflu's FF-interpolation
!
! Revision 1.5  2004/08/07 01:06:57  wasistho
! bugfixed, defined pointer cv
!
! Revision 1.4  2004/05/28 02:01:00  wasistho
! update unstructured grid LES
!
! Revision 1.3  2004/03/19 02:50:31  wasistho
! prepared for RFLU
!
! Revision 1.2  2004/03/12 02:55:35  wasistho
! changed rocturb routine names
!
! Revision 1.1  2004/03/05 04:37:00  wasistho
! changed nomenclature
!
! Revision 1.2  2003/05/15 02:57:06  jblazek
! Inlined index function.
!
! Revision 1.1  2002/10/14 23:55:30  wasistho
! Install Rocturb
!
!
!******************************************************************************