TURB_floLesUniFiltFF.F90

Go to the documentation of this file.

! *********************************************************************
! * Rocstar Simulation Suite                                          *
! * Copyright@2015, Illinois Rocstar LLC. All rights reserved.        *
! *                                                                   *
! * Illinois Rocstar LLC                                              *
! * Champaign, IL                                                     *
! * www.illinoisrocstar.com                                           *
! * sales@illinoisrocstar.com                                         *
! *                                                                   *
! * License: See LICENSE file in top level of distribution package or *
! * http://opensource.org/licenses/NCSA                               *
! *********************************************************************
! *********************************************************************
! * THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND,   *
! * EXPRESS OR IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES   *
! * OF MERCHANTABILITY, FITNESS FOR A PARTICULAR PURPOSE AND          *
! * NONINFRINGEMENT.  IN NO EVENT SHALL THE CONTRIBUTORS OR           *
! * COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER       *
! * LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE,   *
! * Arising FROM, OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE    *
! * USE OR OTHER DEALINGS WITH THE SOFTWARE.                          *
! *********************************************************************
!******************************************************************************
!
! Purpose: Perform face to face uniform filtering.
!
! Description: We treat the filter-operation in three consequtive sweeps
!              corresponding to the three coordinate directions. We use the
!              composite trapezoidal rule. This can be applied directly if
!              ndel=even and leads to integration weights:(1/2,1,..,1,1/2)/ndel
!              i.e. weight 1/2 for the end-points and 1 for the inner points
!              on a uniform grid. If ndel=0 we do not filter at all and if
!              ndel=odd we filter the inner points as usual and use a linear
!              interpolation for the end-intervals. For the weights this
!              implies (1/8,6/8,1/8): ndel=1 and (1/8,7/8,1,..,1,7/8,1/8)/ndel
!              if ndel=odd and > 1. This has an obvious extension for
!              nonuniform grids.
!
! Input: region  = data of current region 
!        ijk     = ijk-face is being treated
!        nDel    = three components filter width parameter
!        idBeg   = begin variable index to be filtered
!        idEnd   = end variable index to be filtered
!        fVar    = face variable to be filtered
!
! Output: fbVar  = filtered face variable
!
! Notes: none.
!
!******************************************************************************
!
! $Id: TURB_floLesUniFiltFF.F90,v 1.4 2008/12/06 08:44:43 mtcampbe Exp $
!
! Copyright: (c) 2001 by the University of Illinois
!
!******************************************************************************

SUBROUTINE turb_flolesunifiltff( region,ijk,nDel,idBeg,idEnd,fVar,fbVar )

  USE moddatatypes
  USE moddatastruct, ONLY : t_region
  USE modglobal, ONLY     : t_global
  USE modinterfaces, ONLY : rflo_getdimensdummynodes, rflo_getnodeoffset
  USE turb_modinterfaces, ONLY : turb_flolesunifiltffi, &
                                 turb_flolesunifiltffj, &
                                 turb_flolesunifiltffk, turb_floextrapolfacevec
  USE modturbulence
  USE moderror
  USE modparameters
  USE turb_modparameters
  IMPLICIT NONE

#include "Indexing.h"

! ... parameters
  TYPE(t_region)        :: region
  INTEGER               :: ijk,ndel(diri:dirk),idbeg,idend
  REAL(RFREAL), POINTER :: fvar(:,:),fbvar(:,:)

! ... loop variables
  INTEGER :: i, j, k, l, ijkn

! ... local variables
  CHARACTER(CHRLEN)       :: rcsidentstring
  TYPE(t_global), POINTER :: global

  INTEGER           :: ibeg,iend,jbeg,jend,kbeg,kend
  INTEGER           :: idnbeg,idnend,jdnbeg,jdnend,kdnbeg,kdnend
  INTEGER           :: ilev,inoff,ijnoff,ibn,ien

  REAL(RFREAL)      :: fact1(filwidth_four), fact2(filwidth_four)
  REAL(RFREAL), POINTER :: wrkbar(:,:)

