TURB_floLesGenFiltFF.F90

Go to the documentation of this file.

! *********************************************************************
! * Rocstar Simulation Suite                                          *
! * Copyright@2015, Illinois Rocstar LLC. All rights reserved.        *
! *                                                                   *
! * Illinois Rocstar LLC                                              *
! * Champaign, IL                                                     *
! * www.illinoisrocstar.com                                           *
! * sales@illinoisrocstar.com                                         *
! *                                                                   *
! * License: See LICENSE file in top level of distribution package or *
! * http://opensource.org/licenses/NCSA                               *
! *********************************************************************
! *********************************************************************
! * THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND,   *
! * EXPRESS OR IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES   *
! * OF MERCHANTABILITY, FITNESS FOR A PARTICULAR PURPOSE AND          *
! * NONINFRINGEMENT.  IN NO EVENT SHALL THE CONTRIBUTORS OR           *
! * COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER       *
! * LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE,   *
! * Arising FROM, OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE    *
! * USE OR OTHER DEALINGS WITH THE SOFTWARE.                          *
! *********************************************************************
!******************************************************************************
!
! Purpose: Perform face to face filtering.
!
! Description: The filtering is performed in i, j and k direction, subsequently.
!              For each direction, distinction is made between homogeneous
!              and non-homogeneous direction. If the filtering direction is
!              homogeneous, uniform filtering is carried out, otherwise
!              nonuniform filtering.
!
! Input: region  = data of current region 
!        ijk     = ijk-face being treated
!        nDel    = three components filter width parameter
!        idBeg   = begin variable index to be filtered
!        idEnd   = end variable index to be filtered
!        fVar    = face variable to be filtered
!
! Output: fbVar  = filtered face variable
!
! Notes: This routine is only relevant if non-uniform filter is selected.
!
!******************************************************************************
!
! $Id: TURB_floLesGenFiltFF.F90,v 1.4 2008/12/06 08:44:43 mtcampbe Exp $
!
! Copyright: (c) 2001 by the University of Illinois
!
!******************************************************************************

SUBROUTINE turb_flolesgenfiltff( region,ijk,nDel,idBeg,idEnd,fVar,fbVar )

  USE moddatatypes
  USE moddatastruct, ONLY : t_region
  USE modglobal, ONLY     : t_global
  USE modinterfaces, ONLY : rflo_getdimensdummynodes, rflo_getnodeoffset
  USE turb_modinterfaces, ONLY : turb_flolesunifiltffi, &
                               turb_flolesunifiltffj, turb_flolesunifiltffk, &
                               turb_flolesgenfiltffi, turb_flolesgenfiltffj, &
                               turb_flolesgenfiltffk, turb_floextrapolfacevec
  USE modturbulence
  USE moderror
  USE modparameters
  USE turb_modparameters
  IMPLICIT NONE

#include "Indexing.h"

! ... parameters
  TYPE(t_region)        :: region
  INTEGER               :: ijk,ndel(diri:dirk),idbeg,idend
  REAL(RFREAL), POINTER :: fvar(:,:),fbvar(:,:)

! ... loop variables
  INTEGER :: i, j, k, l, ijkn

! ... local variables
  CHARACTER(CHRLEN)       :: rcsidentstring
  TYPE(t_global), POINTER :: global

  INTEGER           :: ibeg,iend,jbeg,jend,kbeg,kend
  INTEGER           :: idnbeg,idnend,jdnbeg,jdnend,kdnbeg,kdnend
  INTEGER           :: ilev,inoff,ijnoff,ibn,ien
  INTEGER           :: homdir(diri:dirk)

  REAL(RFREAL)      :: fact1(filwidth_four), fact2(filwidth_four)
  REAL(RFREAL), POINTER :: wrkbar(:,:)

!******************************************************************************

  rcsidentstring = '$RCSfile: TURB_floLesGenFiltFF.F90,v $'

  global => region%global
  CALL registerfunction( global,'TURB_FloLesGenFiltFF',&
  'TURB_floLesGenFiltFF.F90' )

