TFLU_WriteFluGrid.F90

Go to the documentation of this file.

! *********************************************************************
! * Rocstar Simulation Suite                                          *
! * Copyright@2015, Illinois Rocstar LLC. All rights reserved.        *
! *                                                                   *
! * Illinois Rocstar LLC                                              *
! * Champaign, IL                                                     *
! * www.illinoisrocstar.com                                           *
! * sales@illinoisrocstar.com                                         *
! *                                                                   *
! * License: See LICENSE file in top level of distribution package or *
! * http://opensource.org/licenses/NCSA                               *
! *********************************************************************
! *********************************************************************
! * THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND,   *
! * EXPRESS OR IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES   *
! * OF MERCHANTABILITY, FITNESS FOR A PARTICULAR PURPOSE AND          *
! * NONINFRINGEMENT.  IN NO EVENT SHALL THE CONTRIBUTORS OR           *
! * COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER       *
! * LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE,   *
! * Arising FROM, OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE    *
! * USE OR OTHER DEALINGS WITH THE SOFTWARE.                          *
! *********************************************************************
! ******************************************************************************
!
! Purpose: write unstructured grid file in Rocflu format.
!
! Description: none.
!
! Notes: currently only ASCII Rocflu format is supported.
!
! ******************************************************************************
!
! $Id: TFLU_WriteFluGrid.F90,v 1.4 2008/12/06 08:44:53 mtcampbe Exp $
!
! Copyright: (c) 2004 by the University of Illinois
!
! ******************************************************************************

SUBROUTINE writeflugrid( global )

  USE modparameters
  USE moddatatypes
  USE moderror
  USE modglobal, ONLY: t_global 
  USE modmpi
    
  IMPLICIT NONE

! ... parameters
  TYPE(t_global), POINTER :: global

! ... loop variables
  INTEGER :: ipatch, i, j, k
   
! ... local variables
  CHARACTER(CHRLEN) :: ifilename, sectionstring

  INTEGER :: errorflag, ifile
  INTEGER :: ntets, npris, npyrs, vertflag, hexflag
  INTEGER :: nbtris, nbquads, nbverts, bvflag
  
! ******************************************************************************

  CALL registerfunction(global,'WriteFluGrid',&
  'TFLU_WriteFluGrid.F90')

! start ------------------------------------------------------------------------

  IF ( global%verbLevel > verbose_none ) THEN 
    WRITE(stdout,'(A,1X,A)') solver_name,'Writing ASCII Rocflu grid file...'
  END IF 

  ifile = if_grid

  WRITE(ifilename,'(A,I5.5)') &
        trim(global%outDir)//trim(global%casename)//'.grda_',0

  OPEN(ifile,file=ifilename,form="FORMATTED",status="UNKNOWN",iostat=errorflag)   
  global%error = errorflag        

  IF ( global%error /= err_none ) THEN 
    CALL errorstop(global,err_file_open,__line__,ifilename)
  END IF ! global%error

! header and general information -----------------------------------------------

  IF ( global%verbLevel > verbose_low ) THEN  
    WRITE(stdout,'(A,3X,A)') solver_name,'Header information...'
  END IF ! global%verbLevel 

  sectionstring = '# ROCFLU grid file'  
  WRITE(ifile,'(A)') trim(sectionstring)  

  sectionstring = '# Precision and range'
  WRITE(ifile,'(A)') trim(sectionstring) 
  WRITE(ifile,'(2(I8))') precision(1.0_rfreal),range(1.0_rfreal)

  sectionstring = '# Physical time'
  WRITE(ifile,'(A)') trim(sectionstring) 
  WRITE(ifile,'(E23.16)') global%currentTime 

! dimensions -------------------------------------------------------------------

  ntets = 0
  npris = 0
  npyrs = 0
  sectionstring = '# Dimensions'
  WRITE(ifile,'(A)') trim(sectionstring) 
  WRITE(ifile,'(5(I8))') global%tofluNVerts,ntets,global%tofluNHexs, &
                         npris,npyrs

