RFLO_C2fAvgCoeffsPatch.F90

Go to the documentation of this file.

! *********************************************************************
! * Rocstar Simulation Suite                                          *
! * Copyright@2015, Illinois Rocstar LLC. All rights reserved.        *
! *                                                                   *
! * Illinois Rocstar LLC                                              *
! * Champaign, IL                                                     *
! * www.illinoisrocstar.com                                           *
! * sales@illinoisrocstar.com                                         *
! *                                                                   *
! * License: See LICENSE file in top level of distribution package or *
! * http://opensource.org/licenses/NCSA                               *
! *********************************************************************
! *********************************************************************
! * THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND,   *
! * EXPRESS OR IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES   *
! * OF MERCHANTABILITY, FITNESS FOR A PARTICULAR PURPOSE AND          *
! * NONINFRINGEMENT.  IN NO EVENT SHALL THE CONTRIBUTORS OR           *
! * COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER       *
! * LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE,   *
! * Arising FROM, OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE    *
! * USE OR OTHER DEALINGS WITH THE SOFTWARE.                          *
! *********************************************************************
!******************************************************************************
!
! Purpose: Construct averaging coeffients at patches of physical and symmetry
!          boundaries
!
! Description: For symmetry and physical bc with linear dummy extrapolation
!              the averaging coefficients are half-half, while for physical
!              bc with constant dummy extrapolation, they are one-zero.
!
! Input: region        = info of current region data
!        patch         = current patch data
!  
! Output: Averaging coefficients c2fCoI, c2fCoJ, c2fCoK at boundary patches. 
!
! Notes: Mother routine = RFLO_C2fAvgCoeffs.
!
!******************************************************************************
!
! $Id: RFLO_C2fAvgCoeffsPatch.F90,v 1.4 2008/12/06 08:44:26 mtcampbe Exp $
!
! Copyright: (c) 2001 by the University of Illinois
!
!******************************************************************************

SUBROUTINE rflo_c2favgcoeffspatch( region,patch )

  USE moddatatypes
  USE modbndpatch, ONLY   : t_patch
  USE moddatastruct, ONLY : t_region
  USE modglobal, ONLY     : t_global
  USE modinterfaces, ONLY : rflo_getpatchindices,rflo_getpatchdirection, &
                            rflo_getnodeoffset
  USE moderror
  USE modparameters
  IMPLICIT NONE

#include "Indexing.h"

! ... parameters
  TYPE(t_region) :: region
  TYPE(t_patch)  :: patch

! ... loop variables
  INTEGER :: i, j, k 

! ... local variables
  TYPE(t_global), POINTER :: global

  INTEGER :: ilev, lbound, bctype
  INTEGER :: ibeg, iend, jbeg, jend, kbeg, kend
  INTEGER :: inode, jnode, knode, idir, jdir, kdir, coindx(2) 
  INTEGER :: inoff, ijnoff, ijkn
  INTEGER :: iextrap_slipw,iextrap_inject

  REAL(RFREAL), POINTER :: avgco(:,:)

!******************************************************************************

  global => region%global
  CALL registerfunction( global,'RFLO_C2fAvgCoeffsPatch',&
  'RFLO_C2fAvgCoeffsPatch.F90' )

