TFLU_Main.F90

Go to the documentation of this file.

! *********************************************************************
! * Rocstar Simulation Suite                                          *
! * Copyright@2015, Illinois Rocstar LLC. All rights reserved.        *
! *                                                                   *
! * Illinois Rocstar LLC                                              *
! * Champaign, IL                                                     *
! * www.illinoisrocstar.com                                           *
! * sales@illinoisrocstar.com                                         *
! *                                                                   *
! * License: See LICENSE file in top level of distribution package or *
! * http://opensource.org/licenses/NCSA                               *
! *********************************************************************
! *********************************************************************
! * THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND,   *
! * EXPRESS OR IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES   *
! * OF MERCHANTABILITY, FITNESS FOR A PARTICULAR PURPOSE AND          *
! * NONINFRINGEMENT.  IN NO EVENT SHALL THE CONTRIBUTORS OR           *
! * COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER       *
! * LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE,   *
! * Arising FROM, OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE    *
! * USE OR OTHER DEALINGS WITH THE SOFTWARE.                          *
! *********************************************************************
!******************************************************************************
!
! Purpose: conversion of structured grid into its equivalent hex unstructured.
!
! Description: the conversion is from RFLO format to RFLU format.
!
! Input: case name (and verbosity) from screen input, others from .inp file.
!
! Output: [case name].grda_00000
!
! Notes: none
!
!******************************************************************************
!
! $Id: TFLU_Main.F90,v 1.6 2008/12/06 08:44:53 mtcampbe Exp $
!
! Copyright: (c) 2001 by the University of Illinois
!
!******************************************************************************

PROGRAM rocflo_toflu

  USE moddatatypes
  USE moderror
  USE moddatastruct, ONLY : t_region
  USE modglobal, ONLY     : t_global
  USE modgrid, ONLY       : t_grid
  USE tflu_modinterfaces, ONLY : buildversionstring, &
                               rflo_readregiontopology, readinputfile, &
                               printtofluinput, convertflo2flumesh, &
                               convertflo2flupatch, getbndverttype, &
                               correctnedges, writeflucellmap, &
                               writeflugrid, writefludimens
!  USE ModMPI
  USE modparameters
  IMPLICIT NONE

! ... loop variables
  INTEGER :: ireg, ilev

! ... local variables
  CHARACTER(CHRLEN) :: casename, verbosity, msg, versionstring, headerstring

  INTEGER :: ipc, jpc, kpc, ni, nj, nk, gridlevel
  INTEGER :: margin, versionwidth, errorflag
  INTEGER :: npatches, nverts, nhexs, nbfmax, nbnmax
  INTEGER, PARAMETER :: headerwidth = 53

  TYPE(t_global), POINTER :: global
  TYPE(t_grid) , POINTER  :: grid
  TYPE(t_region), POINTER :: regions(:)

!******************************************************************************

  ALLOCATE( global )

  global%nFunTree = 0
  CALL registerfunction( global,'ROCFLO_Init',&
  'TFLU_Main.F90' )

! initialize global parameters ------------------------------------------------

  global%verbLevel = verbose_none

  global%flowType    = flow_steady  ! stationary flow
  global%currentTime = 0._rfreal    ! no physical time set
  global%currentIter = 0            ! no iteration yet
  global%resInit     = 1._rfreal

  global%inDir  = './'              ! directory path
  global%outDir = './'

  global%nProcAlloc = 1
  global%myProcid   = 0             ! default process number (if not MPI)
  global%mpierr     = err_none
  global%error      = err_none

  global%startLevel  = 1 
  global%gridFormat  = format_ascii 
  global%solutFormat = format_ascii 

! print header ----------------------------------------------------------------

