RFLO_ExchangeDnodeSend.F90

Go to the documentation of this file.

! *********************************************************************
! * Rocstar Simulation Suite                                          *
! * Copyright@2015, Illinois Rocstar LLC. All rights reserved.        *
! *                                                                   *
! * Illinois Rocstar LLC                                              *
! * Champaign, IL                                                     *
! * www.illinoisrocstar.com                                           *
! * sales@illinoisrocstar.com                                         *
! *                                                                   *
! * License: See LICENSE file in top level of distribution package or *
! * http://opensource.org/licenses/NCSA                               *
! *********************************************************************
! *********************************************************************
! * THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND,   *
! * EXPRESS OR IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES   *
! * OF MERCHANTABILITY, FITNESS FOR A PARTICULAR PURPOSE AND          *
! * NONINFRINGEMENT.  IN NO EVENT SHALL THE CONTRIBUTORS OR           *
! * COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER       *
! * LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE,   *
! * Arising FROM, OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE    *
! * USE OR OTHER DEALINGS WITH THE SOFTWARE.                          *
! *********************************************************************
!******************************************************************************
!
! Purpose: send node movement of an interface to the adjacent region
!          which is on another processor.
!
! Description: none.
!
! Input: region    = current region
!        regionSrc = region to send data to
!        patch     = current patch of region
!        dNode     = node movement of current region.
!
! Output: patch%mixt%sendBuff = send buffer.
!
! Notes: operation carried out for the finest grid only. Intended for
!        conforming grid boundaries (also periodic) only.
!
!******************************************************************************
!
! $Id: RFLO_ExchangeDnodeSend.F90,v 1.4 2008/12/06 08:44:06 mtcampbe Exp $
!
! Copyright: (c) 2003 by the University of Illinois
!
!******************************************************************************

SUBROUTINE rflo_exchangednodesend( region,regionSrc,patch,dNode )

  USE moddatatypes
  USE modbndpatch, ONLY   : t_patch
  USE moddatastruct, ONLY : t_region
  USE modglobal, ONLY     : t_global
  USE modinterfaces, ONLY : rflo_getpatchindicesnodes, rflo_getnodeoffset
  USE moderror
  USE modmpi
  USE modparameters
  IMPLICIT NONE

#include "Indexing.h"

! ... parameters
  REAL(RFREAL), POINTER :: dnode(:,:)

  TYPE(t_region) :: region, regionsrc
  TYPE(t_patch)  :: patch

! ... loop variables
  INTEGER :: i, j, k, ijkbuff

! ... local variables
  INTEGER :: bctype, ibeg, iend, jbeg, jend, kbeg, kend, inoff, ijnoff, ijkn, &
             ijknb, n1, n2, ndim, dest, tag, request, ibnd, jbnd, kbnd
  INTEGER :: lb, l1srcdir, l2srcdir, l1beg, l1end, l1step, l2beg, l2end, l2step

  LOGICAL :: align

  REAL(RFREAL) :: v1(3), v2(3)
  REAL(RFREAL), POINTER :: xyz(:,:)

  TYPE(t_global), POINTER :: global

!******************************************************************************

  global => region%global

  CALL registerfunction( global,'RFLO_ExchangeDnodeSend',&
  'RFLO_ExchangeDnodeSend.F90' )

! check if the source region is active

  IF (regionsrc%active == off) THEN
    CALL errorstop( global,err_srcregion_off,&
    __line__ )
  ENDIF

! get dimensions and pointers

  CALL rflo_getpatchindicesnodes( region,patch,1,ibeg,iend, &
                                  jbeg,jend,kbeg,kend )
  CALL rflo_getnodeoffset( region,1,inoff,ijnoff )

  xyz => region%levels(1)%gridOld%xyz

  n1   = abs(patch%l1end-patch%l1beg) + 2   ! here, dimensions of current
  n2   = abs(patch%l2end-patch%l2beg) + 2   ! and source patch are identical
  ndim = n1*n2

  lb     = patch%lbound
  align  = patch%align
  bctype = patch%bcType

