TURB_floExtrapolFaceVec.F90

Go to the documentation of this file.

! *********************************************************************
! * Rocstar Simulation Suite                                          *
! * Copyright@2015, Illinois Rocstar LLC. All rights reserved.        *
! *                                                                   *
! * Illinois Rocstar LLC                                              *
! * Champaign, IL                                                     *
! * www.illinoisrocstar.com                                           *
! * sales@illinoisrocstar.com                                         *
! *                                                                   *
! * License: See LICENSE file in top level of distribution package or *
! * http://opensource.org/licenses/NCSA                               *
! *********************************************************************
! *********************************************************************
! * THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND,   *
! * EXPRESS OR IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES   *
! * OF MERCHANTABILITY, FITNESS FOR A PARTICULAR PURPOSE AND          *
! * NONINFRINGEMENT.  IN NO EVENT SHALL THE CONTRIBUTORS OR           *
! * COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER       *
! * LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE,   *
! * Arising FROM, OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE    *
! * USE OR OTHER DEALINGS WITH THE SOFTWARE.                          *
! *********************************************************************
!******************************************************************************
!
! Purpose: Extrapolate face vector variable to outerst dummy faces.
!
! Description: The values are already available up to second outerst dummy faces.
!              Here the values are extrapolated to the outers dummy faces.
!
! Input: region  = data of current region
!        intDIR  = identifier for integration direction
!        idBeg,idEnd = begin and end variable index of the vector variable
!        fVec        = vector variable to be extrapolated
!
! Output: fVec = values of fVec at the remaining dummy cells are defined.
!
! Notes: This routine is used by LesUniFiltFF and LesGenFiltFF.
!
!******************************************************************************
!
! $Id: TURB_floExtrapolFaceVec.F90,v 1.4 2008/12/06 08:44:43 mtcampbe Exp $
!
! Copyright: (c) 2001 by the University of Illinois
!
!******************************************************************************

SUBROUTINE turb_floextrapolfacevec( region,intDIR,idBeg,idEnd,fVec )

  USE moddatatypes
  USE moddatastruct, ONLY : t_region
  USE modglobal, ONLY     : t_global
  USE modinterfaces, ONLY : rflo_getdimensdummynodes, rflo_getnodeoffset
  USE modturbulence
  USE moderror
  USE turb_modparameters
  IMPLICIT NONE

#include "Indexing.h"

! ... parameters
  TYPE(t_region)        :: region
  INTEGER               :: intdir,idbeg,idend
  REAL(RFREAL), POINTER :: fvec(:,:)

! ... loop variables
  INTEGER :: i, j, k, l, m, ijkn, ijkn0, ijkn1, ijkn2
  INTEGER :: indxn, indxn0, indxn1, indxn2

! ... local variables
  CHARACTER(CHRLEN)       :: rcsidentstring
  TYPE(t_global), POINTER :: global

  INTEGER           :: ibeg,iend,jbeg,jend,kbeg,kend
  INTEGER           :: idnbeg,idnend,jdnbeg,jdnend,kdnbeg,kdnend
  INTEGER           :: ilev,inoff,ijnoff,ndum,nadd,sign(2),indx(2)
  INTEGER, PARAMETER:: two=2

!******************************************************************************

  rcsidentstring = '$RCSfile: TURB_floExtrapolFaceVec.F90,v $'

  global => region%global
  CALL registerfunction( global,'TURB_FloExtrapolFaceVec',&
  'TURB_floExtrapolFaceVec.F90' )

! get indices ---------------------------------------------------------------

  sign(1)= 1
  sign(2)=-1
  ndum   = region%nDumCells
  nadd   = -ndum
  ilev   = region%currLevel

  CALL rflo_getdimensdummynodes( region,ilev,idnbeg,idnend, &
                            jdnbeg,jdnend,kdnbeg,kdnend )
  CALL rflo_getnodeoffset( region,ilev,inoff,ijnoff )

  ibeg = idnbeg
  iend = idnend
  jbeg = jdnbeg
  jend = jdnend
  kbeg = kdnbeg
  kend = kdnend

! extrapolation to outerst layers

  IF (intdir==diri) THEN
      indx(1)=ibeg
      indx(2)=iend
      DO m=1,2
        indxn2 = indx(m)-two*sign(m)*nadd
        indxn1 = indx(m)-sign(m)*nadd
        indxn  = indx(m)
        DO k=kbeg,kend
          DO j=jbeg,jend
            ijkn  = indijk(indxn   ,j   ,k   ,inoff,ijnoff)
            ijkn1 = ijkn + indxn1-indxn
            ijkn2 = ijkn + indxn2-indxn

            DO l=idbeg,idend
              fvec(l,ijkn)=2._rfreal*fvec(l,ijkn1)-fvec(l,ijkn2) 
            ENDDO   ! l
          ENDDO     ! j
        ENDDO       ! k
      ENDDO         ! m
  ELSEIF (intdir==dirj) THEN
      indx(1)=jbeg
      indx(2)=jend
      DO m=1,2
        indxn2 = indx(m)-two*sign(m)*nadd
        indxn1 = indx(m)-sign(m)*nadd
        indxn  = indx(m)
        DO k=kbeg,kend
          DO i=ibeg,iend
            ijkn  = indijk(i   ,indxn    ,k   ,inoff,ijnoff)
            ijkn1 = ijkn + (indxn1-indxn)*inoff
            ijkn2 = ijkn + (indxn2-indxn)*inoff

            DO l=idbeg,idend
              fvec(l,ijkn)=2._rfreal*fvec(l,ijkn1)-fvec(l,ijkn2) 
            ENDDO   ! l
          ENDDO     ! i
        ENDDO       ! k
      ENDDO         ! m
  ELSEIF (intdir==dirk) THEN
      indx(1)=kbeg
      indx(2)=kend
      DO m=1,2
        indxn2 = indx(m)-two*sign(m)*nadd
        indxn1 = indx(m)-sign(m)*nadd
        indxn  = indx(m)
        DO j=jbeg,jend
          DO i=ibeg,iend
            ijkn  = indijk(i   ,j   ,indxn     ,inoff,ijnoff)
            ijkn1 = ijkn + (indxn1-indxn)*ijnoff
            ijkn2 = ijkn + (indxn2-indxn)*ijnoff

            DO l=idbeg,idend
              fvec(l,ijkn)=2._rfreal*fvec(l,ijkn1)-fvec(l,ijkn2) 
            ENDDO   ! l
          ENDDO     ! i
        ENDDO       ! j
      ENDDO         ! m
  ENDIF             ! intDir

! finalize --------------------------------------------------------------------

  CALL deregisterfunction( global )

END SUBROUTINE turb_floextrapolfacevec

!******************************************************************************
!
! RCS Revision history:
!
! $Log: TURB_floExtrapolFaceVec.F90,v $
! Revision 1.4  2008/12/06 08:44:43  mtcampbe
! Updated license.
!
! Revision 1.3  2008/11/19 22:17:55  mtcampbe
! Added Illinois Open Source License/Copyright
!
! Revision 1.2  2004/03/12 02:55:35  wasistho
! changed rocturb routine names
!
! Revision 1.1  2004/03/08 23:35:45  wasistho
! changed turb nomenclature
!
! Revision 1.2  2003/05/15 02:57:06  jblazek
! Inlined index function.
!
! Revision 1.1  2002/10/14 23:55:29  wasistho
! Install Rocturb
!
!
!******************************************************************************