! coordinates ------------------------------------------------------------------

  IF ( global%verbLevel > verbose_none ) THEN  
    WRITE(stdout,'(A,3X,A)') solver_name,'Coordinates...'
  END IF

  sectionstring = '# Coordinates'
  WRITE(ifile,'(A)') trim(sectionstring) 
  DO i = 1,3
    WRITE(ifile,'(5(E23.16))') (global%tofluXyz(i,j),j=1,global%tofluNVerts)
  END DO

!  vertFlag = 1
!  WRITE(iFile,'(10(I8))') (vertFlag,j=1,global%tofluNVerts)

! connectivity -----------------------------------------------------------------

  IF ( global%tofluNHexs > 0 ) THEN
    IF ( global%verbLevel > verbose_low ) THEN  
      WRITE(stdout,'(A,3X,A)') solver_name,'Hexahedra...'
    END IF

    sectionstring = '# Hexahedra'
    WRITE(ifile,'(A)') trim(sectionstring)  
    DO i = 1,8
      WRITE(ifile,'(10(I8))') (global%tofluHex2v(i,j),j=1,global%tofluNHexs)
    END DO ! i

!    hexFlag = 1
!    WRITE(iFile,'(10(I8))') (hexFlag,j=1,global%tofluNHexs)    
  END IF ! nHexs

! boundary information ---------------------------------------------------------

  IF ( global%verbLevel > verbose_low ) THEN   
    WRITE(stdout,'(A,3X,A)') solver_name,'Boundary information...'   
  END IF

  sectionstring = '# Boundaries'
  WRITE(ifile,'(A)') trim(sectionstring) 
  WRITE(ifile,'(I8)') global%tofluNPatches

  DO ipatch = 1, global%tofluNPatches
    nbtris  = 0
    nbquads = global%tofluNbFaces(ipatch)
!    nBVerts = global%tofluNbVerts(iPatch)

!    WRITE(iFile,'(3(I8))') nBTris, nBQuads, nBVerts
    WRITE(ifile,'(3(I8))') nbtris, nbquads

    IF ( nbquads > 0 ) THEN 
      DO j = 1,4
        WRITE(ifile,'(10(I8))') (global%tofluQuad2v(j,k,ipatch),k=1,nbquads)
      END DO ! j      
    END IF ! bound 

!    WRITE(iFile,'(10(I8))') (global%tofluBLoc2g(k,iPatch),k=1,nBVerts)  

!    bvFlag = 1
!    WRITE(iFile,'(10(I8))') (bvFlag,k=1,nBVerts)           
  ENDDO ! iPatch

! end marker -------------------------------------------------------------------

  IF ( global%verbLevel > verbose_low ) THEN  
    WRITE(stdout,'(A,3X,A)') solver_name,'End marker...'
  END IF

  sectionstring = '# End'
  WRITE(ifile,'(A)') trim(sectionstring) 

! close file -------------------------------------------------------------------

  CLOSE(ifile,iostat=errorflag)
  global%error = errorflag      
  IF ( global%error /= err_none ) THEN 
    CALL errorstop(global,err_file_close,__line__,ifilename)
  END IF

  IF ( global%verbLevel > verbose_none ) THEN   
    WRITE(stdout,'(A,1X,A)') solver_name,'Writing ASCII Rocflu grid file done.'
  END IF

! finalize ---------------------------------------------------------------------

  CALL deregisterfunction( global )
  
END SUBROUTINE writeflugrid

! ******************************************************************************
!
! RCS Revision history:
!
! $Log: TFLU_WriteFluGrid.F90,v $
! Revision 1.4  2008/12/06 08:44:53  mtcampbe
! Updated license.
!
! Revision 1.3  2008/11/19 22:18:04  mtcampbe
! Added Illinois Open Source License/Copyright
!
! Revision 1.2  2005/12/21 19:18:30  wasistho
! modified to adapt changes in Rocflu
!
! Revision 1.1  2004/12/03 02:59:30  wasistho
! added prefix
!
! Revision 1.1  2004/12/03 00:58:20  wasistho
! lower to upper case
!
! Revision 1.1  2004/08/18 02:15:12  wasistho
! added new routines to create dimension file
!
! Revision 1.1.1.1  2004/08/17 01:41:39  wasistho
! initial checkin
!
!
! ******************************************************************************