RFLO_CopyEdgeFaceParal.F90

Go to the documentation of this file.

! *********************************************************************
! * Rocstar Simulation Suite                                          *
! * Copyright@2015, Illinois Rocstar LLC. All rights reserved.        *
! *                                                                   *
! * Illinois Rocstar LLC                                              *
! * Champaign, IL                                                     *
! * www.illinoisrocstar.com                                           *
! * sales@illinoisrocstar.com                                         *
! *                                                                   *
! * License: See LICENSE file in top level of distribution package or *
! * http://opensource.org/licenses/NCSA                               *
! *********************************************************************
! *********************************************************************
! * THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND,   *
! * EXPRESS OR IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES   *
! * OF MERCHANTABILITY, FITNESS FOR A PARTICULAR PURPOSE AND          *
! * NONINFRINGEMENT.  IN NO EVENT SHALL THE CONTRIBUTORS OR           *
! * COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER       *
! * LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE,   *
! * Arising FROM, OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE    *
! * USE OR OTHER DEALINGS WITH THE SOFTWARE.                          *
! *********************************************************************
!******************************************************************************
!
! Purpose: set values in edge and corner faces of a region
!
! Description: - every edge has 2 sides of dummy faces at which the values to 
!                be copied are known from previous treatments 
!              - face values at edges and corners are then obtaine from 
!                averaging of two known values at each side boundary
!              - face variables set in edges and corners are those whose faces 
!                PARALLEL/ALIGN with faces of the reference values 
!
! Input: region = region data.
!        iFBeg  = begin index of input face variables
!        iFEnd  = end index of input face variables
!        fvari,fvarj,fvark = input variables at face i, j and k
!
! Output: new values of face variables at edges and corners
!
! Notes: - corners are not treated separately but as elongation of edges;
!          hence only eight such extended edges are treated covering corners
!          at their ends
!        - this routine makes use of averaging routine AverageVecVar
!          in libfloflu
!
!******************************************************************************
!
! $Id: RFLO_CopyEdgeFaceParal.F90,v 1.3 2008/12/06 08:44:06 mtcampbe Exp $
!
! Copyright: (c) 2001 by the University of Illinois
!
!******************************************************************************

SUBROUTINE rflo_copyedgefaceparal( region,iFBeg,iFEnd,fvari,fvarj,fvark )

  USE moddatatypes
  USE moddatastruct, ONLY : t_region
  USE modinterfaces, ONLY : averagevecvar, rflo_getdimensdummynodes, &
                            rflo_getdimensphysnodes, rflo_getnodeoffset
  USE moderror
  IMPLICIT NONE

#include "Indexing.h"

! ... parameters
  TYPE(t_region) :: region
  INTEGER        :: ifbeg,ifend
  REAL(RFREAL), POINTER :: fvari(:,:),fvarj(:,:),fvark(:,:)

! ... loop variables
  INTEGER :: i, j, k

! ... local variables
  INTEGER :: idnbeg, idnend, jdnbeg, jdnend, kdnbeg, kdnend
  INTEGER :: ipnbeg, ipnend, jpnbeg, jpnend, kpnbeg, kpnend
  INTEGER :: ilev, inoff, ijnoff, ijkd, ijkn1, ijkn2

!******************************************************************************

  CALL registerfunction( region%global,'RFLO_CopyEdgeFaceParal',&
  'RFLO_CopyEdgeFaceParal.F90' )

! get dimensions and pointers -------------------------------------------------

  ilev = region%currLevel

  CALL rflo_getdimensdummynodes( region,ilev,idnbeg,idnend, &
                                 jdnbeg,jdnend,kdnbeg,kdnend )
  CALL rflo_getdimensphysnodes( region,ilev,ipnbeg,ipnend, &
                                jpnbeg,jpnend,kpnbeg,kpnend )
  CALL rflo_getnodeoffset( region,ilev,inoff,ijnoff )

! edges 9, 10, 11, 12 ---------------------------------------------------------

  DO i=idnbeg,idnend
    DO j=jpnbeg-1,jdnbeg,-1         ! edges 9, 10
      DO k=kpnbeg-1,kdnbeg,-1
        ijkd  = indijk(i,j     ,k     ,inoff,ijnoff)
        ijkn1 = indijk(i,jpnbeg,k     ,inoff,ijnoff)
        ijkn2 = indijk(i,j     ,kpnbeg,inoff,ijnoff)
        CALL averagevecvar( ijkd,ijkn1,ijkn2,ifbeg,ifend,fvari)
      ENDDO
      DO k=kpnend,kdnend
        ijkd  = indijk(i,j     ,k       ,inoff,ijnoff)
        ijkn1 = indijk(i,jpnbeg,k       ,inoff,ijnoff)
        ijkn2 = indijk(i,j     ,kpnend-1,inoff,ijnoff)
        CALL averagevecvar( ijkd,ijkn1,ijkn2,ifbeg,ifend,fvari)
      ENDDO
    ENDDO

    DO j=jpnend,jdnend           ! edges 11, 12
      DO k=kpnbeg-1,kdnbeg,-1
        ijkd  = indijk(i,j       ,k     ,inoff,ijnoff)
        ijkn1 = indijk(i,jpnend-1,k     ,inoff,ijnoff)
        ijkn2 = indijk(i,j       ,kpnbeg,inoff,ijnoff)
        CALL averagevecvar( ijkd,ijkn1,ijkn2,ifbeg,ifend,fvari)
      ENDDO
      DO k=kpnend,kdnend
        ijkd  = indijk(i,j       ,k       ,inoff,ijnoff)
        ijkn1 = indijk(i,jpnend-1,k       ,inoff,ijnoff)
        ijkn2 = indijk(i,j       ,kpnend-1,inoff,ijnoff)
        CALL averagevecvar( ijkd,ijkn1,ijkn2,ifbeg,ifend,fvari)
      ENDDO
    ENDDO
  ENDDO

