RFLU_EndFlowSolver.F90

Go to the documentation of this file.

! *********************************************************************
! * Rocstar Simulation Suite                                          *
! * Copyright@2015, Illinois Rocstar LLC. All rights reserved.        *
! *                                                                   *
! * Illinois Rocstar LLC                                              *
! * Champaign, IL                                                     *
! * www.illinoisrocstar.com                                           *
! * sales@illinoisrocstar.com                                         *
! *                                                                   *
! * License: See LICENSE file in top level of distribution package or *
! * http://opensource.org/licenses/NCSA                               *
! *********************************************************************
! *********************************************************************
! * THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND,   *
! * EXPRESS OR IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES   *
! * OF MERCHANTABILITY, FITNESS FOR A PARTICULAR PURPOSE AND          *
! * NONINFRINGEMENT.  IN NO EVENT SHALL THE CONTRIBUTORS OR           *
! * COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER       *
! * LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE,   *
! * Arising FROM, OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE    *
! * USE OR OTHER DEALINGS WITH THE SOFTWARE.                          *
! *********************************************************************
! ******************************************************************************
!
! Purpose: Shut down Rocflu-MP.
!
! Description: None.
!
! Input: 
!   levels      Data associated with levels
!
! Output: None.
!
! Notes: None.
!
! ******************************************************************************
!
! $Id: RFLU_EndFlowSolver.F90,v 1.62 2008/12/06 08:44:29 mtcampbe Exp $
!
! Copyright: (c) 2001-2006 by the University of Illinois
!
! ******************************************************************************

SUBROUTINE rflu_endflowsolver(levels)

  USE modglobal, ONLY: t_global
  USE modparameters
  USE moddatatypes
  USE modbndpatch, ONLY: t_patch
  USE moddatastruct, ONLY: t_level,t_region
  USE modgrid, ONLY: t_grid
  USE modmixture, ONLY: t_mixt_input   
  USE modbndpatch, ONLY: t_patch
  USE moderror
  USE modmpi  
  
  USE rflu_modbfacegradaccesslist
  USE rflu_modboundlists 
  USE rflu_modboundxvutils
  USE rflu_modnscbc, ONLY: rflu_nscbc_decidehavenscbc
  USE rflu_modcellmapping 
  USE rflu_modcommlists 
  USE rflu_moddimensions
  USE rflu_modedgelist   
  USE rflu_modfacelist  
  USE rflu_modforcesmoments
  USE rflu_modgeometry      
  USE rflu_modmpi
  USE rflu_modoles
  USE rflu_modpatchcoeffs
  USE rflu_modprobes
  USE rflu_modreadwriteflow
  USE rflu_modreadwritegrid
  USE rflu_modreadwritegridspeeds  
  USE rflu_modstencilsbfaces
  USE rflu_modstencilscells
  USE rflu_modstencilsfaces
  USE rflu_modweights
  
#ifdef PETSC
  USE rflu_modpetscadmin
  USE rflu_modpetscnewtonkrylov
#endif
  
#ifdef PLAG
  USE plag_moddimensions, ONLY: plag_calcnpclsglobal, &
                                plag_printnpclsglobal, &
                                plag_rflu_writedimensions
  USE plag_modsurfstats
#endif  
  
  USE modinterfaces, ONLY: rflu_deallocatememorywrapper, &
                           rflu_decideneedbgradface, &
                           rflu_destroygrid, & 
                           rflu_printflowinfowrapper, & 
                           rflu_printgridinfo, & 
                           rflu_printwarninfo, &  
                           rflu_writerestartinfo
    
#ifdef STATS
  USE modinterfaces, ONLY: rflu_writestat
#endif

  IMPLICIT NONE

! ******************************************************************************
! Arguments
! ******************************************************************************

  TYPE(t_level), POINTER :: levels(:)