! get indices, parameters and pointers ----------------------------------------

  ilev      = region%currLevel
  homdir(:) = region%turbInput%homDir(:)
  CALL rflo_getdimensdummynodes( region,ilev,idnbeg,idnend, &
                                 jdnbeg,jdnend,kdnbeg,kdnend )
  CALL rflo_getnodeoffset( region,ilev,inoff,ijnoff )
  ibn = indijk(idnbeg,jdnbeg,kdnbeg,inoff,ijnoff)
  ien = indijk(idnend,jdnend,kdnend,inoff,ijnoff)

  ALLOCATE( wrkbar(idbeg:idend,ibn:ien) )

  fact1(filwidth_one)  = 0.125_rfreal
  fact2(filwidth_one)  = 0.75_rfreal
  fact1(filwidth_two)  = 0.25_rfreal
  fact2(filwidth_two)  = 0.50_rfreal
  fact1(filwidth_four) = 0.125_rfreal
  fact2(filwidth_four) = 0.25_rfreal

!------------------------------------------------------------------------
! we begin with integration over I-direction

  ibeg = idnbeg+1
  iend = idnend-1
  jbeg = jdnbeg
  jend = jdnend
  kbeg = kdnbeg
  kend = kdnend

  IF (homdir(diri) /= off) THEN
    CALL turb_flolesunifiltffi( global,ibeg,iend,jbeg,jend,kbeg,kend,inoff, &
                             ijnoff,ndel,idbeg,idend,fact1,fact2,fvar,fbvar )
  ELSE
    CALL turb_flolesgenfiltffi( region,ijk,ibeg,iend,jbeg,jend,kbeg,kend, &
                             inoff,ijnoff,ndel,idbeg,idend,fvar,fbvar )
  ENDIF

! extrapolate filtered variables to outers ijk-face layers

  CALL turb_floextrapolfacevec( region,diri,idbeg,idend,fbvar )

!------------------------------------------------------------------
! next, integrate over J-direction

  ibeg = idnbeg
  iend = idnend
  jbeg = jdnbeg+1
  jend = jdnend-1
  kbeg = kdnbeg
  kend = kdnend

  IF (homdir(dirj) /= off) THEN
    CALL turb_flolesunifiltffj( global,ibeg,iend,jbeg,jend,kbeg,kend,inoff, &
                             ijnoff,ndel,idbeg,idend,fact1,fact2,fbvar,wrkbar )
  ELSE
    CALL turb_flolesgenfiltffj( region,ijk,ibeg,iend,jbeg,jend,kbeg,kend, &
                             inoff,ijnoff,ndel,idbeg,idend,fbvar,wrkbar )
  ENDIF

! extrapolate filtered variables to outerst ijk-face layers

  CALL turb_floextrapolfacevec( region,dirj,idbeg,idend,wrkbar )

!------------------------------------------------------------------
! finally, integrate over K-direction

  ibeg = idnbeg
  iend = idnend
  jbeg = jdnbeg
  jend = jdnend
  kbeg = kdnbeg+1
  kend = kdnend-1

  IF (homdir(dirk) /= off) THEN
    CALL turb_flolesunifiltffk( global,ibeg,iend,jbeg,jend,kbeg,kend,inoff, &
                             ijnoff,ndel,idbeg,idend,fact1,fact2,wrkbar,fbvar )
  ELSE
    CALL turb_flolesgenfiltffk( region,ijk,ibeg,iend,jbeg,jend,kbeg,kend, &
                             inoff,ijnoff,ndel,idbeg,idend,wrkbar,fbvar )
  ENDIF

! extrapolate filtered variables to outerst ijk-face layers

  CALL turb_floextrapolfacevec( region,dirk,idbeg,idend,fbvar )

! deallocate temporary arrays

  DEALLOCATE( wrkbar )

! finalize --------------------------------------------------------------------

  CALL deregisterfunction( global )

END SUBROUTINE turb_flolesgenfiltff

!******************************************************************************
!
! RCS Revision history:
!
! $Log: TURB_floLesGenFiltFF.F90,v $
! Revision 1.4  2008/12/06 08:44:43  mtcampbe
! Updated license.
!
! Revision 1.3  2008/11/19 22:17:55  mtcampbe
! Added Illinois Open Source License/Copyright
!
! Revision 1.2  2004/03/12 02:55:36  wasistho
! changed rocturb routine names
!
! Revision 1.1  2004/03/08 23:35:45  wasistho
! changed turb nomenclature
!
! Revision 1.2  2003/05/15 02:57:06  jblazek
! Inlined index function.
!
! Revision 1.1  2002/10/14 23:55:30  wasistho
! Install Rocturb
!
!
!******************************************************************************