!******************************************************************************

  rcsidentstring = '$RCSfile: TURB_floLesUniFiltFF.F90,v $'

  global => region%global
  CALL registerfunction( global,'TURB_FloLesUniFiltFF',&
  'TURB_floLesUniFiltFF.F90' )

! get indices, parameters and pointers ----------------------------------------

  ilev  = region%currLevel
  CALL rflo_getdimensdummynodes( region,ilev,idnbeg,idnend, &
                                 jdnbeg,jdnend,kdnbeg,kdnend )
  CALL rflo_getnodeoffset( region,ilev,inoff,ijnoff )
  ibn = indijk(idnbeg,jdnbeg,kdnbeg,inoff,ijnoff)
  ien = indijk(idnend,jdnend,kdnend,inoff,ijnoff)

  ALLOCATE( wrkbar(idbeg:idend,ibn:ien) )

  fact1(filwidth_one)  = 0.125_rfreal
  fact2(filwidth_one)  = 0.75_rfreal
  fact1(filwidth_two)  = 0.25_rfreal
  fact2(filwidth_two)  = 0.50_rfreal
  fact1(filwidth_four) = 0.125_rfreal
  fact2(filwidth_four) = 0.25_rfreal

!------------------------------------------------------------------------
! we begin with integration over I-direction

  ibeg = idnbeg+1
  iend = idnend-1
  jbeg = jdnbeg
  jend = jdnend
  kbeg = kdnbeg
  kend = kdnend

  CALL turb_flolesunifiltffi( global,ibeg,iend,jbeg,jend,kbeg,kend,inoff, &
                              ijnoff,ndel,idbeg,idend,fact1,fact2,fvar,fbvar )

! extrapolate filtered variables to outers ijk-face layers

  CALL turb_floextrapolfacevec( region,diri,idbeg,idend,fbvar )

!------------------------------------------------------------------
! next, integrate over J-direction

  ibeg = idnbeg
  iend = idnend
  jbeg = jdnbeg+1
  jend = jdnend-1
  kbeg = kdnbeg
  kend = kdnend

  CALL turb_flolesunifiltffj( global,ibeg,iend,jbeg,jend,kbeg,kend,inoff, &
                            ijnoff,ndel,idbeg,idend,fact1,fact2,fbvar,wrkbar )

! extrapolate filtered variables to outerst ijk-face layers

  CALL turb_floextrapolfacevec( region,dirj,idbeg,idend,wrkbar )

!------------------------------------------------------------------
! finally, integrate over K-direction

  ibeg = idnbeg
  iend = idnend
  jbeg = jdnbeg
  jend = jdnend
  kbeg = kdnbeg+1
  kend = kdnend-1

  CALL turb_flolesunifiltffk( global,ibeg,iend,jbeg,jend,kbeg,kend,inoff, &
                            ijnoff,ndel,idbeg,idend,fact1,fact2,wrkbar,fbvar )

! extrapolate filtered variables to outerst ijk-face layers

  CALL turb_floextrapolfacevec( region,dirk,idbeg,idend,fbvar )

! deallocate temporary arrays

  DEALLOCATE( wrkbar )

! finalize --------------------------------------------------------------------

  CALL deregisterfunction( global )

END SUBROUTINE turb_flolesunifiltff

!******************************************************************************
!
! RCS Revision history:
!
! $Log: TURB_floLesUniFiltFF.F90,v $
! Revision 1.4  2008/12/06 08:44:43  mtcampbe
! Updated license.
!
! Revision 1.3  2008/11/19 22:17:56  mtcampbe
! Added Illinois Open Source License/Copyright
!
! Revision 1.2  2004/03/12 02:55:36  wasistho
! changed rocturb routine names
!
! Revision 1.1  2004/03/08 23:35:45  wasistho
! changed turb nomenclature
!
! Revision 1.2  2003/05/15 02:57:06  jblazek
! Inlined index function.
!
! Revision 1.1  2002/10/14 23:55:30  wasistho
! Install Rocturb
!
!******************************************************************************