! ******************************************************************************
! Locals
! ******************************************************************************

  CHARACTER(CHRLEN) :: rcsidentstring
  LOGICAL :: movegrid  
  INTEGER :: errorflag,ipatch,iprobe,ireg
  TYPE(t_global), POINTER :: global
  TYPE(t_grid), POINTER :: pgrid
  TYPE(t_mixt_input), POINTER :: pmixtinput 
  TYPE(t_patch), POINTER :: ppatch   
  TYPE(t_region), POINTER :: pregion,pregionserial  

! ******************************************************************************
! Start, initialize some variables
! ******************************************************************************

  rcsidentstring = '$RCSfile: RFLU_EndFlowSolver.F90,v $ $Revision: 1.62 $'

  movegrid = .false. 

! ******************************************************************************
! Set global pointer and initialize global type, register function
! ****************************************************************************** 

  global => levels(1)%regions(1)%global

  CALL registerfunction(global,'RFLU_EndFlowSolver',&
  'RFLU_EndFlowSolver.F90')

! ******************************************************************************
! Determine whether have moving grid
! ******************************************************************************

  DO ireg = 1,global%nRegionsLocal
    pregion => levels(1)%regions(ireg)
  
    IF ( pregion%mixtInput%moveGrid .EQV. .true. ) THEN 
      movegrid = .true.
      EXIT
    END IF ! regions
  END DO ! iReg

! ******************************************************************************
! Write grid file (if necessary) and flow file. Write restart info file after 
! flow (and grid) file so that incomplete flow (and grid) files due to
! exceeding time limit do not show up as iteration or time stamp in restart 
! info file.
! ******************************************************************************

#ifdef PLAG
  IF ( global%plagUsed .EQV. .true. ) THEN
    CALL plag_calcnpclsglobal(levels(1)%regions)

    IF ( global%myProcid == masterproc ) THEN
      pregionserial => levels(1)%regions(0)

      CALL plag_rflu_writedimensions(pregionserial)
    END IF ! global%myProcid
  END IF ! global%plagUsed
#endif

#ifndef GENX
  DO ireg = 1,global%nRegionsLocal
    pregion => levels(1)%regions(ireg) ! single-level grids for now
    
    CALL rflu_writedimensionswrapper(pregion,write_dimens_mode_maybe)    

    IF ( movegrid .EQV. .true. ) THEN
      CALL rflu_writegridwrapper(pregion)
      CALL rflu_writegridspeedswrapper(pregion)
    END IF ! moveGrid    
    
    CALL rflu_writeflowwrapper(pregion)
    CALL rflu_bxv_writevarswrapper(pregion)
    
    IF ( global%patchCoeffFlag .EQV. .true. ) THEN
      CALL rflu_writepatchcoeffswrapper(pregion)
    END IF ! global%patchCoeffFlag
    
#ifdef PLAG
    IF ( global%plagUsed .EQV. .true. ) THEN
      CALL plag_writesurfstatswrapper(pregion)
    END IF ! global%plagUsed
#endif    
    
  END DO ! iReg

  CALL rflu_writerestartinfo(global)
  
#ifdef STATS
    IF ( global%doStat == active ) THEN
      DO ireg = 1,global%nRegionsLocal
        pregion => levels(1)%regions(ireg)
        CALL rflu_writestat(pregion)
      END DO ! iReg
    END IF ! global%doStat
#endif
#endif

! ******************************************************************************
! Print (if necessary, grid, and) flow information 
! ******************************************************************************

  IF ( global%myProcid == masterproc .AND. &
       global%verbLevel > verbose_none ) THEN 
    IF ( movegrid .EQV. .true. ) THEN
      DO ireg = 1,global%nRegionsLocal
        pregion => levels(1)%regions(ireg) ! single-level grids for now
        CALL rflu_printgridinfo(pregion)
      END DO ! iReg     
    END IF ! moveGrid       
       
    DO ireg = 1,global%nRegionsLocal
      pregion => levels(1)%regions(ireg) ! single-level grids for now
      CALL rflu_printflowinfowrapper(pregion)

#ifdef PLAG                     
      IF ( global%plagUsed .EQV. .true. ) THEN
        CALL plag_printnpclsglobal(pregion)
      END IF ! global%plagUsed
