RFLO_ExchangeDnodeCopy.F90

Go to the documentation of this file.

! *********************************************************************
! * Rocstar Simulation Suite                                          *
! * Copyright@2015, Illinois Rocstar LLC. All rights reserved.        *
! *                                                                   *
! * Illinois Rocstar LLC                                              *
! * Champaign, IL                                                     *
! * www.illinoisrocstar.com                                           *
! * sales@illinoisrocstar.com                                         *
! *                                                                   *
! * License: See LICENSE file in top level of distribution package or *
! * http://opensource.org/licenses/NCSA                               *
! *********************************************************************
! *********************************************************************
! * THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND,   *
! * EXPRESS OR IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES   *
! * OF MERCHANTABILITY, FITNESS FOR A PARTICULAR PURPOSE AND          *
! * NONINFRINGEMENT.  IN NO EVENT SHALL THE CONTRIBUTORS OR           *
! * COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER       *
! * LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE,   *
! * Arising FROM, OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE    *
! * USE OR OTHER DEALINGS WITH THE SOFTWARE.                          *
! *********************************************************************
!******************************************************************************
!
! Purpose: copy node movement from a patch of the source region to the nodes
!          of the current region`s patch (both regions are on the same
!          processor).
!
! Description: none.
!
! Input: region    = current region
!        regionSrc = source region
!        patch     = current patch of region
!        patchSrc  = source patch of regionSrc
!        average   = average source and current node movement (true/false)
!        dNode     = node movement of current region
!        dNodeSrc  = node movement of source region.
!
! Output: dNode = resulting node movement of current region.
!
! Notes: operation is carried out for the finest grid only. Intended for
!        conforming grid boundaries (also periodic) only. In the case
!        of rotationally periodic boundary, it is assumed that the
!        axis of rotation coincides with the x-axis.
!
!******************************************************************************
!
! $Id: RFLO_ExchangeDnodeCopy.F90,v 1.3 2008/12/06 08:44:06 mtcampbe Exp $
!
! Copyright: (c) 2003 by the University of Illinois
!
!******************************************************************************

SUBROUTINE rflo_exchangednodecopy( region,regionSrc,patch,patchSrc, &
                                   average,dnode,dnodesrc )

  USE moddatatypes
  USE modbndpatch, ONLY   : t_patch
  USE moddatastruct, ONLY : t_region
  USE modindexing, ONLY   : indijkmap
  USE modinterfaces, ONLY : rflo_getpatchindicesnodes, rflo_getpatchdirection, &
                            rflo_getnodeoffset, rflo_getpatchmapping
  USE moderror
  USE modparameters
  IMPLICIT NONE

#include "Indexing.h"

! ... parameters
  LOGICAL :: average

  REAL(RFREAL), POINTER :: dnode(:,:), dnodesrc(:,:)

  TYPE(t_region) :: region, regionsrc
  TYPE(t_patch)  :: patch, patchsrc

! ... loop variables
  INTEGER :: i, j, k

! ... local variables
  INTEGER :: bctype, ibeg, iend, jbeg, jend, kbeg, kend, idir, jdir, kdir, &
             inoff, ijnoff, ijkn, ijknb
  INTEGER :: ibegsrc, iendsrc, jbegsrc, jendsrc, kbegsrc, kendsrc, &
             idirsrc, jdirsrc, kdirsrc, inoffsrc, ijnoffsrc, ijknsrc, ijknbsrc
  INTEGER :: lb, lbs, l1srcdir, l2srcdir, mapmat(3,4)

  LOGICAL :: align

  REAL(RFREAL) :: dy, dz, sina, cosa, v1(3), v2(3)
  REAL(RFREAL), POINTER :: xyz(:,:), xyzsrc(:,:), dold(:,:)

!******************************************************************************

  CALL registerfunction( region%global,'RFLO_ExchangeDnodeCopy',&
  'RFLO_ExchangeDnodeCopy.F90' )

! check if the source region is active

  IF (regionsrc%active==off .AND. (.NOT.regionsrc%mixtInput%moveGrid)) THEN
    CALL errorstop( region%global,err_srcregion_off,&
    __line__ )
  ENDIF

! get dimensions and pointers

  CALL rflo_getpatchindicesnodes( region,patch,1,ibeg,iend, &
                                  jbeg,jend,kbeg,kend )
  CALL rflo_getpatchindicesnodes( regionsrc,patchsrc,1,ibegsrc,iendsrc, &
                                  jbegsrc,jendsrc,kbegsrc,kendsrc )
  CALL rflo_getpatchdirection( patch   ,idir   ,jdir,   kdir    )
  CALL rflo_getpatchdirection( patchsrc,idirsrc,jdirsrc,kdirsrc )
  CALL rflo_getnodeoffset( region   ,1,inoff   ,ijnoff    )
  CALL rflo_getnodeoffset( regionsrc,1,inoffsrc,ijnoffsrc )

  xyz    => region%levels(1)%gridOld%xyz
  dold   => region%levels(1)%grid%xyzOld
  xyzsrc => regionsrc%levels(1)%gridOld%xyz

  lb     = patch%lbound
  lbs    = patch%srcLbound
  align  = patch%align
  bctype = patch%bcType

! mapping between patches

  l1srcdir = 1
  IF (patch%srcL1beg > patch%srcL1end) THEN
    l1srcdir = -1
  ELSE IF (patch%srcL1beg == patch%srcL1end) THEN
    IF (lbs==1 .OR. lbs==2) THEN
      v1(:) = xyzsrc(:,indijk(ibegsrc,jendsrc,kbegsrc,inoffsrc,ijnoffsrc)) - &
              xyzsrc(:,indijk(ibegsrc,jbegsrc,kbegsrc,inoffsrc,ijnoffsrc))
    ELSE IF (lbs==3 .OR. lbs==4) THEN
      v1(:) = xyzsrc(:,indijk(ibegsrc,jbegsrc,kendsrc,inoffsrc,ijnoffsrc)) - &
              xyzsrc(:,indijk(ibegsrc,jbegsrc,kbegsrc,inoffsrc,ijnoffsrc))
    ELSE IF (lbs==5 .OR. lbs==6) THEN
      v1(:) = xyzsrc(:,indijk(iendsrc,jbegsrc,kbegsrc,inoffsrc,ijnoffsrc)) - &
              xyzsrc(:,indijk(ibegsrc,jbegsrc,kbegsrc,inoffsrc,ijnoffsrc))
    ENDIF
    IF (lb==1 .OR. lb==2) THEN
      IF (align) THEN
        v2(:) = xyz(:,indijk(ibeg,jend,kbeg,inoff,ijnoff)) - &
                xyz(:,indijk(ibeg,jbeg,kbeg,inoff,ijnoff))
      ELSE
        v2(:) = xyz(:,indijk(ibeg,jbeg,kend,inoff,ijnoff)) - &
                xyz(:,indijk(ibeg,jbeg,kbeg,inoff,ijnoff))
      ENDIF
    ELSE IF (lb==3 .OR. lb==4) THEN
      IF (align) THEN
        v2(:) = xyz(:,indijk(ibeg,jbeg,kend,inoff,ijnoff)) - &
                xyz(:,indijk(ibeg,jbeg,kbeg,inoff,ijnoff))
      ELSE
        v2(:) = xyz(:,indijk(iend,jbeg,kbeg,inoff,ijnoff)) - &
                xyz(:,indijk(ibeg,jbeg,kbeg,inoff,ijnoff))
      ENDIF
    ELSE IF (lb==5 .OR. lb==6) THEN
      IF (align) THEN
        v2(:) = xyz(:,indijk(iend,jbeg,kbeg,inoff,ijnoff)) - &
                xyz(:,indijk(ibeg,jbeg,kbeg,inoff,ijnoff))
      ELSE
        v2(:) = xyz(:,indijk(ibeg,jend,kbeg,inoff,ijnoff)) - &
                xyz(:,indijk(ibeg,jbeg,kbeg,inoff,ijnoff))
      ENDIF
    ENDIF
    IF (dot_product(v1,v2) < 0._rfreal) l1srcdir = -1
  ENDIF

  l2srcdir =  1
  IF (patch%srcL2beg > patch%srcL2end) THEN
    l2srcdir = -1
  ELSE IF (patch%srcL2beg == patch%srcL2end) THEN
    IF (lbs==1 .OR. lbs==2) THEN
      v1(:) = xyzsrc(:,indijk(ibegsrc,jbegsrc,kendsrc,inoffsrc,ijnoffsrc)) - &
              xyzsrc(:,indijk(ibegsrc,jbegsrc,kbegsrc,inoffsrc,ijnoffsrc))
    ELSE IF (lbs==3 .OR. lbs==4) THEN
      v1(:) = xyzsrc(:,indijk(iendsrc,jbegsrc,kbegsrc,inoffsrc,ijnoffsrc)) - &
              xyzsrc(:,indijk(ibegsrc,jbegsrc,kbegsrc,inoffsrc,ijnoffsrc))
    ELSE IF (lbs==5 .OR. lbs==6) THEN
      v1(:) = xyzsrc(:,indijk(ibegsrc,jendsrc,kbegsrc,inoffsrc,ijnoffsrc)) - &
              xyzsrc(:,indijk(ibegsrc,jbegsrc,kbegsrc,inoffsrc,ijnoffsrc))
    ENDIF
    IF (lb==1 .OR. lb==2) THEN
      IF (align) THEN
        v2(:) = xyz(:,indijk(ibeg,jbeg,kend,inoff,ijnoff)) - &
                xyz(:,indijk(ibeg,jbeg,kbeg,inoff,ijnoff))
      ELSE
        v2(:) = xyz(:,indijk(ibeg,jend,kbeg,inoff,ijnoff)) - &
                xyz(:,indijk(ibeg,jbeg,kbeg,inoff,ijnoff))
      ENDIF
    ELSE IF (lb==3 .OR. lb==4) THEN
      IF (align) THEN
        v2(:) = xyz(:,indijk(iend,jbeg,kbeg,inoff,ijnoff)) - &
                xyz(:,indijk(ibeg,jbeg,kbeg,inoff,ijnoff))
      ELSE
        v2(:) = xyz(:,indijk(ibeg,jbeg,kend,inoff,ijnoff)) - &
                xyz(:,indijk(ibeg,jbeg,kbeg,inoff,ijnoff))
      ENDIF
    ELSE IF (lb==5 .OR. lb==6) THEN
      IF (align) THEN
        v2(:) = xyz(:,indijk(ibeg,jend,kbeg,inoff,ijnoff)) - &
                xyz(:,indijk(ibeg,jbeg,kbeg,inoff,ijnoff))
      ELSE
        v2(:) = xyz(:,indijk(iend,jbeg,kbeg,inoff,ijnoff)) - &
                xyz(:,indijk(ibeg,jbeg,kbeg,inoff,ijnoff))
      ENDIF
    ENDIF
    IF (dot_product(v1,v2) < 0._rfreal) l2srcdir = -1
  ENDIF

  ibegsrc = ibegsrc + idirsrc    ! shift by one node into the interior
  iendsrc = iendsrc + idirsrc    ! (otherwise would start at the boundary)
  jbegsrc = jbegsrc + jdirsrc
  jendsrc = jendsrc + jdirsrc
  kbegsrc = kbegsrc + kdirsrc
  kendsrc = kendsrc + kdirsrc

  CALL rflo_getpatchmapping( lb,lbs,l1srcdir,l2srcdir,align, &
                             idir,jdir,kdir,idirsrc,jdirsrc,kdirsrc, &
                             ibeg,iend,jbeg,jend,kbeg,kend, &
                             ibegsrc,iendsrc,jbegsrc,jendsrc,kbegsrc,kendsrc, &
                             mapmat )

! inter-region boundary or translational periodicity

  IF ((bctype>=bc_regionconf .AND. bctype<=bc_regionconf+bc_range) .OR. &
      (bctype>=bc_tra_peri   .AND. bctype<=bc_tra_peri  +bc_range)) THEN
    DO k=kbeg,kend
      DO j=jbeg,jend
        DO i=ibeg,iend
          ijkn    = indijk(i,j,k,inoff,ijnoff)
          ijknsrc = indijkmap(i,j,k,mapmat,inoffsrc,ijnoffsrc)
          IF (average) THEN
            IF (abs(dnodesrc(xcoord,ijknsrc)-dold(xcoord,ijkn))<1.e-30_rfreal &
              .OR. abs(dnode(xcoord,ijkn)-dold(xcoord,ijkn))<1.e-30_rfreal) THEN
              dnode(xcoord,ijkn) = dold(xcoord,ijkn)
            ELSE
              dnode(xcoord,ijkn) = 0.5_rfreal*(dnode(xcoord,ijkn)+ &
                                               dnodesrc(xcoord,ijknsrc))
              dnodesrc(xcoord,ijknsrc) = dnode(xcoord,ijkn)
            ENDIF
            IF (abs(dnodesrc(ycoord,ijknsrc)-dold(ycoord,ijkn))<1.e-30_rfreal &
              .OR. abs(dnode(ycoord,ijkn)-dold(ycoord,ijkn))<1.e-30_rfreal) THEN
              dnode(ycoord,ijkn) = dold(ycoord,ijkn)
            ELSE
              dnode(ycoord,ijkn) = 0.5_rfreal*(dnode(ycoord,ijkn)+ &
                                               dnodesrc(ycoord,ijknsrc))
              dnodesrc(ycoord,ijknsrc) = dnode(ycoord,ijkn)
            ENDIF
            IF (abs(dnodesrc(zcoord,ijknsrc)-dold(zcoord,ijkn))<1.e-30_rfreal &
              .OR. abs(dnode(zcoord,ijkn)-dold(zcoord,ijkn))<1.e-30_rfreal) THEN
              dnode(zcoord,ijkn) = dold(zcoord,ijkn)
            ELSE
              dnode(zcoord,ijkn) = 0.5_rfreal*(dnode(zcoord,ijkn)+ &
                                               dnodesrc(zcoord,ijknsrc))
              dnodesrc(zcoord,ijknsrc) = dnode(zcoord,ijkn)
            ENDIF
          ELSE    ! no average
            IF (abs(dnodesrc(xcoord,ijknsrc)) > abs(dnode(xcoord,ijkn))) THEN
              region%levels(1)%grid%boundMoved(lb) = .true.
              dnode(xcoord,ijkn) = dnodesrc(xcoord,ijknsrc)
            ENDIF
            IF (abs(dnodesrc(ycoord,ijknsrc)) > abs(dnode(ycoord,ijkn))) THEN
              region%levels(1)%grid%boundMoved(lb) = .true.
              dnode(ycoord,ijkn) = dnodesrc(ycoord,ijknsrc)
            ENDIF
            IF (abs(dnodesrc(zcoord,ijknsrc)) > abs(dnode(zcoord,ijkn))) THEN
              region%levels(1)%grid%boundMoved(lb) = .true.
              dnode(zcoord,ijkn) = dnodesrc(zcoord,ijknsrc)
            ENDIF
          ENDIF
        ENDDO  ! i
      ENDDO    ! j
    ENDDO      ! k

! rotational periodicity (around x-axis)

  ELSE IF (bctype>=bc_rot_peri .AND. bctype<=bc_rot_peri+bc_range) THEN
    cosa = cos(patch%periodAngle)
    sina = sin(patch%periodAngle)
    DO k=kbeg,kend
      DO j=jbeg,jend
        DO i=ibeg,iend
          ijkn    = indijk(i,j,k,inoff,ijnoff)
          ijknsrc = indijkmap(i,j,k,mapmat,inoffsrc,ijnoffsrc)
          dy      = cosa*dnodesrc(ycoord,ijknsrc) - &
                    sina*dnodesrc(zcoord,ijknsrc)
          dz      = sina*dnodesrc(ycoord,ijknsrc) + &
                    cosa*dnodesrc(zcoord,ijknsrc)
          IF (average) THEN
            dnode(xcoord,ijkn) = dold(xcoord,ijkn)  ! no extra movement here
            dnode(ycoord,ijkn) = dold(ycoord,ijkn)
            dnode(zcoord,ijkn) = dold(zcoord,ijkn)
          ELSE
            IF (abs(dnodesrc(xcoord,ijknsrc)) > abs(dnode(xcoord,ijkn))) THEN
              region%levels(1)%grid%boundMoved(lb) = .true.
              dnode(xcoord,ijkn) = dnodesrc(xcoord,ijknsrc)
            ENDIF
            IF (abs(dy) > abs(dnode(ycoord,ijkn))) THEN
              region%levels(1)%grid%boundMoved(lb) = .true.
              dnode(ycoord,ijkn) = dy
            ENDIF
            IF (abs(dz) > abs(dnode(zcoord,ijkn))) THEN
              region%levels(1)%grid%boundMoved(lb) = .true.
              dnode(zcoord,ijkn) = dz
            ENDIF
          ENDIF
        ENDDO  ! i
      ENDDO    ! j
    ENDDO      ! k

  ENDIF

! finalize

  CALL deregisterfunction( region%global )

END SUBROUTINE rflo_exchangednodecopy

!******************************************************************************
!
! RCS Revision history:
!
! $Log: RFLO_ExchangeDnodeCopy.F90,v $
! Revision 1.3  2008/12/06 08:44:06  mtcampbe
! Updated license.
!
! Revision 1.2  2008/11/19 22:17:20  mtcampbe
! Added Illinois Open Source License/Copyright
!
! Revision 1.1  2004/11/29 21:25:16  wasistho
! lower to upper case
!
! Revision 1.9  2003/11/20 16:40:34  mdbrandy
! Backing out RocfluidMP changes from 11-17-03
!
! Revision 1.6  2003/08/25 21:51:23  jblazek
! Full version of global grid motion scheme.
!
! Revision 1.5  2003/08/11 21:51:17  jblazek
! Added basic global grid smoothing scheme.
!
! Revision 1.4  2003/05/15 02:57:01  jblazek
! Inlined index function.
!
! Revision 1.3  2003/05/06 20:05:38  jblazek
! Corrected bug in grid motion (corner "averaging").
!
! Revision 1.2  2003/03/17 23:48:47  jblazek
! Fixed bug in exchange of node displacements.
!
! Revision 1.1  2003/03/14 22:05:10  jblazek
! Improved mesh motion algorithm - node movement exchaged between blocks.
!
!******************************************************************************