! mapping between patches

  l1srcdir = 1
  IF (patch%srcL1beg > patch%srcL1end) THEN
    l1srcdir = -1
  ELSE IF (patch%srcL1beg == patch%srcL1end) THEN
    IF (lb==1 .OR. lb==2) THEN
      IF (align) THEN
        v2(:) = xyz(:,indijk(ibeg,jend,kbeg,inoff,ijnoff)) - &
                xyz(:,indijk(ibeg,jbeg,kbeg,inoff,ijnoff))
      ELSE
        v2(:) = xyz(:,indijk(ibeg,jbeg,kend,inoff,ijnoff)) - &
                xyz(:,indijk(ibeg,jbeg,kbeg,inoff,ijnoff))
      ENDIF
    ELSE IF (lb==3 .OR. lb==4) THEN
      IF (align) THEN
        v2(:) = xyz(:,indijk(ibeg,jbeg,kend,inoff,ijnoff)) - &
                xyz(:,indijk(ibeg,jbeg,kbeg,inoff,ijnoff))
      ELSE
        v2(:) = xyz(:,indijk(iend,jbeg,kbeg,inoff,ijnoff)) - &
                xyz(:,indijk(ibeg,jbeg,kbeg,inoff,ijnoff))
      ENDIF
    ELSE IF (lb==5 .OR. lb==6) THEN
      IF (align) THEN
        v2(:) = xyz(:,indijk(iend,jbeg,kbeg,inoff,ijnoff)) - &
                xyz(:,indijk(ibeg,jbeg,kbeg,inoff,ijnoff))
      ELSE
        v2(:) = xyz(:,indijk(ibeg,jend,kbeg,inoff,ijnoff)) - &
                xyz(:,indijk(ibeg,jbeg,kbeg,inoff,ijnoff))
      ENDIF
    ENDIF
    v1(:) = patch%l1VecSrc(:)
    IF (dot_product(v1,v2) < 0._rfreal) l1srcdir = -1
  ENDIF

  l2srcdir =  1
  IF (patch%srcL2beg > patch%srcL2end) THEN
    l2srcdir = -1
  ELSE IF (patch%srcL2beg == patch%srcL2end) THEN
    IF (lb==1 .OR. lb==2) THEN
      IF (align) THEN
        v2(:) = xyz(:,indijk(ibeg,jbeg,kend,inoff,ijnoff)) - &
                xyz(:,indijk(ibeg,jbeg,kbeg,inoff,ijnoff))
      ELSE
        v2(:) = xyz(:,indijk(ibeg,jend,kbeg,inoff,ijnoff)) - &
                xyz(:,indijk(ibeg,jbeg,kbeg,inoff,ijnoff))
      ENDIF
    ELSE IF (lb==3 .OR. lb==4) THEN
      IF (align) THEN
        v2(:) = xyz(:,indijk(iend,jbeg,kbeg,inoff,ijnoff)) - &
                xyz(:,indijk(ibeg,jbeg,kbeg,inoff,ijnoff))
      ELSE
        v2(:) = xyz(:,indijk(ibeg,jbeg,kend,inoff,ijnoff)) - &
                xyz(:,indijk(ibeg,jbeg,kbeg,inoff,ijnoff))
      ENDIF
    ELSE IF (lb==5 .OR. lb==6) THEN
      IF (align) THEN
        v2(:) = xyz(:,indijk(ibeg,jend,kbeg,inoff,ijnoff)) - &
                xyz(:,indijk(ibeg,jbeg,kbeg,inoff,ijnoff))
      ELSE
        v2(:) = xyz(:,indijk(iend,jbeg,kbeg,inoff,ijnoff)) - &
                xyz(:,indijk(ibeg,jbeg,kbeg,inoff,ijnoff))
      ENDIF
    ENDIF
    v1(:) = patch%l2VecSrc(:)
    IF (dot_product(v1,v2) < 0._rfreal) l2srcdir = -1
  ENDIF

! loop over interior nodes of current patch -----------------------------------

  ijkbuff = 0

