TURB_LesContract.F90

Go to the documentation of this file.

! *********************************************************************
! * Rocstar Simulation Suite                                          *
! * Copyright@2015, Illinois Rocstar LLC. All rights reserved.        *
! *                                                                   *
! * Illinois Rocstar LLC                                              *
! * Champaign, IL                                                     *
! * www.illinoisrocstar.com                                           *
! * sales@illinoisrocstar.com                                         *
! *                                                                   *
! * License: See LICENSE file in top level of distribution package or *
! * http://opensource.org/licenses/NCSA                               *
! *********************************************************************
! *********************************************************************
! * THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND,   *
! * EXPRESS OR IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES   *
! * OF MERCHANTABILITY, FITNESS FOR A PARTICULAR PURPOSE AND          *
! * NONINFRINGEMENT.  IN NO EVENT SHALL THE CONTRIBUTORS OR           *
! * COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER       *
! * LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE,   *
! * Arising FROM, OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE    *
! * USE OR OTHER DEALINGS WITH THE SOFTWARE.                          *
! *********************************************************************
!******************************************************************************
!
! Purpose: contracting tensors M_{ij} and L_{ij}
!
! Description: We determine the dynamic coefficient by contracting tensors 
!              M_{ij} and (L_{ij}-H_{ij}) and evalutating 
!              C=<M_{ij}(L_{ij}-H_{ij})>/<M_{ij}M_{ij}> in which <.> denotes 
!              an averaging over the homogeneous directions. 
!              On entry lij contains L_{ij}-H_{ij} with H_{ij} appropriate 
!              for the present model. A 1D vector representing model coef is 
!              returned and it is assumed that all information is available 
!              at cell faces.
!
! Input: region  = data of current region
!        ijk     = ijk-face is being treated
!
! Output: coef = turb%coef = model coefficient
!
! Notes: none.
!
!******************************************************************************
!
! $Id: TURB_LesContract.F90,v 1.9 2008/12/06 08:44:41 mtcampbe Exp $
!
! Copyright: (c) 2001 by the University of Illinois
!
!******************************************************************************

SUBROUTINE turb_lescontract( region,ijk )

  USE moddatatypes
  USE moddatastruct, ONLY : t_region
  USE modglobal, ONLY     : t_global
#ifdef RFLU
  USE modbndpatch, ONLY   : t_patch
#endif
#ifdef RFLO
  USE modinterfaces, ONLY : rflo_getdimensdummynodes, rflo_getnodeoffset
  USE turb_modinterfaces, ONLY : turb_flolesaverageface

#include "Indexing.h"
#endif
  USE turb_modinterfaces, ONLY : turb_statfcollector
  USE moderror
  USE turb_modparameters
  IMPLICIT NONE

! ... parameters
#ifdef RFLO
  TYPE(t_region)          :: region
#endif
#ifdef RFLU
  TYPE(t_region), POINTER :: region
#endif
  INTEGER                 :: ijk

! ... loop variables
  INTEGER :: in, ipatch

! ... local variables
  CHARACTER(CHRLEN)       :: rcsidentstring
  TYPE(t_global), POINTER :: global
#ifdef RFLU
  TYPE(t_patch), POINTER  :: patch
#endif

  INTEGER :: ibn, ien, ndel(diri:dirk)
  REAL(RFREAL), POINTER :: coef(:,:),mij(:,:),lij(:,:), colvar(:,:)
  REAL(RFREAL), POINTER :: mijmij(:),mijlij(:),avgmmij(:),avgmlij(:)

#ifdef RFLO
  INTEGER :: idnbeg,idnend,jdnbeg,jdnend,kdnbeg,kdnend
  INTEGER :: ilev,inoff,ijnoff
#endif
#ifdef RFLU
  INTEGER :: npatches, nbfaces
  REAL(RFREAL), POINTER :: bcoef(:,:),bmij(:,:),blij(:,:),colbvar(:,:)
#endif

!******************************************************************************

  rcsidentstring = '$RCSfile: TURB_LesContract.F90,v $'

  global => region%global
  CALL registerfunction( global,'TURB_LesContract',&
  'TURB_LesContract.F90' )

! get indices and pointers --------------------------------------------------

  ndel(:) =  region%turbInput%filterWidth(:)

