TURB_floLesUniFiltFFI.F90

Go to the documentation of this file.

! *********************************************************************
! * Rocstar Simulation Suite                                          *
! * Copyright@2015, Illinois Rocstar LLC. All rights reserved.        *
! *                                                                   *
! * Illinois Rocstar LLC                                              *
! * Champaign, IL                                                     *
! * www.illinoisrocstar.com                                           *
! * sales@illinoisrocstar.com                                         *
! *                                                                   *
! * License: See LICENSE file in top level of distribution package or *
! * http://opensource.org/licenses/NCSA                               *
! *********************************************************************
! *********************************************************************
! * THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND,   *
! * EXPRESS OR IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES   *
! * OF MERCHANTABILITY, FITNESS FOR A PARTICULAR PURPOSE AND          *
! * NONINFRINGEMENT.  IN NO EVENT SHALL THE CONTRIBUTORS OR           *
! * COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER       *
! * LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE,   *
! * Arising FROM, OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE    *
! * USE OR OTHER DEALINGS WITH THE SOFTWARE.                          *
! *********************************************************************
!******************************************************************************
!
! Purpose: Perform face to face uniform filtering in I-direction.
!
! Description: The filtering is performed using fixed filter coefficients.
!              If filterwidth is zero in this direction the cell-variable is 
!              simply copied to the filtered cell-variable.
!
! Input: global  = global data, only used in register function 
!        i,j,kbeg, i,j,kend = node index boundaries
!        iNOff, ijNOff      = node Offset    
!        nDel    = three components filter width parameter
!        idBeg   = begin variable index to be filtered
!        idEnd   = end variable index to be filtered
!        fact1,2 = fixed filter coefficients for uniform grid
!        fVar    = face variable to be filtered
!
! Output: filtVar  = filtered face variable
!
! Notes: Mother routine = LesUniFiltFF.
!
!******************************************************************************
!
! $Id: TURB_floLesUniFiltFFI.F90,v 1.4 2008/12/06 08:44:44 mtcampbe Exp $
!
! Copyright: (c) 2001 by the University of Illinois
!
!******************************************************************************

SUBROUTINE turb_flolesunifiltffi( global,ibeg,iend,jbeg,jend,kbeg,kend,iNOff, &
                                  ijnoff,ndel,idbeg,idend,fact1,fact2,fvar, &
                                  filtvar )
  USE moddatatypes
  USE modglobal, ONLY : t_global
  USE modturbulence
  USE moderror
  USE turb_modparameters
  IMPLICIT NONE

#include "Indexing.h"

! ... parameters
  TYPE(t_global), POINTER :: global
  INTEGER               :: ibeg,iend,jbeg,jend,kbeg,kend,inoff,ijnoff
  INTEGER               :: ndel(diri:dirk),idbeg,idend
  REAL(RFREAL)          :: fact1(filwidth_four),fact2(filwidth_four)
  REAL(RFREAL), POINTER :: fvar(:,:),filtvar(:,:)

! ... loop variables
  INTEGER :: i, j, k, l, ijkn, ijknb, ijkne

! ... local variables
  CHARACTER(CHRLEN) :: rcsidentstring
  REAL(RFREAL)      :: tmpb(idbeg:idend),tmpe(idbeg:idend)

!******************************************************************************

  rcsidentstring = '$RCSfile: TURB_floLesUniFiltFFI.F90,v $'

  CALL registerfunction( global,'TURB_FloLesUniFiltFFI',&
  'TURB_floLesUniFiltFFI.F90' )

! integration over I-direction -----------------------------------------------

  IF (ndel(diri)==filwidth_zero) THEN

! - no filtering in I-direction is needed and we copy fVar into filtVar

    filtvar = fvar

  ELSEIF ((ndel(diri)==filwidth_one) .OR. &
          (ndel(diri)==filwidth_two)) THEN

    DO k=kbeg,kend
      DO j=jbeg,jend

! ----- perform integration

        DO i=ibeg,iend
          ijkn = indijk(i     ,j     ,k     ,inoff,ijnoff)
          DO l=idbeg,idend
            filtvar(l,ijkn)=fact1(ndel(diri))*(fvar(l,ijkn-1)+fvar(l,ijkn+1))+ &
                            fact2(ndel(diri))*fvar(l,ijkn)
          END DO ! l
        ENDDO    ! i
         
      ENDDO      ! j
    ENDDO        ! k

  ELSEIF (ndel(diri)==filwidth_four) THEN

    DO k=kbeg,kend
      DO j=jbeg,jend
  
! ----- perform integration

        DO i=ibeg+1,iend-1           
          ijkn = indijk(i     ,j     ,k     ,inoff,ijnoff)
          DO l=idbeg,idend
            filtvar(l,ijkn)=fact1(ndel(diri))*(fvar(l,ijkn-2)+fvar(l,ijkn+2))+ &
                            fact2(ndel(diri))*(fvar(l,ijkn+1)+fvar(l,ijkn)+ &
                                               fvar(l,ijkn-1))
          ENDDO ! l
        ENDDO   ! i
  
! ----- perform integration at the edges

        ijknb = indijk(ibeg  ,j     ,k     ,inoff,ijnoff)
        ijkne = indijk(iend  ,j     ,k     ,inoff,ijnoff)
        DO l=idbeg,idend
          tmpb(l) = 2._rfreal*fvar(l,ijknb-1)-fvar(l,ijknb)
          tmpe(l) = 2._rfreal*fvar(l,ijkne+1)-fvar(l,ijkne)
          filtvar(l,ijknb)=fact1(ndel(diri))*(tmpb(l)+fvar(l,ijknb+2))+ &
                           fact2(ndel(diri))*(fvar(l,ijknb+1)+fvar(l,ijknb)+ &
                                              fvar(l,ijknb-1))
          filtvar(l,ijkne)=fact1(ndel(diri))*(tmpe(l)+fvar(l,ijkne-2))+ &
                           fact2(ndel(diri))*(fvar(l,ijkne+1)+fvar(l,ijkne)+ &
                                              fvar(l,ijkne-1))
        ENDDO   ! l
      ENDDO     ! j
    ENDDO       ! k
  ENDIF         ! nDel

! finalize --------------------------------------------------------------------

  CALL deregisterfunction( global )

END SUBROUTINE turb_flolesunifiltffi

!******************************************************************************
!
! RCS Revision history:
!
! $Log: TURB_floLesUniFiltFFI.F90,v $
! Revision 1.4  2008/12/06 08:44:44  mtcampbe
! Updated license.
!
! Revision 1.3  2008/11/19 22:17:56  mtcampbe
! Added Illinois Open Source License/Copyright
!
! Revision 1.2  2004/03/12 02:55:36  wasistho
! changed rocturb routine names
!
! Revision 1.1  2004/03/08 23:35:45  wasistho
! changed turb nomenclature
!
! Revision 1.2  2003/05/15 02:57:06  jblazek
! Inlined index function.
!
! Revision 1.1  2002/10/14 23:55:30  wasistho
! Install Rocturb
!
!******************************************************************************