! edges 2, 4, 6, 8 ------------------------------------------------------------

  DO j=jdnbeg,jdnend
    DO i=ipnbeg-1,idnbeg,-1        ! edges 2, 4
      DO k=kpnend,kdnend
        ijkd  = indijk(i     ,j,k       ,inoff,ijnoff)
        ijkn1 = indijk(ipnbeg,j,k       ,inoff,ijnoff)
        ijkn2 = indijk(i     ,j,kpnend-1,inoff,ijnoff)
        CALL averagevecvar( ijkd,ijkn1,ijkn2,ifbeg,ifend,fvarj)
      ENDDO
      DO k=kpnbeg-1,kdnbeg,-1
        ijkd  = indijk(i     ,j,k     ,inoff,ijnoff)
        ijkn1 = indijk(ipnbeg,j,k     ,inoff,ijnoff)
        ijkn2 = indijk(i     ,j,kpnbeg,inoff,ijnoff)
        CALL averagevecvar( ijkd,ijkn1,ijkn2,ifbeg,ifend,fvarj)
      ENDDO
    ENDDO

    DO i=ipnend,idnend           ! edges 6, 8
      DO k=kpnend,kdnend
        ijkd  = indijk(i       ,j,k       ,inoff,ijnoff)
        ijkn1 = indijk(ipnend-1,j,k       ,inoff,ijnoff)
        ijkn2 = indijk(i       ,j,kpnend-1,inoff,ijnoff)
        CALL averagevecvar( ijkd,ijkn1,ijkn2,ifbeg,ifend,fvarj)
      ENDDO
      DO k=kpnbeg-1,kdnbeg,-1
        ijkd  = indijk(i     ,j,k     ,inoff,ijnoff)
        ijkn1 = indijk(ipnend-1,j,k     ,inoff,ijnoff)
        ijkn2 = indijk(i     ,j,kpnbeg,inoff,ijnoff)
        CALL averagevecvar( ijkd,ijkn1,ijkn2,ifbeg,ifend,fvarj)
      ENDDO
    ENDDO
  ENDDO

! edges 1, 3, 5, 7 ------------------------------------------------------------

  DO k=kdnbeg,kdnend
    DO i=ipnbeg-1,idnbeg,-1        ! edges 1, 3
      DO j=jpnbeg-1,jdnbeg,-1
        ijkd  = indijk(i     ,j     ,k,inoff,ijnoff)
        ijkn1 = indijk(ipnbeg,j     ,k,inoff,ijnoff)
        ijkn2 = indijk(i     ,jpnbeg,k,inoff,ijnoff)
        CALL averagevecvar( ijkd,ijkn1,ijkn2,ifbeg,ifend,fvark)
      ENDDO
      DO j=jpnend,jdnend
        ijkd  = indijk(i     ,j     ,k,inoff,ijnoff)
        ijkn1 = indijk(ipnbeg,j     ,k,inoff,ijnoff)
        ijkn2 = indijk(i     ,jpnend-1,k,inoff,ijnoff)
        CALL averagevecvar( ijkd,ijkn1,ijkn2,ifbeg,ifend,fvark)
      ENDDO
    ENDDO

    DO i=ipnend,idnend           ! edges 5, 7
      DO j=jpnbeg-1,jdnbeg,-1
        ijkd  = indijk(i       ,j     ,k,inoff,ijnoff)
        ijkn1 = indijk(ipnend-1,j     ,k,inoff,ijnoff)
        ijkn2 = indijk(i       ,jpnbeg,k,inoff,ijnoff)
        CALL averagevecvar( ijkd,ijkn1,ijkn2,ifbeg,ifend,fvark)
      ENDDO
      DO j=jpnend,jdnend
        ijkd  = indijk(i       ,j     ,k,inoff,ijnoff)
        ijkn1 = indijk(ipnend-1,j     ,k,inoff,ijnoff)
        ijkn2 = indijk(i       ,jpnend-1,k,inoff,ijnoff)
        CALL averagevecvar( ijkd,ijkn1,ijkn2,ifbeg,ifend,fvark)
      ENDDO
    ENDDO
  ENDDO

! finalize --------------------------------------------------------------------

  CALL deregisterfunction( region%global )

END SUBROUTINE rflo_copyedgefaceparal

!******************************************************************************
!
! RCS Revision history:
!
! $Log: RFLO_CopyEdgeFaceParal.F90,v $
! Revision 1.3  2008/12/06 08:44:06  mtcampbe
! Updated license.
!
! Revision 1.2  2008/11/19 22:17:20  mtcampbe
! Added Illinois Open Source License/Copyright
!
! Revision 1.1  2004/11/29 21:25:16  wasistho
! lower to upper case
!
! Revision 1.6  2003/11/20 16:40:34  mdbrandy
! Backing out RocfluidMP changes from 11-17-03
!
! Revision 1.3  2003/05/15 02:57:01  jblazek
! Inlined index function.
!
! Revision 1.2  2002/09/05 17:40:19  jblazek
! Variable global moved into regions().
!
! Revision 1.1  2002/09/02 22:58:54  wasistho
! RFLO grad routines migrated from rocflo to libflo
!
! Revision 1.4  2002/07/30 02:43:27  wasistho
! AverageVecVar moved to libfloflu
!
! Revision 1.3  2002/07/22 22:59:11  jblazek
! Some more clean up.
!
! Revision 1.2  2002/07/19 23:45:12  wasistho
! made compliant with CODING RULE
!
! Revision 1.1  2002/05/21 02:05:34  wasistho
! add viscous terms
!
!******************************************************************************