#ifdef RFLO
  ilev    =  region%currLevel

  CALL rflo_getdimensdummynodes( region,ilev,idnbeg,idnend, &
                                 jdnbeg,jdnend,kdnbeg,kdnend )
  CALL rflo_getnodeoffset( region,ilev,inoff,ijnoff )
  ibn = indijk(idnbeg,jdnbeg,kdnbeg,inoff,ijnoff)
  ien = indijk(idnend,jdnend,kdnend,inoff,ijnoff)

  coef    => region%levels(ilev)%turb%coef
  lij     => region%levels(ilev)%turb%lij
  mij     => region%levels(ilev)%turb%mij
#endif
#ifdef RFLU
  ibn = 1
  ien = region%grid%nFaces

  coef    => region%turb%coef
  lij     => region%turb%lij
  mij     => region%turb%mij
#endif

! allocate temporary arrays

  ALLOCATE( mijmij(ibn:ien) )
  ALLOCATE( mijlij(ibn:ien) )
  ALLOCATE( avgmmij(ibn:ien) )
  ALLOCATE( avgmlij(ibn:ien) )

! first contract the numerator and denominator

  DO in = ibn,ien

! - M_{ij}*M_{ij}:

    mijmij(in) = 2._rfreal*(mij(e11,in)*mij(e11,in) &
                           +mij(e22,in)*mij(e22,in) &
                           +mij(e11,in)*mij(e22,in) &
                           +mij(e12,in)*mij(e12,in) &
                           +mij(e13,in)*mij(e13,in) &
                           +mij(e23,in)*mij(e23,in))

! - M_{ij}*(L_{ij}-H_{ij}):

    mijlij(in) = mij(e11,in)*lij(e11,in)  &
                +mij(e22,in)*lij(e22,in)  &
                +mij(e33,in)*lij(e33,in)  &
          +2.0d0*mij(e12,in)*lij(e12,in)  &
          +2.0d0*mij(e13,in)*lij(e13,in)  &
          +2.0d0*mij(e23,in)*lij(e23,in)
  ENDDO

! dynamic coefficient is obtained by averaging numerator and denominator
! first, denominator

#ifdef RFLO
  CALL turb_flolesaverageface( region,ijk,mijmij,avgmmij )
#endif
#ifdef RFLU
  avgmmij = mijmij
#endif

! then, numerator:

#ifdef RFLO
  CALL turb_flolesaverageface( region,ijk,mijlij,avgmlij )
#endif
#ifdef RFLU
  avgmlij = mijlij
#endif

! we assign avgMLij/avgMMij to coef in which we also limit from below with 0; 
! moreover, if all the filterwidth is zero coef set to zero

  IF (ndel(diri)==0 .AND. ndel(dirj)==0 .AND. ndel(dirk)==0) THEN
    coef=0.0_rfreal
  ELSE
    DO in = ibn,ien
      IF (avgmlij(in) > 0.1_rfreal*avgmmij(in)) avgmlij(in) = 0._rfreal
      coef(1,in)= max(0._rfreal,avgmlij(in)/(avgmmij(in)+real_small))
    ENDDO
  ENDIF

!#ifdef STATS
! if desired, collect quantities of interest at cell centers for statistics

!  IF (region%turbInput%nSt > 0) THEN
!    ALLOCATE( colVar(2,ibn:ien) )
!    colVar(1,:) = avgMMij
!    colVar(2,:) = avgMLij
!#ifdef RFLO
!    CALL TURB_StatFCollector( region,ijk,1,2,colVar )
!    DEALLOCATE( colVar )
!#endif
!  ENDIF
!#endif

! deallocate retired arrays
  DEALLOCATE( mijmij,mijlij,avgmmij,avgmlij )

! RFLU boundary treatments =====================================================
#ifdef RFLU

  npatches = region%grid%nPatches
  nbfaces  = 0

  DO ipatch = 1,npatches
    patch   => region%patches(ipatch)
    nbfaces =  nbfaces + patch%nBTris + patch%nBQuads
  END DO ! iPatch
  ibn = 1
  ien = nbfaces

  bcoef   => region%turb%bCoef
  blij    => region%turb%bLij
  bmij    => region%turb%bMij