!#ifdef MPI
!  CALL MPI_Init( global%mpierr )
!  IF (global%mpierr /=0 ) CALL ErrorStop( global,ERR_MPI_TROUBLE,__LINE__ )
!#endif

  CALL buildversionstring( versionstring )

  headerstring = ' '
  versionwidth = len_trim(versionstring)
  margin       = (headerwidth-versionwidth)/2
  headerstring(margin+1:margin+versionwidth) = versionstring(1:versionwidth)
  headerstring(1:1) = '*'
  headerstring(headerwidth:headerwidth) = '*'

  WRITE(stdout,'(/,A)') solver_name//'  *****************************************************'
  WRITE(stdout,  '(A)') solver_name//'  *                                                   *'
  WRITE(stdout,  '(A)') solver_name//'  *          ROCFLO-MP: Conversion to ROCFLU          *'
  WRITE(stdout,  '(A)') solver_name//'  *          ===============================          *'
  WRITE(stdout,  '(A)') solver_name//'  *                                                   *'
  WRITE(stdout,  '(A)') solver_name//'  '//trim(headerstring)
  WRITE(stdout,  '(A)') solver_name//'  *    Copyright (c) by the University of Illinois    *'
  WRITE(stdout,  '(A)') solver_name//'  *                                                   *'
  WRITE(stdout,'(A,/)') solver_name//'  *****************************************************'

! print required input and read argument list ---------------------------------

  WRITE(stdout,'(/,A,/,A,/,8(A,/))') &
    solver_name//' Required Rocflo2Flu input:', &
    solver_name, &
    solver_name//'   <casename>        =>  command line input', &
    solver_name//'   <verbosity>       =>  command line input', &
    solver_name//'   grid level        => .inp file: # MULTIGRID: START', &
    solver_name//'   Rocflo grd format => .inp file: # FORMATS: GRID', &
    solver_name//'   Rocflu grd format => .inp file: # FORMATS: SOLUTION'

  CALL getarg(1,casename)
  CALL getarg(2,verbosity)

  IF (len_trim(casename)==0 .OR. &
      len_trim(verbosity)==0) THEN
    WRITE(stdout,'(/,A,/)') &
      solver_name//' Usage: rflo2flu <casename> <verbosity>'
!#ifdef MPI
!    CALL MPI_Finalize( global%mpierr )
!#endif
    stop
  ENDIF

  READ(casename ,*) global%casename
  READ(verbosity,*) global%verbLevel

! read, check and print user input -------------------------------------------

  WRITE(stdout,'(/,A)') solver_name//' Reading region topology ...'

  CALL rflo_readregiontopology( global,regions )

  WRITE(stdout,'(A)') solver_name//' Reading user input file  ...'

  CALL readinputfile( regions )

  IF (global%verbLevel >= verbose_low) CALL printtofluinput( regions )

  gridlevel = global%startLevel

! check grid level and obtain region grid size --------------------------------

  DO ireg=1,global%nRegions
    IF (regions(ireg)%nGridLevels < gridlevel) THEN
      WRITE(msg,1000) solver_name,ireg,gridlevel
      CALL errorstop( global,err_grid_level,__line__,msg )
    ENDIF
    DO ilev=2,regions(ireg)%nGridLevels
      ipc = regions(ireg)%levels(ilev-1)%grid%ipc
      jpc = regions(ireg)%levels(ilev-1)%grid%jpc
      kpc = regions(ireg)%levels(ilev-1)%grid%kpc
      regions(ireg)%levels(ilev)%grid%ipc = ipc/2
      regions(ireg)%levels(ilev)%grid%jpc = jpc/2
      regions(ireg)%levels(ilev)%grid%kpc = kpc/2
    ENDDO
  ENDDO

! start conversion multi regions Rocflo to single region Rocflu --------------
! obtain sizes of global unstructured grid arrays at whole domain, all patches

  global%tofluNPatches = 0
  global%tofluNHexs    = 0
  global%tofluNVerts   = 0
  global%tofluNbfMax   = 0
  global%tofluNbnMax   = 0
  global%tofluNFaces   = 0
  global%tofluNEdges   = 0

  DO ireg=1,global%nregions
    regions(ireg)%currLevel = gridlevel
    CALL convertflo2flumesh( 0,ireg,regions )
  ENDDO   ! iReg