#endif
    END DO ! iReg    
  END IF ! global%verbLevel

! ******************************************************************************
! Deallocate memory. NOTE must be done before calling deallocation wrapper. 
! NOTE weights must be deallocated before stencils.
! ******************************************************************************

! ==============================================================================
! Weights for cell and face gradients
! ==============================================================================

  DO ireg = 1,global%nRegionsLocal 
    pregion => levels(1)%regions(ireg)
    pmixtinput => pregion%mixtInput   

    IF ( pmixtinput%spaceOrder > 1 ) THEN 
      CALL rflu_destroywtsc2cwrapper(pregion)
    END IF ! pMixtInput%spaceOrder      

    IF ( pmixtinput%flowModel == flow_navst ) THEN      
      CALL rflu_destroywtsf2cwrapper(pregion)
    END IF ! pMixtInput%flowModel 
      
    DO ipatch = 1,pregion%grid%nPatches
      ppatch => pregion%patches(ipatch)

      IF ( rflu_decideneedbgradface(pregion,ppatch) .EQV. .true. ) THEN
        CALL rflu_destroywtsbf2cwrapper(pregion,ppatch)      
      END IF ! RFLU_DecideNeedBGradFace
    END DO ! iPatch
  END DO ! iReg   
  
! ==============================================================================
! Weights for optimal LES approach
! ==============================================================================

  DO ireg = 1,global%nRegionsLocal
    pregion => levels(1)%regions(ireg) 
    pmixtinput => pregion%mixtInput 
         
    IF ( pmixtinput%spaceDiscr == discr_opt_les ) THEN 
      CALL rflu_destroystencilsweightsoles(pregion)
    END IF ! pMixtInput
  END DO ! iReg
 
! ******************************************************************************
! Deallocate memory for stencils
! ******************************************************************************

  DO ireg = 1,global%nRegionsLocal 
    pregion => levels(1)%regions(ireg)
    pmixtinput => pregion%mixtInput 
    
    IF ( pmixtinput%spaceOrder > 1 ) THEN 
      CALL rflu_destroyc2cstencilwrapper(pregion)
      CALL rflu_destroylistcc2cstencil(pregion)  
    END IF ! pMixtInput%spaceOrder
    
    IF ( pmixtinput%flowModel == flow_navst ) THEN      
      CALL rflu_destroyf2cstencilwrapper(pregion) 
      CALL rflu_destroylistcf2cstencil(pregion)
    END IF ! pMixtInput%flowModel

    DO ipatch = 1,pregion%grid%nPatches
      ppatch => pregion%patches(ipatch)
    
      IF ( rflu_decideneedbgradface(pregion,ppatch) .EQV. .true. ) THEN
        CALL rflu_destroybf2cstencilwrapper(pregion,ppatch)
      END IF ! RFLU_DecideNeedBGradFace
    END DO ! iPatch

  END DO ! iReg

! ******************************************************************************
! Destroy boundary-face gradient access list for viscous flows
! ******************************************************************************

  DO ireg = 1,global%nRegionsLocal 
    pregion => levels(1)%regions(ireg) 
    
    IF ( pregion%mixtInput%flowModel == flow_navst ) THEN          
      CALL rflu_destroybfacegradaccesslist(pregion)
    END IF ! pRegion%mixtInput
  END DO ! iReg  

! ******************************************************************************
! Deallocate memory
! ******************************************************************************

  DO ireg = 1,global%nRegionsLocal
    pregion => levels(1)%regions(ireg) ! single-level grids for now
    pgrid   => pregion%grid
        
    CALL rflu_destroypatchcoeffs(pregion)

    IF ( rflu_nscbc_decidehavenscbc(pregion) .EQV. .true. ) THEN
      CALL rflu_bxv_destroyvarscv(pregion)
      CALL rflu_bxv_destroyvarsdv(pregion)
      CALL rflu_bxv_destroyvarststep(pregion)
    END IF ! RFLU_NSCBC_DecideHaveNSCBC(pRegion)   
 
    IF ( global%forceFlag .EQV. .true. ) THEN 
      CALL rflu_destroyforcesmoments(pregion)   
      CALL rflu_destroyglobalthrustflags(pregion)   
    END IF ! global%forceFlag