! face i=const.

  IF (lb==1 .OR. lb==2) THEN

    IF (lb == 1) THEN
      i    = ibeg
      ibnd = ibeg
    ELSE IF (lb == 2) THEN
      i    = iend
      ibnd = iend
    ENDIF

    IF (align) THEN
      IF (l1srcdir > 0) THEN
        l1beg = jbeg
        l1end = jend
      ELSE
        l1beg = jend
        l1end = jbeg
      ENDIF
      l1step = l1srcdir
      IF (l2srcdir > 0) THEN
        l2beg = kbeg
        l2end = kend
      ELSE
        l2beg = kend
        l2end = kbeg
      ENDIF
      l2step = l2srcdir
      IF ((bctype>=bc_regionconf .AND. bctype<=bc_regionconf+bc_range) .OR. &
          (bctype>=bc_rot_peri   .AND. bctype<=bc_rot_peri  +bc_range) .OR. &
          (bctype>=bc_tra_peri   .AND. bctype<=bc_tra_peri  +bc_range)) THEN
        DO k=l2beg,l2end,l2step
          DO j=l1beg,l1end,l1step
            ijkn    = indijk(i,j,k,inoff,ijnoff)
            ijkbuff = ijkbuff + 1
            patch%mixt%sendBuff(ijkbuff       ) = dnode(xcoord,ijkn)
            patch%mixt%sendBuff(ijkbuff+  ndim) = dnode(ycoord,ijkn)
            patch%mixt%sendBuff(ijkbuff+2*ndim) = dnode(zcoord,ijkn)
          ENDDO
        ENDDO
      ENDIF
    ELSE   ! not aligned
      IF (l1srcdir > 0) THEN
        l1beg = kbeg
        l1end = kend
      ELSE
        l1beg = kend
        l1end = kbeg
      ENDIF
      l1step = l1srcdir
      IF (l2srcdir > 0) THEN
        l2beg = jbeg
        l2end = jend
      ELSE
        l2beg = jend
        l2end = jbeg
      ENDIF
      l2step = l2srcdir
      IF ((bctype>=bc_regionconf .AND. bctype<=bc_regionconf+bc_range) .OR. &
          (bctype>=bc_rot_peri   .AND. bctype<=bc_rot_peri  +bc_range) .OR. &
          (bctype>=bc_tra_peri   .AND. bctype<=bc_tra_peri  +bc_range)) THEN
        DO j=l2beg,l2end,l2step
          DO k=l1beg,l1end,l1step
            ijkn    = indijk(i,j,k,inoff,ijnoff)
            ijkbuff = ijkbuff + 1
            patch%mixt%sendBuff(ijkbuff       ) = dnode(xcoord,ijkn)
            patch%mixt%sendBuff(ijkbuff+  ndim) = dnode(ycoord,ijkn)
            patch%mixt%sendBuff(ijkbuff+2*ndim) = dnode(zcoord,ijkn)
          ENDDO
        ENDDO
      ENDIF
    ENDIF   ! align

! face j=const.

  ELSE IF (lb==3 .OR. lb==4) THEN

    IF (lb == 3) THEN
      j    = jbeg
      jbnd = jbeg
    ELSE IF (lb == 4) THEN
      j    = jend
      jbnd = jend
    ENDIF

    IF (align) THEN
      IF (l1srcdir > 0) THEN
        l1beg = kbeg
        l1end = kend
      ELSE
        l1beg = kend
        l1end = kbeg
      ENDIF
      l1step = l1srcdir
      IF (l2srcdir > 0) THEN
        l2beg = ibeg
        l2end = iend
      ELSE
        l2beg = iend
        l2end = ibeg
      ENDIF
      l2step = l2srcdir
      IF ((bctype>=bc_regionconf .AND. bctype<=bc_regionconf+bc_range) .OR. &
          (bctype>=bc_rot_peri   .AND. bctype<=bc_rot_peri  +bc_range) .OR. &
          (bctype>=bc_tra_peri   .AND. bctype<=bc_tra_peri  +bc_range)) THEN
        DO i=l2beg,l2end,l2step
          DO k=l1beg,l1end,l1step
            ijkn    = indijk(i,j,k,inoff,ijnoff)
            ijkbuff = ijkbuff + 1
            patch%mixt%sendBuff(ijkbuff       ) = dnode(xcoord,ijkn)
            patch%mixt%sendBuff(ijkbuff+  ndim) = dnode(ycoord,ijkn)
            patch%mixt%sendBuff(ijkbuff+2*ndim) = dnode(zcoord,ijkn)
          ENDDO
        ENDDO
      ENDIF
    ELSE   ! not aligned
      IF (l1srcdir > 0) THEN
        l1beg = ibeg
        l1end = iend
      ELSE
        l1beg = iend
        l1end = ibeg
      ENDIF
      l1step = l1srcdir
      IF (l2srcdir > 0) THEN
        l2beg = kbeg
        l2end = kend
      ELSE
        l2beg = kend
        l2end = kbeg
      ENDIF
      l2step = l2srcdir
      IF ((bctype>=bc_regionconf .AND. bctype<=bc_regionconf+bc_range) .OR. &
          (bctype>=bc_rot_peri   .AND. bctype<=bc_rot_peri  +bc_range) .OR. &
          (bctype>=bc_tra_peri   .AND. bctype<=bc_tra_peri  +bc_range)) THEN
        DO k=l2beg,l2end,l2step
          DO i=l1beg,l1end,l1step
            ijkn    = indijk(i,j,k,inoff,ijnoff)
            ijkbuff = ijkbuff + 1
            patch%mixt%sendBuff(ijkbuff       ) = dnode(xcoord,ijkn)
            patch%mixt%sendBuff(ijkbuff+  ndim) = dnode(ycoord,ijkn)
            patch%mixt%sendBuff(ijkbuff+2*ndim) = dnode(zcoord,ijkn)
          ENDDO
        ENDDO
      ENDIF
    ENDIF   ! align