! allocate unstructured coordinates and connectivities -----------------------

  npatches = global%tofluNPatches
  nverts   = global%tofluNVerts
  nhexs    = global%tofluNHexs
  nbfmax   = global%tofluNbfMax
  nbnmax   = global%tofluNbnMax

  ALLOCATE( global%tofluXyz(3,nverts),stat=errorflag )
  global%error = errorflag
  IF (global%error /= 0) CALL errorstop( global,err_deallocate,__line__ )

  ALLOCATE( global%tofluNbVerts(npatches),stat=errorflag )
  global%error = errorflag
  IF (global%error /= 0) CALL errorstop( global,err_deallocate,__line__ )

  ALLOCATE( global%tofluNbFaces(npatches),stat=errorflag )
  global%error = errorflag
  IF (global%error /= 0) CALL errorstop( global,err_deallocate,__line__ )

  ALLOCATE( global%tofluHex2v(8,nhexs),stat=errorflag )
  global%error = errorflag
  IF (global%error /= 0) CALL errorstop( global,err_deallocate,__line__ )

  ALLOCATE( global%tofluQuad2v(4,nbfmax,npatches),stat=errorflag )
  global%error = errorflag
  IF (global%error /= 0) CALL errorstop( global,err_deallocate,__line__ )

  ALLOCATE( global%tofluBLoc2g(nbnmax,npatches),stat=errorflag )
  global%error = errorflag
  IF (global%error /= 0) CALL errorstop( global,err_deallocate,__line__ )

  ALLOCATE( global%tofluIq(npatches),stat=errorflag )
  global%error = errorflag
  IF (global%error /= 0) CALL errorstop( global,err_deallocate,__line__ )

! generate and store Rocflu files --------------------------------------------

  WRITE(stdout,'(A)') solver_name//' Generating and storing Rocflu files ...'

  global%tofluNPatches   = 0
  global%tofluNHexs      = 0
  global%tofluNVerts     = 0
  global%tofluNbVerts(:) = 0
  global%tofluNbFaces(:) = 0
  global%tofluIq(:)      = 0
  global%tofluMaxBind    = 0

  DO ireg=1,global%nregions
    WRITE(stdout,'(A,I5.5)') solver_name//'   - region ',ireg

    ilev =  regions(ireg)%currLevel
    grid => regions(ireg)%levels(ilev)%grid

    CALL convertflo2flumesh( 1,ireg,regions )

    CALL convertflo2flupatch( ireg,regions )

! - note, only grid%xyz is deallocated, grid%tofluLoc2g is still needed

    DEALLOCATE( grid%xyz,stat=errorflag )
    global%error = errorflag
    IF (global%error /= 0) CALL errorstop( global,err_deallocate,__line__ )

  ENDDO   ! iReg

! correct number of edges per global patch

  ALLOCATE( global%tofluBType(6,global%tofluMaxBind),stat=errorflag )
  global%error = errorflag
  IF (global%error /= 0) CALL errorstop( global,err_deallocate,__line__ )

  global%tofluBType(:,:) = 0  

  DO ireg=1,global%nregions
    CALL getbndverttype( ireg,regions )
  ENDDO

  CALL correctnedges( global )

! write Rocflu files

  CALL writeflugrid( global )
  CALL writefludimens( global )
  CALL writeflucellmap( global )

! finalize --------------------------------------------------------------------

  CALL deregisterfunction( global )

  WRITE(stdout,'(/,A)') solver_name//' Finished.'

!#ifdef MPI
!  CALL MPI_Finalize( global%mpierr )
!#endif

1000 FORMAT(a,' Region ',i5,', grid level= ',i2,'.')

END PROGRAM rocflo_toflu

!******************************************************************************
!
! RCS Revision history:
!
! $Log: TFLU_Main.F90,v $
! Revision 1.6  2008/12/06 08:44:53  mtcampbe
! Updated license.
!
! Revision 1.5  2008/11/19 22:18:03  mtcampbe
! Added Illinois Open Source License/Copyright
!
! Revision 1.4  2006/03/07 03:23:32  wasistho
! enabled serial execution
!
! Revision 1.3  2005/12/21 22:38:02  wasistho
! added writeFluCellMap
!
! Revision 1.2  2004/12/03 03:44:10  wasistho
! rflo_modinterfacestoflu to tflu_modinterfaces
!
! Revision 1.1  2004/12/03 02:59:30  wasistho
! added prefix
!
! Revision 1.1  2004/12/03 00:58:20  wasistho
! lower to upper case
!
! Revision 1.3  2004/08/18 02:14:21  wasistho
! removed explicit dimensions in initializing tofluBType
!
! Revision 1.2  2004/08/18 02:10:20  wasistho
! added new routines to create dimension file
!
! Revision 1.1.1.1  2004/08/17 01:41:39  wasistho
! initial checkin
!
!
!******************************************************************************