#ifdef PLAG
    IF ( global%plagUsed .EQV. .true. ) THEN 
      CALL plag_destroysurfstats(pregion)
    END IF ! global%plagUsed
#endif    
            
    IF ( pgrid%nBorders > 0 ) THEN 
      CALL rflu_mpi_destroybufferswrapper(pregion)

#ifdef PLAG
      IF ( pregion%global%plagUsed .EQV. .true. ) THEN 
        CALL rflu_mpi_destroybufferipclsend(pregion)
      END IF ! pRegion%global%plagUsed
#endif

      CALL rflu_comm_destroycommlists(pregion)
      CALL rflu_comm_destroyborders(pregion)
    END IF ! pGrid%nBorders 
        
    CALL rflu_deallocatememorywrapper(pregion)

    CALL rflu_destroycellmapping(pregion)
    CALL rflu_destroyfacelist(pregion)
    
#ifdef PLAG
    IF ( (pregion%global%plagUsed .EQV. .true.) .AND. & 
         (pregion%grid%nFacesAV > 0) ) THEN
      CALL rflu_destroyavface2borderlist(pregion)      
      CALL rflu_destroyavface2patchlist(pregion)      
    END IF ! pRegion%global%plagUsed
#endif    
    
    IF ( pregion%mixtInput%movegrid .EQV. .true. ) THEN
      CALL rflu_destroyedgelist(pregion)
    END IF ! pRegion 
    
    CALL rflu_destroygeometry(pregion)
    CALL rflu_destroygrid(pregion)           
  END DO ! iReg

! ******************************************************************************
! Close convergence, mass, and probe files
! ******************************************************************************

  IF ( global%myProcid == masterproc ) THEN
    CLOSE(if_conver,iostat=errorflag)
    global%error = errorflag
    IF ( global%error /= 0 ) THEN 
      CALL errorstop(global,err_file_close,__line__)
    END IF ! global%error
  END IF ! global%myProcid

  IF ( (global%myProcid == masterproc) .AND. (movegrid .EQV. .true.) ) THEN
    CLOSE(if_mass,iostat=errorflag)
    global%error = errorflag
    IF ( global%error /= 0 ) THEN 
      CALL errorstop(global,err_file_close,__line__)
    END IF ! global%error
  END IF ! global%myProcid  

  IF ( global%nProbes > 0 ) THEN
    DO ireg = 1,global%nRegionsLocal
      pregion => levels(1)%regions(ireg) ! single-level grids for now 
         
      CALL rflu_closeprobefiles(pregion)
    END DO ! iReg
  END IF ! global%nProbes

! ******************************************************************************
! Print info about warnings
! ******************************************************************************

  CALL rflu_printwarninfo(global)

! ******************************************************************************
! Deallocate PETSc memory & finalize PETSc
! ******************************************************************************

#ifdef PETSC
  IF ( global%solverType == solv_implicit_nk ) THEN
    CALL rflu_petsc_destroyvectors(pregion)
    CALL rflu_petsc_destroyjacobian(pregion)
    CALL rflu_petsc_finalize(global)
  END IF ! global%solverType
#endif

#ifndef GENX
! ******************************************************************************
! Finalize Rocprof
! ****************************************************************************** 

#ifdef ROCPROF
  CALL rocprof_finalize(1)
#endif

! ******************************************************************************
! Finalize MPI
! ****************************************************************************** 

  CALL mpi_finalize(errorflag)
  global%error = errorflag
  IF ( global%error /= err_none ) THEN 
    CALL errorstop(global,err_mpi_output,__line__)
  END IF ! global%error
#endif