! allocate temporary arrays

  ALLOCATE( mijmij(ibn:ien) )
  ALLOCATE( mijlij(ibn:ien) )
  ALLOCATE( avgmmij(ibn:ien) )
  ALLOCATE( avgmlij(ibn:ien) )

! first contract the numerator and denominator

  DO in = ibn,ien

! - M_{ij}*M_{ij}:

    mijmij(in) = 2._rfreal*(bmij(e11,in)*bmij(e11,in) &
                           +bmij(e22,in)*bmij(e22,in) &
                           +bmij(e11,in)*bmij(e22,in) &
                           +bmij(e12,in)*bmij(e12,in) &
                           +bmij(e13,in)*bmij(e13,in) &
                           +bmij(e23,in)*bmij(e23,in))

! - M_{ij}*(L_{ij}-H_{ij}):

    mijlij(in) = bmij(e11,in)*blij(e11,in)  &
                +bmij(e22,in)*blij(e22,in)  &
                +bmij(e33,in)*blij(e33,in)  &
          +2.0d0*bmij(e12,in)*blij(e12,in)  &
          +2.0d0*bmij(e13,in)*blij(e13,in)  &
          +2.0d0*bmij(e23,in)*blij(e23,in)
  ENDDO

! dynamic coefficient is obtained by averaging numerator and denominator
! first, denominator

  avgmmij = mijmij

! then, numerator:

  avgmlij = mijlij

! we assign avgMLij/avgMMij to coef in which we also limit from below with 0; 
! moreover, if all the filterwidth is zero coef set to zero

  IF (ndel(diri)==0 .AND. ndel(dirj)==0 .AND. ndel(dirk)==0) THEN
    bcoef=0.0_rfreal
  ELSE
    DO in = ibn,ien
      IF (avgmlij(in) > 0.1_rfreal*avgmmij(in)) avgmlij(in) = 0._rfreal
      bcoef(1,in)= max(0._rfreal,avgmlij(in)/(avgmmij(in)+real_small))
    ENDDO
  ENDIF

!#ifdef STATS
! if desired, collect quantities of interest at cell centers for statistics

!  IF (region%turbInput%nSt > 0) THEN
!    ALLOCATE( colBVar(2,ibn:ien) )
!    colBVar(1,:) = avgMMij
!    colBVar(2,:) = avgMLij
!    CALL TURB_StatFCollector( region,ijk,1,2,colVar,colBVar )
!    DEALLOCATE( colVar,colBVar )
!  ENDIF
!#endif

! deallocate retired arrays
  DEALLOCATE( mijmij,mijlij,avgmmij,avgmlij )

#endif

! finalize --------------------------------------------------------------------

  CALL deregisterfunction( global )

END SUBROUTINE turb_lescontract

!******************************************************************************
!
! RCS Revision history:
!
! $Log: TURB_LesContract.F90,v $
! Revision 1.9  2008/12/06 08:44:41  mtcampbe
! Updated license.
!
! Revision 1.8  2008/11/19 22:17:54  mtcampbe
! Added Illinois Open Source License/Copyright
!
! Revision 1.7  2006/01/30 23:12:08  wasistho
! removed comment after endif RFLU
!
! Revision 1.6  2004/10/22 23:18:26  wasistho
! comment out statistics collection of Mij and Lij
!
! Revision 1.5  2004/05/28 02:01:35  wasistho
! update unstructured grid LES
!
! Revision 1.4  2004/03/27 02:16:42  wasistho
! compiled with Rocflu
!
! Revision 1.3  2004/03/19 02:49:35  wasistho
! prepared for RFLU
!
! Revision 1.2  2004/03/12 02:55:35  wasistho
! changed rocturb routine names
!
! Revision 1.1  2004/03/05 04:37:00  wasistho
! changed nomenclature
!
! Revision 1.4  2004/02/18 21:30:26  wasistho
! set <Mij.Lij> to zero when Lij/Mij is excessively large
!
! Revision 1.3  2003/05/24 02:07:33  wasistho
! turbulence statistics expanded
!
! Revision 1.2  2003/05/15 02:57:06  jblazek
! Inlined index function.
!
! Revision 1.1  2002/10/14 23:55:29  wasistho
! Install Rocturb
!
!
!******************************************************************************