! get dimensions and pointers-------------------------------------------------

  ilev   = region%currLevel
  lbound = patch%lbound
  bctype = patch%bcType

  CALL rflo_getpatchindices( region,patch,ilev,ibeg,iend,jbeg,jend,kbeg,kend )
  CALL rflo_getpatchdirection( patch,idir,jdir,kdir )
  CALL rflo_getnodeoffset( region,ilev,inoff,ijnoff )

  inode = 0
  jnode = 0
  knode = 0
  coindx(1) = 1
  coindx(2) = 2
  IF( lbound==2 .OR. lbound==4 .OR. lbound==6 ) THEN
    inode = -idir
    jnode = -jdir
    knode = -kdir
    coindx(1) = 2
    coindx(2) = 1
  ENDIF

  IF (lbound==1 .OR. lbound==2) THEN
    avgco => region%levels(ilev)%grid%c2fCoI
  ELSE IF (lbound==3 .OR. lbound==4) THEN
    avgco => region%levels(ilev)%grid%c2fCoJ
  ELSE IF (lbound==5 .OR. lbound==6) THEN
    avgco => region%levels(ilev)%grid%c2fCoK
  ENDIF

  IF (bctype>=bc_slipwall .AND. bctype<=bc_slipwall+bc_range) &
     iextrap_slipw  = patch%mixt%switches(bcswi_slipw_extrap)
  IF (bctype>=bc_injection .AND. bctype<=bc_injection+bc_range) &
     iextrap_inject = patch%mixt%switches(bcswi_inject_extrap)

  IF ((bctype>=bc_slipwall .AND. bctype<=bc_slipwall+bc_range &
                           .AND. iextrap_slipw==extrapol_linear) .OR. &
      (bctype>=bc_noslipwall .AND. bctype<=bc_noslipwall+bc_range) .OR. &
      (bctype>=bc_injection .AND. bctype<=bc_injection+bc_range &
                            .AND. iextrap_inject==extrapol_linear) .OR. &
      (bctype>=bc_inflow .AND. bctype<=bc_inflow+bc_range) .OR. &
      (bctype>=bc_outflow .AND. bctype<=bc_outflow+bc_range) .OR. &
      (bctype>=bc_farfield .AND. bctype<=bc_farfield+bc_range) .OR. &
      (bctype>=bc_symmetry .AND. bctype<=bc_symmetry+bc_range)) THEN

    CALL avgcopatchlinear

  ELSE IF ((bctype>=bc_slipwall .AND. bctype<=bc_slipwall+bc_range &
                                .AND. iextrap_slipw==extrapol_const ) .OR. &
           (bctype>=bc_injection .AND. bctype<=bc_injection+bc_range &
                                 .AND. iextrap_inject==extrapol_const )) THEN

    CALL avgcopatchconstant

  ELSE IF (bctype>=bc_regionint .AND. bctype<=bc_regionint+bc_range) THEN

  ELSE IF (bctype>=bc_regnonconf .AND. bctype<=bc_regnonconf+bc_range) THEN

! everything else 

  ELSE

  ENDIF

! finalize --------------------------------------------------------------------

  CALL deregisterfunction( global )

! ==============================================================================
! completion subroutines for linear and constant extrap. case
! ==============================================================================

CONTAINS

  SUBROUTINE avgcopatchlinear

! define averaging coefficient at patch with linearly extrapolated dummies

    DO k=kbeg,kend
      DO j=jbeg,jend
        DO i=ibeg,iend

          ijkn  = indijk(i+inode  ,j+jnode  ,k+knode  ,inoff,ijnoff)

          avgco(coindx(2),ijkn) = 0.5_rfreal
          avgco(coindx(1),ijkn) = 0.5_rfreal

        ENDDO   ! i
      ENDDO     ! j
    ENDDO       ! k

  END SUBROUTINE avgcopatchlinear

! ##############################################################################

  SUBROUTINE avgcopatchconstant

! define averaging coefficient at patch with linearly extrapolated dummies

    DO k=kbeg,kend
      DO j=jbeg,jend
        DO i=ibeg,iend

          ijkn  = indijk(i+inode  ,j+jnode  ,k+knode  ,inoff,ijnoff)

          avgco(coindx(2),ijkn) = 0._rfreal
          avgco(coindx(1),ijkn) = 1._rfreal

        ENDDO   ! i
      ENDDO     ! j
    ENDDO       ! k

  END SUBROUTINE avgcopatchconstant

END SUBROUTINE rflo_c2favgcoeffspatch

!******************************************************************************
!
! RCS Revision history:
!
! $Log: RFLO_C2fAvgCoeffsPatch.F90,v $
! Revision 1.4  2008/12/06 08:44:26  mtcampbe
! Updated license.
!
! Revision 1.3  2008/11/19 22:17:37  mtcampbe
! Added Illinois Open Source License/Copyright
!
! Revision 1.2  2006/08/19 15:39:26  mparmar
! Renamed patch variables
!
! Revision 1.1  2004/11/29 20:51:38  wasistho
! lower to upper case
!
! Revision 1.3  2004/08/03 00:51:51  wasistho
! changed avgCo to c2fCo in the description
!
! Revision 1.2  2004/08/02 19:33:02  wasistho
! changed grid%avgCo to grid%c2fCo
!
! Revision 1.1  2004/07/30 17:30:31  wasistho
! initial import routines starting with RFLO_c2fAvg...
!
!
!
!******************************************************************************