! ******************************************************************************
! End
! ******************************************************************************

  IF ( global%myProcid == masterproc .AND. & 
       global%verbLevel /= verbose_none ) THEN
    WRITE(stdout,'(A)') solver_name    
    WRITE(stdout,'(A,1X,A)') solver_name,'Finalization done.'
    WRITE(stdout,'(A,1X,A)') solver_name,'Program finished.'
    WRITE(stdout,'(A)') solver_name         
  END IF ! global%myProcid 

  CALL deregisterfunction(global)

END SUBROUTINE rflu_endflowsolver

! ******************************************************************************
!
! RCS Revision history:
!
! $Log: RFLU_EndFlowSolver.F90,v $
! Revision 1.62  2008/12/06 08:44:29  mtcampbe
! Updated license.
!
! Revision 1.61  2008/11/19 22:17:42  mtcampbe
! Added Illinois Open Source License/Copyright
!
! Revision 1.60  2007/03/31 23:53:39  haselbac
! Added calls to determine, write, and print nPclsGlobal
!
! Revision 1.59  2006/10/20 21:32:08  mparmar
! Added call to RFLU_DestroyGlobalThrustFlags
!
! Revision 1.58  2006/08/19 15:46:41  mparmar
! Changed logic for NSCBC and added calls to deallocate patch arrays
!
! Revision 1.57  2006/08/18 14:04:02  haselbac
! Added call to destroy AVFace2Patch list
!
! Revision 1.56  2006/04/07 16:04:03  haselbac
! Adapted to changes in bf2c wts computation
!
! Revision 1.55  2006/04/07 15:19:22  haselbac
! Removed tabs
!
! Revision 1.54  2006/04/07 14:53:11  haselbac
! Adapted to changes in bface stencil routines
!
! Revision 1.53  2006/03/09 14:09:49  haselbac
! Now call wrapper routines for stencils
!
! Revision 1.52  2006/01/06 22:15:07  haselbac
! Adapted to name changes
!
! Revision 1.51  2005/11/10 16:51:29  fnajjar
! Added plagUsed IF statement around PLAG routines
!
! Revision 1.50  2005/10/27 19:20:06  haselbac
! Adapted to changes in stencil routine names
!
! Revision 1.49  2005/10/25 19:39:23  haselbac
! Added IF on forceFlag
!
! Revision 1.48  2005/10/05 14:18:41  haselbac
! Adapted to changes in stencil modules, added call to destroy bface wts
!
! Revision 1.47  2005/09/14 15:59:33  haselbac
! Minor clean-up
!
! Revision 1.46  2005/09/13 20:44:06  mtcampbe
! Added Rocprof finalization
!
! Revision 1.45  2005/08/09 00:59:42  haselbac
! Enclosed writing of patch coeffs within IF (patchCoeffFlag)
!
! Revision 1.44  2005/08/03 18:28:11  hdewey2
! Enclosed PETSc deallocation calls within IF
!
! Revision 1.43  2005/08/02 18:24:32  hdewey2
! Added PETSc support
!
! Revision 1.42  2005/05/18 22:12:55  fnajjar
! ACH: Added destruction of iPclSend buffers, now use nFacesAV
!
! Revision 1.41  2005/04/29 23:03:22  haselbac
! Added destruction of avf2b list
!
! Revision 1.40  2005/04/29 12:48:23  haselbac
! Updated closing of probe files to changes in probe handling
!
! Revision 1.39  2005/04/15 16:31:18  haselbac
! Removed calls to XyzEdge2RegionDegrList routines
!
! Revision 1.38  2005/04/15 15:07:15  haselbac
! Converted to MPI
!
! Revision 1.37  2005/01/18 15:18:19  haselbac
! Commented out COMM calls for now
!
! Revision 1.36  2005/01/14 21:33:56  haselbac
! Added calls to destroy comm lists and borders
!
! Revision 1.35  2005/01/03 16:14:57  haselbac
! Added call to destroy bface stencils
!
! Revision 1.34  2004/12/21 15:05:11  fnajjar
! Included calls for PLAG surface statistics
!
! Revision 1.33  2004/10/19 19:29:15  haselbac
! Adapted to GENX changes
!
! Revision 1.32  2004/07/06 15:14:50  haselbac
! Adapted to changes in libflu and modflu, cosmetics
!
! Revision 1.31  2004/06/16 20:01:08  haselbac
! Added writing of patch coeffs, destruction of memory
!
! Revision 1.30  2004/03/17 04:28:26  haselbac
! Adapted call to RFLU_WriteDimensionsWrapper
!
! Revision 1.29  2004/03/11 16:33:22  fnajjar
! ACH: Moved call to RFLU_WriteDimWrapper outside if bcos of Rocpart
!
! Revision 1.28  2004/03/08 22:01:43  fnajjar
! ACH: Changed call to RFLU_WriteDimensionsWrapper so PLAG data also written
!
! Revision 1.27  2004/01/29 22:59:19  haselbac
! Removed hardcoded error computation for supersonic vortex
!
! Revision 1.26  2003/12/04 03:30:01  haselbac
! Added destruction calls for gradients, cleaned up
!
! Revision 1.25  2003/11/25 21:04:40  haselbac
! Added call to RFLU_PrintFlowInfoWrapper, cosmetic changes
!
! Revision 1.24  2003/11/03 03:51:17  haselbac
! Added call to destroy boundary-face gradient access list
!
! Revision 1.23  2003/08/07 15:33:30  haselbac
! Added call to RFLU_PrintWarnInfo
!
! Revision 1.22  2003/07/22 02:07:00  haselbac
! Added writing out of warnings
!
! Revision 1.21  2003/06/20 22:35:26  haselbac
! Added call to RFLU_WriteRestartInfo
!
! Revision 1.20  2003/01/28 14:36:53  haselbac
! Added deallocation, merged printing of grid and flow info, cosmetics
!
! Revision 1.19  2002/12/20 23:20:06  haselbac
! Fixed output bug: no output for verbosity=0
!
! Revision 1.18  2002/11/08 21:31:32  haselbac
! Added closing of total-mass file
!
! Revision 1.17  2002/11/02 02:03:20  wasistho
! Added TURB statistics
!
! Revision 1.16  2002/10/27 19:12:09  haselbac
! Added writing of grid for moving grid calcs
!
! Revision 1.15  2002/10/19 16:12:16  haselbac
! Cosmetic changes to output
!
! Revision 1.14  2002/10/16 21:16:06  haselbac
! Added writing of header when running
!
! Revision 1.13  2002/10/12 14:57:37  haselbac
! Enclosed RFLU_WriteFlowWrapper between ifndef GENX
!
! Revision 1.12  2002/10/08 15:49:29  haselbac
! {IO}STAT=global%error replaced by {IO}STAT=errorFlag - SGI problem
!
! Revision 1.11  2002/10/05 19:20:55  haselbac
! GENX integration, close probe file, use flow wrapper routine
!
! Revision 1.10  2002/09/09 15:49:26  haselbac
! global and mixtInput now under region
!
! Revision 1.9  2002/07/25 14:25:07  haselbac
! No longer called finalize for CHARM=1
!
! Revision 1.8  2002/06/27 15:27:11  haselbac
! Change name if CHARM defined, comment out destruction for now (crashes with CHARM)
!
! Revision 1.7  2002/06/17 13:34:12  haselbac
! Prefixed SOLVER_NAME to all screen output
!
! Revision 1.6  2002/06/14 22:26:08  wasistho
! update statistics
!
! Revision 1.5  2002/06/14 21:54:35  wasistho
! Added time avg statistics
!
! Revision 1.4  2002/06/14 20:20:43  haselbac
! Deleted ModLocal, changed local%nRegions to global%nRegionsLocal, added destroy flag
!
! Revision 1.3  2002/05/04 17:08:13  haselbac
! Close convergence file and print flow information
!
! Revision 1.2  2002/04/11 19:03:22  haselbac
! Added calls and cosmetic changes
!
! Revision 1.1  2002/03/14 19:11:00  haselbac
! Initial revision
!
! ******************************************************************************