! face k=const.

  ELSE IF (lb==5 .OR. lb==6) THEN

    IF (lb == 5) THEN
      k    = kbeg
      kbnd = kbeg
    ELSE IF (lb == 6) THEN
      k    = kend
      kbnd = kend
    ENDIF

    IF (align) THEN
      IF (l1srcdir > 0) THEN
        l1beg = ibeg
        l1end = iend
      ELSE
        l1beg = iend
        l1end = ibeg
      ENDIF
      l1step = l1srcdir
      IF (l2srcdir > 0) THEN
        l2beg = jbeg
        l2end = jend
      ELSE
        l2beg = jend
        l2end = jbeg
      ENDIF
      l2step = l2srcdir
      IF ((bctype>=bc_regionconf .AND. bctype<=bc_regionconf+bc_range) .OR. &
          (bctype>=bc_rot_peri   .AND. bctype<=bc_rot_peri  +bc_range) .OR. &
          (bctype>=bc_tra_peri   .AND. bctype<=bc_tra_peri  +bc_range)) THEN
        DO j=l2beg,l2end,l2step
          DO i=l1beg,l1end,l1step
            ijkn    = indijk(i,j,k,inoff,ijnoff)
            ijkbuff = ijkbuff + 1
            patch%mixt%sendBuff(ijkbuff       ) = dnode(xcoord,ijkn)
            patch%mixt%sendBuff(ijkbuff+  ndim) = dnode(ycoord,ijkn)
            patch%mixt%sendBuff(ijkbuff+2*ndim) = dnode(zcoord,ijkn)
          ENDDO
        ENDDO
      ENDIF
    ELSE   ! not aligned
      IF (l1srcdir > 0) THEN
        l1beg = jbeg
        l1end = jend
      ELSE
        l1beg = jend
        l1end = jbeg
      ENDIF
      l1step = l1srcdir
      IF (l2srcdir > 0) THEN
        l2beg = ibeg
        l2end = iend
      ELSE
        l2beg = iend
        l2end = ibeg
      ENDIF
      l2step = l2srcdir
      IF ((bctype>=bc_regionconf .AND. bctype<=bc_regionconf+bc_range) .OR. &
          (bctype>=bc_rot_peri   .AND. bctype<=bc_rot_peri  +bc_range) .OR. &
          (bctype>=bc_tra_peri   .AND. bctype<=bc_tra_peri  +bc_range)) THEN
        DO i=l2beg,l2end,l2step
          DO j=l1beg,l1end,l1step
            ijkn    = indijk(i,j,k,inoff,ijnoff)
            ijkbuff = ijkbuff + 1
            patch%mixt%sendBuff(ijkbuff       ) = dnode(xcoord,ijkn)
            patch%mixt%sendBuff(ijkbuff+  ndim) = dnode(ycoord,ijkn)
            patch%mixt%sendBuff(ijkbuff+2*ndim) = dnode(zcoord,ijkn)
          ENDDO
        ENDDO
      ENDIF
    ENDIF   ! align

  ENDIF     ! lb

! send data -------------------------------------------------------------------

#ifdef MPI
  dest = regionsrc%procid
  tag  = regionsrc%localNumber + mpi_patchoff*patch%srcPatch
  CALL mpi_isend( patch%mixt%sendBuff,3*ndim,mpi_rfreal,dest,tag, &
                  global%mpiComm,global%requests(patch%mixt%iRequest), &
                  global%mpierr )
  IF (global%mpierr /= 0) CALL errorstop( global,err_mpi_trouble,&
  __line__ )
#endif

! finalize --------------------------------------------------------------------

  CALL deregisterfunction( global )

END SUBROUTINE rflo_exchangednodesend

!******************************************************************************
!
! RCS Revision history:
!
! $Log: RFLO_ExchangeDnodeSend.F90,v $
! Revision 1.4  2008/12/06 08:44:06  mtcampbe
! Updated license.
!
! Revision 1.3  2008/11/19 22:17:20  mtcampbe
! Added Illinois Open Source License/Copyright
!
! Revision 1.2  2006/08/19 15:38:04  mparmar
! Renamed patch variables
!
! Revision 1.1  2004/11/29 21:25:16  wasistho
! lower to upper case
!
! Revision 1.5  2003/11/20 16:40:34  mdbrandy
! Backing out RocfluidMP changes from 11-17-03
!
! Revision 1.2  2003/05/15 02:57:01  jblazek
! Inlined index function.
!
! Revision 1.1  2003/03/14 22:05:10  jblazek
! Improved mesh motion algorithm - node movement exchaged between blocks.
!
!******************************************************************************